lib/DBIx/Class/Storage/DBI/Replicated/Pool.pm

   1 package DBIx::Class::Storage::DBI::Replicated::Pool;
   2
   3 use Moose;
   4 use DBIx::Class::Storage::DBI::Replicated::Replicant;
   5 use List::Util 'sum';
   6 use Scalar::Util 'reftype';
   7 use DBI ();
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use MooseX::Types::Moose qw/Num Int ClassName HashRef/;
  10 use DBIx::Class::Storage::DBI::Replicated::Types 'DBICStorageDBI';
  11
  12 use namespace::clean -except => 'meta';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Storage::DBI::Replicated::Pool - Manage a pool of replicants
  17
  18 =head1 SYNOPSIS
  19
  20 This class is used internally by L<DBIx::Class::Storage::DBI::Replicated>.  You
  21 shouldn't need to create instances of this class.
  22
  23 =head1 DESCRIPTION
  24
  25 In a replicated storage type, there is at least one replicant to handle the
  26 read only traffic.  The Pool class manages this replicant, or list of
  27 replicants, and gives some methods for querying information about their status.
  28
  29 =head1 ATTRIBUTES
  30
  31 This class defines the following attributes.
  32
  33 =head2 maximum_lag ($num)
  34
  35 This is a number which defines the maximum allowed lag returned by the
  36 L<DBIx::Class::Storage::DBI/lag_behind_master> method.  The default is 0.  In
  37 general, this should return a larger number when the replicant is lagging
  38 behind its master, however the implementation of this is database specific, so
  39 don't count on this number having a fixed meaning.  For example, MySQL will
  40 return a number of seconds that the replicating database is lagging.
  41
  42 =cut
  43
  44 has 'maximum_lag' => (
  45   is=>'rw',
  46   isa=>Num,
  47   required=>1,
  48   lazy=>1,
  49   default=>0,
  50 );
  51
  52 =head2 last_validated
  53
  54 This is an integer representing a time since the last time the replicants were
  55 validated. It's nothing fancy, just an integer provided via the perl L<time|perlfunc/time>
  56 builtin.
  57
  58 =cut
  59
  60 has 'last_validated' => (
  61   is=>'rw',
  62   isa=>Int,
  63   reader=>'last_validated',
  64   writer=>'_last_validated',
  65   lazy=>1,
  66   default=>0,
  67 );
  68
  69 =head2 replicant_type ($classname)
  70
  71 Base class used to instantiate replicants that are in the pool.  Unless you
  72 need to subclass L<DBIx::Class::Storage::DBI::Replicated::Replicant> you should
  73 just leave this alone.
  74
  75 =cut
  76
  77 has 'replicant_type' => (
  78   is=>'ro',
  79   isa=>ClassName,
  80   required=>1,
  81   default=>'DBIx::Class::Storage::DBI',
  82   handles=>{
  83     'create_replicant' => 'new',
  84   },
  85 );
  86
  87 =head2 replicants
  88
  89 A hashref of replicant, with the key being the dsn and the value returning the
  90 actual replicant storage.  For example if the $dsn element is something like:
  91
  92   "dbi:SQLite:dbname=dbfile"
  93
  94 You could access the specific replicant via:
  95
  96   $schema->storage->replicants->{'dbname=dbfile'}
  97
  98 This attributes also supports the following helper methods:
  99
 100 =over 4
 101
 102 =item set_replicant($key=>$storage)
 103
 104 Pushes a replicant onto the HashRef under $key
 105
 106 =item get_replicant($key)
 107
 108 Retrieves the named replicant
 109
 110 =item has_replicants
 111
 112 Returns true if the Pool defines replicants.
 113
 114 =item num_replicants
 115
 116 The number of replicants in the pool
 117
 118 =item delete_replicant ($key)
 119
 120 removes the replicant under $key from the pool
 121
 122 =back
 123
 124 =cut
 125
 126 has 'replicants' => (
 127   is=>'rw',
 128   traits => ['Hash'],
 129   isa=>HashRef['Object'],
 130   default=>sub {{}},
 131   handles  => {
 132     'set_replicant' => 'set',
 133     'get_replicant' => 'get',
 134     'has_replicants' => 'is_empty',
 135     'num_replicants' => 'count',
 136     'delete_replicant' => 'delete',
 137     'all_replicant_storages' => 'values',
 138   },
 139 );
 140
 141 around has_replicants => sub {
 142     my ($orig, $self) = @_;
 143     return !$self->$orig;
 144 };
 145
 146 has next_unknown_replicant_id => (
 147   is => 'rw',
 148   traits => ['Counter'],
 149   isa => Int,
 150   default => 1,
 151   handles => {
 152     'inc_unknown_replicant_id' => 'inc',
 153   },
 154 );
 155
 156 =head2 master
 157
 158 Reference to the master Storage.
 159
 160 =cut
 161
 162 has master => (is => 'rw', isa => DBICStorageDBI, weak_ref => 1);
 163
 164 =head1 METHODS
 165
 166 This class defines the following methods.
 167
 168 =head2 connect_replicants ($schema, Array[$connect_info])
 169
 170 Given an array of $dsn or connect_info structures suitable for connected to a
 171 database, create an L<DBIx::Class::Storage::DBI::Replicated::Replicant> object
 172 and store it in the L</replicants> attribute.
 173
 174 =cut
 175
 176 sub connect_replicants {
 177   my $self = shift @_;
 178   my $schema = shift @_;
 179
 180   my @newly_created = ();
 181   foreach my $connect_info (@_) {
 182     $connect_info = [ $connect_info ]
 183       if reftype $connect_info ne 'ARRAY';
 184
 185     my $connect_coderef =
 186       (reftype($connect_info->[0])||'') eq 'CODE' ? $connect_info->[0]
 187         : (reftype($connect_info->[0])||'') eq 'HASH' &&
 188           $connect_info->[0]->{dbh_maker};
 189
 190     my $dsn;
 191     my $replicant = do {
 192 # yes this is evil, but it only usually happens once (for coderefs)
 193 # this will fail if the coderef does not actually DBI::connect
 194       no warnings 'redefine';
 195       my $connect = \&DBI::connect;
 196       local *DBI::connect = sub {
 197         $dsn = $_[1];
 198         goto $connect;
 199       };
 200       $self->connect_replicant($schema, $connect_info);
 201     };
 202
 203     my $key;
 204
 205     if (!$dsn) {
 206       if (!$connect_coderef) {
 207         $dsn = $connect_info->[0];
 208         $dsn = $dsn->{dsn} if (reftype($dsn)||'') eq 'HASH';
 209       }
 210       else {
 211         # all attempts to get the DSN failed
 212         $key = "UNKNOWN_" . $self->next_unknown_replicant_id;
 213         $self->inc_unknown_replicant_id;
 214       }
 215     }
 216     if ($dsn) {
 217       $replicant->dsn($dsn);
 218       ($key) = ($dsn =~ m/^dbi\:.+\:(.+)$/i);
 219     }
 220
 221     $replicant->id($key);
 222     $self->set_replicant($key => $replicant);
 223
 224     push @newly_created, $replicant;
 225   }
 226
 227   return @newly_created;
 228 }
 229
 230 =head2 connect_replicant ($schema, $connect_info)
 231
 232 Given a schema object and a hashref of $connect_info, connect the replicant
 233 and return it.
 234
 235 =cut
 236
 237 sub connect_replicant {
 238   my ($self, $schema, $connect_info) = @_;
 239   my $replicant = $self->create_replicant($schema);
 240   $replicant->connect_info($connect_info);
 241
 242 ## It is undesirable for catalyst to connect at ->conect_replicants time, as
 243 ## connections should only happen on the first request that uses the database.
 244 ## So we try to set the driver without connecting, however this doesn't always
 245 ## work, as a driver may need to connect to determine the DB version, and this
 246 ## may fail.
 247 ##
 248 ## Why this is necessary at all, is that we need to have the final storage
 249 ## class to apply the Replicant role.
 250
 251   $self->_safely($replicant, '->_determine_driver', sub {
 252     $replicant->_determine_driver
 253   });
 254
 255   Moose::Meta::Class->initialize(ref $replicant);
 256
 257   my $class = Moose::Meta::Class->create_anon_class(
 258     superclasses => [ ref $replicant ],
 259     roles        => [ 'DBIx::Class::Storage::DBI::Replicated::Replicant' ],
 260     cache        => 1,
 261   );
 262   $class->rebless_instance($replicant);
 263
 264   # link back to master
 265   $replicant->master($self->master);
 266
 267   return $replicant;
 268 }
 269
 270 =head2 _safely_ensure_connected ($replicant)
 271
 272 The standard ensure_connected method with throw an exception should it fail to
 273 connect.  For the master database this is desirable, but since replicants are
 274 allowed to fail, this behavior is not desirable.  This method wraps the call
 275 to ensure_connected in an eval in order to catch any generated errors.  That
 276 way a slave can go completely offline (ie, the box itself can die) without
 277 bringing down your entire pool of databases.
 278
 279 =cut
 280
 281 sub _safely_ensure_connected {
 282   my ($self, $replicant, @args) = @_;
 283
 284   return $self->_safely($replicant, '->ensure_connected', sub {
 285     $replicant->ensure_connected(@args)
 286   });
 287 }
 288
 289 =head2 _safely ($replicant, $name, $code)
 290
 291 Execute C<$code> for operation C<$name> catching any exceptions and printing an
 292 error message to the C<<$replicant->debugobj>>.
 293
 294 Returns 1 on success and undef on failure.
 295
 296 =cut
 297
 298 sub _safely {
 299   my ($self, $replicant, $name, $code) = @_;
 300
 301   eval {
 302     $code->()
 303   };
 304   if ($@) {
 305     $replicant->debugobj->print(sprintf(
 306       "Exception trying to $name for replicant %s, error is %s",
 307       $replicant->_dbi_connect_info->[0], $@)
 308     );
 309     return undef;
 310   }
 311
 312   return 1;
 313 }
 314
 315 =head2 connected_replicants
 316
 317 Returns true if there are connected replicants.  Actually is overloaded to
 318 return the number of replicants.  So you can do stuff like:
 319
 320   if( my $num_connected = $storage->has_connected_replicants ) {
 321     print "I have $num_connected connected replicants";
 322   } else {
 323     print "Sorry, no replicants.";
 324   }
 325
 326 This method will actually test that each replicant in the L</replicants> hashref
 327 is actually connected, try not to hit this 10 times a second.
 328
 329 =cut
 330
 331 sub connected_replicants {
 332   my $self = shift @_;
 333   return sum( map {
 334     $_->connected ? 1:0
 335   } $self->all_replicants );
 336 }
 337
 338 =head2 active_replicants
 339
 340 This is an array of replicants that are considered to be active in the pool.
 341 This does not check to see if they are connected, but if they are not, DBIC
 342 should automatically reconnect them for us when we hit them with a query.
 343
 344 =cut
 345
 346 sub active_replicants {
 347   my $self = shift @_;
 348   return ( grep {$_} map {
 349     $_->active ? $_:0
 350   } $self->all_replicants );
 351 }
 352
 353 =head2 all_replicants
 354
 355 Just a simple array of all the replicant storages.  No particular order to the
 356 array is given, nor should any meaning be derived.
 357
 358 =cut
 359
 360 sub all_replicants {
 361   my $self = shift @_;
 362   return values %{$self->replicants};
 363 }
 364
 365 =head2 validate_replicants
 366
 367 This does a check to see if 1) each replicate is connected (or reconnectable),
 368 2) that is ->is_replicating, and 3) that it is not exceeding the lag amount
 369 defined by L</maximum_lag>.  Replicants that fail any of these tests are set to
 370 inactive, and thus removed from the replication pool.
 371
 372 This tests L<all_replicants>, since a replicant that has been previous marked
 373 as inactive can be reactived should it start to pass the validation tests again.
 374
 375 See L<DBIx::Class::Storage::DBI> for more about checking if a replicating
 376 connection is not following a master or is lagging.
 377
 378 Calling this method will generate queries on the replicant databases so it is
 379 not recommended that you run them very often.
 380
 381 This method requires that your underlying storage engine supports some sort of
 382 native replication mechanism.  Currently only MySQL native replication is
 383 supported.  Your patches to make other replication types work are welcomed.
 384
 385 =cut
 386
 387 sub validate_replicants {
 388   my $self = shift @_;
 389   foreach my $replicant($self->all_replicants) {
 390     if($self->_safely_ensure_connected($replicant)) {
 391       my $is_replicating = $replicant->is_replicating;
 392       unless(defined $is_replicating) {
 393         $replicant->debugobj->print("Storage Driver ".ref($self)." Does not support the 'is_replicating' method.  Assuming you are manually managing.\n");
 394         next;
 395       } else {
 396         if($is_replicating) {
 397           my $lag_behind_master = $replicant->lag_behind_master;
 398           unless(defined $lag_behind_master) {
 399             $replicant->debugobj->print("Storage Driver ".ref($self)." Does not support the 'lag_behind_master' method.  Assuming you are manually managing.\n");
 400             next;
 401           } else {
 402             if($lag_behind_master <= $self->maximum_lag) {
 403               $replicant->active(1);
 404             } else {
 405               $replicant->active(0);
 406             }
 407           }
 408         } else {
 409           $replicant->active(0);
 410         }
 411       }
 412     } else {
 413       $replicant->active(0);
 414     }
 415   }
 416   ## Mark that we completed this validation.
 417   $self->_last_validated(time);
 418 }
 419
 420 =head1 AUTHOR
 421
 422 John Napiorkowski <john.napiorkowski@takkle.com>
 423
 424 =head1 LICENSE
 425
 426 You may distribute this code under the same terms as Perl itself.
 427
 428 =cut
 429
 430 __PACKAGE__->meta->make_immutable;
 431
 432 1;