lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI::MultiColumnIn/;
   7 use mro 'c3';
   8
   9 use DBD::Pg qw(:pg_types);
  10
  11 # Ask for a DBD::Pg with array support
  12 warn "DBD::Pg 2.9.2 or greater is strongly recommended\n"
  13   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  14
  15 sub with_deferred_fk_checks {
  16   my ($self, $sub) = @_;
  17
  18   $self->last_dbh->do('SET CONSTRAINTS ALL DEFERRED');
  19   $sub->();
  20 }
  21
  22 sub _dbh_last_insert_id {
  23   my ($self, $dbh, $seq) = @_;
  24   $dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  25 }
  26
  27 sub last_insert_id {
  28   my ($self,$source,$col) = @_;
  29   my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
  30   $self->throw_exception("could not fetch primary key for " . $source->name . ", could not "
  31     . "get autoinc sequence for $col (check that table and column specifications are correct "
  32     . "and in the correct case)") unless defined $seq;
  33   $self->dbh_do('_dbh_last_insert_id', $seq);
  34 }
  35
  36 sub _dbh_get_autoinc_seq {
  37   my ($self, $dbh, $schema, $table, @pri) = @_;
  38
  39   while (my $col = shift @pri) {
  40     my $info = $dbh->column_info(undef,$schema,$table,$col)->fetchrow_hashref;
  41     if(defined $info->{COLUMN_DEF} and
  42        $info->{COLUMN_DEF} =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/) {
  43       my $seq = $1;
  44       # may need to strip quotes -- see if this works
  45       return $seq =~ /\./ ? $seq : $info->{TABLE_SCHEM} . "." . $seq;
  46     }
  47   }
  48   return;
  49 }
  50
  51 sub get_autoinc_seq {
  52   my ($self,$source,$col) = @_;
  53
  54   my @pri = $source->primary_columns;
  55
  56   my $schema;
  57   my $table = $source->name;
  58
  59   if (ref $table eq 'SCALAR') {
  60     $table = $$table;
  61   }
  62   elsif ($table =~ /^(.+)\.(.+)$/) {
  63     ($schema, $table) = ($1, $2);
  64   }
  65
  66   $self->dbh_do('_dbh_get_autoinc_seq', $schema, $table, @pri);
  67 }
  68
  69 sub sqlt_type {
  70   return 'PostgreSQL';
  71 }
  72
  73 sub datetime_parser_type { return "DateTime::Format::Pg"; }
  74
  75 sub bind_attribute_by_data_type {
  76   my ($self,$data_type) = @_;
  77
  78   my $bind_attributes = {
  79     bytea => { pg_type => DBD::Pg::PG_BYTEA },
  80     blob  => { pg_type => DBD::Pg::PG_BYTEA },
  81   };
  82
  83   if( defined $bind_attributes->{$data_type} ) {
  84     return $bind_attributes->{$data_type};
  85   }
  86   else {
  87     return;
  88   }
  89 }
  90
  91 sub _sequence_fetch {
  92   my ( $self, $type, $seq ) = @_;
  93   my ($id) = $self->last_dbh->selectrow_array("SELECT nextval('${seq}')");
  94   return $id;
  95 }
  96
  97 sub _svp_begin {
  98     my ($self, $name) = @_;
  99
 100     $self->last_dbh->pg_savepoint($name);
 101 }
 102
 103 sub _svp_release {
 104     my ($self, $name) = @_;
 105
 106     $self->last_dbh->pg_release($name);
 107 }
 108
 109 sub _svp_rollback {
 110     my ($self, $name) = @_;
 111
 112     $self->last_dbh->pg_rollback_to($name);
 113 }
 114
 115 1;
 116
 117 =head1 NAME
 118
 119 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 120
 121 =head1 SYNOPSIS
 122
 123   # In your table classes
 124   __PACKAGE__->load_components(qw/PK::Auto Core/);
 125   __PACKAGE__->set_primary_key('id');
 126   __PACKAGE__->sequence('mysequence');
 127
 128 =head1 DESCRIPTION
 129
 130 This class implements autoincrements for PostgreSQL.
 131
 132 =head1 AUTHORS
 133
 134 Marcus Ramberg <m.ramberg@cpan.org>
 135
 136 =head1 LICENSE
 137
 138 You may distribute this code under the same terms as Perl itself.
 139
 140 =cut