lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('RowNum');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  17 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  18
  19 sub __cache_queries_with_max_lob_parts { 2 }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  24
  25 =head1 SYNOPSIS
  26
  27   # In your result (table) classes
  28   use base 'DBIx::Class::Core';
  29   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  30   __PACKAGE__->set_primary_key('id');
  31
  32   # Somewhere in your Code
  33   # add some data to a table with a hierarchical relationship
  34   $schema->resultset('Person')->create ({
  35         firstname => 'foo',
  36         lastname => 'bar',
  37         children => [
  38             {
  39                 firstname => 'child1',
  40                 lastname => 'bar',
  41                 children => [
  42                     {
  43                         firstname => 'grandchild',
  44                         lastname => 'bar',
  45                     }
  46                 ],
  47             },
  48             {
  49                 firstname => 'child2',
  50                 lastname => 'bar',
  51             },
  52         ],
  53     });
  54
  55   # select from the hierarchical relationship
  56   my $rs = $schema->resultset('Person')->search({},
  57     {
  58       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  59       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  60       'order_siblings_by' => { -asc => 'name' },
  61     };
  62   );
  63
  64   # this will select the whole tree starting from person "foo bar", creating
  65   # following query:
  66   # SELECT
  67   #     me.persionid me.firstname, me.lastname, me.parentid
  68   # FROM
  69   #     person me
  70   # START WITH
  71   #     firstname = 'foo' and lastname = 'bar'
  72   # CONNECT BY
  73   #     parentid = prior personid
  74   # ORDER SIBLINGS BY
  75   #     firstname ASC
  76
  77 =head1 DESCRIPTION
  78
  79 This class implements base Oracle support. The subclass
  80 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  81 versions before 9.0.
  82
  83 =head1 METHODS
  84
  85 =cut
  86
  87 sub _determine_supports_insert_returning {
  88   my $self = shift;
  89
  90 # TODO find out which version supports the RETURNING syntax
  91 # 8i has it and earlier docs are a 404 on oracle.com
  92
  93   return 1
  94     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  95
  96   return 0;
  97 }
  98
  99 __PACKAGE__->_use_insert_returning_bound (1);
 100
 101 sub deployment_statements {
 102   my $self = shift;;
 103   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 104
 105   $sqltargs ||= {};
 106   my $quote_char = $self->schema->storage->sql_maker->quote_char;
 107   $sqltargs->{quote_table_names} = $quote_char ? 1 : 0;
 108   $sqltargs->{quote_field_names} = $quote_char ? 1 : 0;
 109
 110   if (
 111     ! exists $sqltargs->{producer_args}{oracle_version}
 112       and
 113     my $dver = $self->_server_info->{dbms_version}
 114   ) {
 115     $sqltargs->{producer_args}{oracle_version} = $dver;
 116   }
 117
 118   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 119 }
 120
 121 sub _dbh_last_insert_id {
 122   my ($self, $dbh, $source, @columns) = @_;
 123   my @ids = ();
 124   foreach my $col (@columns) {
 125     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 126     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 127     push @ids, $id;
 128   }
 129   return @ids;
 130 }
 131
 132 sub _dbh_get_autoinc_seq {
 133   my ($self, $dbh, $source, $col) = @_;
 134
 135   my $sql_maker = $self->sql_maker;
 136   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 137
 138   my $source_name;
 139   if ( ref $source->name eq 'SCALAR' ) {
 140     $source_name = ${$source->name};
 141
 142     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 143     # stuff unless it is already quoted
 144     $source_name = uc ($source_name) if $source_name !~ /\"/;
 145   }
 146   else {
 147     $source_name = $source->name;
 148     $source_name = uc($source_name) unless $ql;
 149   }
 150
 151   # trigger_body is a LONG
 152   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 153
 154   # disable default bindtype
 155   local $sql_maker->{bindtype} = 'normal';
 156
 157   # look up the correct sequence automatically
 158   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 159
 160   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 161   $schema ||= \'= USER';
 162
 163   my ($sql, @bind) = $sql_maker->select (
 164     'ALL_TRIGGERS',
 165     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 166     {
 167       OWNER => $schema,
 168       TABLE_NAME => $table || $source_name,
 169       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 170       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 171       STATUS => 'ENABLED',
 172      },
 173   );
 174
 175   # to find all the triggers that mention the column in question a simple
 176   # regex grep since the trigger_body above is a LONG and hence not searchable
 177   # via -like
 178   my @triggers = ( map
 179     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 180     ( grep
 181       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 182       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 183     )
 184   );
 185
 186   # extract all sequence names mentioned in each trigger, throw away
 187   # triggers without apparent sequences
 188   @triggers = map {
 189     my @seqs = $_->{body} =~ / ( [\.\w\"\-]+ ) \. nextval /xig;
 190     @seqs
 191       ? { %$_, sequences => \@seqs }
 192       : ()
 193     ;
 194   } @triggers;
 195
 196   my $chosen_trigger;
 197
 198   # if only one trigger matched things are easy
 199   if (@triggers == 1) {
 200
 201     if ( @{$triggers[0]{sequences}} == 1 ) {
 202       $chosen_trigger = $triggers[0];
 203     }
 204     else {
 205       $self->throw_exception( sprintf (
 206         "Unable to introspect trigger '%s' for column %s.%s (references multiple sequences). "
 207       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 208         $triggers[0]{name},
 209         $source_name,
 210         $col,
 211         $col,
 212       ) );
 213     }
 214   }
 215   # got more than one matching trigger - see if we can narrow it down
 216   elsif (@triggers > 1) {
 217
 218     my @candidates = grep
 219       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 220       @triggers
 221     ;
 222
 223     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 224       $chosen_trigger = $candidates[0];
 225     }
 226     else {
 227       $self->throw_exception( sprintf (
 228         "Unable to reliably select a BEFORE INSERT trigger for column %s.%s (possibilities: %s). "
 229       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 230         $source_name,
 231         $col,
 232         ( join ', ', map { "'$_->{name}'" } @triggers ),
 233         $col,
 234       ) );
 235     }
 236   }
 237
 238   if ($chosen_trigger) {
 239     my $seq_name = $chosen_trigger->{sequences}[0];
 240
 241     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 242       unless $seq_name =~ /\./;
 243
 244     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 245     return $seq_name;
 246   }
 247
 248   $self->throw_exception( sprintf (
 249     "No suitable BEFORE INSERT triggers found for column %s.%s. "
 250   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 251     $source_name,
 252     $col,
 253     $col,
 254   ));
 255 }
 256
 257 sub _sequence_fetch {
 258   my ( $self, $type, $seq ) = @_;
 259
 260   # use the maker to leverage quoting settings
 261   my $sth = $self->_dbh->prepare_cached(
 262     $self->sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] )
 263   );
 264   $sth->execute;
 265   my ($id) = $sth->fetchrow_array;
 266   $sth->finish;
 267   return $id;
 268 }
 269
 270 sub _ping {
 271   my $self = shift;
 272
 273   my $dbh = $self->_dbh or return 0;
 274
 275   local $dbh->{RaiseError} = 1;
 276   local $dbh->{PrintError} = 0;
 277
 278   return try {
 279     $dbh->do('select 1 from dual');
 280     1;
 281   } catch {
 282     0;
 283   };
 284 }
 285
 286 sub _dbh_execute {
 287   my ($self, $dbh, $sql, @args) = @_;
 288
 289   my (@res, $tried);
 290   my $want = wantarray;
 291   my $next = $self->next::can;
 292   do {
 293     try {
 294       my $exec = sub {
 295         # Turn off sth caching for multi-part LOBs. See _prep_for_execute above.
 296         local $self->{disable_sth_caching} = 1
 297           if first {
 298             ($_->[0]{_ora_lob_autosplit_part}||0)
 299               > (__cache_queries_with_max_lob_parts-1)
 300           } @{ $args[0] };
 301
 302         $self->$next($dbh, $sql, @args)
 303       };
 304
 305       if (!defined $want) {
 306         $exec->();
 307       }
 308       elsif (! $want) {
 309         $res[0] = $exec->();
 310       }
 311       else {
 312         @res = $exec->();
 313       }
 314
 315       $tried++;
 316     }
 317     catch {
 318       if (! $tried and $_ =~ /ORA-01003/) {
 319         # ORA-01003: no statement parsed (someone changed the table somehow,
 320         # invalidating your cursor.)
 321         delete $dbh->{CachedKids}{$sql};
 322       }
 323       else {
 324         $self->throw_exception($_);
 325       }
 326     };
 327   } while (! $tried++);
 328
 329   return wantarray ? @res : $res[0];
 330 }
 331
 332 sub _dbh_execute_array {
 333   #my ($self, $sth, $tuple_status, @extra) = @_;
 334
 335   # DBD::Oracle warns loudly on partial execute_array failures
 336   local $_[1]->{PrintWarn} = 0;
 337
 338   shift->next::method(@_);
 339 }
 340
 341 =head2 get_autoinc_seq
 342
 343 Returns the sequence name for an autoincrement column
 344
 345 =cut
 346
 347 sub get_autoinc_seq {
 348   my ($self, $source, $col) = @_;
 349
 350   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 351 }
 352
 353 =head2 datetime_parser_type
 354
 355 This sets the proper DateTime::Format module for use with
 356 L<DBIx::Class::InflateColumn::DateTime>.
 357
 358 =head2 connect_call_datetime_setup
 359
 360 Used as:
 361
 362     on_connect_call => 'datetime_setup'
 363
 364 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 365 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 366 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 367 is used by it.
 368
 369 Maximum allowable precision is used, unless the environment variables have
 370 already been set.
 371
 372 These are the defaults used:
 373
 374   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 375   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 376   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 377
 378 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 379 for your timestamps, use something like this:
 380
 381   use Time::HiRes 'time';
 382   my $ts = DateTime->from_epoch(epoch => time);
 383
 384 =cut
 385
 386 sub connect_call_datetime_setup {
 387   my $self = shift;
 388
 389   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 390   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 391     'YYYY-MM-DD HH24:MI:SS.FF';
 392   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 393     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 394
 395   $self->_do_query(
 396     "alter session set nls_date_format = '$date_format'"
 397   );
 398   $self->_do_query(
 399     "alter session set nls_timestamp_format = '$timestamp_format'"
 400   );
 401   $self->_do_query(
 402     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 403   );
 404 }
 405
 406 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 407 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 408 #
 409 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 410 # with the driver assuming your input is the deprecated LONG type if you
 411 # encode it as a hex string.  That ain't gonna fly at larger values, where
 412 # you'll discover you have to do what this does.
 413 #
 414 # This method had to be overridden because we need to set ora_field to the
 415 # actual column, and that isn't passed to the call (provided by Storage) to
 416 # bind_attribute_by_data_type.
 417 #
 418 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 419 # adding it doesn't hurt, and will save your bacon if you're modifying a
 420 # table with more than one LOB column.
 421 #
 422 sub _dbi_attrs_for_bind {
 423   my ($self, $ident, $bind) = @_;
 424
 425   my $attrs = $self->next::method($ident, $bind);
 426
 427   for my $i (0 .. $#$attrs) {
 428     if (keys %{$attrs->[$i]||{}} and my $col = $bind->[$i][0]{dbic_colname}) {
 429       $attrs->[$i]{ora_field} = $col;
 430     }
 431   }
 432
 433   $attrs;
 434 }
 435
 436 my $dbd_loaded;
 437 sub bind_attribute_by_data_type {
 438   my ($self, $dt) = @_;
 439
 440   $dbd_loaded ||= do {
 441     require DBD::Oracle;
 442     if ($DBD::Oracle::VERSION eq '1.23') {
 443       $self->throw_exception(
 444         "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later ".
 445         "version.\n\nSee: https://rt.cpan.org/Public/Bug/Display.html?id=46016\n"
 446       );
 447     }
 448     1;
 449   };
 450
 451   if ($self->_is_lob_type($dt)) {
 452     return {
 453       ora_type => $self->_is_text_lob_type($dt)
 454         ? DBD::Oracle::ORA_CLOB()
 455         : DBD::Oracle::ORA_BLOB()
 456     };
 457   }
 458 }
 459
 460 # Handle blob columns in WHERE.
 461 #
 462 # For equality comparisons:
 463 #
 464 # We split data intended for comparing to a LOB into 2000 character chunks and
 465 # compare them using dbms_lob.substr on the LOB column.
 466 #
 467 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 468 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 469 # otherwise the query will fail.
 470 #
 471 # Since the most common comparison size is likely to be under 4000 characters
 472 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 473 # prepare_cached for queries with more than two part comparisons to a LOB
 474 # column. This is done in _dbh_execute (above) which was previously overridden
 475 # to gracefully recover from an Oracle error. This is to be careful to not
 476 # exhaust your application's open cursor limit.
 477 #
 478 # See:
 479 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 480 # on the open_cursor limit.
 481 #
 482 # For everything else:
 483 #
 484 # We assume that everything that is not a LOB comparison, will most likely be a
 485 # LIKE query or some sort of function invocation. This may prove to be a naive
 486 # assumption in the future, but for now it should cover the two most likely
 487 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 488 # query (on a CLOB.)
 489 #
 490 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 491 # DBD::Oracle, otherwise the query will fail. This is done by passing
 492 # dbd_attrs => undef.
 493
 494 sub _prep_for_execute {
 495   my $self = shift;
 496   my ($op) = @_;
 497
 498   my ($sql, $bind) = $self->next::method(@_);
 499
 500   return ($sql, $bind) if $op eq 'insert';
 501
 502   my $blob_bind_index;
 503   for (0 .. $#$bind) {
 504     $blob_bind_index->{$_} = 1 if $self->_is_lob_type(
 505       $bind->[$_][0]{sqlt_datatype}
 506     );
 507   }
 508
 509   return ($sql, $bind) unless $blob_bind_index;
 510
 511   my (@sql_parts, $new_sql, @new_binds);
 512
 513   if ($op eq 'select' || $op eq 'delete') {
 514     @sql_parts = split /\?/, $sql;
 515   }
 516   elsif ($op eq 'update') {
 517     $self->throw_exception('Update with complex WHERE clauses currently not supported')
 518       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 519
 520     my ($set_part, $where_part) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 521
 522     my $set_bind_count = $set_part =~ y/?//;
 523     @new_binds = splice @$bind, 0, $set_bind_count;
 524
 525     @sql_parts = split /\?/, $where_part;
 526     $new_sql  = $set_part;
 527   }
 528   else {
 529     $self->throw_exception("Unsupported \$op: $op");
 530   }
 531
 532   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 533
 534   for my $b_idx (0 .. $#$bind) {
 535     my $bound = $bind->[$b_idx];
 536
 537     if ($blob_bind_index->{$b_idx}) {
 538       if (my ($col, $eq) = $sql_parts[0] =~ $col_equality_re) {
 539         my $data = $bound->[1];
 540
 541         $data = "$data" if ref $data;
 542
 543         my @parts = unpack '(a2000)*', $data;
 544
 545         my @sql_frag;
 546
 547         for my $idx (0..$#parts) {
 548           push @sql_frag, sprintf (
 549             'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 550             $col, ($idx*2000 + 1),
 551           );
 552         }
 553
 554         my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 555
 556         $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 557
 558         $new_sql .= shift @sql_parts;
 559
 560         for my $idx (0..$#parts) {
 561           push @new_binds, [
 562             {
 563               %{ $bound->[0] },
 564               _ora_lob_autosplit_part => $idx,
 565               dbd_attrs => undef,
 566             },
 567             $parts[$idx]
 568           ];
 569         }
 570       }
 571       else {
 572         $new_sql .= shift(@sql_parts) . '?';
 573
 574         push @new_binds, [
 575           {
 576             %{ $bound->[0] },
 577             dbd_attrs => undef,
 578           },
 579           $bound->[1],
 580         ];
 581       }
 582     }
 583     else {
 584       $new_sql .= shift(@sql_parts) . '?';
 585       push @new_binds, $bound;
 586     }
 587   }
 588
 589   if (@sql_parts > 1) {
 590     carp "There are more placeholders than binds, this should not happen!";
 591     @sql_parts = join ('?', @sql_parts);
 592   }
 593
 594   $new_sql .= $sql_parts[0];
 595
 596   return ($new_sql, \@new_binds);
 597 }
 598
 599 # Savepoints stuff.
 600
 601 sub _exec_svp_begin {
 602   my ($self, $name) = @_;
 603   $self->_dbh->do("SAVEPOINT $name");
 604 }
 605
 606 # Oracle automatically releases a savepoint when you start another one with the
 607 # same name.
 608 sub _exec_svp_release { 1 }
 609
 610 sub _exec_svp_rollback {
 611   my ($self, $name) = @_;
 612   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 613 }
 614
 615 =head2 relname_to_table_alias
 616
 617 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 618 queries.
 619
 620 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 621 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 622 MD5 hash.
 623
 624 See L<DBIx::Class::Storage/"relname_to_table_alias">.
 625
 626 =cut
 627
 628 sub relname_to_table_alias {
 629   my $self = shift;
 630   my ($relname, $join_count) = @_;
 631
 632   my $alias = $self->next::method(@_);
 633
 634   # we need to shorten here in addition to the shortening in SQLA itself,
 635   # since the final relnames are a crucial for the join optimizer
 636   return $self->sql_maker->_shorten_identifier($alias);
 637 }
 638
 639 =head2 with_deferred_fk_checks
 640
 641 Runs a coderef between:
 642
 643   alter session set constraints = deferred
 644   ...
 645   alter session set constraints = immediate
 646
 647 to defer foreign key checks.
 648
 649 Constraints must be declared C<DEFERRABLE> for this to work.
 650
 651 =cut
 652
 653 sub with_deferred_fk_checks {
 654   my ($self, $sub) = @_;
 655
 656   my $txn_scope_guard = $self->txn_scope_guard;
 657
 658   $self->_do_query('alter session set constraints = deferred');
 659
 660   my $sg = Scope::Guard->new(sub {
 661     $self->_do_query('alter session set constraints = immediate');
 662   });
 663
 664   return
 665     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 666 }
 667
 668 =head1 ATTRIBUTES
 669
 670 Following additional attributes can be used in resultsets.
 671
 672 =head2 connect_by or connect_by_nocycle
 673
 674 =over 4
 675
 676 =item Value: \%connect_by
 677
 678 =back
 679
 680 A hashref of conditions used to specify the relationship between parent rows
 681 and child rows of the hierarchy.
 682
 683
 684   connect_by => { parentid => 'prior personid' }
 685
 686   # adds a connect by statement to the query:
 687   # SELECT
 688   #     me.persionid me.firstname, me.lastname, me.parentid
 689   # FROM
 690   #     person me
 691   # CONNECT BY
 692   #     parentid = prior persionid
 693
 694
 695   connect_by_nocycle => { parentid => 'prior personid' }
 696
 697   # adds a connect by statement to the query:
 698   # SELECT
 699   #     me.persionid me.firstname, me.lastname, me.parentid
 700   # FROM
 701   #     person me
 702   # CONNECT BY NOCYCLE
 703   #     parentid = prior persionid
 704
 705
 706 =head2 start_with
 707
 708 =over 4
 709
 710 =item Value: \%condition
 711
 712 =back
 713
 714 A hashref of conditions which specify the root row(s) of the hierarchy.
 715
 716 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 717
 718   start_with => { firstname => 'Foo', lastname => 'Bar' }
 719
 720   # SELECT
 721   #     me.persionid me.firstname, me.lastname, me.parentid
 722   # FROM
 723   #     person me
 724   # START WITH
 725   #     firstname = 'foo' and lastname = 'bar'
 726   # CONNECT BY
 727   #     parentid = prior persionid
 728
 729 =head2 order_siblings_by
 730
 731 =over 4
 732
 733 =item Value: ($order_siblings_by | \@order_siblings_by)
 734
 735 =back
 736
 737 Which column(s) to order the siblings by.
 738
 739 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 740
 741   'order_siblings_by' => 'firstname ASC'
 742
 743   # SELECT
 744   #     me.persionid me.firstname, me.lastname, me.parentid
 745   # FROM
 746   #     person me
 747   # CONNECT BY
 748   #     parentid = prior persionid
 749   # ORDER SIBLINGS BY
 750   #     firstname ASC
 751
 752 =head1 AUTHOR
 753
 754 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 755
 756 =head1 LICENSE
 757
 758 You may distribute this code under the same terms as Perl itself.
 759
 760 =cut
 761
 762 1;
 763 # vim:sts=2 sw=2: