lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve ();
  14
  15 # Ask for a DBD::Pg with array support
  16 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  17   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  18
  19 sub can_insert_returning {
  20   # FIXME !!!
  21   # pg before 8.2 doesn't support this, need to check version
  22   return 1;
  23 }
  24
  25 sub with_deferred_fk_checks {
  26   my ($self, $sub) = @_;
  27
  28   my $txn_scope_guard = $self->txn_scope_guard;
  29
  30   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  31
  32   my $sg = Scope::Guard->new(sub {
  33     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  34   });
  35
  36   return Context::Preserve::preserve_context(sub { $sub->() },
  37     after => sub { $txn_scope_guard->commit });
  38 }
  39
  40 sub last_insert_id {
  41   my ($self,$source,@cols) = @_;
  42
  43   my @values;
  44
  45   for my $col (@cols) {
  46     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  47       or $self->throw_exception( sprintf(
  48         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  49           $source->name,
  50           $col,
  51       ));
  52
  53     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  54   }
  55
  56   return @values;
  57 }
  58
  59 sub _sequence_fetch {
  60   my ($self, $function, $sequence) = @_;
  61
  62   $self->throw_exception('No sequence to fetch') unless $sequence;
  63
  64   my ($val) = $self->_get_dbh->selectrow_array(
  65     sprintf ("select %s('%s')", $function, $sequence)
  66   );
  67
  68   return $val;
  69 }
  70
  71 sub _dbh_get_autoinc_seq {
  72   my ($self, $dbh, $source, $col) = @_;
  73
  74   my $schema;
  75   my $table = $source->name;
  76
  77   # deref table name if it needs it
  78   $table = $$table
  79       if ref $table eq 'SCALAR';
  80
  81   # parse out schema name if present
  82   if( $table =~ /^(.+)\.(.+)$/ ) {
  83     ( $schema, $table ) = ( $1, $2 );
  84   }
  85
  86   # get the column default using a Postgres-specific pg_catalog query
  87   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  88
  89   # if no default value is set on the column, or if we can't parse the
  90   # default value as a sequence, throw.
  91   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  92     $seq_expr = '' unless defined $seq_expr;
  93     $schema = "$schema." if defined $schema && length $schema;
  94     $self->throw_exception( sprintf (
  95       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
  96       "'sequence' for this column in %s",
  97         $schema ? "$schema." : '',
  98         $table,
  99         $col,
 100         $source->source_name,
 101     ));
 102   }
 103
 104   return $1;
 105 }
 106
 107 # custom method for fetching column default, since column_info has a
 108 # bug with older versions of DBD::Pg
 109 sub _dbh_get_column_default {
 110   my ( $self, $dbh, $schema, $table, $col ) = @_;
 111
 112   # Build and execute a query into the pg_catalog to find the Pg
 113   # expression for the default value for this column in this table.
 114   # If the table name is schema-qualified, query using that specific
 115   # schema name.
 116
 117   # Otherwise, find the table in the standard Postgres way, using the
 118   # search path.  This is done with the pg_catalog.pg_table_is_visible
 119   # function, which returns true if a given table is 'visible',
 120   # meaning the first table of that name to be found in the search
 121   # path.
 122
 123   # I *think* we can be assured that this query will always find the
 124   # correct column according to standard Postgres semantics.
 125   #
 126   # -- rbuels
 127
 128   my $sqlmaker = $self->sql_maker;
 129   local $sqlmaker->{bindtype} = 'normal';
 130
 131   my ($where, @bind) = $sqlmaker->where ({
 132     'a.attnum' => {'>', 0},
 133     'c.relname' => $table,
 134     'a.attname' => $col,
 135     -not_bool => 'a.attisdropped',
 136     (defined $schema && length $schema)
 137       ? ( 'n.nspname' => $schema )
 138       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 139   });
 140
 141   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 142
 143 SELECT
 144   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 145    FROM pg_catalog.pg_attrdef d
 146    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 147 FROM pg_catalog.pg_class c
 148      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 149      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 150 $where
 151
 152 EOS
 153
 154   return $seq_expr;
 155 }
 156
 157
 158 sub sqlt_type {
 159   return 'PostgreSQL';
 160 }
 161
 162 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 163
 164 sub bind_attribute_by_data_type {
 165   my ($self,$data_type) = @_;
 166
 167   my $bind_attributes = {
 168     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 169     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 170   };
 171
 172   if( defined $bind_attributes->{$data_type} ) {
 173     return $bind_attributes->{$data_type};
 174   }
 175   else {
 176     return;
 177   }
 178 }
 179
 180 sub _svp_begin {
 181     my ($self, $name) = @_;
 182
 183     $self->_get_dbh->pg_savepoint($name);
 184 }
 185
 186 sub _svp_release {
 187     my ($self, $name) = @_;
 188
 189     $self->_get_dbh->pg_release($name);
 190 }
 191
 192 sub _svp_rollback {
 193     my ($self, $name) = @_;
 194
 195     $self->_get_dbh->pg_rollback_to($name);
 196 }
 197
 198 1;
 199
 200 __END__
 201
 202 =head1 NAME
 203
 204 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 205
 206 =head1 SYNOPSIS
 207
 208   # In your result (table) classes
 209   use base 'DBIx::Class::Core';
 210   __PACKAGE__->set_primary_key('id');
 211   __PACKAGE__->sequence('mysequence');
 212
 213 =head1 DESCRIPTION
 214
 215 This class implements autoincrements for PostgreSQL.
 216
 217 =head1 POSTGRESQL SCHEMA SUPPORT
 218
 219 This driver supports multiple PostgreSQL schemas, with one caveat: for
 220 performance reasons, data about the search path, sequence names, and
 221 so forth is queried as needed and CACHED for subsequent uses.
 222
 223 For this reason, once your schema is instantiated, you should not
 224 change the PostgreSQL schema search path for that schema's database
 225 connection. If you do, Bad Things may happen.
 226
 227 You should do any necessary manipulation of the search path BEFORE
 228 instantiating your schema object, or as part of the on_connect_do
 229 option to connect(), for example:
 230
 231    my $schema = My::Schema->connect
 232                   ( $dsn,$user,$pass,
 233                     { on_connect_do =>
 234                         [ 'SET search_path TO myschema, foo, public' ],
 235                     },
 236                   );
 237
 238 =head1 AUTHORS
 239
 240 See L<DBIx::Class/CONTRIBUTORS>
 241
 242 =head1 LICENSE
 243
 244 You may distribute this code under the same terms as Perl itself.
 245
 246 =cut