lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use Scope::Guard ();
  12 use Context::Preserve 'preserve_context';
  13 use DBIx::Class::Carp;
  14 use Try::Tiny;
  15 use namespace::clean;
  16
  17 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  18 __PACKAGE__->sql_quote_char ('"');
  19 __PACKAGE__->datetime_parser_type ('DateTime::Format::Pg');
  20
  21 sub _determine_supports_insert_returning {
  22   return shift->_server_info->{normalized_dbms_version} >= 8.002
  23     ? 1
  24     : 0
  25   ;
  26 }
  27
  28 sub with_deferred_fk_checks {
  29   my ($self, $sub) = @_;
  30
  31   my $txn_scope_guard = $self->txn_scope_guard;
  32
  33   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  34
  35   my $sg = Scope::Guard->new(sub {
  36     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  37   });
  38
  39   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  40 }
  41
  42 # only used when INSERT ... RETURNING is disabled
  43 sub last_insert_id {
  44   my ($self,$source,@cols) = @_;
  45
  46   my @values;
  47
  48   my $col_info = $source->columns_info(\@cols);
  49
  50   for my $col (@cols) {
  51     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  52       or $self->throw_exception( sprintf(
  53         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  54           $source->name,
  55           $col,
  56       ));
  57
  58     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  59   }
  60
  61   return @values;
  62 }
  63
  64 sub _sequence_fetch {
  65   my ($self, $function, $sequence) = @_;
  66
  67   $self->throw_exception('No sequence to fetch') unless $sequence;
  68
  69   my ($val) = $self->_get_dbh->selectrow_array(
  70     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  71   );
  72
  73   return $val;
  74 }
  75
  76 sub _dbh_get_autoinc_seq {
  77   my ($self, $dbh, $source, $col) = @_;
  78
  79   my $schema;
  80   my $table = $source->name;
  81
  82   # deref table name if it needs it
  83   $table = $$table
  84       if ref $table eq 'SCALAR';
  85
  86   # parse out schema name if present
  87   if( $table =~ /^(.+)\.(.+)$/ ) {
  88     ( $schema, $table ) = ( $1, $2 );
  89   }
  90
  91   # get the column default using a Postgres-specific pg_catalog query
  92   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  93
  94   # if no default value is set on the column, or if we can't parse the
  95   # default value as a sequence, throw.
  96   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  97     $seq_expr = '' unless defined $seq_expr;
  98     $schema = "$schema." if defined $schema && length $schema;
  99     $self->throw_exception( sprintf (
 100       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 101       "'sequence' for this column in %s",
 102         $schema ? "$schema." : '',
 103         $table,
 104         $col,
 105         $source->source_name,
 106     ));
 107   }
 108
 109   return $1;
 110 }
 111
 112 # custom method for fetching column default, since column_info has a
 113 # bug with older versions of DBD::Pg
 114 sub _dbh_get_column_default {
 115   my ( $self, $dbh, $schema, $table, $col ) = @_;
 116
 117   # Build and execute a query into the pg_catalog to find the Pg
 118   # expression for the default value for this column in this table.
 119   # If the table name is schema-qualified, query using that specific
 120   # schema name.
 121
 122   # Otherwise, find the table in the standard Postgres way, using the
 123   # search path.  This is done with the pg_catalog.pg_table_is_visible
 124   # function, which returns true if a given table is 'visible',
 125   # meaning the first table of that name to be found in the search
 126   # path.
 127
 128   # I *think* we can be assured that this query will always find the
 129   # correct column according to standard Postgres semantics.
 130   #
 131   # -- rbuels
 132
 133   my $sqlmaker = $self->sql_maker;
 134   local $sqlmaker->{bindtype} = 'normal';
 135
 136   my ($where, @bind) = $sqlmaker->where ({
 137     'a.attnum' => {'>', 0},
 138     'c.relname' => $table,
 139     'a.attname' => $col,
 140     -not_bool => 'a.attisdropped',
 141     (defined $schema && length $schema)
 142       ? ( 'n.nspname' => $schema )
 143       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 144   });
 145
 146   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 147
 148 SELECT
 149   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 150    FROM pg_catalog.pg_attrdef d
 151    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 152 FROM pg_catalog.pg_class c
 153      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 154      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 155 $where
 156
 157 EOS
 158
 159   return $seq_expr;
 160 }
 161
 162
 163 sub sqlt_type {
 164   return 'PostgreSQL';
 165 }
 166
 167 sub bind_attribute_by_data_type {
 168   my ($self,$data_type) = @_;
 169
 170   if ($self->_is_binary_lob_type($data_type)) {
 171     # this is a hot-ish codepath, use an escape flag to minimize
 172     # amount of function/method calls
 173     # additionally version.pm is cock, and memleaks on multiple
 174     # ->VERSION calls
 175     # the flag is stored in the DBD namespace, so that Class::Unload
 176     # will work (unlikely, but still)
 177     unless ($DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__) {
 178       if ($self->_server_info->{normalized_dbms_version} >= 9.0) {
 179         try { DBD::Pg->VERSION('2.17.2'); 1 } or carp (
 180           __PACKAGE__.': BYTEA columns are known to not work on Pg >= 9.0 with DBD::Pg < 2.17.2'
 181         );
 182       }
 183       elsif (not try { DBD::Pg->VERSION('2.9.2'); 1 } ) { carp (
 184         __PACKAGE__.': DBD::Pg 2.9.2 or greater is strongly recommended for BYTEA column support'
 185       )}
 186
 187       $DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__ = 1;
 188     }
 189
 190     return { pg_type => DBD::Pg::PG_BYTEA() };
 191   }
 192   else {
 193     return undef;
 194   }
 195 }
 196
 197 sub _exec_svp_begin {
 198     my ($self, $name) = @_;
 199
 200     $self->_dbh->pg_savepoint($name);
 201 }
 202
 203 sub _exec_svp_release {
 204     my ($self, $name) = @_;
 205
 206     $self->_dbh->pg_release($name);
 207 }
 208
 209 sub _exec_svp_rollback {
 210     my ($self, $name) = @_;
 211
 212     $self->_dbh->pg_rollback_to($name);
 213 }
 214
 215 sub deployment_statements {
 216   my $self = shift;;
 217   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 218
 219   $sqltargs ||= {};
 220
 221   if (
 222     ! exists $sqltargs->{producer_args}{postgres_version}
 223       and
 224     my $dver = $self->_server_info->{normalized_dbms_version}
 225   ) {
 226     $sqltargs->{producer_args}{postgres_version} = $dver;
 227   }
 228
 229   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 230 }
 231
 232 1;
 233
 234 __END__
 235
 236 =head1 NAME
 237
 238 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 239
 240 =head1 SYNOPSIS
 241
 242   # In your result (table) classes
 243   use base 'DBIx::Class::Core';
 244   __PACKAGE__->set_primary_key('id');
 245
 246 =head1 DESCRIPTION
 247
 248 This class implements autoincrements for PostgreSQL.
 249
 250 =head1 POSTGRESQL SCHEMA SUPPORT
 251
 252 This driver supports multiple PostgreSQL schemas, with one caveat: for
 253 performance reasons, data about the search path, sequence names, and
 254 so forth is queried as needed and CACHED for subsequent uses.
 255
 256 For this reason, once your schema is instantiated, you should not
 257 change the PostgreSQL schema search path for that schema's database
 258 connection. If you do, Bad Things may happen.
 259
 260 You should do any necessary manipulation of the search path BEFORE
 261 instantiating your schema object, or as part of the on_connect_do
 262 option to connect(), for example:
 263
 264    my $schema = My::Schema->connect
 265                   ( $dsn,$user,$pass,
 266                     { on_connect_do =>
 267                         [ 'SET search_path TO myschema, foo, public' ],
 268                     },
 269                   );
 270
 271 =head1 AUTHORS
 272
 273 See L<DBIx::Class/CONTRIBUTORS>
 274
 275 =head1 LICENSE
 276
 277 You may distribute this code under the same terms as Perl itself.
 278
 279 =cut