lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve ();
  14
  15 # Ask for a DBD::Pg with array support
  16 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  17   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  18
  19 sub can_insert_returning {
  20   my $self = shift;
  21
  22   my ($major, $minor) = $self->_server_info->{dbms_ver} =~ /^(\d+)\.(\d+)/;
  23
  24   return 1
  25     if ($major > 8) || ($major == 8 && $minor >= 2);
  26
  27   return 0;
  28 }
  29
  30 sub with_deferred_fk_checks {
  31   my ($self, $sub) = @_;
  32
  33   my $txn_scope_guard = $self->txn_scope_guard;
  34
  35   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  36
  37   my $sg = Scope::Guard->new(sub {
  38     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  39   });
  40
  41   return Context::Preserve::preserve_context(sub { $sub->() },
  42     after => sub { $txn_scope_guard->commit });
  43 }
  44
  45 # only used when INSERT ... RETURNING is disabled
  46 sub last_insert_id {
  47   my ($self,$source,@cols) = @_;
  48
  49   my @values;
  50
  51   for my $col (@cols) {
  52     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  53       or $self->throw_exception( sprintf(
  54         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  55           $source->name,
  56           $col,
  57       ));
  58
  59     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  60   }
  61
  62   return @values;
  63 }
  64
  65 sub _sequence_fetch {
  66   my ($self, $function, $sequence) = @_;
  67
  68   $self->throw_exception('No sequence to fetch') unless $sequence;
  69
  70   my ($val) = $self->_get_dbh->selectrow_array(
  71     sprintf ("select %s('%s')", $function, $sequence)
  72   );
  73
  74   return $val;
  75 }
  76
  77 sub _dbh_get_autoinc_seq {
  78   my ($self, $dbh, $source, $col) = @_;
  79
  80   my $schema;
  81   my $table = $source->name;
  82
  83   # deref table name if it needs it
  84   $table = $$table
  85       if ref $table eq 'SCALAR';
  86
  87   # parse out schema name if present
  88   if( $table =~ /^(.+)\.(.+)$/ ) {
  89     ( $schema, $table ) = ( $1, $2 );
  90   }
  91
  92   # get the column default using a Postgres-specific pg_catalog query
  93   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  94
  95   # if no default value is set on the column, or if we can't parse the
  96   # default value as a sequence, throw.
  97   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  98     $seq_expr = '' unless defined $seq_expr;
  99     $schema = "$schema." if defined $schema && length $schema;
 100     $self->throw_exception( sprintf (
 101       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 102       "'sequence' for this column in %s",
 103         $schema ? "$schema." : '',
 104         $table,
 105         $col,
 106         $source->source_name,
 107     ));
 108   }
 109
 110   return $1;
 111 }
 112
 113 # custom method for fetching column default, since column_info has a
 114 # bug with older versions of DBD::Pg
 115 sub _dbh_get_column_default {
 116   my ( $self, $dbh, $schema, $table, $col ) = @_;
 117
 118   # Build and execute a query into the pg_catalog to find the Pg
 119   # expression for the default value for this column in this table.
 120   # If the table name is schema-qualified, query using that specific
 121   # schema name.
 122
 123   # Otherwise, find the table in the standard Postgres way, using the
 124   # search path.  This is done with the pg_catalog.pg_table_is_visible
 125   # function, which returns true if a given table is 'visible',
 126   # meaning the first table of that name to be found in the search
 127   # path.
 128
 129   # I *think* we can be assured that this query will always find the
 130   # correct column according to standard Postgres semantics.
 131   #
 132   # -- rbuels
 133
 134   my $sqlmaker = $self->sql_maker;
 135   local $sqlmaker->{bindtype} = 'normal';
 136
 137   my ($where, @bind) = $sqlmaker->where ({
 138     'a.attnum' => {'>', 0},
 139     'c.relname' => $table,
 140     'a.attname' => $col,
 141     -not_bool => 'a.attisdropped',
 142     (defined $schema && length $schema)
 143       ? ( 'n.nspname' => $schema )
 144       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 145   });
 146
 147   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 148
 149 SELECT
 150   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 151    FROM pg_catalog.pg_attrdef d
 152    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 153 FROM pg_catalog.pg_class c
 154      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 155      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 156 $where
 157
 158 EOS
 159
 160   return $seq_expr;
 161 }
 162
 163
 164 sub sqlt_type {
 165   return 'PostgreSQL';
 166 }
 167
 168 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 169
 170 sub bind_attribute_by_data_type {
 171   my ($self,$data_type) = @_;
 172
 173   my $bind_attributes = {
 174     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 175     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 176   };
 177
 178   if( defined $bind_attributes->{$data_type} ) {
 179     return $bind_attributes->{$data_type};
 180   }
 181   else {
 182     return;
 183   }
 184 }
 185
 186 sub _svp_begin {
 187     my ($self, $name) = @_;
 188
 189     $self->_get_dbh->pg_savepoint($name);
 190 }
 191
 192 sub _svp_release {
 193     my ($self, $name) = @_;
 194
 195     $self->_get_dbh->pg_release($name);
 196 }
 197
 198 sub _svp_rollback {
 199     my ($self, $name) = @_;
 200
 201     $self->_get_dbh->pg_rollback_to($name);
 202 }
 203
 204 1;
 205
 206 __END__
 207
 208 =head1 NAME
 209
 210 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 211
 212 =head1 SYNOPSIS
 213
 214   # In your result (table) classes
 215   use base 'DBIx::Class::Core';
 216   __PACKAGE__->set_primary_key('id');
 217   __PACKAGE__->sequence('mysequence');
 218
 219 =head1 DESCRIPTION
 220
 221 This class implements autoincrements for PostgreSQL.
 222
 223 =head1 POSTGRESQL SCHEMA SUPPORT
 224
 225 This driver supports multiple PostgreSQL schemas, with one caveat: for
 226 performance reasons, data about the search path, sequence names, and
 227 so forth is queried as needed and CACHED for subsequent uses.
 228
 229 For this reason, once your schema is instantiated, you should not
 230 change the PostgreSQL schema search path for that schema's database
 231 connection. If you do, Bad Things may happen.
 232
 233 You should do any necessary manipulation of the search path BEFORE
 234 instantiating your schema object, or as part of the on_connect_do
 235 option to connect(), for example:
 236
 237    my $schema = My::Schema->connect
 238                   ( $dsn,$user,$pass,
 239                     { on_connect_do =>
 240                         [ 'SET search_path TO myschema, foo, public' ],
 241                     },
 242                   );
 243
 244 =head1 AUTHORS
 245
 246 See L<DBIx::Class/CONTRIBUTORS>
 247
 248 =head1 LICENSE
 249
 250 You may distribute this code under the same terms as Perl itself.
 251
 252 =cut