lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve ();
  14
  15 # Ask for a DBD::Pg with array support
  16 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  17   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  18
  19 sub can_insert_returning {
  20   # FIXME !!!
  21   # pg before 8.2 doesn't support this, need to check version
  22   return 1;
  23 }
  24
  25 sub with_deferred_fk_checks {
  26   my ($self, $sub) = @_;
  27
  28   my $txn_scope_guard = $self->txn_scope_guard;
  29
  30   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  31
  32   my $sg = Scope::Guard->new(sub {
  33     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  34   });
  35
  36   return Context::Preserve::preserve_context(sub { $sub->() },
  37     after => sub { $txn_scope_guard->commit });
  38 }
  39
  40 sub last_insert_id {
  41   my ($self,$source,@cols) = @_;
  42
  43   my @values;
  44
  45   for my $col (@cols) {
  46     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  47       or $self->throw_exception( sprintf(
  48         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  49           $source->name,
  50           $col,
  51       ));
  52
  53     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  54   }
  55
  56   return @values;
  57 }
  58
  59 sub _sequence_fetch {
  60   my ($self, $function, $sequence) = @_;
  61
  62   $self->throw_exception('No sequence to fetch') unless $sequence;
  63
  64   my ($val) = $self->_get_dbh->selectrow_array(
  65     sprintf "select $function('%s')",
  66       $sequence
  67   );
  68
  69   return $val;
  70 }
  71
  72 sub _dbh_get_autoinc_seq {
  73   my ($self, $dbh, $source, $col) = @_;
  74
  75   my $schema;
  76   my $table = $source->name;
  77
  78   # deref table name if it needs it
  79   $table = $$table
  80       if ref $table eq 'SCALAR';
  81
  82   # parse out schema name if present
  83   if( $table =~ /^(.+)\.(.+)$/ ) {
  84     ( $schema, $table ) = ( $1, $2 );
  85   }
  86
  87   # get the column default using a Postgres-specific pg_catalog query
  88   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  89
  90   # if no default value is set on the column, or if we can't parse the
  91   # default value as a sequence, throw.
  92   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  93     $seq_expr = '' unless defined $seq_expr;
  94     $schema = "$schema." if defined $schema && length $schema;
  95     $self->throw_exception( sprintf (
  96       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
  97       "'sequence' for this column in %s",
  98         $schema ? "$schema." : '',
  99         $table,
 100         $col,
 101         $source->source_name,
 102     ));
 103   }
 104
 105   return $1;
 106 }
 107
 108 # custom method for fetching column default, since column_info has a
 109 # bug with older versions of DBD::Pg
 110 sub _dbh_get_column_default {
 111   my ( $self, $dbh, $schema, $table, $col ) = @_;
 112
 113   # Build and execute a query into the pg_catalog to find the Pg
 114   # expression for the default value for this column in this table.
 115   # If the table name is schema-qualified, query using that specific
 116   # schema name.
 117
 118   # Otherwise, find the table in the standard Postgres way, using the
 119   # search path.  This is done with the pg_catalog.pg_table_is_visible
 120   # function, which returns true if a given table is 'visible',
 121   # meaning the first table of that name to be found in the search
 122   # path.
 123
 124   # I *think* we can be assured that this query will always find the
 125   # correct column according to standard Postgres semantics.
 126   #
 127   # -- rbuels
 128
 129   my $sqlmaker = $self->sql_maker;
 130   local $sqlmaker->{bindtype} = 'normal';
 131
 132   my ($where, @bind) = $sqlmaker->where ({
 133     'a.attnum' => {'>', 0},
 134     'c.relname' => $table,
 135     'a.attname' => $col,
 136     -not_bool => 'a.attisdropped',
 137     (defined $schema && length $schema)
 138       ? ( 'n.nspname' => $schema )
 139       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 140   });
 141
 142   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 143
 144 SELECT
 145   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 146    FROM pg_catalog.pg_attrdef d
 147    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 148 FROM pg_catalog.pg_class c
 149      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 150      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 151 $where
 152
 153 EOS
 154
 155   return $seq_expr;
 156 }
 157
 158
 159 sub sqlt_type {
 160   return 'PostgreSQL';
 161 }
 162
 163 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 164
 165 sub bind_attribute_by_data_type {
 166   my ($self,$data_type) = @_;
 167
 168   my $bind_attributes = {
 169     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 170     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 171   };
 172
 173   if( defined $bind_attributes->{$data_type} ) {
 174     return $bind_attributes->{$data_type};
 175   }
 176   else {
 177     return;
 178   }
 179 }
 180
 181 sub _svp_begin {
 182     my ($self, $name) = @_;
 183
 184     $self->_get_dbh->pg_savepoint($name);
 185 }
 186
 187 sub _svp_release {
 188     my ($self, $name) = @_;
 189
 190     $self->_get_dbh->pg_release($name);
 191 }
 192
 193 sub _svp_rollback {
 194     my ($self, $name) = @_;
 195
 196     $self->_get_dbh->pg_rollback_to($name);
 197 }
 198
 199 1;
 200
 201 __END__
 202
 203 =head1 NAME
 204
 205 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 206
 207 =head1 SYNOPSIS
 208
 209   # In your result (table) classes
 210   use base 'DBIx::Class::Core';
 211   __PACKAGE__->set_primary_key('id');
 212   __PACKAGE__->sequence('mysequence');
 213
 214 =head1 DESCRIPTION
 215
 216 This class implements autoincrements for PostgreSQL.
 217
 218 =head1 POSTGRESQL SCHEMA SUPPORT
 219
 220 This driver supports multiple PostgreSQL schemas, with one caveat: for
 221 performance reasons, data about the search path, sequence names, and
 222 so forth is queried as needed and CACHED for subsequent uses.
 223
 224 For this reason, once your schema is instantiated, you should not
 225 change the PostgreSQL schema search path for that schema's database
 226 connection. If you do, Bad Things may happen.
 227
 228 You should do any necessary manipulation of the search path BEFORE
 229 instantiating your schema object, or as part of the on_connect_do
 230 option to connect(), for example:
 231
 232    my $schema = My::Schema->connect
 233                   ( $dsn,$user,$pass,
 234                     { on_connect_do =>
 235                         [ 'SET search_path TO myschema, foo, public' ],
 236                     },
 237                   );
 238
 239 =head1 AUTHORS
 240
 241 See L<DBIx::Class/CONTRIBUTORS>
 242
 243 =head1 LICENSE
 244
 245 You may distribute this code under the same terms as Perl itself.
 246
 247 =cut