lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve 'preserve_context';
  14 use namespace::clean;
  15
  16 # Ask for a DBD::Pg with array support
  17 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  18   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  19
  20 sub _determine_supports_insert_returning {
  21   return shift->_server_info->{normalized_dbms_version} >= 8.002
  22     ? 1
  23     : 0
  24   ;
  25 }
  26
  27 sub with_deferred_fk_checks {
  28   my ($self, $sub) = @_;
  29
  30   my $txn_scope_guard = $self->txn_scope_guard;
  31
  32   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  33
  34   my $sg = Scope::Guard->new(sub {
  35     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  36   });
  37
  38   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  39 }
  40
  41 # only used when INSERT ... RETURNING is disabled
  42 sub last_insert_id {
  43   my ($self,$source,@cols) = @_;
  44
  45   my @values;
  46
  47   for my $col (@cols) {
  48     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  49       or $self->throw_exception( sprintf(
  50         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  51           $source->name,
  52           $col,
  53       ));
  54
  55     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  56   }
  57
  58   return @values;
  59 }
  60
  61 sub _sequence_fetch {
  62   my ($self, $function, $sequence) = @_;
  63
  64   $self->throw_exception('No sequence to fetch') unless $sequence;
  65
  66   my ($val) = $self->_get_dbh->selectrow_array(
  67     sprintf ("select %s('%s')", $function, $sequence)
  68   );
  69
  70   return $val;
  71 }
  72
  73 sub _dbh_get_autoinc_seq {
  74   my ($self, $dbh, $source, $col) = @_;
  75
  76   my $schema;
  77   my $table = $source->name;
  78
  79   # deref table name if it needs it
  80   $table = $$table
  81       if ref $table eq 'SCALAR';
  82
  83   # parse out schema name if present
  84   if( $table =~ /^(.+)\.(.+)$/ ) {
  85     ( $schema, $table ) = ( $1, $2 );
  86   }
  87
  88   # get the column default using a Postgres-specific pg_catalog query
  89   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  90
  91   # if no default value is set on the column, or if we can't parse the
  92   # default value as a sequence, throw.
  93   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  94     $seq_expr = '' unless defined $seq_expr;
  95     $schema = "$schema." if defined $schema && length $schema;
  96     $self->throw_exception( sprintf (
  97       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
  98       "'sequence' for this column in %s",
  99         $schema ? "$schema." : '',
 100         $table,
 101         $col,
 102         $source->source_name,
 103     ));
 104   }
 105
 106   return $1;
 107 }
 108
 109 # custom method for fetching column default, since column_info has a
 110 # bug with older versions of DBD::Pg
 111 sub _dbh_get_column_default {
 112   my ( $self, $dbh, $schema, $table, $col ) = @_;
 113
 114   # Build and execute a query into the pg_catalog to find the Pg
 115   # expression for the default value for this column in this table.
 116   # If the table name is schema-qualified, query using that specific
 117   # schema name.
 118
 119   # Otherwise, find the table in the standard Postgres way, using the
 120   # search path.  This is done with the pg_catalog.pg_table_is_visible
 121   # function, which returns true if a given table is 'visible',
 122   # meaning the first table of that name to be found in the search
 123   # path.
 124
 125   # I *think* we can be assured that this query will always find the
 126   # correct column according to standard Postgres semantics.
 127   #
 128   # -- rbuels
 129
 130   my $sqlmaker = $self->sql_maker;
 131   local $sqlmaker->{bindtype} = 'normal';
 132
 133   my ($where, @bind) = $sqlmaker->where ({
 134     'a.attnum' => {'>', 0},
 135     'c.relname' => $table,
 136     'a.attname' => $col,
 137     -not_bool => 'a.attisdropped',
 138     (defined $schema && length $schema)
 139       ? ( 'n.nspname' => $schema )
 140       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 141   });
 142
 143   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 144
 145 SELECT
 146   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 147    FROM pg_catalog.pg_attrdef d
 148    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 149 FROM pg_catalog.pg_class c
 150      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 151      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 152 $where
 153
 154 EOS
 155
 156   return $seq_expr;
 157 }
 158
 159
 160 sub sqlt_type {
 161   return 'PostgreSQL';
 162 }
 163
 164 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 165
 166 sub bind_attribute_by_data_type {
 167   my ($self,$data_type) = @_;
 168
 169   my $bind_attributes = {
 170     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 171     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 172   };
 173
 174   if( defined $bind_attributes->{$data_type} ) {
 175     return $bind_attributes->{$data_type};
 176   }
 177   else {
 178     return;
 179   }
 180 }
 181
 182 sub _svp_begin {
 183     my ($self, $name) = @_;
 184
 185     $self->_get_dbh->pg_savepoint($name);
 186 }
 187
 188 sub _svp_release {
 189     my ($self, $name) = @_;
 190
 191     $self->_get_dbh->pg_release($name);
 192 }
 193
 194 sub _svp_rollback {
 195     my ($self, $name) = @_;
 196
 197     $self->_get_dbh->pg_rollback_to($name);
 198 }
 199
 200 sub deployment_statements {
 201   my $self = shift;;
 202   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 203
 204   $sqltargs ||= {};
 205
 206   if (
 207     ! exists $sqltargs->{producer_args}{postgres_version}
 208       and
 209     my $dver = $self->_server_info->{normalized_dbms_version}
 210   ) {
 211     $sqltargs->{producer_args}{postgres_version} = $dver;
 212   }
 213
 214   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 215 }
 216
 217 1;
 218
 219 __END__
 220
 221 =head1 NAME
 222
 223 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 224
 225 =head1 SYNOPSIS
 226
 227   # In your result (table) classes
 228   use base 'DBIx::Class::Core';
 229   __PACKAGE__->set_primary_key('id');
 230   __PACKAGE__->sequence('mysequence');
 231
 232 =head1 DESCRIPTION
 233
 234 This class implements autoincrements for PostgreSQL.
 235
 236 =head1 POSTGRESQL SCHEMA SUPPORT
 237
 238 This driver supports multiple PostgreSQL schemas, with one caveat: for
 239 performance reasons, data about the search path, sequence names, and
 240 so forth is queried as needed and CACHED for subsequent uses.
 241
 242 For this reason, once your schema is instantiated, you should not
 243 change the PostgreSQL schema search path for that schema's database
 244 connection. If you do, Bad Things may happen.
 245
 246 You should do any necessary manipulation of the search path BEFORE
 247 instantiating your schema object, or as part of the on_connect_do
 248 option to connect(), for example:
 249
 250    my $schema = My::Schema->connect
 251                   ( $dsn,$user,$pass,
 252                     { on_connect_do =>
 253                         [ 'SET search_path TO myschema, foo, public' ],
 254                     },
 255                   );
 256
 257 =head1 AUTHORS
 258
 259 See L<DBIx::Class/CONTRIBUTORS>
 260
 261 =head1 LICENSE
 262
 263 You may distribute this code under the same terms as Perl itself.
 264
 265 =cut