lib/DBIx/Class/Storage/DBI/SQLAnywhere.pm

   1 package DBIx::Class::Storage::DBI::SQLAnywhere;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI::UniqueIdentifier/;
   6 use mro 'c3';
   7 use List::Util 'first';
   8 use Try::Tiny;
   9 use DBIx::Class::Storage::DBI::SQLAnywhere::Cursor ();
  10 use namespace::clean;
  11
  12 __PACKAGE__->mk_group_accessors(simple => qw/_identity/);
  13 __PACKAGE__->sql_limit_dialect ('RowNumberOver');
  14 __PACKAGE__->sql_quote_char ('"');
  15
  16 __PACKAGE__->new_guid('UUIDTOSTR(NEWID())');
  17
  18 # default to the UUID decoding cursor, overridable by the user
  19 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::SQLAnywhere::Cursor');
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::SQLAnywhere - Driver for SQL Anywhere
  24
  25 =head1 DESCRIPTION
  26
  27 This class implements autoincrements for SQL Anywhere and provides
  28 L<DBIx::Class::InflateColumn::DateTime> support and support for the
  29 C<uniqueidentifier> type (via
  30 L<DBIx::Class::Storage::DBI::SQLAnywhere::Cursor>.)
  31
  32 You need the C<DBD::SQLAnywhere> driver that comes with the SQL Anywhere
  33 distribution, B<NOT> the one on CPAN. It is usually under a path such as:
  34
  35   /opt/sqlanywhere11/sdk/perl
  36
  37 Recommended L<connect_info|DBIx::Class::Storage::DBI/connect_info> settings:
  38
  39   on_connect_call => 'datetime_setup'
  40
  41 =head1 METHODS
  42
  43 =cut
  44
  45 sub last_insert_id { shift->_identity }
  46
  47 sub _prefetch_autovalues {
  48   my $self = shift;
  49   my ($source, $to_insert) = @_;
  50
  51   my $values = $self->next::method(@_);
  52
  53   my $colinfo = $source->columns_info;
  54
  55   my $identity_col =
  56     first { $colinfo->{$_}{is_auto_increment} } keys %$colinfo;
  57
  58 # user might have an identity PK without is_auto_increment
  59 #
  60 # FIXME we probably should not have supported the above, see what
  61 # does it take to move away from it
  62   if (not $identity_col) {
  63     foreach my $pk_col ($source->primary_columns) {
  64       if (
  65         ! exists $to_insert->{$pk_col}
  66           and
  67         $colinfo->{$pk_col}{data_type}
  68           and
  69         $colinfo->{$pk_col}{data_type} !~ /^uniqueidentifier/i
  70       ) {
  71         $identity_col = $pk_col;
  72         last;
  73       }
  74     }
  75   }
  76
  77   if ($identity_col && (not exists $to_insert->{$identity_col})) {
  78     my $dbh = $self->_get_dbh;
  79     my $table_name = $source->from;
  80     $table_name    = $$table_name if ref $table_name;
  81
  82     my ($identity) = try {
  83       $dbh->selectrow_array("SELECT GET_IDENTITY('$table_name')")
  84     };
  85
  86     if (defined $identity) {
  87       $values->{$identity_col} = $identity;
  88       $self->_identity($identity);
  89     }
  90   }
  91
  92   return $values;
  93 }
  94
  95 sub _uuid_to_str {
  96   my ($self, $data) = @_;
  97
  98   $data = unpack 'H*', $data;
  99
 100   for my $pos (8, 13, 18, 23) {
 101     substr($data, $pos, 0) = '-';
 102   }
 103
 104   return $data;
 105 }
 106
 107 # select_single does not invoke a cursor object at all, hence UUID decoding happens
 108 # here if the proper cursor class is set
 109 sub select_single {
 110   my $self = shift;
 111
 112   my @row = $self->next::method(@_);
 113
 114   return @row
 115     unless $self->cursor_class->isa('DBIx::Class::Storage::DBI::SQLAnywhere::Cursor');
 116
 117   my ($ident, $select) = @_;
 118
 119   my $col_info = $self->_resolve_column_info($ident);
 120
 121   for my $select_idx (0..$#$select) {
 122     my $selected = $select->[$select_idx];
 123
 124     next if ref $selected;
 125
 126     my $data_type = $col_info->{$selected}{data_type}
 127       or next;
 128
 129     if ($self->_is_guid_type($data_type)) {
 130       my $returned = $row[$select_idx];
 131
 132       if (length $returned == 16) {
 133         $row[$select_idx] = $self->_uuid_to_str($returned);
 134       }
 135     }
 136   }
 137
 138   return @row;
 139 }
 140
 141 # this sub stolen from MSSQL
 142
 143 sub build_datetime_parser {
 144   my $self = shift;
 145   my $type = "DateTime::Format::Strptime";
 146   try {
 147     eval "require ${type}"
 148   }
 149   catch {
 150     $self->throw_exception("Couldn't load ${type}: $_");
 151   };
 152
 153   return $type->new( pattern => '%Y-%m-%d %H:%M:%S.%6N' );
 154 }
 155
 156 =head2 connect_call_datetime_setup
 157
 158 Used as:
 159
 160     on_connect_call => 'datetime_setup'
 161
 162 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the date and
 163 timestamp formats (as temporary options for the session) for use with
 164 L<DBIx::Class::InflateColumn::DateTime>.
 165
 166 The C<TIMESTAMP> data type supports up to 6 digits after the decimal point for
 167 second precision. The full precision is used.
 168
 169 The C<DATE> data type supposedly stores hours and minutes too, according to the
 170 documentation, but I could not get that to work. It seems to only store the
 171 date.
 172
 173 You will need the L<DateTime::Format::Strptime> module for inflation to work.
 174
 175 =cut
 176
 177 sub connect_call_datetime_setup {
 178   my $self = shift;
 179
 180   $self->_do_query(
 181     "set temporary option timestamp_format = 'yyyy-mm-dd hh:mm:ss.ssssss'"
 182   );
 183   $self->_do_query(
 184     "set temporary option date_format      = 'yyyy-mm-dd hh:mm:ss.ssssss'"
 185   );
 186 }
 187
 188 sub _exec_svp_begin {
 189     my ($self, $name) = @_;
 190
 191     $self->_dbh->do("SAVEPOINT $name");
 192 }
 193
 194 # can't release savepoints that have been rolled back
 195 sub _exec_svp_release { 1 }
 196
 197 sub _exec_svp_rollback {
 198     my ($self, $name) = @_;
 199
 200     $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 201 }
 202
 203 1;
 204
 205 =head1 MAXIMUM CURSORS
 206
 207 A L<DBIx::Class> application can use a lot of cursors, due to the usage of
 208 L<prepare_cached|DBI/prepare_cached>.
 209
 210 The default cursor maximum is C<50>, which can be a bit too low. This limit can
 211 be turned off (or increased) by the DBA by executing:
 212
 213   set option max_statement_count = 0
 214   set option max_cursor_count    = 0
 215
 216 Highly recommended.
 217
 218 =head1 AUTHOR
 219
 220 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 221
 222 =head1 LICENSE
 223
 224 You may distribute this code under the same terms as Perl itself.
 225
 226 =cut