lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('RowNum');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  17 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  18
  19 sub __cache_queries_with_max_lob_parts { 2 }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  24
  25 =head1 SYNOPSIS
  26
  27   # In your result (table) classes
  28   use base 'DBIx::Class::Core';
  29   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  30   __PACKAGE__->set_primary_key('id');
  31
  32   # Somewhere in your Code
  33   # add some data to a table with a hierarchical relationship
  34   $schema->resultset('Person')->create ({
  35         firstname => 'foo',
  36         lastname => 'bar',
  37         children => [
  38             {
  39                 firstname => 'child1',
  40                 lastname => 'bar',
  41                 children => [
  42                     {
  43                         firstname => 'grandchild',
  44                         lastname => 'bar',
  45                     }
  46                 ],
  47             },
  48             {
  49                 firstname => 'child2',
  50                 lastname => 'bar',
  51             },
  52         ],
  53     });
  54
  55   # select from the hierarchical relationship
  56   my $rs = $schema->resultset('Person')->search({},
  57     {
  58       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  59       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  60       'order_siblings_by' => { -asc => 'name' },
  61     };
  62   );
  63
  64   # this will select the whole tree starting from person "foo bar", creating
  65   # following query:
  66   # SELECT
  67   #     me.persionid me.firstname, me.lastname, me.parentid
  68   # FROM
  69   #     person me
  70   # START WITH
  71   #     firstname = 'foo' and lastname = 'bar'
  72   # CONNECT BY
  73   #     parentid = prior personid
  74   # ORDER SIBLINGS BY
  75   #     firstname ASC
  76
  77 =head1 DESCRIPTION
  78
  79 This class implements base Oracle support. The subclass
  80 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  81 versions before 9.0.
  82
  83 =head1 METHODS
  84
  85 =cut
  86
  87 sub _determine_supports_insert_returning {
  88   my $self = shift;
  89
  90 # TODO find out which version supports the RETURNING syntax
  91 # 8i has it and earlier docs are a 404 on oracle.com
  92
  93   return 1
  94     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  95
  96   return 0;
  97 }
  98
  99 __PACKAGE__->_use_insert_returning_bound (1);
 100
 101 sub deployment_statements {
 102   my $self = shift;;
 103   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 104
 105   $sqltargs ||= {};
 106   my $quote_char = $self->schema->storage->sql_maker->quote_char;
 107   $sqltargs->{quote_table_names} = $quote_char ? 1 : 0;
 108   $sqltargs->{quote_field_names} = $quote_char ? 1 : 0;
 109
 110   if (
 111     ! exists $sqltargs->{producer_args}{oracle_version}
 112       and
 113     my $dver = $self->_server_info->{dbms_version}
 114   ) {
 115     $sqltargs->{producer_args}{oracle_version} = $dver;
 116   }
 117
 118   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 119 }
 120
 121 sub _dbh_last_insert_id {
 122   my ($self, $dbh, $source, @columns) = @_;
 123   my @ids = ();
 124   foreach my $col (@columns) {
 125     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 126     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 127     push @ids, $id;
 128   }
 129   return @ids;
 130 }
 131
 132 sub _dbh_get_autoinc_seq {
 133   my ($self, $dbh, $source, $col) = @_;
 134
 135   my $sql_maker = $self->sql_maker;
 136   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 137
 138   my $source_name;
 139   if ( ref $source->name eq 'SCALAR' ) {
 140     $source_name = ${$source->name};
 141
 142     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 143     # stuff unless it is already quoted
 144     $source_name = uc ($source_name) if $source_name !~ /\"/;
 145   }
 146   else {
 147     $source_name = $source->name;
 148     $source_name = uc($source_name) unless $ql;
 149   }
 150
 151   # trigger_body is a LONG
 152   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 153
 154   # disable default bindtype
 155   local $sql_maker->{bindtype} = 'normal';
 156
 157   # look up the correct sequence automatically
 158   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 159
 160   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 161   $schema ||= \'= USER';
 162
 163   my ($sql, @bind) = $sql_maker->select (
 164     'ALL_TRIGGERS',
 165     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 166     {
 167       OWNER => $schema,
 168       TABLE_NAME => $table || $source_name,
 169       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 170       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 171       STATUS => 'ENABLED',
 172      },
 173   );
 174
 175   # to find all the triggers that mention the column in question a simple
 176   # regex grep since the trigger_body above is a LONG and hence not searchable
 177   # via -like
 178   my @triggers = ( map
 179     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 180     ( grep
 181       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 182       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 183     )
 184   );
 185
 186   # extract all sequence names mentioned in each trigger, throw away
 187   # triggers without apparent sequences
 188   @triggers = map {
 189     my @seqs = $_->{body} =~ / ( [\.\w\"\-]+ ) \. nextval /xig;
 190     @seqs
 191       ? { %$_, sequences => \@seqs }
 192       : ()
 193     ;
 194   } @triggers;
 195
 196   my $chosen_trigger;
 197
 198   # if only one trigger matched things are easy
 199   if (@triggers == 1) {
 200
 201     if ( @{$triggers[0]{sequences}} == 1 ) {
 202       $chosen_trigger = $triggers[0];
 203     }
 204     else {
 205       $self->throw_exception( sprintf (
 206         "Unable to introspect trigger '%s' for column %s.%s (references multiple sequences). "
 207       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 208         $triggers[0]{name},
 209         $source_name,
 210         $col,
 211         $col,
 212       ) );
 213     }
 214   }
 215   # got more than one matching trigger - see if we can narrow it down
 216   elsif (@triggers > 1) {
 217
 218     my @candidates = grep
 219       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 220       @triggers
 221     ;
 222
 223     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 224       $chosen_trigger = $candidates[0];
 225     }
 226     else {
 227       $self->throw_exception( sprintf (
 228         "Unable to reliably select a BEFORE INSERT trigger for column %s.%s (possibilities: %s). "
 229       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 230         $source_name,
 231         $col,
 232         ( join ', ', map { "'$_->{name}'" } @triggers ),
 233         $col,
 234       ) );
 235     }
 236   }
 237
 238   if ($chosen_trigger) {
 239     my $seq_name = $chosen_trigger->{sequences}[0];
 240
 241     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 242       unless $seq_name =~ /\./;
 243
 244     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 245     return $seq_name;
 246   }
 247
 248   $self->throw_exception( sprintf (
 249     "No suitable BEFORE INSERT triggers found for column %s.%s. "
 250   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 251     $source_name,
 252     $col,
 253     $col,
 254   ));
 255 }
 256
 257 sub _sequence_fetch {
 258   my ( $self, $type, $seq ) = @_;
 259
 260   # use the maker to leverage quoting settings
 261   my $sth = $self->_dbh->prepare_cached(
 262     $self->sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] )
 263   );
 264   $sth->execute;
 265   my ($id) = $sth->fetchrow_array;
 266   $sth->finish;
 267   return $id;
 268 }
 269
 270 sub _ping {
 271   my $self = shift;
 272
 273   my $dbh = $self->_dbh or return 0;
 274
 275   local $dbh->{RaiseError} = 1;
 276   local $dbh->{PrintError} = 0;
 277
 278   return try {
 279     $dbh->do('select 1 from dual');
 280     1;
 281   } catch {
 282     0;
 283   };
 284 }
 285
 286 sub _dbh_execute {
 287   my ($self, $dbh, $sql, $bind) = @_;
 288
 289   # Turn off sth caching for multi-part LOBs. See _prep_for_execute above.
 290   local $self->{disable_sth_caching} = 1 if first {
 291     ($_->[0]{_ora_lob_autosplit_part}||0)
 292       >
 293     (__cache_queries_with_max_lob_parts - 1)
 294   } @$bind;
 295
 296   my $next = $self->next::can;
 297
 298   # if we are already in a txn we can't retry anything
 299   return shift->$next(@_)
 300     if $self->transaction_depth;
 301
 302   # cheat the blockrunner - we do want to rerun things regardless of outer state
 303   local $self->{_in_do_block};
 304
 305   return DBIx::Class::Storage::BlockRunner->new(
 306     storage => $self,
 307     run_code => $next,
 308     run_args => \@_,
 309     wrap_txn => 0,
 310     retry_handler => sub {
 311       # ORA-01003: no statement parsed (someone changed the table somehow,
 312       # invalidating your cursor.)
 313       return 0 if ($_[0]->retried_count or $_[0]->last_exception !~ /ORA-01003/);
 314
 315       # re-prepare towards new table data
 316       if (my $dbh = $_[0]->storage->_dbh) {
 317         delete $dbh->{CachedKids}{$_[0]->run_args->[2]};
 318       }
 319       return 1;
 320     },
 321   )->run;
 322 }
 323
 324 sub _dbh_execute_for_fetch {
 325   #my ($self, $sth, $tuple_status, @extra) = @_;
 326
 327   # DBD::Oracle warns loudly on partial execute_for_fetch failures
 328   local $_[1]->{PrintWarn} = 0;
 329
 330   shift->next::method(@_);
 331 }
 332
 333 =head2 get_autoinc_seq
 334
 335 Returns the sequence name for an autoincrement column
 336
 337 =cut
 338
 339 sub get_autoinc_seq {
 340   my ($self, $source, $col) = @_;
 341
 342   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 343 }
 344
 345 =head2 datetime_parser_type
 346
 347 This sets the proper DateTime::Format module for use with
 348 L<DBIx::Class::InflateColumn::DateTime>.
 349
 350 =head2 connect_call_datetime_setup
 351
 352 Used as:
 353
 354     on_connect_call => 'datetime_setup'
 355
 356 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 357 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 358 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 359 is used by it.
 360
 361 Maximum allowable precision is used, unless the environment variables have
 362 already been set.
 363
 364 These are the defaults used:
 365
 366   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 367   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 368   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 369
 370 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 371 for your timestamps, use something like this:
 372
 373   use Time::HiRes 'time';
 374   my $ts = DateTime->from_epoch(epoch => time);
 375
 376 =cut
 377
 378 sub connect_call_datetime_setup {
 379   my $self = shift;
 380
 381   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 382   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 383     'YYYY-MM-DD HH24:MI:SS.FF';
 384   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 385     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 386
 387   $self->_do_query(
 388     "alter session set nls_date_format = '$date_format'"
 389   );
 390   $self->_do_query(
 391     "alter session set nls_timestamp_format = '$timestamp_format'"
 392   );
 393   $self->_do_query(
 394     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 395   );
 396 }
 397
 398 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 399 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 400 #
 401 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 402 # with the driver assuming your input is the deprecated LONG type if you
 403 # encode it as a hex string.  That ain't gonna fly at larger values, where
 404 # you'll discover you have to do what this does.
 405 #
 406 # This method had to be overridden because we need to set ora_field to the
 407 # actual column, and that isn't passed to the call (provided by Storage) to
 408 # bind_attribute_by_data_type.
 409 #
 410 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 411 # adding it doesn't hurt, and will save your bacon if you're modifying a
 412 # table with more than one LOB column.
 413 #
 414 sub _dbi_attrs_for_bind {
 415   my ($self, $ident, $bind) = @_;
 416
 417   my $attrs = $self->next::method($ident, $bind);
 418
 419   for my $i (0 .. $#$attrs) {
 420     if (keys %{$attrs->[$i]||{}} and my $col = $bind->[$i][0]{dbic_colname}) {
 421       $attrs->[$i]{ora_field} = $col;
 422     }
 423   }
 424
 425   $attrs;
 426 }
 427
 428 sub bind_attribute_by_data_type {
 429   my ($self, $dt) = @_;
 430
 431   if ($self->_is_lob_type($dt)) {
 432
 433     # this is a hot-ish codepath, store an escape-flag in the DBD namespace, so that
 434     # things like Class::Unload work (unlikely but possible)
 435     unless ($DBD::Oracle::__DBIC_DBD_VERSION_CHECK_OK__) {
 436
 437       # no earlier - no later
 438       if ($DBD::Oracle::VERSION eq '1.23') {
 439         $self->throw_exception(
 440           "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later ".
 441           "version (https://rt.cpan.org/Public/Bug/Display.html?id=46016)"
 442         );
 443       }
 444
 445       $DBD::Oracle::__DBIC_DBD_VERSION_CHECK_OK__ = 1;
 446     }
 447
 448     return {
 449       ora_type => $self->_is_text_lob_type($dt)
 450         ? DBD::Oracle::ORA_CLOB()
 451         : DBD::Oracle::ORA_BLOB()
 452     };
 453   }
 454   else {
 455     return undef;
 456   }
 457 }
 458
 459 # Handle blob columns in WHERE.
 460 #
 461 # For equality comparisons:
 462 #
 463 # We split data intended for comparing to a LOB into 2000 character chunks and
 464 # compare them using dbms_lob.substr on the LOB column.
 465 #
 466 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 467 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 468 # otherwise the query will fail.
 469 #
 470 # Since the most common comparison size is likely to be under 4000 characters
 471 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 472 # prepare_cached for queries with more than two part comparisons to a LOB
 473 # column. This is done in _dbh_execute (above) which was previously overridden
 474 # to gracefully recover from an Oracle error. This is to be careful to not
 475 # exhaust your application's open cursor limit.
 476 #
 477 # See:
 478 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 479 # on the open_cursor limit.
 480 #
 481 # For everything else:
 482 #
 483 # We assume that everything that is not a LOB comparison, will most likely be a
 484 # LIKE query or some sort of function invocation. This may prove to be a naive
 485 # assumption in the future, but for now it should cover the two most likely
 486 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 487 # query (on a CLOB.)
 488 #
 489 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 490 # DBD::Oracle, otherwise the query will fail. This is done by passing
 491 # dbd_attrs => undef.
 492
 493 sub _prep_for_execute {
 494   my $self = shift;
 495   my ($op) = @_;
 496
 497   return $self->next::method(@_)
 498     if $op eq 'insert';
 499
 500   my ($sql, $bind) = $self->next::method(@_);
 501
 502   my $lob_bind_indices = { map {
 503     (
 504       $bind->[$_][0]{sqlt_datatype}
 505         and
 506       $self->_is_lob_type($bind->[$_][0]{sqlt_datatype})
 507     ) ? ( $_ => 1 ) : ()
 508   } ( 0 .. $#$bind ) };
 509
 510   return ($sql, $bind) unless %$lob_bind_indices;
 511
 512   my ($final_sql, @final_binds);
 513   if ($op eq 'update') {
 514     $self->throw_exception('Update with complex WHERE clauses currently not supported')
 515       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 516
 517     my $where_sql;
 518     ($final_sql, $where_sql) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 519
 520     if (my $set_bind_count = $final_sql =~ y/?//) {
 521
 522       delete $lob_bind_indices->{$_} for (0 .. ($set_bind_count - 1));
 523
 524       # bail if only the update part contains blobs
 525       return ($sql, $bind) unless %$lob_bind_indices;
 526
 527       @final_binds = splice @$bind, 0, $set_bind_count;
 528       $lob_bind_indices = { map
 529         { $_ - $set_bind_count => $lob_bind_indices->{$_} }
 530         keys %$lob_bind_indices
 531       };
 532     }
 533
 534     # if we got that far - assume the where SQL is all we got
 535     # (the first part is already shoved into $final_sql)
 536     $sql = $where_sql;
 537   }
 538   elsif ($op ne 'select' and $op ne 'delete') {
 539     $self->throw_exception("Unsupported \$op: $op");
 540   }
 541
 542   my @sql_parts = split /\?/, $sql;
 543
 544   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 545
 546   for my $b_idx (0 .. $#$bind) {
 547     my $bound = $bind->[$b_idx];
 548
 549     if (
 550       $lob_bind_indices->{$b_idx}
 551         and
 552       my ($col, $eq) = $sql_parts[0] =~ $col_equality_re
 553     ) {
 554       my $data = $bound->[1];
 555
 556       $data = "$data" if ref $data;
 557
 558       my @parts = unpack '(a2000)*', $data;
 559
 560       my @sql_frag;
 561
 562       for my $idx (0..$#parts) {
 563         push @sql_frag, sprintf (
 564           'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 565           $col, ($idx*2000 + 1),
 566         );
 567       }
 568
 569       my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 570
 571       $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 572
 573       $final_sql .= shift @sql_parts;
 574
 575       for my $idx (0..$#parts) {
 576         push @final_binds, [
 577           {
 578             %{ $bound->[0] },
 579             _ora_lob_autosplit_part => $idx,
 580             dbd_attrs => undef,
 581           },
 582           $parts[$idx]
 583         ];
 584       }
 585     }
 586     else {
 587       $final_sql .= shift(@sql_parts) . '?';
 588       push @final_binds, $lob_bind_indices->{$b_idx}
 589         ? [
 590           {
 591             %{ $bound->[0] },
 592             dbd_attrs => undef,
 593           },
 594           $bound->[1],
 595         ] : $bound
 596       ;
 597     }
 598   }
 599
 600   if (@sql_parts > 1) {
 601     carp "There are more placeholders than binds, this should not happen!";
 602     @sql_parts = join ('?', @sql_parts);
 603   }
 604
 605   $final_sql .= $sql_parts[0];
 606
 607   return ($final_sql, \@final_binds);
 608 }
 609
 610 # Savepoints stuff.
 611
 612 sub _exec_svp_begin {
 613   my ($self, $name) = @_;
 614   $self->_dbh->do("SAVEPOINT $name");
 615 }
 616
 617 # Oracle automatically releases a savepoint when you start another one with the
 618 # same name.
 619 sub _exec_svp_release { 1 }
 620
 621 sub _exec_svp_rollback {
 622   my ($self, $name) = @_;
 623   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 624 }
 625
 626 =head2 relname_to_table_alias
 627
 628 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 629 queries.
 630
 631 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 632 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 633 MD5 hash.
 634
 635 See L<DBIx::Class::Storage/"relname_to_table_alias">.
 636
 637 =cut
 638
 639 sub relname_to_table_alias {
 640   my $self = shift;
 641   my ($relname, $join_count) = @_;
 642
 643   my $alias = $self->next::method(@_);
 644
 645   # we need to shorten here in addition to the shortening in SQLA itself,
 646   # since the final relnames are a crucial for the join optimizer
 647   return $self->sql_maker->_shorten_identifier($alias);
 648 }
 649
 650 =head2 with_deferred_fk_checks
 651
 652 Runs a coderef between:
 653
 654   alter session set constraints = deferred
 655   ...
 656   alter session set constraints = immediate
 657
 658 to defer foreign key checks.
 659
 660 Constraints must be declared C<DEFERRABLE> for this to work.
 661
 662 =cut
 663
 664 sub with_deferred_fk_checks {
 665   my ($self, $sub) = @_;
 666
 667   my $txn_scope_guard = $self->txn_scope_guard;
 668
 669   $self->_do_query('alter session set constraints = deferred');
 670
 671   my $sg = Scope::Guard->new(sub {
 672     $self->_do_query('alter session set constraints = immediate');
 673   });
 674
 675   return
 676     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 677 }
 678
 679 =head1 ATTRIBUTES
 680
 681 Following additional attributes can be used in resultsets.
 682
 683 =head2 connect_by or connect_by_nocycle
 684
 685 =over 4
 686
 687 =item Value: \%connect_by
 688
 689 =back
 690
 691 A hashref of conditions used to specify the relationship between parent rows
 692 and child rows of the hierarchy.
 693
 694
 695   connect_by => { parentid => 'prior personid' }
 696
 697   # adds a connect by statement to the query:
 698   # SELECT
 699   #     me.persionid me.firstname, me.lastname, me.parentid
 700   # FROM
 701   #     person me
 702   # CONNECT BY
 703   #     parentid = prior persionid
 704
 705
 706   connect_by_nocycle => { parentid => 'prior personid' }
 707
 708   # adds a connect by statement to the query:
 709   # SELECT
 710   #     me.persionid me.firstname, me.lastname, me.parentid
 711   # FROM
 712   #     person me
 713   # CONNECT BY NOCYCLE
 714   #     parentid = prior persionid
 715
 716
 717 =head2 start_with
 718
 719 =over 4
 720
 721 =item Value: \%condition
 722
 723 =back
 724
 725 A hashref of conditions which specify the root row(s) of the hierarchy.
 726
 727 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 728
 729   start_with => { firstname => 'Foo', lastname => 'Bar' }
 730
 731   # SELECT
 732   #     me.persionid me.firstname, me.lastname, me.parentid
 733   # FROM
 734   #     person me
 735   # START WITH
 736   #     firstname = 'foo' and lastname = 'bar'
 737   # CONNECT BY
 738   #     parentid = prior persionid
 739
 740 =head2 order_siblings_by
 741
 742 =over 4
 743
 744 =item Value: ($order_siblings_by | \@order_siblings_by)
 745
 746 =back
 747
 748 Which column(s) to order the siblings by.
 749
 750 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 751
 752   'order_siblings_by' => 'firstname ASC'
 753
 754   # SELECT
 755   #     me.persionid me.firstname, me.lastname, me.parentid
 756   # FROM
 757   #     person me
 758   # CONNECT BY
 759   #     parentid = prior persionid
 760   # ORDER SIBLINGS BY
 761   #     firstname ASC
 762
 763 =head1 AUTHOR
 764
 765 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 766
 767 =head1 LICENSE
 768
 769 You may distribute this code under the same terms as Perl itself.
 770
 771 =cut
 772
 773 1;
 774 # vim:sts=2 sw=2: