lib/DBIx/Class/Storage/DBI/Replicated/Pool.pm

   1 package DBIx::Class::Storage::DBI::Replicated::Pool;
   2
   3 use Moose;
   4 use MooseX::AttributeHelpers;
   5 use DBIx::Class::Storage::DBI::Replicated::Replicant;
   6 use List::Util 'sum';
   7 use Scalar::Util 'reftype';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use MooseX::Types::Moose qw/Num Int ClassName HashRef/;
  10
  11 use namespace::clean -except => 'meta';
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Storage::DBI::Replicated::Pool - Manage a pool of replicants
  16
  17 =head1 SYNOPSIS
  18
  19 This class is used internally by L<DBIx::Class::Storage::DBI::Replicated>.  You
  20 shouldn't need to create instances of this class.
  21
  22 =head1 DESCRIPTION
  23
  24 In a replicated storage type, there is at least one replicant to handle the
  25 read only traffic.  The Pool class manages this replicant, or list of
  26 replicants, and gives some methods for querying information about their status.
  27
  28 =head1 ATTRIBUTES
  29
  30 This class defines the following attributes.
  31
  32 =head2 maximum_lag ($num)
  33
  34 This is a number which defines the maximum allowed lag returned by the
  35 L<DBIx::Class::Storage::DBI/lag_behind_master> method.  The default is 0.  In
  36 general, this should return a larger number when the replicant is lagging
  37 behind it's master, however the implementation of this is database specific, so
  38 don't count on this number having a fixed meaning.  For example, MySQL will
  39 return a number of seconds that the replicating database is lagging.
  40
  41 =cut
  42
  43 has 'maximum_lag' => (
  44   is=>'rw',
  45   isa=>Num,
  46   required=>1,
  47   lazy=>1,
  48   default=>0,
  49 );
  50
  51 =head2 last_validated
  52
  53 This is an integer representing a time since the last time the replicants were
  54 validated. It's nothing fancy, just an integer provided via the perl time
  55 builtin.
  56
  57 =cut
  58
  59 has 'last_validated' => (
  60   is=>'rw',
  61   isa=>Int,
  62   reader=>'last_validated',
  63   writer=>'_last_validated',
  64   lazy=>1,
  65   default=>0,
  66 );
  67
  68 =head2 replicant_type ($classname)
  69
  70 Base class used to instantiate replicants that are in the pool.  Unless you
  71 need to subclass L<DBIx::Class::Storage::DBI::Replicated::Replicant> you should
  72 just leave this alone.
  73
  74 =cut
  75
  76 has 'replicant_type' => (
  77   is=>'ro',
  78   isa=>ClassName,
  79   required=>1,
  80   default=>'DBIx::Class::Storage::DBI',
  81   handles=>{
  82     'create_replicant' => 'new',
  83   },
  84 );
  85
  86 =head2 replicants
  87
  88 A hashref of replicant, with the key being the dsn and the value returning the
  89 actual replicant storage.  For example if the $dsn element is something like:
  90
  91   "dbi:SQLite:dbname=dbfile"
  92
  93 You could access the specific replicant via:
  94
  95   $schema->storage->replicants->{'dbname=dbfile'}
  96
  97 This attributes also supports the following helper methods:
  98
  99 =over 4
 100
 101 =item set_replicant($key=>$storage)
 102
 103 Pushes a replicant onto the HashRef under $key
 104
 105 =item get_replicant($key)
 106
 107 Retrieves the named replicant
 108
 109 =item has_replicants
 110
 111 Returns true if the Pool defines replicants.
 112
 113 =item num_replicants
 114
 115 The number of replicants in the pool
 116
 117 =item delete_replicant ($key)
 118
 119 removes the replicant under $key from the pool
 120
 121 =back
 122
 123 =cut
 124
 125 has 'replicants' => (
 126   is=>'rw',
 127   metaclass => 'Collection::Hash',
 128   isa=>HashRef['DBIx::Class::Storage::DBI'],
 129   default=>sub {{}},
 130   provides  => {
 131     'set' => 'set_replicant',
 132     'get' => 'get_replicant',
 133     'empty' => 'has_replicants',
 134     'count' => 'num_replicants',
 135     'delete' => 'delete_replicant',
 136   },
 137 );
 138
 139 =head1 METHODS
 140
 141 This class defines the following methods.
 142
 143 =head2 connect_replicants ($schema, Array[$connect_info])
 144
 145 Given an array of $dsn or connect_info structures suitable for connected to a
 146 database, create an L<DBIx::Class::Storage::DBI::Replicated::Replicant> object
 147 and store it in the L</replicants> attribute.
 148
 149 =cut
 150
 151 sub connect_replicants {
 152   my $self = shift @_;
 153   my $schema = shift @_;
 154
 155   my @newly_created = ();
 156   foreach my $connect_info (@_) {
 157     $connect_info = [ $connect_info ]
 158       if reftype $connect_info ne 'ARRAY';
 159
 160     croak "coderef replicant connect_info not supported"
 161       if ref $connect_info->[0] && reftype $connect_info->[0] eq 'CODE';
 162
 163     my $replicant = $self->connect_replicant($schema, $connect_info);
 164
 165     my $key = $connect_info->[0];
 166     $key = $key->{dsn} if ref $key && reftype $key eq 'HASH';
 167     ($key) = ($key =~ m/^dbi\:.+\:(.+)$/);
 168
 169     $self->set_replicant( $key => $replicant);
 170     push @newly_created, $replicant;
 171   }
 172
 173   return @newly_created;
 174 }
 175
 176 =head2 connect_replicant ($schema, $connect_info)
 177
 178 Given a schema object and a hashref of $connect_info, connect the replicant
 179 and return it.
 180
 181 =cut
 182
 183 sub connect_replicant {
 184   my ($self, $schema, $connect_info) = @_;
 185   my $replicant = $self->create_replicant($schema);
 186   $replicant->connect_info($connect_info);
 187
 188 ## It is undesirable for catalyst to connect at ->conect_replicants time, as
 189 ## connections should only happen on the first request that uses the database.
 190 ## So we try to set the driver without connecting, however this doesn't always
 191 ## work, as a driver may need to connect to determine the DB version, and this
 192 ## may fail.
 193
 194   $self->_safely($replicant, '->_determine_driver', sub {
 195     $replicant->_determine_driver
 196   });
 197
 198   DBIx::Class::Storage::DBI::Replicated::Replicant->meta->apply($replicant);
 199   return $replicant;
 200 }
 201
 202 =head2 _safely_ensure_connected ($replicant)
 203
 204 The standard ensure_connected method with throw an exception should it fail to
 205 connect.  For the master database this is desirable, but since replicants are
 206 allowed to fail, this behavior is not desirable.  This method wraps the call
 207 to ensure_connected in an eval in order to catch any generated errors.  That
 208 way a slave can go completely offline (ie, the box itself can die) without
 209 bringing down your entire pool of databases.
 210
 211 =cut
 212
 213 sub _safely_ensure_connected {
 214   my ($self, $replicant, @args) = @_;
 215
 216   return $self->_safely($replicant, '->ensure_connected', sub {
 217     $replicant->ensure_connected(@args)
 218   });
 219 }
 220
 221 =head2 _safely ($replicant, $name, $code)
 222
 223 Execute C<$code> for operation C<$name> catching any exceptions and printing an
 224 error message to the C<<$replicant->debugobj>>.
 225
 226 Returns 1 on success and undef on failure.
 227
 228 =cut
 229
 230 sub _safely {
 231   my ($self, $replicant, $name, $code) = @_;
 232
 233   eval {
 234     $code->()
 235   };
 236   if ($@) {
 237     $replicant
 238       ->debugobj
 239       ->print(
 240         sprintf( "Exception trying to $name for replicant %s, error is %s",
 241           $replicant->_dbi_connect_info->[0], $@)
 242         );
 243         return;
 244   }
 245   return 1;
 246 }
 247
 248 =head2 connected_replicants
 249
 250 Returns true if there are connected replicants.  Actually is overloaded to
 251 return the number of replicants.  So you can do stuff like:
 252
 253   if( my $num_connected = $storage->has_connected_replicants ) {
 254     print "I have $num_connected connected replicants";
 255   } else {
 256     print "Sorry, no replicants.";
 257   }
 258
 259 This method will actually test that each replicant in the L</replicants> hashref
 260 is actually connected, try not to hit this 10 times a second.
 261
 262 =cut
 263
 264 sub connected_replicants {
 265   my $self = shift @_;
 266   return sum( map {
 267     $_->connected ? 1:0
 268   } $self->all_replicants );
 269 }
 270
 271 =head2 active_replicants
 272
 273 This is an array of replicants that are considered to be active in the pool.
 274 This does not check to see if they are connected, but if they are not, DBIC
 275 should automatically reconnect them for us when we hit them with a query.
 276
 277 =cut
 278
 279 sub active_replicants {
 280   my $self = shift @_;
 281   return ( grep {$_} map {
 282     $_->active ? $_:0
 283   } $self->all_replicants );
 284 }
 285
 286 =head2 all_replicants
 287
 288 Just a simple array of all the replicant storages.  No particular order to the
 289 array is given, nor should any meaning be derived.
 290
 291 =cut
 292
 293 sub all_replicants {
 294   my $self = shift @_;
 295   return values %{$self->replicants};
 296 }
 297
 298 =head2 validate_replicants
 299
 300 This does a check to see if 1) each replicate is connected (or reconnectable),
 301 2) that is ->is_replicating, and 3) that it is not exceeding the lag amount
 302 defined by L</maximum_lag>.  Replicants that fail any of these tests are set to
 303 inactive, and thus removed from the replication pool.
 304
 305 This tests L<all_replicants>, since a replicant that has been previous marked
 306 as inactive can be reactived should it start to pass the validation tests again.
 307
 308 See L<DBIx::Class::Storage::DBI> for more about checking if a replicating
 309 connection is not following a master or is lagging.
 310
 311 Calling this method will generate queries on the replicant databases so it is
 312 not recommended that you run them very often.
 313
 314 This method requires that your underlying storage engine supports some sort of
 315 native replication mechanism.  Currently only MySQL native replication is
 316 supported.  Your patches to make other replication types work are welcomed.
 317
 318 =cut
 319
 320 sub validate_replicants {
 321   my $self = shift @_;
 322   foreach my $replicant($self->all_replicants) {
 323     if($self->_safely_ensure_connected($replicant)) {
 324       my $is_replicating = $replicant->is_replicating;
 325       unless(defined $is_replicating) {
 326         $replicant->debugobj->print("Storage Driver ".ref($self)." Does not support the 'is_replicating' method.  Assuming you are manually managing.\n");
 327         next;
 328       } else {
 329         if($is_replicating) {
 330           my $lag_behind_master = $replicant->lag_behind_master;
 331           unless(defined $lag_behind_master) {
 332             $replicant->debugobj->print("Storage Driver ".ref($self)." Does not support the 'lag_behind_master' method.  Assuming you are manually managing.\n");
 333             next;
 334           } else {
 335             if($lag_behind_master <= $self->maximum_lag) {
 336               $replicant->active(1);
 337             } else {
 338               $replicant->active(0);
 339             }
 340           }
 341         } else {
 342           $replicant->active(0);
 343         }
 344       }
 345     } else {
 346       $replicant->active(0);
 347     }
 348   }
 349   ## Mark that we completed this validation.
 350   $self->_last_validated(time);
 351 }
 352
 353 =head1 AUTHOR
 354
 355 John Napiorkowski <john.napiorkowski@takkle.com>
 356
 357 =head1 LICENSE
 358
 359 You may distribute this code under the same terms as Perl itself.
 360
 361 =cut
 362
 363 __PACKAGE__->meta->make_immutable;
 364
 365 1;