lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBD::Pg qw(:pg_types);
   7
   8 use base qw/DBIx::Class::Storage::DBI/;
   9
  10 # __PACKAGE__->load_components(qw/PK::Auto/);
  11
  12 # Warn about problematic versions of DBD::Pg
  13 warn "DBD::Pg 1.49 is strongly recommended"
  14   if ($DBD::Pg::VERSION < 1.49);
  15
  16 sub with_deferred_fk_checks {
  17   my ($self, $sub) = @_;
  18
  19   $self->dbh->do('SET CONSTRAINTS ALL DEFERRED');
  20   $sub->();
  21 }
  22
  23 sub _dbh_last_insert_id {
  24   my ($self, $dbh, $seq) = @_;
  25   $dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  26 }
  27
  28 sub last_insert_id {
  29   my ($self,$source,$col) = @_;
  30   my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
  31   $self->throw_exception("could not fetch primary key for " . $source->name . ", could not "
  32     . "get autoinc sequence for $col (check that table and column specifications are correct "
  33     . "and in the correct case)") unless defined $seq;
  34   $self->dbh_do('_dbh_last_insert_id', $seq);
  35 }
  36
  37 sub _dbh_get_autoinc_seq {
  38   my ($self, $dbh, $schema, $table, @pri) = @_;
  39
  40   while (my $col = shift @pri) {
  41     my $info = $dbh->column_info(undef,$schema,$table,$col)->fetchrow_hashref;
  42     if(defined $info->{COLUMN_DEF} and
  43        $info->{COLUMN_DEF} =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/) {
  44       my $seq = $1;
  45       # may need to strip quotes -- see if this works
  46       return $seq =~ /\./ ? $seq : $info->{TABLE_SCHEM} . "." . $seq;
  47     }
  48   }
  49   return;
  50 }
  51
  52 sub get_autoinc_seq {
  53   my ($self,$source,$col) = @_;
  54
  55   my @pri = $source->primary_columns;
  56   my ($schema,$table) = $source->name =~ /^(.+)\.(.+)$/ ? ($1,$2)
  57     : (undef,$source->name);
  58
  59   $self->dbh_do('_dbh_get_autoinc_seq', $schema, $table, @pri);
  60 }
  61
  62 sub sqlt_type {
  63   return 'PostgreSQL';
  64 }
  65
  66 sub datetime_parser_type { return "DateTime::Format::Pg"; }
  67
  68 sub bind_attribute_by_data_type {
  69   my ($self,$data_type) = @_;
  70
  71   my $bind_attributes = {
  72     bytea => { pg_type => DBD::Pg::PG_BYTEA },
  73     blob  => { pg_type => DBD::Pg::PG_BYTEA },
  74   };
  75
  76   if( defined $bind_attributes->{$data_type} ) {
  77     return $bind_attributes->{$data_type};
  78   }
  79   else {
  80     return;
  81   }
  82 }
  83
  84 sub _sequence_fetch {
  85   my ( $self, $type, $seq ) = @_;
  86   my ($id) = $self->dbh->selectrow_array("SELECT nextval('${seq}')");
  87   return $id;
  88 }
  89
  90 sub _svp_begin {
  91     my ($self, $name) = @_;
  92
  93     $self->dbh->pg_savepoint($name);
  94 }
  95
  96 sub _svp_release {
  97     my ($self, $name) = @_;
  98
  99     $self->dbh->pg_release($name);
 100 }
 101
 102 sub _svp_rollback {
 103     my ($self, $name) = @_;
 104
 105     $self->dbh->pg_rollback_to($name);
 106 }
 107
 108 1;
 109
 110 =head1 NAME
 111
 112 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 113
 114 =head1 SYNOPSIS
 115
 116   # In your table classes
 117   __PACKAGE__->load_components(qw/PK::Auto Core/);
 118   __PACKAGE__->set_primary_key('id');
 119   __PACKAGE__->sequence('mysequence');
 120
 121 =head1 DESCRIPTION
 122
 123 This class implements autoincrements for PostgreSQL.
 124
 125 =head1 AUTHORS
 126
 127 Marcus Ramberg <m.ramberg@cpan.org>
 128
 129 =head1 LICENSE
 130
 131 You may distribute this code under the same terms as Perl itself.
 132
 133 =cut