lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8     DBIx::Class::Storage::DBI::InsertReturning
   9 /;
  10 use mro 'c3';
  11
  12 use DBD::Pg qw(:pg_types);
  13 use Scope::Guard ();
  14 use Context::Preserve ();
  15
  16 # Ask for a DBD::Pg with array support
  17 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  18   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  19
  20 sub with_deferred_fk_checks {
  21   my ($self, $sub) = @_;
  22
  23   my $txn_scope_guard = $self->txn_scope_guard;
  24
  25   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  26
  27   my $sg = Scope::Guard->new(sub {
  28     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  29   });
  30
  31   return Context::Preserve::preserve_context(sub { $sub->() },
  32     after => sub { $txn_scope_guard->commit });
  33 }
  34
  35 sub _sequence_fetch {
  36   my ($self, $function, $sequence) = @_;
  37
  38   $self->throw_exception('No sequence to fetch') unless $sequence;
  39
  40   my ($val) = $self->_get_dbh->selectrow_array(
  41     sprintf "select $function('%s')",
  42       $sequence
  43   );
  44
  45   return $val;
  46 }
  47
  48 sub _dbh_get_autoinc_seq {
  49   my ($self, $dbh, $source, $col) = @_;
  50
  51   my $schema;
  52   my $table = $source->name;
  53
  54   # deref table name if it needs it
  55   $table = $$table
  56       if ref $table eq 'SCALAR';
  57
  58   # parse out schema name if present
  59   if( $table =~ /^(.+)\.(.+)$/ ) {
  60     ( $schema, $table ) = ( $1, $2 );
  61   }
  62
  63   # get the column default using a Postgres-specific pg_catalog query
  64   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  65
  66   # if no default value is set on the column, or if we can't parse the
  67   # default value as a sequence, throw.
  68   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  69     $seq_expr = '' unless defined $seq_expr;
  70     $schema = "$schema." if defined $schema && length $schema;
  71     $self->throw_exception( sprintf (
  72       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
  73       "'sequence' for this column in %s",
  74         $schema ? "$schema." : '',
  75         $table,
  76         $col,
  77         $source->source_name,
  78     ));
  79   }
  80
  81   return $1;
  82 }
  83
  84 # custom method for fetching column default, since column_info has a
  85 # bug with older versions of DBD::Pg
  86 sub _dbh_get_column_default {
  87   my ( $self, $dbh, $schema, $table, $col ) = @_;
  88
  89   # Build and execute a query into the pg_catalog to find the Pg
  90   # expression for the default value for this column in this table.
  91   # If the table name is schema-qualified, query using that specific
  92   # schema name.
  93
  94   # Otherwise, find the table in the standard Postgres way, using the
  95   # search path.  This is done with the pg_catalog.pg_table_is_visible
  96   # function, which returns true if a given table is 'visible',
  97   # meaning the first table of that name to be found in the search
  98   # path.
  99
 100   # I *think* we can be assured that this query will always find the
 101   # correct column according to standard Postgres semantics.
 102   #
 103   # -- rbuels
 104
 105   my $sqlmaker = $self->sql_maker;
 106   local $sqlmaker->{bindtype} = 'normal';
 107
 108   my ($where, @bind) = $sqlmaker->where ({
 109     'a.attnum' => {'>', 0},
 110     'c.relname' => $table,
 111     'a.attname' => $col,
 112     -not_bool => 'a.attisdropped',
 113     (defined $schema && length $schema)
 114       ? ( 'n.nspname' => $schema )
 115       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 116   });
 117
 118   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 119
 120 SELECT
 121   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 122    FROM pg_catalog.pg_attrdef d
 123    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 124 FROM pg_catalog.pg_class c
 125      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 126      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 127 $where
 128
 129 EOS
 130
 131   return $seq_expr;
 132 }
 133
 134
 135 sub sqlt_type {
 136   return 'PostgreSQL';
 137 }
 138
 139 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 140
 141 sub bind_attribute_by_data_type {
 142   my ($self,$data_type) = @_;
 143
 144   my $bind_attributes = {
 145     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 146     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 147   };
 148
 149   if( defined $bind_attributes->{$data_type} ) {
 150     return $bind_attributes->{$data_type};
 151   }
 152   else {
 153     return;
 154   }
 155 }
 156
 157 sub _svp_begin {
 158     my ($self, $name) = @_;
 159
 160     $self->_get_dbh->pg_savepoint($name);
 161 }
 162
 163 sub _svp_release {
 164     my ($self, $name) = @_;
 165
 166     $self->_get_dbh->pg_release($name);
 167 }
 168
 169 sub _svp_rollback {
 170     my ($self, $name) = @_;
 171
 172     $self->_get_dbh->pg_rollback_to($name);
 173 }
 174
 175 1;
 176
 177 __END__
 178
 179 =head1 NAME
 180
 181 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 182
 183 =head1 SYNOPSIS
 184
 185   # In your result (table) classes
 186   use base 'DBIx::Class::Core';
 187   __PACKAGE__->set_primary_key('id');
 188   __PACKAGE__->sequence('mysequence');
 189
 190 =head1 DESCRIPTION
 191
 192 This class implements autoincrements for PostgreSQL.
 193
 194 =head1 POSTGRESQL SCHEMA SUPPORT
 195
 196 This driver supports multiple PostgreSQL schemas, with one caveat: for
 197 performance reasons, data about the search path, sequence names, and
 198 so forth is queried as needed and CACHED for subsequent uses.
 199
 200 For this reason, once your schema is instantiated, you should not
 201 change the PostgreSQL schema search path for that schema's database
 202 connection. If you do, Bad Things may happen.
 203
 204 You should do any necessary manipulation of the search path BEFORE
 205 instantiating your schema object, or as part of the on_connect_do
 206 option to connect(), for example:
 207
 208    my $schema = My::Schema->connect
 209                   ( $dsn,$user,$pass,
 210                     { on_connect_do =>
 211                         [ 'SET search_path TO myschema, foo, public' ],
 212                     },
 213                   );
 214
 215 =head1 AUTHORS
 216
 217 See L<DBIx::Class/CONTRIBUTORS>
 218
 219 =head1 LICENSE
 220
 221 You may distribute this code under the same terms as Perl itself.
 222
 223 =cut