lib/DBIx/Class/Storage/DBI/Replicated.pm

   1 package DBIx::Class::Storage::DBI::Replicated;
   2
   3 BEGIN {
   4   use Carp::Clan qw/^DBIx::Class/;
   5
   6   ## Modules required for Replication support not required for general DBIC
   7   ## use, so we explicitly test for these.
   8
   9   my %replication_required = (
  10     Moose => '0.77',
  11     MooseX::AttributeHelpers => '0.12',
  12     MooseX::Types => '0.10',
  13     namespace::clean => '0.11',
  14     Hash::Merge => '0.11'
  15   );
  16
  17   my @didnt_load;
  18
  19   for my $module (keys %replication_required) {
  20         eval "use $module $replication_required{$module}";
  21         push @didnt_load, "$module $replication_required{$module}"
  22          if $@;
  23   }
  24
  25   croak("@{[ join ', ', @didnt_load ]} are missing and are required for Replication")
  26     if @didnt_load;
  27 }
  28
  29 use Moose;
  30 use DBIx::Class::Storage::DBI;
  31 use DBIx::Class::Storage::DBI::Replicated::Pool;
  32 use DBIx::Class::Storage::DBI::Replicated::Balancer;
  33 use DBIx::Class::Storage::DBI::Replicated::Types 'BalancerClassNamePart';
  34 use MooseX::Types::Moose qw/ClassName HashRef Object/;
  35 use Scalar::Util 'reftype';
  36 use Carp::Clan qw/^DBIx::Class/;
  37 use Hash::Merge 'merge';
  38
  39 use namespace::clean -except => 'meta';
  40
  41 =head1 NAME
  42
  43 DBIx::Class::Storage::DBI::Replicated - BETA Replicated database support
  44
  45 =head1 SYNOPSIS
  46
  47 The Following example shows how to change an existing $schema to a replicated
  48 storage type, add some replicated (readonly) databases, and perform reporting
  49 tasks.
  50
  51   ## Change storage_type in your schema class
  52   $schema->storage_type( ['::DBI::Replicated', {balancer=>'::Random'}] );
  53
  54   ## Add some slaves.  Basically this is an array of arrayrefs, where each
  55   ## arrayref is database connect information
  56
  57   $schema->storage->connect_replicants(
  58     [$dsn1, $user, $pass, \%opts],
  59     [$dsn2, $user, $pass, \%opts],
  60     [$dsn3, $user, $pass, \%opts],
  61   );
  62
  63   ## Now, just use the $schema as normal
  64   $schema->resultset('Source')->search({name=>'etc'});
  65
  66   ## You can force a given query to use a particular storage using the search
  67   ### attribute 'force_pool'.  For example:
  68
  69   my $RS = $schema->resultset('Source')->search(undef, {force_pool=>'master'});
  70
  71   ## Now $RS will force everything (both reads and writes) to use whatever was
  72   ## setup as the master storage.  'master' is hardcoded to always point to the
  73   ## Master, but you can also use any Replicant name.  Please see:
  74   ## L<DBIx::Class::Storage::Replicated::Pool> and the replicants attribute for
  75   ## More. Also see transactions and L</execute_reliably> for alternative ways
  76   ## to force read traffic to the master.
  77
  78 =head1 DESCRIPTION
  79
  80 Warning: This class is marked BETA.  This has been running a production
  81 website using MySQL native replication as its backend and we have some decent
  82 test coverage but the code hasn't yet been stressed by a variety of databases.
  83 Individual DB's may have quirks we are not aware of.  Please use this in first
  84 development and pass along your experiences/bug fixes.
  85
  86 This class implements replicated data store for DBI. Currently you can define
  87 one master and numerous slave database connections. All write-type queries
  88 (INSERT, UPDATE, DELETE and even LAST_INSERT_ID) are routed to master
  89 database, all read-type queries (SELECTs) go to the slave database.
  90
  91 Basically, any method request that L<DBIx::Class::Storage::DBI> would normally
  92 handle gets delegated to one of the two attributes: L</read_handler> or to
  93 L</write_handler>.  Additionally, some methods need to be distributed
  94 to all existing storages.  This way our storage class is a drop in replacement
  95 for L<DBIx::Class::Storage::DBI>.
  96
  97 Read traffic is spread across the replicants (slaves) occuring to a user
  98 selected algorithm.  The default algorithm is random weighted.
  99
 100 =head1 NOTES
 101
 102 The consistancy betweeen master and replicants is database specific.  The Pool
 103 gives you a method to validate it's replicants, removing and replacing them
 104 when they fail/pass predefined criteria.  Please make careful use of the ways
 105 to force a query to run against Master when needed.
 106
 107 =head1 REQUIREMENTS
 108
 109 Replicated Storage has additional requirements not currently part of L<DBIx::Class>
 110
 111   Moose => 0.77
 112   MooseX::AttributeHelpers => 0.12
 113   MooseX::Types => 0.10
 114   namespace::clean => 0.11
 115   Hash::Merge => 0.11
 116
 117 You will need to install these modules manually via CPAN or make them part of the
 118 Makefile for your distribution.
 119
 120 =head1 ATTRIBUTES
 121
 122 This class defines the following attributes.
 123
 124 =head2 schema
 125
 126 The underlying L<DBIx::Class::Schema> object this storage is attaching
 127
 128 =cut
 129
 130 has 'schema' => (
 131     is=>'rw',
 132     isa=>'DBIx::Class::Schema',
 133     weak_ref=>1,
 134     required=>1,
 135 );
 136
 137 =head2 pool_type
 138
 139 Contains the classname which will instantiate the L</pool> object.  Defaults
 140 to: L<DBIx::Class::Storage::DBI::Replicated::Pool>.
 141
 142 =cut
 143
 144 has 'pool_type' => (
 145   is=>'rw',
 146   isa=>ClassName,
 147   default=>'DBIx::Class::Storage::DBI::Replicated::Pool',
 148   handles=>{
 149     'create_pool' => 'new',
 150   },
 151 );
 152
 153 =head2 pool_args
 154
 155 Contains a hashref of initialized information to pass to the Balancer object.
 156 See L<DBIx::Class::Storage::Replicated::Pool> for available arguments.
 157
 158 =cut
 159
 160 has 'pool_args' => (
 161   is=>'rw',
 162   isa=>HashRef,
 163   lazy=>1,
 164   default=>sub { {} },
 165 );
 166
 167
 168 =head2 balancer_type
 169
 170 The replication pool requires a balance class to provider the methods for
 171 choose how to spread the query load across each replicant in the pool.
 172
 173 =cut
 174
 175 has 'balancer_type' => (
 176   is=>'rw',
 177   isa=>BalancerClassNamePart,
 178   coerce=>1,
 179   required=>1,
 180   default=> 'DBIx::Class::Storage::DBI::Replicated::Balancer::First',
 181   handles=>{
 182     'create_balancer' => 'new',
 183   },
 184 );
 185
 186 =head2 balancer_args
 187
 188 Contains a hashref of initialized information to pass to the Balancer object.
 189 See L<DBIx::Class::Storage::Replicated::Balancer> for available arguments.
 190
 191 =cut
 192
 193 has 'balancer_args' => (
 194   is=>'rw',
 195   isa=>HashRef,
 196   lazy=>1,
 197   required=>1,
 198   default=>sub { {} },
 199 );
 200
 201 =head2 pool
 202
 203 Is a <DBIx::Class::Storage::DBI::Replicated::Pool> or derived class.  This is a
 204 container class for one or more replicated databases.
 205
 206 =cut
 207
 208 has 'pool' => (
 209   is=>'ro',
 210   isa=>'DBIx::Class::Storage::DBI::Replicated::Pool',
 211   lazy_build=>1,
 212   handles=>[qw/
 213     connect_replicants
 214     replicants
 215     has_replicants
 216   /],
 217 );
 218
 219 =head2 balancer
 220
 221 Is a <DBIx::Class::Storage::DBI::Replicated::Balancer> or derived class.  This
 222 is a class that takes a pool (<DBIx::Class::Storage::DBI::Replicated::Pool>)
 223
 224 =cut
 225
 226 has 'balancer' => (
 227   is=>'rw',
 228   isa=>'DBIx::Class::Storage::DBI::Replicated::Balancer',
 229   lazy_build=>1,
 230   handles=>[qw/auto_validate_every/],
 231 );
 232
 233 =head2 master
 234
 235 The master defines the canonical state for a pool of connected databases.  All
 236 the replicants are expected to match this databases state.  Thus, in a classic
 237 Master / Slaves distributed system, all the slaves are expected to replicate
 238 the Master's state as quick as possible.  This is the only database in the
 239 pool of databases that is allowed to handle write traffic.
 240
 241 =cut
 242
 243 has 'master' => (
 244   is=> 'ro',
 245   isa=>'DBIx::Class::Storage::DBI',
 246   lazy_build=>1,
 247 );
 248
 249 =head1 ATTRIBUTES IMPLEMENTING THE DBIx::Storage::DBI INTERFACE
 250
 251 The following methods are delegated all the methods required for the
 252 L<DBIx::Class::Storage::DBI> interface.
 253
 254 =head2 read_handler
 255
 256 Defines an object that implements the read side of L<BIx::Class::Storage::DBI>.
 257
 258 =cut
 259
 260 has 'read_handler' => (
 261   is=>'rw',
 262   isa=>Object,
 263   lazy_build=>1,
 264   handles=>[qw/
 265     select
 266     select_single
 267     columns_info_for
 268   /],
 269 );
 270
 271 =head2 write_handler
 272
 273 Defines an object that implements the write side of L<BIx::Class::Storage::DBI>.
 274
 275 =cut
 276
 277 has 'write_handler' => (
 278   is=>'ro',
 279   isa=>Object,
 280   lazy_build=>1,
 281   handles=>[qw/
 282     on_connect_do
 283     on_disconnect_do
 284     connect_info
 285     throw_exception
 286     sql_maker
 287     sqlt_type
 288     create_ddl_dir
 289     deployment_statements
 290     datetime_parser
 291     datetime_parser_type
 292     last_insert_id
 293     insert
 294     insert_bulk
 295     update
 296     delete
 297     dbh
 298     txn_begin
 299     txn_do
 300     txn_commit
 301     txn_rollback
 302     txn_scope_guard
 303     sth
 304     deploy
 305     with_deferred_fk_checks
 306
 307     reload_row
 308     _prep_for_execute
 309
 310   /],
 311 );
 312
 313 has _master_connect_info_opts =>
 314   (is => 'rw', isa => HashRef, default => sub { {} });
 315
 316 =head2 around: connect_info
 317
 318 Preserve master's C<connect_info> options (for merging with replicants.)
 319 Also set any Replicated related options from connect_info, such as
 320 C<pool_type>, C<pool_args>, C<balancer_type> and C<balancer_args>.
 321
 322 =cut
 323
 324 around connect_info => sub {
 325   my ($next, $self, $info, @extra) = @_;
 326
 327   my $wantarray = wantarray;
 328
 329   my %opts;
 330   for my $arg (@$info) {
 331     next unless (reftype($arg)||'') eq 'HASH';
 332     %opts = %{ merge($arg, \%opts) };
 333   }
 334   delete $opts{dsn};
 335
 336   if (@opts{qw/pool_type pool_args/}) {
 337     $self->pool_type(delete $opts{pool_type})
 338       if $opts{pool_type};
 339
 340     $self->pool_args(
 341       merge((delete $opts{pool_args} || {}), $self->pool_args)
 342     );
 343
 344     $self->pool($self->_build_pool)
 345         if $self->pool;
 346   }
 347
 348   if (@opts{qw/balancer_type balancer_args/}) {
 349     $self->balancer_type(delete $opts{balancer_type})
 350       if $opts{balancer_type};
 351
 352     $self->balancer_args(
 353       merge((delete $opts{balancer_args} || {}), $self->balancer_args)
 354     );
 355
 356     $self->balancer($self->_build_balancer)
 357         if $self->balancer;
 358   }
 359
 360   $self->_master_connect_info_opts(\%opts);
 361
 362   my (@res, $res);
 363   if ($wantarray) {
 364     @res = $self->$next($info, @extra);
 365   } else {
 366     $res = $self->$next($info, @extra);
 367   }
 368
 369   # Make sure master is blessed into the correct class and apply role to it.
 370   my $master = $self->master;
 371   $master->_determine_driver;
 372   Moose::Meta::Class->initialize(ref $master);
 373   DBIx::Class::Storage::DBI::Replicated::WithDSN->meta->apply($master);
 374
 375   $wantarray ? @res : $res;
 376 };
 377
 378 =head1 METHODS
 379
 380 This class defines the following methods.
 381
 382 =head2 BUILDARGS
 383
 384 L<DBIx::Class::Schema> when instantiating it's storage passed itself as the
 385 first argument.  So we need to massage the arguments a bit so that all the
 386 bits get put into the correct places.
 387
 388 =cut
 389
 390 sub BUILDARGS {
 391   my ($class, $schema, $storage_type_args, @args) = @_;
 392
 393   return {
 394         schema=>$schema,
 395         %$storage_type_args,
 396         @args
 397   }
 398 }
 399
 400 =head2 _build_master
 401
 402 Lazy builder for the L</master> attribute.
 403
 404 =cut
 405
 406 sub _build_master {
 407   my $self = shift @_;
 408   my $master = DBIx::Class::Storage::DBI->new($self->schema);
 409   $master
 410 }
 411
 412 =head2 _build_pool
 413
 414 Lazy builder for the L</pool> attribute.
 415
 416 =cut
 417
 418 sub _build_pool {
 419   my $self = shift @_;
 420   $self->create_pool(%{$self->pool_args});
 421 }
 422
 423 =head2 _build_balancer
 424
 425 Lazy builder for the L</balancer> attribute.  This takes a Pool object so that
 426 the balancer knows which pool it's balancing.
 427
 428 =cut
 429
 430 sub _build_balancer {
 431   my $self = shift @_;
 432   $self->create_balancer(
 433     pool=>$self->pool,
 434     master=>$self->master,
 435     %{$self->balancer_args},
 436   );
 437 }
 438
 439 =head2 _build_write_handler
 440
 441 Lazy builder for the L</write_handler> attribute.  The default is to set this to
 442 the L</master>.
 443
 444 =cut
 445
 446 sub _build_write_handler {
 447   return shift->master;
 448 }
 449
 450 =head2 _build_read_handler
 451
 452 Lazy builder for the L</read_handler> attribute.  The default is to set this to
 453 the L</balancer>.
 454
 455 =cut
 456
 457 sub _build_read_handler {
 458   return shift->balancer;
 459 }
 460
 461 =head2 around: connect_replicants
 462
 463 All calls to connect_replicants needs to have an existing $schema tacked onto
 464 top of the args, since L<DBIx::Storage::DBI> needs it, and any C<connect_info>
 465 options merged with the master, with replicant opts having higher priority.
 466
 467 =cut
 468
 469 around connect_replicants => sub {
 470   my ($next, $self, @args) = @_;
 471
 472   for my $r (@args) {
 473     $r = [ $r ] unless reftype $r eq 'ARRAY';
 474
 475     croak "coderef replicant connect_info not supported"
 476       if ref $r->[0] && reftype $r->[0] eq 'CODE';
 477
 478 # any connect_info options?
 479     my $i = 0;
 480     $i++ while $i < @$r && (reftype($r->[$i])||'') ne 'HASH';
 481
 482 # make one if none
 483     $r->[$i] = {} unless $r->[$i];
 484
 485 # merge if two hashes
 486     my @hashes = @$r[$i .. $#{$r}];
 487
 488     croak "invalid connect_info options"
 489       if (grep { reftype($_) eq 'HASH' } @hashes) != @hashes;
 490
 491     croak "too many hashrefs in connect_info"
 492       if @hashes > 2;
 493
 494     my %opts = %{ merge(reverse @hashes) };
 495
 496 # delete them
 497     splice @$r, $i+1, ($#{$r} - $i), ();
 498
 499 # merge with master
 500     %opts = %{ merge(\%opts, $self->_master_connect_info_opts) };
 501
 502 # update
 503     $r->[$i] = \%opts;
 504   }
 505
 506   $self->$next($self->schema, @args);
 507 };
 508
 509 =head2 all_storages
 510
 511 Returns an array of of all the connected storage backends.  The first element
 512 in the returned array is the master, and the remainings are each of the
 513 replicants.
 514
 515 =cut
 516
 517 sub all_storages {
 518   my $self = shift @_;
 519   return grep {defined $_ && blessed $_} (
 520      $self->master,
 521      values %{ $self->replicants },
 522   );
 523 }
 524
 525 =head2 execute_reliably ($coderef, ?@args)
 526
 527 Given a coderef, saves the current state of the L</read_handler>, forces it to
 528 use reliable storage (ie sets it to the master), executes a coderef and then
 529 restores the original state.
 530
 531 Example:
 532
 533   my $reliably = sub {
 534     my $name = shift @_;
 535     $schema->resultset('User')->create({name=>$name});
 536     my $user_rs = $schema->resultset('User')->find({name=>$name});
 537     return $user_rs;
 538   };
 539
 540   my $user_rs = $schema->storage->execute_reliably($reliably, 'John');
 541
 542 Use this when you must be certain of your database state, such as when you just
 543 inserted something and need to get a resultset including it, etc.
 544
 545 =cut
 546
 547 sub execute_reliably {
 548   my ($self, $coderef, @args) = @_;
 549
 550   unless( ref $coderef eq 'CODE') {
 551     $self->throw_exception('Second argument must be a coderef');
 552   }
 553
 554   ##Get copy of master storage
 555   my $master = $self->master;
 556
 557   ##Get whatever the current read hander is
 558   my $current = $self->read_handler;
 559
 560   ##Set the read handler to master
 561   $self->read_handler($master);
 562
 563   ## do whatever the caller needs
 564   my @result;
 565   my $want_array = wantarray;
 566
 567   eval {
 568     if($want_array) {
 569       @result = $coderef->(@args);
 570     } elsif(defined $want_array) {
 571       ($result[0]) = ($coderef->(@args));
 572     } else {
 573       $coderef->(@args);
 574     }
 575   };
 576
 577   ##Reset to the original state
 578   $self->read_handler($current);
 579
 580   ##Exception testing has to come last, otherwise you might leave the
 581   ##read_handler set to master.
 582
 583   if($@) {
 584     $self->throw_exception("coderef returned an error: $@");
 585   } else {
 586     return $want_array ? @result : $result[0];
 587   }
 588 }
 589
 590 =head2 set_reliable_storage
 591
 592 Sets the current $schema to be 'reliable', that is all queries, both read and
 593 write are sent to the master
 594
 595 =cut
 596
 597 sub set_reliable_storage {
 598   my $self = shift @_;
 599   my $schema = $self->schema;
 600   my $write_handler = $self->schema->storage->write_handler;
 601
 602   $schema->storage->read_handler($write_handler);
 603 }
 604
 605 =head2 set_balanced_storage
 606
 607 Sets the current $schema to be use the </balancer> for all reads, while all
 608 writea are sent to the master only
 609
 610 =cut
 611
 612 sub set_balanced_storage {
 613   my $self = shift @_;
 614   my $schema = $self->schema;
 615   my $write_handler = $self->schema->storage->balancer;
 616
 617   $schema->storage->read_handler($write_handler);
 618 }
 619
 620 =head2 around: txn_do ($coderef)
 621
 622 Overload to the txn_do method, which is delegated to whatever the
 623 L<write_handler> is set to.  We overload this in order to wrap in inside a
 624 L</execute_reliably> method.
 625
 626 =cut
 627
 628 around 'txn_do' => sub {
 629   my($txn_do, $self, $coderef, @args) = @_;
 630   $self->execute_reliably(sub {$self->$txn_do($coderef, @args)});
 631 };
 632
 633 =head2 connected
 634
 635 Check that the master and at least one of the replicants is connected.
 636
 637 =cut
 638
 639 sub connected {
 640   my $self = shift @_;
 641   return
 642     $self->master->connected &&
 643     $self->pool->connected_replicants;
 644 }
 645
 646 =head2 ensure_connected
 647
 648 Make sure all the storages are connected.
 649
 650 =cut
 651
 652 sub ensure_connected {
 653   my $self = shift @_;
 654   foreach my $source ($self->all_storages) {
 655     $source->ensure_connected(@_);
 656   }
 657 }
 658
 659 =head2 limit_dialect
 660
 661 Set the limit_dialect for all existing storages
 662
 663 =cut
 664
 665 sub limit_dialect {
 666   my $self = shift @_;
 667   foreach my $source ($self->all_storages) {
 668     $source->limit_dialect(@_);
 669   }
 670   return $self->master->quote_char;
 671 }
 672
 673 =head2 quote_char
 674
 675 Set the quote_char for all existing storages
 676
 677 =cut
 678
 679 sub quote_char {
 680   my $self = shift @_;
 681   foreach my $source ($self->all_storages) {
 682     $source->quote_char(@_);
 683   }
 684   return $self->master->quote_char;
 685 }
 686
 687 =head2 name_sep
 688
 689 Set the name_sep for all existing storages
 690
 691 =cut
 692
 693 sub name_sep {
 694   my $self = shift @_;
 695   foreach my $source ($self->all_storages) {
 696     $source->name_sep(@_);
 697   }
 698   return $self->master->name_sep;
 699 }
 700
 701 =head2 set_schema
 702
 703 Set the schema object for all existing storages
 704
 705 =cut
 706
 707 sub set_schema {
 708   my $self = shift @_;
 709   foreach my $source ($self->all_storages) {
 710     $source->set_schema(@_);
 711   }
 712 }
 713
 714 =head2 debug
 715
 716 set a debug flag across all storages
 717
 718 =cut
 719
 720 sub debug {
 721   my $self = shift @_;
 722   if(@_) {
 723     foreach my $source ($self->all_storages) {
 724       $source->debug(@_);
 725     }
 726   }
 727   return $self->master->debug;
 728 }
 729
 730 =head2 debugobj
 731
 732 set a debug object across all storages
 733
 734 =cut
 735
 736 sub debugobj {
 737   my $self = shift @_;
 738   if(@_) {
 739     foreach my $source ($self->all_storages) {
 740       $source->debugobj(@_);
 741     }
 742   }
 743   return $self->master->debugobj;
 744 }
 745
 746 =head2 debugfh
 747
 748 set a debugfh object across all storages
 749
 750 =cut
 751
 752 sub debugfh {
 753   my $self = shift @_;
 754   if(@_) {
 755     foreach my $source ($self->all_storages) {
 756       $source->debugfh(@_);
 757     }
 758   }
 759   return $self->master->debugfh;
 760 }
 761
 762 =head2 debugcb
 763
 764 set a debug callback across all storages
 765
 766 =cut
 767
 768 sub debugcb {
 769   my $self = shift @_;
 770   if(@_) {
 771     foreach my $source ($self->all_storages) {
 772       $source->debugcb(@_);
 773     }
 774   }
 775   return $self->master->debugcb;
 776 }
 777
 778 =head2 disconnect
 779
 780 disconnect everything
 781
 782 =cut
 783
 784 sub disconnect {
 785   my $self = shift @_;
 786   foreach my $source ($self->all_storages) {
 787     $source->disconnect(@_);
 788   }
 789 }
 790
 791 =head2 cursor_class
 792
 793 set cursor class on all storages, or return master's
 794
 795 =cut
 796
 797 sub cursor_class {
 798   my ($self, $cursor_class) = @_;
 799
 800   if ($cursor_class) {
 801     $_->cursor_class($cursor_class) for $self->all_storages;
 802   }
 803   $self->master->cursor_class;
 804 }
 805
 806 =head1 GOTCHAS
 807
 808 Due to the fact that replicants can lag behind a master, you must take care to
 809 make sure you use one of the methods to force read queries to a master should
 810 you need realtime data integrity.  For example, if you insert a row, and then
 811 immediately re-read it from the database (say, by doing $row->discard_changes)
 812 or you insert a row and then immediately build a query that expects that row
 813 to be an item, you should force the master to handle reads.  Otherwise, due to
 814 the lag, there is no certainty your data will be in the expected state.
 815
 816 For data integrity, all transactions automatically use the master storage for
 817 all read and write queries.  Using a transaction is the preferred and recommended
 818 method to force the master to handle all read queries.
 819
 820 Otherwise, you can force a single query to use the master with the 'force_pool'
 821 attribute:
 822
 823   my $row = $resultset->search(undef, {force_pool=>'master'})->find($pk);
 824
 825 This attribute will safely be ignore by non replicated storages, so you can use
 826 the same code for both types of systems.
 827
 828 Lastly, you can use the L</execute_reliably> method, which works very much like
 829 a transaction.
 830
 831 For debugging, you can turn replication on/off with the methods L</set_reliable_storage>
 832 and L</set_balanced_storage>, however this operates at a global level and is not
 833 suitable if you have a shared Schema object being used by multiple processes,
 834 such as on a web application server.  You can get around this limitation by
 835 using the Schema clone method.
 836
 837   my $new_schema = $schema->clone;
 838   $new_schema->set_reliable_storage;
 839
 840   ## $new_schema will use only the Master storage for all reads/writes while
 841   ## the $schema object will use replicated storage.
 842
 843 =head1 AUTHOR
 844
 845   John Napiorkowski <john.napiorkowski@takkle.com>
 846
 847 Based on code originated by:
 848
 849   Norbert Csongrádi <bert@cpan.org>
 850   Peter Siklósi <einon@einon.hu>
 851
 852 =head1 LICENSE
 853
 854 You may distribute this code under the same terms as Perl itself.
 855
 856 =cut
 857
 858 __PACKAGE__->meta->make_immutable;
 859
 860 1;