lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use DBIx::Class::_Util qw( modver_gt_or_eq_and_lt dbic_internal_try );
  11 use namespace::clean;
  12
  13 __PACKAGE__->sql_limit_dialect ('RowNum');
  14 __PACKAGE__->sql_quote_char ('"');
  15 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  16 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  17
  18 sub __cache_queries_with_max_lob_parts { 2 }
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  23
  24 =head1 SYNOPSIS
  25
  26   # In your result (table) classes
  27   use base 'DBIx::Class::Core';
  28   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  29   __PACKAGE__->set_primary_key('id');
  30
  31   # Somewhere in your Code
  32   # add some data to a table with a hierarchical relationship
  33   $schema->resultset('Person')->create ({
  34         firstname => 'foo',
  35         lastname => 'bar',
  36         children => [
  37             {
  38                 firstname => 'child1',
  39                 lastname => 'bar',
  40                 children => [
  41                     {
  42                         firstname => 'grandchild',
  43                         lastname => 'bar',
  44                     }
  45                 ],
  46             },
  47             {
  48                 firstname => 'child2',
  49                 lastname => 'bar',
  50             },
  51         ],
  52     });
  53
  54   # select from the hierarchical relationship
  55   my $rs = $schema->resultset('Person')->search({},
  56     {
  57       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  58       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  59       'order_siblings_by' => { -asc => 'name' },
  60     };
  61   );
  62
  63   # this will select the whole tree starting from person "foo bar", creating
  64   # following query:
  65   # SELECT
  66   #     me.persionid me.firstname, me.lastname, me.parentid
  67   # FROM
  68   #     person me
  69   # START WITH
  70   #     firstname = 'foo' and lastname = 'bar'
  71   # CONNECT BY
  72   #     parentid = prior personid
  73   # ORDER SIBLINGS BY
  74   #     firstname ASC
  75
  76 =head1 DESCRIPTION
  77
  78 This class implements base Oracle support. The subclass
  79 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  80 versions before 9.0.
  81
  82 =head1 METHODS
  83
  84 =cut
  85
  86 sub _determine_supports_insert_returning {
  87   my $self = shift;
  88
  89 # TODO find out which version supports the RETURNING syntax
  90 # 8i has it and earlier docs are a 404 on oracle.com
  91
  92   return 1
  93     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  94
  95   return 0;
  96 }
  97
  98 __PACKAGE__->_use_insert_returning_bound (1);
  99
 100 sub deployment_statements {
 101   my $self = shift;;
 102   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 103
 104   $sqltargs ||= {};
 105
 106   if (
 107     ! exists $sqltargs->{producer_args}{oracle_version}
 108       and
 109     my $dver = $self->_server_info->{dbms_version}
 110   ) {
 111     $sqltargs->{producer_args}{oracle_version} = $dver;
 112   }
 113
 114   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 115 }
 116
 117 sub _dbh_last_insert_id {
 118   my ($self, $dbh, $source, @columns) = @_;
 119   my @ids = ();
 120   foreach my $col (@columns) {
 121     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 122     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 123     push @ids, $id;
 124   }
 125   return @ids;
 126 }
 127
 128 sub _dbh_get_autoinc_seq {
 129   my ($self, $dbh, $source, $col) = @_;
 130
 131   my $sql_maker = $self->sql_maker;
 132   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 133
 134   my $source_name;
 135   if ( ref $source->name eq 'SCALAR' ) {
 136     $source_name = ${$source->name};
 137
 138     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 139     # stuff unless it is already quoted
 140     $source_name = uc ($source_name) if $source_name !~ /\"/;
 141   }
 142   else {
 143     $source_name = $source->name;
 144     $source_name = uc($source_name) unless $ql;
 145   }
 146
 147   # trigger_body is a LONG
 148   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 149
 150   # disable default bindtype
 151   local $sql_maker->{bindtype} = 'normal';
 152
 153   # look up the correct sequence automatically
 154   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 155
 156   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 157   $schema ||= \'= USER';
 158
 159   my ($sql, @bind) = $sql_maker->select (
 160     'ALL_TRIGGERS',
 161     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 162     {
 163       OWNER => $schema,
 164       TABLE_NAME => $table || $source_name,
 165       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 166       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 167       STATUS => 'ENABLED',
 168      },
 169   );
 170
 171   # to find all the triggers that mention the column in question a simple
 172   # regex grep since the trigger_body above is a LONG and hence not searchable
 173   # via -like
 174   my @triggers = ( map
 175     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 176     ( grep
 177       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 178       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 179     )
 180   );
 181
 182   # extract all sequence names mentioned in each trigger, throw away
 183   # triggers without apparent sequences
 184   @triggers = map {
 185     my @seqs = $_->{body} =~ / ( [\.\w\"\-]+ ) \. nextval /xig;
 186     @seqs
 187       ? { %$_, sequences => \@seqs }
 188       : ()
 189     ;
 190   } @triggers;
 191
 192   my $chosen_trigger;
 193
 194   # if only one trigger matched things are easy
 195   if (@triggers == 1) {
 196
 197     if ( @{$triggers[0]{sequences}} == 1 ) {
 198       $chosen_trigger = $triggers[0];
 199     }
 200     else {
 201       $self->throw_exception( sprintf (
 202         "Unable to introspect trigger '%s' for column '%s.%s' (references multiple sequences). "
 203       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 204         $triggers[0]{name},
 205         $source_name,
 206         $col,
 207         $col,
 208       ) );
 209     }
 210   }
 211   # got more than one matching trigger - see if we can narrow it down
 212   elsif (@triggers > 1) {
 213
 214     my @candidates = grep
 215       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 216       @triggers
 217     ;
 218
 219     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 220       $chosen_trigger = $candidates[0];
 221     }
 222     else {
 223       $self->throw_exception( sprintf (
 224         "Unable to reliably select a BEFORE INSERT trigger for column '%s.%s' (possibilities: %s). "
 225       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 226         $source_name,
 227         $col,
 228         ( join ', ', map { "'$_->{name}'" } @triggers ),
 229         $col,
 230       ) );
 231     }
 232   }
 233
 234   if ($chosen_trigger) {
 235     my $seq_name = $chosen_trigger->{sequences}[0];
 236
 237     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 238       unless $seq_name =~ /\./;
 239
 240     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 241     return $seq_name;
 242   }
 243
 244   $self->throw_exception( sprintf (
 245     "No suitable BEFORE INSERT triggers found for column '%s.%s'. "
 246   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 247     $source_name,
 248     $col,
 249     $col,
 250   ));
 251 }
 252
 253 sub _sequence_fetch {
 254   my ( $self, $type, $seq ) = @_;
 255
 256   # use the maker to leverage quoting settings
 257   my $sth = $self->_dbh->prepare_cached(
 258     $self->sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] )
 259   );
 260   $sth->execute;
 261   my ($id) = $sth->fetchrow_array;
 262   $sth->finish;
 263   return $id;
 264 }
 265
 266 sub _ping {
 267   my $self = shift;
 268
 269   my $dbh = $self->_dbh or return 0;
 270
 271   local $dbh->{RaiseError} = 1;
 272   local $dbh->{PrintError} = 0;
 273
 274   ( dbic_internal_try {
 275     $dbh->do('select 1 from dual');
 276     1;
 277   })
 278     ? 1
 279     : 0
 280   ;
 281 }
 282
 283 sub _dbh_execute {
 284   #my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
 285   my ($self, $sql, $bind) = @_[0,2,3];
 286
 287   # Turn off sth caching for multi-part LOBs. See _prep_for_execute below
 288   local $self->{disable_sth_caching} = 1 if grep {
 289     ($_->[0]{_ora_lob_autosplit_part}||0)
 290       >
 291     (__cache_queries_with_max_lob_parts - 1)
 292   } @$bind;
 293
 294   my $next = $self->next::can;
 295
 296   # if we are already in a txn we can't retry anything
 297   return shift->$next(@_)
 298     if $self->transaction_depth;
 299
 300   # cheat the blockrunner we are just about to create
 301   # we do want to rerun things regardless of outer state
 302   local $self->{_in_do_block};
 303
 304   return DBIx::Class::Storage::BlockRunner->new(
 305     storage => $self,
 306     wrap_txn => 0,
 307     retry_handler => sub {
 308       # ORA-01003: no statement parsed (someone changed the table somehow,
 309       # invalidating your cursor.)
 310       if (
 311         $_[0]->failed_attempt_count == 1
 312           and
 313         $_[0]->last_exception =~ /ORA-01003/
 314           and
 315         my $dbh = $_[0]->storage->_dbh
 316       ) {
 317         delete $dbh->{CachedKids}{$sql};
 318         return 1;
 319       }
 320       else {
 321         return 0;
 322       }
 323     },
 324   )->run( $next, @_ );
 325 }
 326
 327 sub _dbh_execute_for_fetch {
 328   #my ($self, $sth, $tuple_status, @extra) = @_;
 329
 330   # DBD::Oracle warns loudly on partial execute_for_fetch failures
 331   local $_[1]->{PrintWarn} = 0;
 332
 333   shift->next::method(@_);
 334 }
 335
 336 =head2 get_autoinc_seq
 337
 338 Returns the sequence name for an autoincrement column
 339
 340 =cut
 341
 342 sub get_autoinc_seq {
 343   my ($self, $source, $col) = @_;
 344
 345   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 346 }
 347
 348 =head2 datetime_parser_type
 349
 350 This sets the proper DateTime::Format module for use with
 351 L<DBIx::Class::InflateColumn::DateTime>.
 352
 353 =head2 connect_call_datetime_setup
 354
 355 Used as:
 356
 357     on_connect_call => 'datetime_setup'
 358
 359 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 360 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 361 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 362 is used by it.
 363
 364 Maximum allowable precision is used, unless the environment variables have
 365 already been set.
 366
 367 These are the defaults used:
 368
 369   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 370   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 371   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 372
 373 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 374 for your timestamps, use something like this:
 375
 376   use Time::HiRes 'time';
 377   my $ts = DateTime->from_epoch(epoch => time);
 378
 379 =cut
 380
 381 sub connect_call_datetime_setup {
 382   my $self = shift;
 383
 384   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 385   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 386     'YYYY-MM-DD HH24:MI:SS.FF';
 387   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 388     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 389
 390   $self->_do_query(
 391     "alter session set nls_date_format = '$date_format'"
 392   );
 393   $self->_do_query(
 394     "alter session set nls_timestamp_format = '$timestamp_format'"
 395   );
 396   $self->_do_query(
 397     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 398   );
 399 }
 400
 401 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 402 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 403 #
 404 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 405 # with the driver assuming your input is the deprecated LONG type if you
 406 # encode it as a hex string.  That ain't gonna fly at larger values, where
 407 # you'll discover you have to do what this does.
 408 #
 409 # This method had to be overridden because we need to set ora_field to the
 410 # actual column, and that isn't passed to the call (provided by Storage) to
 411 # bind_attribute_by_data_type.
 412 #
 413 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 414 # adding it doesn't hurt, and will save your bacon if you're modifying a
 415 # table with more than one LOB column.
 416 #
 417 sub _dbi_attrs_for_bind {
 418   my ($self, $ident, $bind) = @_;
 419
 420   my $attrs = $self->next::method($ident, $bind);
 421
 422   # Push the column name into all bind attrs, make sure to *NOT* write into
 423   # the existing $attrs->[$idx]{..} hashref, as it is cached by the call to
 424   # next::method above.
 425   # FIXME - this code will go away when the LobWriter refactor lands
 426   $attrs->[$_]
 427     and
 428   keys %{ $attrs->[$_] }
 429     and
 430   $bind->[$_][0]{dbic_colname}
 431     and
 432   $attrs->[$_] = { %{$attrs->[$_]}, ora_field => $bind->[$_][0]{dbic_colname} }
 433     for 0 .. $#$attrs;
 434
 435   $attrs;
 436 }
 437
 438 sub bind_attribute_by_data_type {
 439   my ($self, $dt) = @_;
 440
 441   if ($self->_is_lob_type($dt)) {
 442
 443     # no earlier - no later
 444     $self->throw_exception(
 445       "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later "
 446     . "version (https://rt.cpan.org/Public/Bug/Display.html?id=46016)"
 447     ) if modver_gt_or_eq_and_lt( 'DBD::Oracle', '1.23', '1.24' );
 448
 449     return {
 450       ora_type => $self->_is_text_lob_type($dt)
 451         ? DBD::Oracle::ORA_CLOB()
 452         : DBD::Oracle::ORA_BLOB()
 453     };
 454   }
 455   else {
 456     return undef;
 457   }
 458 }
 459
 460 # Handle blob columns in WHERE.
 461 #
 462 # For equality comparisons:
 463 #
 464 # We split data intended for comparing to a LOB into 2000 character chunks and
 465 # compare them using dbms_lob.substr on the LOB column.
 466 #
 467 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 468 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 469 # otherwise the query will fail.
 470 #
 471 # Since the most common comparison size is likely to be under 4000 characters
 472 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 473 # prepare_cached for queries with more than two part comparisons to a LOB
 474 # column. This is done in _dbh_execute (above) which was previously overridden
 475 # to gracefully recover from an Oracle error. This is to be careful to not
 476 # exhaust your application's open cursor limit.
 477 #
 478 # See:
 479 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 480 # on the open_cursor limit.
 481 #
 482 # For everything else:
 483 #
 484 # We assume that everything that is not a LOB comparison, will most likely be a
 485 # LIKE query or some sort of function invocation. This may prove to be a naive
 486 # assumption in the future, but for now it should cover the two most likely
 487 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 488 # query (on a CLOB.)
 489 #
 490 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 491 # DBD::Oracle, otherwise the query will fail. This is done by passing
 492 # dbd_attrs => undef.
 493
 494 sub _prep_for_execute {
 495   my $self = shift;
 496   my ($op) = @_;
 497
 498   return $self->next::method(@_)
 499     if $op eq 'insert';
 500
 501   my ($sql, $bind) = $self->next::method(@_);
 502
 503   my $lob_bind_indices = { map {
 504     (
 505       $bind->[$_][0]{sqlt_datatype}
 506         and
 507       $self->_is_lob_type($bind->[$_][0]{sqlt_datatype})
 508     ) ? ( $_ => 1 ) : ()
 509   } ( 0 .. $#$bind ) };
 510
 511   return ($sql, $bind) unless %$lob_bind_indices;
 512
 513   my ($final_sql, @final_binds);
 514   if ($op eq 'update') {
 515     $self->throw_exception('Update with complex WHERE clauses involving BLOB columns currently not supported')
 516       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 517
 518     my $where_sql;
 519     ($final_sql, $where_sql) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 520
 521     if (my $set_bind_count = $final_sql =~ y/?//) {
 522
 523       delete $lob_bind_indices->{$_} for (0 .. ($set_bind_count - 1));
 524
 525       # bail if only the update part contains blobs
 526       return ($sql, $bind) unless %$lob_bind_indices;
 527
 528       @final_binds = splice @$bind, 0, $set_bind_count;
 529       $lob_bind_indices = { map
 530         { $_ - $set_bind_count => $lob_bind_indices->{$_} }
 531         keys %$lob_bind_indices
 532       };
 533     }
 534
 535     # if we got that far - assume the where SQL is all we got
 536     # (the first part is already shoved into $final_sql)
 537     $sql = $where_sql;
 538   }
 539   elsif ($op ne 'select' and $op ne 'delete') {
 540     $self->throw_exception("Unsupported \$op: $op");
 541   }
 542
 543   my @sql_parts = split /\?/, $sql;
 544
 545   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 546
 547   for my $b_idx (0 .. $#$bind) {
 548     my $bound = $bind->[$b_idx];
 549
 550     if (
 551       $lob_bind_indices->{$b_idx}
 552         and
 553       my ($col, $eq) = $sql_parts[0] =~ $col_equality_re
 554     ) {
 555       my $data = $bound->[1];
 556
 557       $data = "$data" if ref $data;
 558
 559       my @parts = unpack '(a2000)*', $data;
 560
 561       my @sql_frag;
 562
 563       for my $idx (0..$#parts) {
 564         push @sql_frag, sprintf (
 565           'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 566           $col, ($idx*2000 + 1),
 567         );
 568       }
 569
 570       my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 571
 572       $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 573
 574       $final_sql .= shift @sql_parts;
 575
 576       for my $idx (0..$#parts) {
 577         push @final_binds, [
 578           {
 579             %{ $bound->[0] },
 580             _ora_lob_autosplit_part => $idx,
 581             dbd_attrs => undef,
 582           },
 583           $parts[$idx]
 584         ];
 585       }
 586     }
 587     else {
 588       $final_sql .= shift(@sql_parts) . '?';
 589       push @final_binds, $lob_bind_indices->{$b_idx}
 590         ? [
 591           {
 592             %{ $bound->[0] },
 593             dbd_attrs => undef,
 594           },
 595           $bound->[1],
 596         ] : $bound
 597       ;
 598     }
 599   }
 600
 601   if (@sql_parts > 1) {
 602     carp "There are more placeholders than binds, this should not happen!";
 603     @sql_parts = join ('?', @sql_parts);
 604   }
 605
 606   $final_sql .= $sql_parts[0];
 607
 608   return ($final_sql, \@final_binds);
 609 }
 610
 611 # Savepoints stuff.
 612
 613 sub _exec_svp_begin {
 614   my ($self, $name) = @_;
 615   $self->_dbh->do("SAVEPOINT $name");
 616 }
 617
 618 # Oracle automatically releases a savepoint when you start another one with the
 619 # same name.
 620 sub _exec_svp_release { 1 }
 621
 622 sub _exec_svp_rollback {
 623   my ($self, $name) = @_;
 624   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 625 }
 626
 627 =head2 relname_to_table_alias
 628
 629 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 630 queries.
 631
 632 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 633 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 634 MD5 hash.
 635
 636 See L<DBIx::Class::Storage::DBI/relname_to_table_alias>.
 637
 638 =cut
 639
 640 sub relname_to_table_alias {
 641   my $self = shift;
 642   my ($relname, $join_count) = @_;
 643
 644   my $alias = $self->next::method(@_);
 645
 646   # we need to shorten here in addition to the shortening in SQLA itself,
 647   # since the final relnames are crucial for the join optimizer
 648   return $self->sql_maker->_shorten_identifier($alias);
 649 }
 650
 651 =head2 with_deferred_fk_checks
 652
 653 Runs a coderef between:
 654
 655   alter session set constraints = deferred
 656   ...
 657   alter session set constraints = immediate
 658
 659 to defer foreign key checks.
 660
 661 Constraints must be declared C<DEFERRABLE> for this to work.
 662
 663 =cut
 664
 665 sub with_deferred_fk_checks {
 666   my ($self, $sub) = @_;
 667
 668   my $txn_scope_guard = $self->txn_scope_guard;
 669
 670   $self->_do_query('alter session set constraints = deferred');
 671
 672   my $sg = Scope::Guard->new(sub {
 673     $self->_do_query('alter session set constraints = immediate');
 674   });
 675
 676   return
 677     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 678 }
 679
 680 =head1 ATTRIBUTES
 681
 682 Following additional attributes can be used in resultsets.
 683
 684 =head2 connect_by or connect_by_nocycle
 685
 686 =over 4
 687
 688 =item Value: \%connect_by
 689
 690 =back
 691
 692 A hashref of conditions used to specify the relationship between parent rows
 693 and child rows of the hierarchy.
 694
 695
 696   connect_by => { parentid => 'prior personid' }
 697
 698   # adds a connect by statement to the query:
 699   # SELECT
 700   #     me.persionid me.firstname, me.lastname, me.parentid
 701   # FROM
 702   #     person me
 703   # CONNECT BY
 704   #     parentid = prior persionid
 705
 706
 707   connect_by_nocycle => { parentid => 'prior personid' }
 708
 709   # adds a connect by statement to the query:
 710   # SELECT
 711   #     me.persionid me.firstname, me.lastname, me.parentid
 712   # FROM
 713   #     person me
 714   # CONNECT BY NOCYCLE
 715   #     parentid = prior persionid
 716
 717
 718 =head2 start_with
 719
 720 =over 4
 721
 722 =item Value: \%condition
 723
 724 =back
 725
 726 A hashref of conditions which specify the root row(s) of the hierarchy.
 727
 728 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 729
 730   start_with => { firstname => 'Foo', lastname => 'Bar' }
 731
 732   # SELECT
 733   #     me.persionid me.firstname, me.lastname, me.parentid
 734   # FROM
 735   #     person me
 736   # START WITH
 737   #     firstname = 'foo' and lastname = 'bar'
 738   # CONNECT BY
 739   #     parentid = prior persionid
 740
 741 =head2 order_siblings_by
 742
 743 =over 4
 744
 745 =item Value: ($order_siblings_by | \@order_siblings_by)
 746
 747 =back
 748
 749 Which column(s) to order the siblings by.
 750
 751 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 752
 753   'order_siblings_by' => 'firstname ASC'
 754
 755   # SELECT
 756   #     me.persionid me.firstname, me.lastname, me.parentid
 757   # FROM
 758   #     person me
 759   # CONNECT BY
 760   #     parentid = prior persionid
 761   # ORDER SIBLINGS BY
 762   #     firstname ASC
 763
 764 =head1 FURTHER QUESTIONS?
 765
 766 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 767
 768 =head1 COPYRIGHT AND LICENSE
 769
 770 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 771 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 772 redistribute it and/or modify it under the same terms as the
 773 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 774
 775 =cut
 776
 777 1;
 778 # vim:sts=2 sw=2: