lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use List::Util 'first';
  11 use DBIx::Class::_Util qw( modver_gt_or_eq_and_lt dbic_internal_try );
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('RowNum');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  17 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  18
  19 sub __cache_queries_with_max_lob_parts { 2 }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  24
  25 =head1 SYNOPSIS
  26
  27   # In your result (table) classes
  28   use base 'DBIx::Class::Core';
  29   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  30   __PACKAGE__->set_primary_key('id');
  31
  32   # Somewhere in your Code
  33   # add some data to a table with a hierarchical relationship
  34   $schema->resultset('Person')->create ({
  35         firstname => 'foo',
  36         lastname => 'bar',
  37         children => [
  38             {
  39                 firstname => 'child1',
  40                 lastname => 'bar',
  41                 children => [
  42                     {
  43                         firstname => 'grandchild',
  44                         lastname => 'bar',
  45                     }
  46                 ],
  47             },
  48             {
  49                 firstname => 'child2',
  50                 lastname => 'bar',
  51             },
  52         ],
  53     });
  54
  55   # select from the hierarchical relationship
  56   my $rs = $schema->resultset('Person')->search({},
  57     {
  58       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  59       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  60       'order_siblings_by' => { -asc => 'name' },
  61     };
  62   );
  63
  64   # this will select the whole tree starting from person "foo bar", creating
  65   # following query:
  66   # SELECT
  67   #     me.persionid me.firstname, me.lastname, me.parentid
  68   # FROM
  69   #     person me
  70   # START WITH
  71   #     firstname = 'foo' and lastname = 'bar'
  72   # CONNECT BY
  73   #     parentid = prior personid
  74   # ORDER SIBLINGS BY
  75   #     firstname ASC
  76
  77 =head1 DESCRIPTION
  78
  79 This class implements base Oracle support. The subclass
  80 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  81 versions before 9.0.
  82
  83 =head1 METHODS
  84
  85 =cut
  86
  87 sub _determine_supports_insert_returning {
  88   my $self = shift;
  89
  90 # TODO find out which version supports the RETURNING syntax
  91 # 8i has it and earlier docs are a 404 on oracle.com
  92
  93   return 1
  94     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  95
  96   return 0;
  97 }
  98
  99 __PACKAGE__->_use_insert_returning_bound (1);
 100
 101 sub deployment_statements {
 102   my $self = shift;;
 103   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 104
 105   $sqltargs ||= {};
 106
 107   if (
 108     ! exists $sqltargs->{producer_args}{oracle_version}
 109       and
 110     my $dver = $self->_server_info->{dbms_version}
 111   ) {
 112     $sqltargs->{producer_args}{oracle_version} = $dver;
 113   }
 114
 115   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 116 }
 117
 118 sub _dbh_last_insert_id {
 119   my ($self, $dbh, $source, @columns) = @_;
 120   my @ids = ();
 121   foreach my $col (@columns) {
 122     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 123     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 124     push @ids, $id;
 125   }
 126   return @ids;
 127 }
 128
 129 sub _dbh_get_autoinc_seq {
 130   my ($self, $dbh, $source, $col) = @_;
 131
 132   my $sql_maker = $self->sql_maker;
 133   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 134
 135   my $source_name;
 136   if ( ref $source->name eq 'SCALAR' ) {
 137     $source_name = ${$source->name};
 138
 139     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 140     # stuff unless it is already quoted
 141     $source_name = uc ($source_name) if $source_name !~ /\"/;
 142   }
 143   else {
 144     $source_name = $source->name;
 145     $source_name = uc($source_name) unless $ql;
 146   }
 147
 148   # trigger_body is a LONG
 149   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 150
 151   # disable default bindtype
 152   local $sql_maker->{bindtype} = 'normal';
 153
 154   # look up the correct sequence automatically
 155   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 156
 157   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 158   $schema ||= \'= USER';
 159
 160   my ($sql, @bind) = $sql_maker->select (
 161     'ALL_TRIGGERS',
 162     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 163     {
 164       OWNER => $schema,
 165       TABLE_NAME => $table || $source_name,
 166       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 167       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 168       STATUS => 'ENABLED',
 169      },
 170   );
 171
 172   # to find all the triggers that mention the column in question a simple
 173   # regex grep since the trigger_body above is a LONG and hence not searchable
 174   # via -like
 175   my @triggers = ( map
 176     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 177     ( grep
 178       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 179       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 180     )
 181   );
 182
 183   # extract all sequence names mentioned in each trigger, throw away
 184   # triggers without apparent sequences
 185   @triggers = map {
 186     my @seqs = $_->{body} =~ / ( [\.\w\"\-]+ ) \. nextval /xig;
 187     @seqs
 188       ? { %$_, sequences => \@seqs }
 189       : ()
 190     ;
 191   } @triggers;
 192
 193   my $chosen_trigger;
 194
 195   # if only one trigger matched things are easy
 196   if (@triggers == 1) {
 197
 198     if ( @{$triggers[0]{sequences}} == 1 ) {
 199       $chosen_trigger = $triggers[0];
 200     }
 201     else {
 202       $self->throw_exception( sprintf (
 203         "Unable to introspect trigger '%s' for column '%s.%s' (references multiple sequences). "
 204       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 205         $triggers[0]{name},
 206         $source_name,
 207         $col,
 208         $col,
 209       ) );
 210     }
 211   }
 212   # got more than one matching trigger - see if we can narrow it down
 213   elsif (@triggers > 1) {
 214
 215     my @candidates = grep
 216       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 217       @triggers
 218     ;
 219
 220     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 221       $chosen_trigger = $candidates[0];
 222     }
 223     else {
 224       $self->throw_exception( sprintf (
 225         "Unable to reliably select a BEFORE INSERT trigger for column '%s.%s' (possibilities: %s). "
 226       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 227         $source_name,
 228         $col,
 229         ( join ', ', map { "'$_->{name}'" } @triggers ),
 230         $col,
 231       ) );
 232     }
 233   }
 234
 235   if ($chosen_trigger) {
 236     my $seq_name = $chosen_trigger->{sequences}[0];
 237
 238     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 239       unless $seq_name =~ /\./;
 240
 241     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 242     return $seq_name;
 243   }
 244
 245   $self->throw_exception( sprintf (
 246     "No suitable BEFORE INSERT triggers found for column '%s.%s'. "
 247   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 248     $source_name,
 249     $col,
 250     $col,
 251   ));
 252 }
 253
 254 sub _sequence_fetch {
 255   my ( $self, $type, $seq ) = @_;
 256
 257   # use the maker to leverage quoting settings
 258   my $sth = $self->_dbh->prepare_cached(
 259     $self->sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] )
 260   );
 261   $sth->execute;
 262   my ($id) = $sth->fetchrow_array;
 263   $sth->finish;
 264   return $id;
 265 }
 266
 267 sub _ping {
 268   my $self = shift;
 269
 270   my $dbh = $self->_dbh or return 0;
 271
 272   local $dbh->{RaiseError} = 1;
 273   local $dbh->{PrintError} = 0;
 274
 275   ( dbic_internal_try {
 276     $dbh->do('select 1 from dual');
 277     1;
 278   })
 279     ? 1
 280     : 0
 281   ;
 282 }
 283
 284 sub _dbh_execute {
 285   #my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
 286   my ($self, $sql, $bind) = @_[0,2,3];
 287
 288   # Turn off sth caching for multi-part LOBs. See _prep_for_execute below
 289   local $self->{disable_sth_caching} = 1 if first {
 290     ($_->[0]{_ora_lob_autosplit_part}||0)
 291       >
 292     (__cache_queries_with_max_lob_parts - 1)
 293   } @$bind;
 294
 295   my $next = $self->next::can;
 296
 297   # if we are already in a txn we can't retry anything
 298   return shift->$next(@_)
 299     if $self->transaction_depth;
 300
 301   # cheat the blockrunner we are just about to create
 302   # we do want to rerun things regardless of outer state
 303   local $self->{_in_do_block};
 304
 305   return DBIx::Class::Storage::BlockRunner->new(
 306     storage => $self,
 307     wrap_txn => 0,
 308     retry_handler => sub {
 309       # ORA-01003: no statement parsed (someone changed the table somehow,
 310       # invalidating your cursor.)
 311       if (
 312         $_[0]->failed_attempt_count == 1
 313           and
 314         $_[0]->last_exception =~ /ORA-01003/
 315           and
 316         my $dbh = $_[0]->storage->_dbh
 317       ) {
 318         delete $dbh->{CachedKids}{$sql};
 319         return 1;
 320       }
 321       else {
 322         return 0;
 323       }
 324     },
 325   )->run( $next, @_ );
 326 }
 327
 328 sub _dbh_execute_for_fetch {
 329   #my ($self, $sth, $tuple_status, @extra) = @_;
 330
 331   # DBD::Oracle warns loudly on partial execute_for_fetch failures
 332   local $_[1]->{PrintWarn} = 0;
 333
 334   shift->next::method(@_);
 335 }
 336
 337 =head2 get_autoinc_seq
 338
 339 Returns the sequence name for an autoincrement column
 340
 341 =cut
 342
 343 sub get_autoinc_seq {
 344   my ($self, $source, $col) = @_;
 345
 346   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 347 }
 348
 349 =head2 datetime_parser_type
 350
 351 This sets the proper DateTime::Format module for use with
 352 L<DBIx::Class::InflateColumn::DateTime>.
 353
 354 =head2 connect_call_datetime_setup
 355
 356 Used as:
 357
 358     on_connect_call => 'datetime_setup'
 359
 360 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 361 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 362 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 363 is used by it.
 364
 365 Maximum allowable precision is used, unless the environment variables have
 366 already been set.
 367
 368 These are the defaults used:
 369
 370   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 371   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 372   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 373
 374 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 375 for your timestamps, use something like this:
 376
 377   use Time::HiRes 'time';
 378   my $ts = DateTime->from_epoch(epoch => time);
 379
 380 =cut
 381
 382 sub connect_call_datetime_setup {
 383   my $self = shift;
 384
 385   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 386   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 387     'YYYY-MM-DD HH24:MI:SS.FF';
 388   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 389     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 390
 391   $self->_do_query(
 392     "alter session set nls_date_format = '$date_format'"
 393   );
 394   $self->_do_query(
 395     "alter session set nls_timestamp_format = '$timestamp_format'"
 396   );
 397   $self->_do_query(
 398     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 399   );
 400 }
 401
 402 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 403 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 404 #
 405 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 406 # with the driver assuming your input is the deprecated LONG type if you
 407 # encode it as a hex string.  That ain't gonna fly at larger values, where
 408 # you'll discover you have to do what this does.
 409 #
 410 # This method had to be overridden because we need to set ora_field to the
 411 # actual column, and that isn't passed to the call (provided by Storage) to
 412 # bind_attribute_by_data_type.
 413 #
 414 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 415 # adding it doesn't hurt, and will save your bacon if you're modifying a
 416 # table with more than one LOB column.
 417 #
 418 sub _dbi_attrs_for_bind {
 419   my ($self, $ident, $bind) = @_;
 420
 421   my $attrs = $self->next::method($ident, $bind);
 422
 423   # Push the column name into all bind attrs, make sure to *NOT* write into
 424   # the existing $attrs->[$idx]{..} hashref, as it is cached by the call to
 425   # next::method above.
 426   # FIXME - this code will go away when the LobWriter refactor lands
 427   $attrs->[$_]
 428     and
 429   keys %{ $attrs->[$_] }
 430     and
 431   $bind->[$_][0]{dbic_colname}
 432     and
 433   $attrs->[$_] = { %{$attrs->[$_]}, ora_field => $bind->[$_][0]{dbic_colname} }
 434     for 0 .. $#$attrs;
 435
 436   $attrs;
 437 }
 438
 439 sub bind_attribute_by_data_type {
 440   my ($self, $dt) = @_;
 441
 442   if ($self->_is_lob_type($dt)) {
 443
 444     # no earlier - no later
 445     $self->throw_exception(
 446       "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later "
 447     . "version (https://rt.cpan.org/Public/Bug/Display.html?id=46016)"
 448     ) if modver_gt_or_eq_and_lt( 'DBD::Oracle', '1.23', '1.24' );
 449
 450     return {
 451       ora_type => $self->_is_text_lob_type($dt)
 452         ? DBD::Oracle::ORA_CLOB()
 453         : DBD::Oracle::ORA_BLOB()
 454     };
 455   }
 456   else {
 457     return undef;
 458   }
 459 }
 460
 461 # Handle blob columns in WHERE.
 462 #
 463 # For equality comparisons:
 464 #
 465 # We split data intended for comparing to a LOB into 2000 character chunks and
 466 # compare them using dbms_lob.substr on the LOB column.
 467 #
 468 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 469 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 470 # otherwise the query will fail.
 471 #
 472 # Since the most common comparison size is likely to be under 4000 characters
 473 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 474 # prepare_cached for queries with more than two part comparisons to a LOB
 475 # column. This is done in _dbh_execute (above) which was previously overridden
 476 # to gracefully recover from an Oracle error. This is to be careful to not
 477 # exhaust your application's open cursor limit.
 478 #
 479 # See:
 480 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 481 # on the open_cursor limit.
 482 #
 483 # For everything else:
 484 #
 485 # We assume that everything that is not a LOB comparison, will most likely be a
 486 # LIKE query or some sort of function invocation. This may prove to be a naive
 487 # assumption in the future, but for now it should cover the two most likely
 488 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 489 # query (on a CLOB.)
 490 #
 491 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 492 # DBD::Oracle, otherwise the query will fail. This is done by passing
 493 # dbd_attrs => undef.
 494
 495 sub _prep_for_execute {
 496   my $self = shift;
 497   my ($op) = @_;
 498
 499   return $self->next::method(@_)
 500     if $op eq 'insert';
 501
 502   my ($sql, $bind) = $self->next::method(@_);
 503
 504   my $lob_bind_indices = { map {
 505     (
 506       $bind->[$_][0]{sqlt_datatype}
 507         and
 508       $self->_is_lob_type($bind->[$_][0]{sqlt_datatype})
 509     ) ? ( $_ => 1 ) : ()
 510   } ( 0 .. $#$bind ) };
 511
 512   return ($sql, $bind) unless %$lob_bind_indices;
 513
 514   my ($final_sql, @final_binds);
 515   if ($op eq 'update') {
 516     $self->throw_exception('Update with complex WHERE clauses involving BLOB columns currently not supported')
 517       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 518
 519     my $where_sql;
 520     ($final_sql, $where_sql) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 521
 522     if (my $set_bind_count = $final_sql =~ y/?//) {
 523
 524       delete $lob_bind_indices->{$_} for (0 .. ($set_bind_count - 1));
 525
 526       # bail if only the update part contains blobs
 527       return ($sql, $bind) unless %$lob_bind_indices;
 528
 529       @final_binds = splice @$bind, 0, $set_bind_count;
 530       $lob_bind_indices = { map
 531         { $_ - $set_bind_count => $lob_bind_indices->{$_} }
 532         keys %$lob_bind_indices
 533       };
 534     }
 535
 536     # if we got that far - assume the where SQL is all we got
 537     # (the first part is already shoved into $final_sql)
 538     $sql = $where_sql;
 539   }
 540   elsif ($op ne 'select' and $op ne 'delete') {
 541     $self->throw_exception("Unsupported \$op: $op");
 542   }
 543
 544   my @sql_parts = split /\?/, $sql;
 545
 546   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 547
 548   for my $b_idx (0 .. $#$bind) {
 549     my $bound = $bind->[$b_idx];
 550
 551     if (
 552       $lob_bind_indices->{$b_idx}
 553         and
 554       my ($col, $eq) = $sql_parts[0] =~ $col_equality_re
 555     ) {
 556       my $data = $bound->[1];
 557
 558       $data = "$data" if ref $data;
 559
 560       my @parts = unpack '(a2000)*', $data;
 561
 562       my @sql_frag;
 563
 564       for my $idx (0..$#parts) {
 565         push @sql_frag, sprintf (
 566           'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 567           $col, ($idx*2000 + 1),
 568         );
 569       }
 570
 571       my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 572
 573       $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 574
 575       $final_sql .= shift @sql_parts;
 576
 577       for my $idx (0..$#parts) {
 578         push @final_binds, [
 579           {
 580             %{ $bound->[0] },
 581             _ora_lob_autosplit_part => $idx,
 582             dbd_attrs => undef,
 583           },
 584           $parts[$idx]
 585         ];
 586       }
 587     }
 588     else {
 589       $final_sql .= shift(@sql_parts) . '?';
 590       push @final_binds, $lob_bind_indices->{$b_idx}
 591         ? [
 592           {
 593             %{ $bound->[0] },
 594             dbd_attrs => undef,
 595           },
 596           $bound->[1],
 597         ] : $bound
 598       ;
 599     }
 600   }
 601
 602   if (@sql_parts > 1) {
 603     carp "There are more placeholders than binds, this should not happen!";
 604     @sql_parts = join ('?', @sql_parts);
 605   }
 606
 607   $final_sql .= $sql_parts[0];
 608
 609   return ($final_sql, \@final_binds);
 610 }
 611
 612 # Savepoints stuff.
 613
 614 sub _exec_svp_begin {
 615   my ($self, $name) = @_;
 616   $self->_dbh->do("SAVEPOINT $name");
 617 }
 618
 619 # Oracle automatically releases a savepoint when you start another one with the
 620 # same name.
 621 sub _exec_svp_release { 1 }
 622
 623 sub _exec_svp_rollback {
 624   my ($self, $name) = @_;
 625   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 626 }
 627
 628 =head2 relname_to_table_alias
 629
 630 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 631 queries.
 632
 633 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 634 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 635 MD5 hash.
 636
 637 See L<DBIx::Class::Storage::DBI/relname_to_table_alias>.
 638
 639 =cut
 640
 641 sub relname_to_table_alias {
 642   my $self = shift;
 643   my ($relname, $join_count) = @_;
 644
 645   my $alias = $self->next::method(@_);
 646
 647   # we need to shorten here in addition to the shortening in SQLA itself,
 648   # since the final relnames are crucial for the join optimizer
 649   return $self->sql_maker->_shorten_identifier($alias);
 650 }
 651
 652 =head2 with_deferred_fk_checks
 653
 654 Runs a coderef between:
 655
 656   alter session set constraints = deferred
 657   ...
 658   alter session set constraints = immediate
 659
 660 to defer foreign key checks.
 661
 662 Constraints must be declared C<DEFERRABLE> for this to work.
 663
 664 =cut
 665
 666 sub with_deferred_fk_checks {
 667   my ($self, $sub) = @_;
 668
 669   my $txn_scope_guard = $self->txn_scope_guard;
 670
 671   $self->_do_query('alter session set constraints = deferred');
 672
 673   my $sg = Scope::Guard->new(sub {
 674     $self->_do_query('alter session set constraints = immediate');
 675   });
 676
 677   return
 678     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 679 }
 680
 681 =head1 ATTRIBUTES
 682
 683 Following additional attributes can be used in resultsets.
 684
 685 =head2 connect_by or connect_by_nocycle
 686
 687 =over 4
 688
 689 =item Value: \%connect_by
 690
 691 =back
 692
 693 A hashref of conditions used to specify the relationship between parent rows
 694 and child rows of the hierarchy.
 695
 696
 697   connect_by => { parentid => 'prior personid' }
 698
 699   # adds a connect by statement to the query:
 700   # SELECT
 701   #     me.persionid me.firstname, me.lastname, me.parentid
 702   # FROM
 703   #     person me
 704   # CONNECT BY
 705   #     parentid = prior persionid
 706
 707
 708   connect_by_nocycle => { parentid => 'prior personid' }
 709
 710   # adds a connect by statement to the query:
 711   # SELECT
 712   #     me.persionid me.firstname, me.lastname, me.parentid
 713   # FROM
 714   #     person me
 715   # CONNECT BY NOCYCLE
 716   #     parentid = prior persionid
 717
 718
 719 =head2 start_with
 720
 721 =over 4
 722
 723 =item Value: \%condition
 724
 725 =back
 726
 727 A hashref of conditions which specify the root row(s) of the hierarchy.
 728
 729 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 730
 731   start_with => { firstname => 'Foo', lastname => 'Bar' }
 732
 733   # SELECT
 734   #     me.persionid me.firstname, me.lastname, me.parentid
 735   # FROM
 736   #     person me
 737   # START WITH
 738   #     firstname = 'foo' and lastname = 'bar'
 739   # CONNECT BY
 740   #     parentid = prior persionid
 741
 742 =head2 order_siblings_by
 743
 744 =over 4
 745
 746 =item Value: ($order_siblings_by | \@order_siblings_by)
 747
 748 =back
 749
 750 Which column(s) to order the siblings by.
 751
 752 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 753
 754   'order_siblings_by' => 'firstname ASC'
 755
 756   # SELECT
 757   #     me.persionid me.firstname, me.lastname, me.parentid
 758   # FROM
 759   #     person me
 760   # CONNECT BY
 761   #     parentid = prior persionid
 762   # ORDER SIBLINGS BY
 763   #     firstname ASC
 764
 765 =head1 FURTHER QUESTIONS?
 766
 767 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 768
 769 =head1 COPYRIGHT AND LICENSE
 770
 771 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 772 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 773 redistribute it and/or modify it under the same terms as the
 774 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 775
 776 =cut
 777
 778 1;
 779 # vim:sts=2 sw=2: