lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve ();
  14
  15 # Ask for a DBD::Pg with array support
  16 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  17   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  18
  19 sub can_insert_returning {
  20   my $self = shift;
  21
  22   my $pg_ver = $self->_get_dbh->get_info(18);
  23
  24   my ($major, $minor) = $pg_ver =~ /^(\d+)\.(\d+)/;
  25
  26   return 1
  27     if ($major > 8) || ($major == 8 && $minor >= 2);
  28
  29   return 0;
  30 }
  31
  32 sub with_deferred_fk_checks {
  33   my ($self, $sub) = @_;
  34
  35   my $txn_scope_guard = $self->txn_scope_guard;
  36
  37   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  38
  39   my $sg = Scope::Guard->new(sub {
  40     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  41   });
  42
  43   return Context::Preserve::preserve_context(sub { $sub->() },
  44     after => sub { $txn_scope_guard->commit });
  45 }
  46
  47 # only used when INSERT ... RETURNING is disabled
  48 sub last_insert_id {
  49   my ($self,$source,@cols) = @_;
  50
  51   my @values;
  52
  53   for my $col (@cols) {
  54     my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  55       or $self->throw_exception( sprintf(
  56         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  57           $source->name,
  58           $col,
  59       ));
  60
  61     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  62   }
  63
  64   return @values;
  65 }
  66
  67 sub _sequence_fetch {
  68   my ($self, $function, $sequence) = @_;
  69
  70   $self->throw_exception('No sequence to fetch') unless $sequence;
  71
  72   my ($val) = $self->_get_dbh->selectrow_array(
  73     sprintf ("select %s('%s')", $function, $sequence)
  74   );
  75
  76   return $val;
  77 }
  78
  79 sub _dbh_get_autoinc_seq {
  80   my ($self, $dbh, $source, $col) = @_;
  81
  82   my $schema;
  83   my $table = $source->name;
  84
  85   # deref table name if it needs it
  86   $table = $$table
  87       if ref $table eq 'SCALAR';
  88
  89   # parse out schema name if present
  90   if( $table =~ /^(.+)\.(.+)$/ ) {
  91     ( $schema, $table ) = ( $1, $2 );
  92   }
  93
  94   # get the column default using a Postgres-specific pg_catalog query
  95   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  96
  97   # if no default value is set on the column, or if we can't parse the
  98   # default value as a sequence, throw.
  99   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
 100     $seq_expr = '' unless defined $seq_expr;
 101     $schema = "$schema." if defined $schema && length $schema;
 102     $self->throw_exception( sprintf (
 103       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 104       "'sequence' for this column in %s",
 105         $schema ? "$schema." : '',
 106         $table,
 107         $col,
 108         $source->source_name,
 109     ));
 110   }
 111
 112   return $1;
 113 }
 114
 115 # custom method for fetching column default, since column_info has a
 116 # bug with older versions of DBD::Pg
 117 sub _dbh_get_column_default {
 118   my ( $self, $dbh, $schema, $table, $col ) = @_;
 119
 120   # Build and execute a query into the pg_catalog to find the Pg
 121   # expression for the default value for this column in this table.
 122   # If the table name is schema-qualified, query using that specific
 123   # schema name.
 124
 125   # Otherwise, find the table in the standard Postgres way, using the
 126   # search path.  This is done with the pg_catalog.pg_table_is_visible
 127   # function, which returns true if a given table is 'visible',
 128   # meaning the first table of that name to be found in the search
 129   # path.
 130
 131   # I *think* we can be assured that this query will always find the
 132   # correct column according to standard Postgres semantics.
 133   #
 134   # -- rbuels
 135
 136   my $sqlmaker = $self->sql_maker;
 137   local $sqlmaker->{bindtype} = 'normal';
 138
 139   my ($where, @bind) = $sqlmaker->where ({
 140     'a.attnum' => {'>', 0},
 141     'c.relname' => $table,
 142     'a.attname' => $col,
 143     -not_bool => 'a.attisdropped',
 144     (defined $schema && length $schema)
 145       ? ( 'n.nspname' => $schema )
 146       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 147   });
 148
 149   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 150
 151 SELECT
 152   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 153    FROM pg_catalog.pg_attrdef d
 154    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 155 FROM pg_catalog.pg_class c
 156      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 157      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 158 $where
 159
 160 EOS
 161
 162   return $seq_expr;
 163 }
 164
 165
 166 sub sqlt_type {
 167   return 'PostgreSQL';
 168 }
 169
 170 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 171
 172 sub bind_attribute_by_data_type {
 173   my ($self,$data_type) = @_;
 174
 175   my $bind_attributes = {
 176     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 177     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 178   };
 179
 180   if( defined $bind_attributes->{$data_type} ) {
 181     return $bind_attributes->{$data_type};
 182   }
 183   else {
 184     return;
 185   }
 186 }
 187
 188 sub _svp_begin {
 189     my ($self, $name) = @_;
 190
 191     $self->_get_dbh->pg_savepoint($name);
 192 }
 193
 194 sub _svp_release {
 195     my ($self, $name) = @_;
 196
 197     $self->_get_dbh->pg_release($name);
 198 }
 199
 200 sub _svp_rollback {
 201     my ($self, $name) = @_;
 202
 203     $self->_get_dbh->pg_rollback_to($name);
 204 }
 205
 206 1;
 207
 208 __END__
 209
 210 =head1 NAME
 211
 212 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 213
 214 =head1 SYNOPSIS
 215
 216   # In your result (table) classes
 217   use base 'DBIx::Class::Core';
 218   __PACKAGE__->set_primary_key('id');
 219   __PACKAGE__->sequence('mysequence');
 220
 221 =head1 DESCRIPTION
 222
 223 This class implements autoincrements for PostgreSQL.
 224
 225 =head1 POSTGRESQL SCHEMA SUPPORT
 226
 227 This driver supports multiple PostgreSQL schemas, with one caveat: for
 228 performance reasons, data about the search path, sequence names, and
 229 so forth is queried as needed and CACHED for subsequent uses.
 230
 231 For this reason, once your schema is instantiated, you should not
 232 change the PostgreSQL schema search path for that schema's database
 233 connection. If you do, Bad Things may happen.
 234
 235 You should do any necessary manipulation of the search path BEFORE
 236 instantiating your schema object, or as part of the on_connect_do
 237 option to connect(), for example:
 238
 239    my $schema = My::Schema->connect
 240                   ( $dsn,$user,$pass,
 241                     { on_connect_do =>
 242                         [ 'SET search_path TO myschema, foo, public' ],
 243                     },
 244                   );
 245
 246 =head1 AUTHORS
 247
 248 See L<DBIx::Class/CONTRIBUTORS>
 249
 250 =head1 LICENSE
 251
 252 You may distribute this code under the same terms as Perl itself.
 253
 254 =cut