lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve 'preserve_context';
  14 use namespace::clean;
  15
  16 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  17
  18 # Ask for a DBD::Pg with array support
  19 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  20   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  21
  22 sub _determine_supports_insert_returning {
  23   return shift->_server_info->{normalized_dbms_version} >= 8.002
  24     ? 1
  25     : 0
  26   ;
  27 }
  28
  29 sub with_deferred_fk_checks {
  30   my ($self, $sub) = @_;
  31
  32   my $txn_scope_guard = $self->txn_scope_guard;
  33
  34   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  35
  36   my $sg = Scope::Guard->new(sub {
  37     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  38   });
  39
  40   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  41 }
  42
  43 # only used when INSERT ... RETURNING is disabled
  44 sub last_insert_id {
  45   my ($self,$source,@cols) = @_;
  46
  47   my @values;
  48
  49   for my $col (@cols) {
  50     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  51       or $self->throw_exception( sprintf(
  52         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  53           $source->name,
  54           $col,
  55       ));
  56
  57     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  58   }
  59
  60   return @values;
  61 }
  62
  63 sub _sequence_fetch {
  64   my ($self, $function, $sequence) = @_;
  65
  66   $self->throw_exception('No sequence to fetch') unless $sequence;
  67
  68   my ($val) = $self->_get_dbh->selectrow_array(
  69     sprintf ("select %s('%s')", $function, $sequence)
  70   );
  71
  72   return $val;
  73 }
  74
  75 sub _dbh_get_autoinc_seq {
  76   my ($self, $dbh, $source, $col) = @_;
  77
  78   my $schema;
  79   my $table = $source->name;
  80
  81   # deref table name if it needs it
  82   $table = $$table
  83       if ref $table eq 'SCALAR';
  84
  85   # parse out schema name if present
  86   if( $table =~ /^(.+)\.(.+)$/ ) {
  87     ( $schema, $table ) = ( $1, $2 );
  88   }
  89
  90   # get the column default using a Postgres-specific pg_catalog query
  91   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  92
  93   # if no default value is set on the column, or if we can't parse the
  94   # default value as a sequence, throw.
  95   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  96     $seq_expr = '' unless defined $seq_expr;
  97     $schema = "$schema." if defined $schema && length $schema;
  98     $self->throw_exception( sprintf (
  99       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 100       "'sequence' for this column in %s",
 101         $schema ? "$schema." : '',
 102         $table,
 103         $col,
 104         $source->source_name,
 105     ));
 106   }
 107
 108   return $1;
 109 }
 110
 111 # custom method for fetching column default, since column_info has a
 112 # bug with older versions of DBD::Pg
 113 sub _dbh_get_column_default {
 114   my ( $self, $dbh, $schema, $table, $col ) = @_;
 115
 116   # Build and execute a query into the pg_catalog to find the Pg
 117   # expression for the default value for this column in this table.
 118   # If the table name is schema-qualified, query using that specific
 119   # schema name.
 120
 121   # Otherwise, find the table in the standard Postgres way, using the
 122   # search path.  This is done with the pg_catalog.pg_table_is_visible
 123   # function, which returns true if a given table is 'visible',
 124   # meaning the first table of that name to be found in the search
 125   # path.
 126
 127   # I *think* we can be assured that this query will always find the
 128   # correct column according to standard Postgres semantics.
 129   #
 130   # -- rbuels
 131
 132   my $sqlmaker = $self->sql_maker;
 133   local $sqlmaker->{bindtype} = 'normal';
 134
 135   my ($where, @bind) = $sqlmaker->where ({
 136     'a.attnum' => {'>', 0},
 137     'c.relname' => $table,
 138     'a.attname' => $col,
 139     -not_bool => 'a.attisdropped',
 140     (defined $schema && length $schema)
 141       ? ( 'n.nspname' => $schema )
 142       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 143   });
 144
 145   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 146
 147 SELECT
 148   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 149    FROM pg_catalog.pg_attrdef d
 150    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 151 FROM pg_catalog.pg_class c
 152      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 153      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 154 $where
 155
 156 EOS
 157
 158   return $seq_expr;
 159 }
 160
 161
 162 sub sqlt_type {
 163   return 'PostgreSQL';
 164 }
 165
 166 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 167
 168 sub bind_attribute_by_data_type {
 169   my ($self,$data_type) = @_;
 170
 171   my $bind_attributes = {
 172     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 173     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 174   };
 175
 176   if( defined $bind_attributes->{$data_type} ) {
 177     return $bind_attributes->{$data_type};
 178   }
 179   else {
 180     return;
 181   }
 182 }
 183
 184 sub _svp_begin {
 185     my ($self, $name) = @_;
 186
 187     $self->_get_dbh->pg_savepoint($name);
 188 }
 189
 190 sub _svp_release {
 191     my ($self, $name) = @_;
 192
 193     $self->_get_dbh->pg_release($name);
 194 }
 195
 196 sub _svp_rollback {
 197     my ($self, $name) = @_;
 198
 199     $self->_get_dbh->pg_rollback_to($name);
 200 }
 201
 202 sub deployment_statements {
 203   my $self = shift;;
 204   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 205
 206   $sqltargs ||= {};
 207
 208   if (
 209     ! exists $sqltargs->{producer_args}{postgres_version}
 210       and
 211     my $dver = $self->_server_info->{normalized_dbms_version}
 212   ) {
 213     $sqltargs->{producer_args}{postgres_version} = $dver;
 214   }
 215
 216   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 217 }
 218
 219 1;
 220
 221 __END__
 222
 223 =head1 NAME
 224
 225 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 226
 227 =head1 SYNOPSIS
 228
 229   # In your result (table) classes
 230   use base 'DBIx::Class::Core';
 231   __PACKAGE__->set_primary_key('id');
 232   __PACKAGE__->sequence('mysequence');
 233
 234 =head1 DESCRIPTION
 235
 236 This class implements autoincrements for PostgreSQL.
 237
 238 =head1 POSTGRESQL SCHEMA SUPPORT
 239
 240 This driver supports multiple PostgreSQL schemas, with one caveat: for
 241 performance reasons, data about the search path, sequence names, and
 242 so forth is queried as needed and CACHED for subsequent uses.
 243
 244 For this reason, once your schema is instantiated, you should not
 245 change the PostgreSQL schema search path for that schema's database
 246 connection. If you do, Bad Things may happen.
 247
 248 You should do any necessary manipulation of the search path BEFORE
 249 instantiating your schema object, or as part of the on_connect_do
 250 option to connect(), for example:
 251
 252    my $schema = My::Schema->connect
 253                   ( $dsn,$user,$pass,
 254                     { on_connect_do =>
 255                         [ 'SET search_path TO myschema, foo, public' ],
 256                     },
 257                   );
 258
 259 =head1 AUTHORS
 260
 261 See L<DBIx::Class/CONTRIBUTORS>
 262
 263 =head1 LICENSE
 264
 265 You may distribute this code under the same terms as Perl itself.
 266
 267 =cut