lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI/;
   7
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::_Util 'modver_gt_or_eq';
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->datetime_parser_type ('DateTime::Format::Pg');
  17 __PACKAGE__->_use_multicolumn_in (1);
  18
  19 sub _determine_supports_insert_returning {
  20   return shift->_server_info->{normalized_dbms_version} >= 8.002
  21     ? 1
  22     : 0
  23   ;
  24 }
  25
  26 sub with_deferred_fk_checks {
  27   my ($self, $sub) = @_;
  28
  29   my $txn_scope_guard = $self->txn_scope_guard;
  30
  31   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  32
  33   my $sg = Scope::Guard->new(sub {
  34     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  35   });
  36
  37   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  38 }
  39
  40 # only used when INSERT ... RETURNING is disabled
  41 sub last_insert_id {
  42   my ($self,$source,@cols) = @_;
  43
  44   my @values;
  45
  46   my $col_info = $source->columns_info(\@cols);
  47
  48   for my $col (@cols) {
  49     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  50       or $self->throw_exception( sprintf(
  51         "Could not determine sequence for column '%s.%s', please consider adding a schema-qualified sequence to its column info",
  52           $source->name,
  53           $col,
  54       ));
  55
  56     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  57   }
  58
  59   return @values;
  60 }
  61
  62 sub _sequence_fetch {
  63   my ($self, $function, $sequence) = @_;
  64
  65   $self->throw_exception('No sequence to fetch') unless $sequence;
  66
  67   my ($val) = $self->_get_dbh->selectrow_array(
  68     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  69   );
  70
  71   return $val;
  72 }
  73
  74 sub _dbh_get_autoinc_seq {
  75   my ($self, $dbh, $source, $col) = @_;
  76
  77   my $schema;
  78   my $table = $source->name;
  79
  80   # deref table name if it needs it
  81   $table = $$table
  82       if ref $table eq 'SCALAR';
  83
  84   # parse out schema name if present
  85   if( $table =~ /^(.+)\.(.+)$/ ) {
  86     ( $schema, $table ) = ( $1, $2 );
  87   }
  88
  89   # get the column default using a Postgres-specific pg_catalog query
  90   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  91
  92   # if no default value is set on the column, or if we can't parse the
  93   # default value as a sequence, throw.
  94   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  95     $seq_expr = '' unless defined $seq_expr;
  96     $schema = "$schema." if defined $schema && length $schema;
  97     $self->throw_exception( sprintf (
  98       "No sequence found for '%s%s.%s', check the RDBMS table definition or explicitly set the ".
  99       "'sequence' for this column in %s",
 100         $schema ? "$schema." : '',
 101         $table,
 102         $col,
 103         $source->source_name,
 104     ));
 105   }
 106
 107   return $1;  # exception thrown unless match is made above
 108 }
 109
 110 # custom method for fetching column default, since column_info has a
 111 # bug with older versions of DBD::Pg
 112 sub _dbh_get_column_default {
 113   my ( $self, $dbh, $schema, $table, $col ) = @_;
 114
 115   # Build and execute a query into the pg_catalog to find the Pg
 116   # expression for the default value for this column in this table.
 117   # If the table name is schema-qualified, query using that specific
 118   # schema name.
 119
 120   # Otherwise, find the table in the standard Postgres way, using the
 121   # search path.  This is done with the pg_catalog.pg_table_is_visible
 122   # function, which returns true if a given table is 'visible',
 123   # meaning the first table of that name to be found in the search
 124   # path.
 125
 126   # I *think* we can be assured that this query will always find the
 127   # correct column according to standard Postgres semantics.
 128   #
 129   # -- rbuels
 130
 131   my $sqlmaker = $self->sql_maker;
 132   local $sqlmaker->{bindtype} = 'normal';
 133
 134   my ($where, @bind) = $sqlmaker->where ({
 135     'a.attnum' => {'>', 0},
 136     'c.relname' => $table,
 137     'a.attname' => $col,
 138     -not_bool => 'a.attisdropped',
 139     (defined $schema && length $schema)
 140       ? ( 'n.nspname' => $schema )
 141       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 142   });
 143
 144   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 145
 146 SELECT
 147   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 148    FROM pg_catalog.pg_attrdef d
 149    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 150 FROM pg_catalog.pg_class c
 151      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 152      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 153 $where
 154
 155 EOS
 156
 157   return $seq_expr;
 158 }
 159
 160
 161 sub sqlt_type {
 162   return 'PostgreSQL';
 163 }
 164
 165 sub bind_attribute_by_data_type {
 166   my ($self,$data_type) = @_;
 167
 168   if ($self->_is_binary_lob_type($data_type)) {
 169     # this is a hot-ish codepath, use an escape flag to minimize
 170     # amount of function/method calls
 171     # the flag is stored in the DBD namespace, so that Class::Unload
 172     # will work (unlikely, but still)
 173     unless (
 174       modver_gt_or_eq( 'DBD::Pg', '2.17.2' )
 175         or
 176       $DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__
 177     ) {
 178       if ( $self->_server_info->{normalized_dbms_version} >= 9.0 ) {
 179         $self->throw_exception(
 180           'BYTEA columns are known to not work on Pg >= 9.0 with DBD::Pg < 2.17.2'
 181         );
 182       }
 183       elsif (
 184         my $missing = DBIx::Class::Optional::Dependencies->req_missing_for([qw( rdbms_pg binary_data )])
 185       ) {
 186         # FIXME - perhaps this needs to be an exception too...?
 187         # too old to test sensibly...
 188         carp (
 189           __PACKAGE__ . ": BYTEA column support strongly recommends $missing"
 190         )
 191       }
 192
 193       $DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__ = 1;
 194     }
 195
 196     return { pg_type => DBD::Pg::PG_BYTEA() };
 197   }
 198   else {
 199     return undef;
 200   }
 201 }
 202
 203 sub _exec_svp_begin {
 204     my ($self, $name) = @_;
 205
 206     $self->_dbh->pg_savepoint($name);
 207 }
 208
 209 sub _exec_svp_release {
 210     my ($self, $name) = @_;
 211
 212     $self->_dbh->pg_release($name);
 213 }
 214
 215 sub _exec_svp_rollback {
 216     my ($self, $name) = @_;
 217
 218     $self->_dbh->pg_rollback_to($name);
 219 }
 220
 221 sub deployment_statements {
 222   my $self = shift;;
 223   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 224
 225   $sqltargs ||= {};
 226
 227   if (
 228     ! exists $sqltargs->{producer_args}{postgres_version}
 229       and
 230     my $dver = $self->_server_info->{normalized_dbms_version}
 231   ) {
 232     $sqltargs->{producer_args}{postgres_version} = $dver;
 233   }
 234
 235   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 236 }
 237
 238 1;
 239
 240 __END__
 241
 242 =head1 NAME
 243
 244 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 245
 246 =head1 SYNOPSIS
 247
 248   # In your result (table) classes
 249   use base 'DBIx::Class::Core';
 250   __PACKAGE__->set_primary_key('id');
 251
 252 =head1 DESCRIPTION
 253
 254 This class implements autoincrements for PostgreSQL.
 255
 256 =head1 POSTGRESQL SCHEMA SUPPORT
 257
 258 This driver supports multiple PostgreSQL schemas, with one caveat: for
 259 performance reasons, data about the search path, sequence names, and
 260 so forth is queried as needed and CACHED for subsequent uses.
 261
 262 For this reason, once your schema is instantiated, you should not
 263 change the PostgreSQL schema search path for that schema's database
 264 connection. If you do, Bad Things may happen.
 265
 266 You should do any necessary manipulation of the search path BEFORE
 267 instantiating your schema object, or as part of the on_connect_do
 268 option to connect(), for example:
 269
 270    my $schema = My::Schema->connect
 271                   ( $dsn,$user,$pass,
 272                     { on_connect_do =>
 273                         [ 'SET search_path TO myschema, foo, public' ],
 274                     },
 275                   );
 276
 277 =head1 FURTHER QUESTIONS?
 278
 279 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 280
 281 =head1 COPYRIGHT AND LICENSE
 282
 283 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 284 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 285 redistribute it and/or modify it under the same terms as the
 286 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.