lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use DBIx::Class::Carp;
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('RowNum');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Oracle');
  17 __PACKAGE__->datetime_parser_type('DateTime::Format::Oracle');
  18
  19 sub __cache_queries_with_max_lob_parts { 2 }
  20
  21 =head1 NAME
  22
  23 DBIx::Class::Storage::DBI::Oracle::Generic - Oracle Support for DBIx::Class
  24
  25 =head1 SYNOPSIS
  26
  27   # In your result (table) classes
  28   use base 'DBIx::Class::Core';
  29   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  30   __PACKAGE__->set_primary_key('id');
  31
  32   # Somewhere in your Code
  33   # add some data to a table with a hierarchical relationship
  34   $schema->resultset('Person')->create ({
  35         firstname => 'foo',
  36         lastname => 'bar',
  37         children => [
  38             {
  39                 firstname => 'child1',
  40                 lastname => 'bar',
  41                 children => [
  42                     {
  43                         firstname => 'grandchild',
  44                         lastname => 'bar',
  45                     }
  46                 ],
  47             },
  48             {
  49                 firstname => 'child2',
  50                 lastname => 'bar',
  51             },
  52         ],
  53     });
  54
  55   # select from the hierarchical relationship
  56   my $rs = $schema->resultset('Person')->search({},
  57     {
  58       'start_with' => { 'firstname' => 'foo', 'lastname' => 'bar' },
  59       'connect_by' => { 'parentid' => { '-prior' => { -ident => 'personid' } },
  60       'order_siblings_by' => { -asc => 'name' },
  61     };
  62   );
  63
  64   # this will select the whole tree starting from person "foo bar", creating
  65   # following query:
  66   # SELECT
  67   #     me.persionid me.firstname, me.lastname, me.parentid
  68   # FROM
  69   #     person me
  70   # START WITH
  71   #     firstname = 'foo' and lastname = 'bar'
  72   # CONNECT BY
  73   #     parentid = prior personid
  74   # ORDER SIBLINGS BY
  75   #     firstname ASC
  76
  77 =head1 DESCRIPTION
  78
  79 This class implements base Oracle support. The subclass
  80 L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> is for C<(+)> joins in Oracle
  81 versions before 9.0.
  82
  83 =head1 METHODS
  84
  85 =cut
  86
  87 sub _determine_supports_insert_returning {
  88   my $self = shift;
  89
  90 # TODO find out which version supports the RETURNING syntax
  91 # 8i has it and earlier docs are a 404 on oracle.com
  92
  93   return 1
  94     if $self->_server_info->{normalized_dbms_version} >= 8.001;
  95
  96   return 0;
  97 }
  98
  99 __PACKAGE__->_use_insert_returning_bound (1);
 100
 101 sub deployment_statements {
 102   my $self = shift;;
 103   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 104
 105   $sqltargs ||= {};
 106
 107   if (
 108     ! exists $sqltargs->{producer_args}{oracle_version}
 109       and
 110     my $dver = $self->_server_info->{dbms_version}
 111   ) {
 112     $sqltargs->{producer_args}{oracle_version} = $dver;
 113   }
 114
 115   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 116 }
 117
 118 sub _dbh_last_insert_id {
 119   my ($self, $dbh, $source, @columns) = @_;
 120   my @ids = ();
 121   foreach my $col (@columns) {
 122     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
 123     my $id = $self->_sequence_fetch( 'CURRVAL', $seq );
 124     push @ids, $id;
 125   }
 126   return @ids;
 127 }
 128
 129 sub _dbh_get_autoinc_seq {
 130   my ($self, $dbh, $source, $col) = @_;
 131
 132   my $sql_maker = $self->sql_maker;
 133   my ($ql, $qr) = map { $_ ? (quotemeta $_) : '' } $sql_maker->_quote_chars;
 134
 135   my $source_name;
 136   if ( ref $source->name eq 'SCALAR' ) {
 137     $source_name = ${$source->name};
 138
 139     # the ALL_TRIGGERS match further on is case sensitive - thus uppercase
 140     # stuff unless it is already quoted
 141     $source_name = uc ($source_name) if $source_name !~ /\"/;
 142   }
 143   else {
 144     $source_name = $source->name;
 145     $source_name = uc($source_name) unless $ql;
 146   }
 147
 148   # trigger_body is a LONG
 149   local $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
 150
 151   # disable default bindtype
 152   local $sql_maker->{bindtype} = 'normal';
 153
 154   # look up the correct sequence automatically
 155   my ( $schema, $table ) = $source_name =~ /( (?:${ql})? \w+ (?:${qr})? ) \. ( (?:${ql})? \w+ (?:${qr})? )/x;
 156
 157   # if no explicit schema was requested - use the default schema (which in the case of Oracle is the db user)
 158   $schema ||= \'= USER';
 159
 160   my ($sql, @bind) = $sql_maker->select (
 161     'ALL_TRIGGERS',
 162     [qw/TRIGGER_BODY TABLE_OWNER TRIGGER_NAME/],
 163     {
 164       OWNER => $schema,
 165       TABLE_NAME => $table || $source_name,
 166       TRIGGERING_EVENT => { -like => '%INSERT%' },  # this will also catch insert_or_update
 167       TRIGGER_TYPE => { -like => '%BEFORE%' },      # we care only about 'before' triggers
 168       STATUS => 'ENABLED',
 169      },
 170   );
 171
 172   # to find all the triggers that mention the column in question a simple
 173   # regex grep since the trigger_body above is a LONG and hence not searchable
 174   # via -like
 175   my @triggers = ( map
 176     { my %inf; @inf{qw/body schema name/} = @$_; \%inf }
 177     ( grep
 178       { $_->[0] =~ /\:new\.${ql}${col}${qr} | \:new\.$col/xi }
 179       @{ $dbh->selectall_arrayref( $sql, {}, @bind ) }
 180     )
 181   );
 182
 183   # extract all sequence names mentioned in each trigger, throw away
 184   # triggers without apparent sequences
 185   @triggers = map {
 186     my @seqs = $_->{body} =~ / ( [\.\w\"\-]+ ) \. nextval /xig;
 187     @seqs
 188       ? { %$_, sequences => \@seqs }
 189       : ()
 190     ;
 191   } @triggers;
 192
 193   my $chosen_trigger;
 194
 195   # if only one trigger matched things are easy
 196   if (@triggers == 1) {
 197
 198     if ( @{$triggers[0]{sequences}} == 1 ) {
 199       $chosen_trigger = $triggers[0];
 200     }
 201     else {
 202       $self->throw_exception( sprintf (
 203         "Unable to introspect trigger '%s' for column '%s.%s' (references multiple sequences). "
 204       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 205         $triggers[0]{name},
 206         $source_name,
 207         $col,
 208         $col,
 209       ) );
 210     }
 211   }
 212   # got more than one matching trigger - see if we can narrow it down
 213   elsif (@triggers > 1) {
 214
 215     my @candidates = grep
 216       { $_->{body} =~ / into \s+ \:new\.$col /xi }
 217       @triggers
 218     ;
 219
 220     if (@candidates == 1 && @{$candidates[0]{sequences}} == 1) {
 221       $chosen_trigger = $candidates[0];
 222     }
 223     else {
 224       $self->throw_exception( sprintf (
 225         "Unable to reliably select a BEFORE INSERT trigger for column '%s.%s' (possibilities: %s). "
 226       . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 227         $source_name,
 228         $col,
 229         ( join ', ', map { "'$_->{name}'" } @triggers ),
 230         $col,
 231       ) );
 232     }
 233   }
 234
 235   if ($chosen_trigger) {
 236     my $seq_name = $chosen_trigger->{sequences}[0];
 237
 238     $seq_name = "$chosen_trigger->{schema}.$seq_name"
 239       unless $seq_name =~ /\./;
 240
 241     return \$seq_name if $seq_name =~ /\"/; # may already be quoted in-trigger
 242     return $seq_name;
 243   }
 244
 245   $self->throw_exception( sprintf (
 246     "No suitable BEFORE INSERT triggers found for column '%s.%s'. "
 247   . "You need to specify the correct 'sequence' explicitly in '%s's column_info.",
 248     $source_name,
 249     $col,
 250     $col,
 251   ));
 252 }
 253
 254 sub _sequence_fetch {
 255   my ( $self, $type, $seq ) = @_;
 256
 257   # use the maker to leverage quoting settings
 258   my $sth = $self->_dbh->prepare_cached(
 259     $self->sql_maker->select('DUAL', [ ref $seq ? \"$$seq.$type" : "$seq.$type" ] )
 260   );
 261   $sth->execute;
 262   my ($id) = $sth->fetchrow_array;
 263   $sth->finish;
 264   return $id;
 265 }
 266
 267 sub _ping {
 268   my $self = shift;
 269
 270   my $dbh = $self->_dbh or return 0;
 271
 272   local $dbh->{RaiseError} = 1;
 273   local $dbh->{PrintError} = 0;
 274
 275   return try {
 276     $dbh->do('select 1 from dual');
 277     1;
 278   } catch {
 279     0;
 280   };
 281 }
 282
 283 sub _dbh_execute {
 284   #my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
 285   my ($self, $sql, $bind) = @_[0,2,3];
 286
 287   # Turn off sth caching for multi-part LOBs. See _prep_for_execute below
 288   local $self->{disable_sth_caching} = 1 if first {
 289     ($_->[0]{_ora_lob_autosplit_part}||0)
 290       >
 291     (__cache_queries_with_max_lob_parts - 1)
 292   } @$bind;
 293
 294   my $next = $self->next::can;
 295
 296   # if we are already in a txn we can't retry anything
 297   return shift->$next(@_)
 298     if $self->transaction_depth;
 299
 300   # cheat the blockrunner we are just about to create
 301   # we do want to rerun things regardless of outer state
 302   local $self->{_in_do_block};
 303
 304   return DBIx::Class::Storage::BlockRunner->new(
 305     storage => $self,
 306     wrap_txn => 0,
 307     retry_handler => sub {
 308       # ORA-01003: no statement parsed (someone changed the table somehow,
 309       # invalidating your cursor.)
 310       if (
 311         $_[0]->failed_attempt_count == 1
 312           and
 313         $_[0]->last_exception =~ /ORA-01003/
 314           and
 315         my $dbh = $_[0]->storage->_dbh
 316       ) {
 317         delete $dbh->{CachedKids}{$sql};
 318         return 1;
 319       }
 320       else {
 321         return 0;
 322       }
 323     },
 324   )->run( $next, @_ );
 325 }
 326
 327 sub _dbh_execute_for_fetch {
 328   #my ($self, $sth, $tuple_status, @extra) = @_;
 329
 330   # DBD::Oracle warns loudly on partial execute_for_fetch failures
 331   local $_[1]->{PrintWarn} = 0;
 332
 333   shift->next::method(@_);
 334 }
 335
 336 =head2 get_autoinc_seq
 337
 338 Returns the sequence name for an autoincrement column
 339
 340 =cut
 341
 342 sub get_autoinc_seq {
 343   my ($self, $source, $col) = @_;
 344
 345   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 346 }
 347
 348 =head2 datetime_parser_type
 349
 350 This sets the proper DateTime::Format module for use with
 351 L<DBIx::Class::InflateColumn::DateTime>.
 352
 353 =head2 connect_call_datetime_setup
 354
 355 Used as:
 356
 357     on_connect_call => 'datetime_setup'
 358
 359 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the session nls
 360 date, and timestamp values for use with L<DBIx::Class::InflateColumn::DateTime>
 361 and the necessary environment variables for L<DateTime::Format::Oracle>, which
 362 is used by it.
 363
 364 Maximum allowable precision is used, unless the environment variables have
 365 already been set.
 366
 367 These are the defaults used:
 368
 369   $ENV{NLS_DATE_FORMAT}         ||= 'YYYY-MM-DD HH24:MI:SS';
 370   $ENV{NLS_TIMESTAMP_FORMAT}    ||= 'YYYY-MM-DD HH24:MI:SS.FF';
 371   $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 372
 373 To get more than second precision with L<DBIx::Class::InflateColumn::DateTime>
 374 for your timestamps, use something like this:
 375
 376   use Time::HiRes 'time';
 377   my $ts = DateTime->from_epoch(epoch => time);
 378
 379 =cut
 380
 381 sub connect_call_datetime_setup {
 382   my $self = shift;
 383
 384   my $date_format = $ENV{NLS_DATE_FORMAT} ||= 'YYYY-MM-DD HH24:MI:SS';
 385   my $timestamp_format = $ENV{NLS_TIMESTAMP_FORMAT} ||=
 386     'YYYY-MM-DD HH24:MI:SS.FF';
 387   my $timestamp_tz_format = $ENV{NLS_TIMESTAMP_TZ_FORMAT} ||=
 388     'YYYY-MM-DD HH24:MI:SS.FF TZHTZM';
 389
 390   $self->_do_query(
 391     "alter session set nls_date_format = '$date_format'"
 392   );
 393   $self->_do_query(
 394     "alter session set nls_timestamp_format = '$timestamp_format'"
 395   );
 396   $self->_do_query(
 397     "alter session set nls_timestamp_tz_format='$timestamp_tz_format'"
 398   );
 399 }
 400
 401 ### Note originally by Ron "Quinn" Straight <quinnfazigu@gmail.org>
 402 ### http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=dbsrgits/DBIx-Class.git;a=commitdiff;h=5db2758de644d53e07cd3e05f0e9037bf40116fc
 403 #
 404 # Handle LOB types in Oracle.  Under a certain size (4k?), you can get away
 405 # with the driver assuming your input is the deprecated LONG type if you
 406 # encode it as a hex string.  That ain't gonna fly at larger values, where
 407 # you'll discover you have to do what this does.
 408 #
 409 # This method had to be overridden because we need to set ora_field to the
 410 # actual column, and that isn't passed to the call (provided by Storage) to
 411 # bind_attribute_by_data_type.
 412 #
 413 # According to L<DBD::Oracle>, the ora_field isn't always necessary, but
 414 # adding it doesn't hurt, and will save your bacon if you're modifying a
 415 # table with more than one LOB column.
 416 #
 417 sub _dbi_attrs_for_bind {
 418   my ($self, $ident, $bind) = @_;
 419
 420   my $attrs = $self->next::method($ident, $bind);
 421
 422   # Push the column name into all bind attrs, make sure to *NOT* write into
 423   # the existing $attrs->[$idx]{..} hashref, as it is cached by the call to
 424   # next::method above.
 425   # FIXME - this code will go away when the LobWriter refactor lands
 426   $attrs->[$_]
 427     and
 428   keys %{ $attrs->[$_] }
 429     and
 430   $bind->[$_][0]{dbic_colname}
 431     and
 432   $attrs->[$_] = { %{$attrs->[$_]}, ora_field => $bind->[$_][0]{dbic_colname} }
 433     for 0 .. $#$attrs;
 434
 435   $attrs;
 436 }
 437
 438 sub bind_attribute_by_data_type {
 439   my ($self, $dt) = @_;
 440
 441   if ($self->_is_lob_type($dt)) {
 442
 443     # this is a hot-ish codepath, store an escape-flag in the DBD namespace, so that
 444     # things like Class::Unload work (unlikely but possible)
 445     unless ($DBD::Oracle::__DBIC_DBD_VERSION_CHECK_OK__) {
 446
 447       # no earlier - no later
 448       if ($DBD::Oracle::VERSION eq '1.23') {
 449         $self->throw_exception(
 450           "BLOB/CLOB support in DBD::Oracle == 1.23 is broken, use an earlier or later ".
 451           "version (https://rt.cpan.org/Public/Bug/Display.html?id=46016)"
 452         );
 453       }
 454
 455       $DBD::Oracle::__DBIC_DBD_VERSION_CHECK_OK__ = 1;
 456     }
 457
 458     return {
 459       ora_type => $self->_is_text_lob_type($dt)
 460         ? DBD::Oracle::ORA_CLOB()
 461         : DBD::Oracle::ORA_BLOB()
 462     };
 463   }
 464   else {
 465     return undef;
 466   }
 467 }
 468
 469 # Handle blob columns in WHERE.
 470 #
 471 # For equality comparisons:
 472 #
 473 # We split data intended for comparing to a LOB into 2000 character chunks and
 474 # compare them using dbms_lob.substr on the LOB column.
 475 #
 476 # We turn off DBD::Oracle LOB binds for these partial LOB comparisons by passing
 477 # dbd_attrs => undef, because these are regular varchar2 comparisons and
 478 # otherwise the query will fail.
 479 #
 480 # Since the most common comparison size is likely to be under 4000 characters
 481 # (TEXT comparisons previously deployed to other RDBMSes) we disable
 482 # prepare_cached for queries with more than two part comparisons to a LOB
 483 # column. This is done in _dbh_execute (above) which was previously overridden
 484 # to gracefully recover from an Oracle error. This is to be careful to not
 485 # exhaust your application's open cursor limit.
 486 #
 487 # See:
 488 # http://itcareershift.com/blog1/2011/02/21/oracle-max-number-of-open-cursors-complete-reference-for-the-new-oracle-dba/
 489 # on the open_cursor limit.
 490 #
 491 # For everything else:
 492 #
 493 # We assume that everything that is not a LOB comparison, will most likely be a
 494 # LIKE query or some sort of function invocation. This may prove to be a naive
 495 # assumption in the future, but for now it should cover the two most likely
 496 # things users would want to do with a BLOB or CLOB, an equality test or a LIKE
 497 # query (on a CLOB.)
 498 #
 499 # For these expressions, the bind must NOT have the attributes of a LOB bind for
 500 # DBD::Oracle, otherwise the query will fail. This is done by passing
 501 # dbd_attrs => undef.
 502
 503 sub _prep_for_execute {
 504   my $self = shift;
 505   my ($op) = @_;
 506
 507   return $self->next::method(@_)
 508     if $op eq 'insert';
 509
 510   my ($sql, $bind) = $self->next::method(@_);
 511
 512   my $lob_bind_indices = { map {
 513     (
 514       $bind->[$_][0]{sqlt_datatype}
 515         and
 516       $self->_is_lob_type($bind->[$_][0]{sqlt_datatype})
 517     ) ? ( $_ => 1 ) : ()
 518   } ( 0 .. $#$bind ) };
 519
 520   return ($sql, $bind) unless %$lob_bind_indices;
 521
 522   my ($final_sql, @final_binds);
 523   if ($op eq 'update') {
 524     $self->throw_exception('Update with complex WHERE clauses involving BLOB columns currently not supported')
 525       if $sql =~ /\bWHERE\b .+ \bWHERE\b/xs;
 526
 527     my $where_sql;
 528     ($final_sql, $where_sql) = $sql =~ /^ (.+?) ( \bWHERE\b .+) /xs;
 529
 530     if (my $set_bind_count = $final_sql =~ y/?//) {
 531
 532       delete $lob_bind_indices->{$_} for (0 .. ($set_bind_count - 1));
 533
 534       # bail if only the update part contains blobs
 535       return ($sql, $bind) unless %$lob_bind_indices;
 536
 537       @final_binds = splice @$bind, 0, $set_bind_count;
 538       $lob_bind_indices = { map
 539         { $_ - $set_bind_count => $lob_bind_indices->{$_} }
 540         keys %$lob_bind_indices
 541       };
 542     }
 543
 544     # if we got that far - assume the where SQL is all we got
 545     # (the first part is already shoved into $final_sql)
 546     $sql = $where_sql;
 547   }
 548   elsif ($op ne 'select' and $op ne 'delete') {
 549     $self->throw_exception("Unsupported \$op: $op");
 550   }
 551
 552   my @sql_parts = split /\?/, $sql;
 553
 554   my $col_equality_re = qr/ (?<=\s) ([\w."]+) (\s*=\s*) $/x;
 555
 556   for my $b_idx (0 .. $#$bind) {
 557     my $bound = $bind->[$b_idx];
 558
 559     if (
 560       $lob_bind_indices->{$b_idx}
 561         and
 562       my ($col, $eq) = $sql_parts[0] =~ $col_equality_re
 563     ) {
 564       my $data = $bound->[1];
 565
 566       $data = "$data" if ref $data;
 567
 568       my @parts = unpack '(a2000)*', $data;
 569
 570       my @sql_frag;
 571
 572       for my $idx (0..$#parts) {
 573         push @sql_frag, sprintf (
 574           'UTL_RAW.CAST_TO_VARCHAR2(RAWTOHEX(DBMS_LOB.SUBSTR(%s, 2000, %d))) = ?',
 575           $col, ($idx*2000 + 1),
 576         );
 577       }
 578
 579       my $sql_frag = '( ' . (join ' AND ', @sql_frag) . ' )';
 580
 581       $sql_parts[0] =~ s/$col_equality_re/$sql_frag/;
 582
 583       $final_sql .= shift @sql_parts;
 584
 585       for my $idx (0..$#parts) {
 586         push @final_binds, [
 587           {
 588             %{ $bound->[0] },
 589             _ora_lob_autosplit_part => $idx,
 590             dbd_attrs => undef,
 591           },
 592           $parts[$idx]
 593         ];
 594       }
 595     }
 596     else {
 597       $final_sql .= shift(@sql_parts) . '?';
 598       push @final_binds, $lob_bind_indices->{$b_idx}
 599         ? [
 600           {
 601             %{ $bound->[0] },
 602             dbd_attrs => undef,
 603           },
 604           $bound->[1],
 605         ] : $bound
 606       ;
 607     }
 608   }
 609
 610   if (@sql_parts > 1) {
 611     carp "There are more placeholders than binds, this should not happen!";
 612     @sql_parts = join ('?', @sql_parts);
 613   }
 614
 615   $final_sql .= $sql_parts[0];
 616
 617   return ($final_sql, \@final_binds);
 618 }
 619
 620 # Savepoints stuff.
 621
 622 sub _exec_svp_begin {
 623   my ($self, $name) = @_;
 624   $self->_dbh->do("SAVEPOINT $name");
 625 }
 626
 627 # Oracle automatically releases a savepoint when you start another one with the
 628 # same name.
 629 sub _exec_svp_release { 1 }
 630
 631 sub _exec_svp_rollback {
 632   my ($self, $name) = @_;
 633   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 634 }
 635
 636 =head2 relname_to_table_alias
 637
 638 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
 639 queries.
 640
 641 Unfortunately, Oracle doesn't support identifiers over 30 chars in length, so
 642 the L<DBIx::Class::Relationship> name is shortened and appended with half of an
 643 MD5 hash.
 644
 645 See L<DBIx::Class::Storage::DBI/relname_to_table_alias>.
 646
 647 =cut
 648
 649 sub relname_to_table_alias {
 650   my $self = shift;
 651   my ($relname, $join_count) = @_;
 652
 653   my $alias = $self->next::method(@_);
 654
 655   # we need to shorten here in addition to the shortening in SQLA itself,
 656   # since the final relnames are crucial for the join optimizer
 657   return $self->sql_maker->_shorten_identifier($alias);
 658 }
 659
 660 =head2 with_deferred_fk_checks
 661
 662 Runs a coderef between:
 663
 664   alter session set constraints = deferred
 665   ...
 666   alter session set constraints = immediate
 667
 668 to defer foreign key checks.
 669
 670 Constraints must be declared C<DEFERRABLE> for this to work.
 671
 672 =cut
 673
 674 sub with_deferred_fk_checks {
 675   my ($self, $sub) = @_;
 676
 677   my $txn_scope_guard = $self->txn_scope_guard;
 678
 679   $self->_do_query('alter session set constraints = deferred');
 680
 681   my $sg = Scope::Guard->new(sub {
 682     $self->_do_query('alter session set constraints = immediate');
 683   });
 684
 685   return
 686     preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
 687 }
 688
 689 =head1 ATTRIBUTES
 690
 691 Following additional attributes can be used in resultsets.
 692
 693 =head2 connect_by or connect_by_nocycle
 694
 695 =over 4
 696
 697 =item Value: \%connect_by
 698
 699 =back
 700
 701 A hashref of conditions used to specify the relationship between parent rows
 702 and child rows of the hierarchy.
 703
 704
 705   connect_by => { parentid => 'prior personid' }
 706
 707   # adds a connect by statement to the query:
 708   # SELECT
 709   #     me.persionid me.firstname, me.lastname, me.parentid
 710   # FROM
 711   #     person me
 712   # CONNECT BY
 713   #     parentid = prior persionid
 714
 715
 716   connect_by_nocycle => { parentid => 'prior personid' }
 717
 718   # adds a connect by statement to the query:
 719   # SELECT
 720   #     me.persionid me.firstname, me.lastname, me.parentid
 721   # FROM
 722   #     person me
 723   # CONNECT BY NOCYCLE
 724   #     parentid = prior persionid
 725
 726
 727 =head2 start_with
 728
 729 =over 4
 730
 731 =item Value: \%condition
 732
 733 =back
 734
 735 A hashref of conditions which specify the root row(s) of the hierarchy.
 736
 737 It uses the same syntax as L<DBIx::Class::ResultSet/search>
 738
 739   start_with => { firstname => 'Foo', lastname => 'Bar' }
 740
 741   # SELECT
 742   #     me.persionid me.firstname, me.lastname, me.parentid
 743   # FROM
 744   #     person me
 745   # START WITH
 746   #     firstname = 'foo' and lastname = 'bar'
 747   # CONNECT BY
 748   #     parentid = prior persionid
 749
 750 =head2 order_siblings_by
 751
 752 =over 4
 753
 754 =item Value: ($order_siblings_by | \@order_siblings_by)
 755
 756 =back
 757
 758 Which column(s) to order the siblings by.
 759
 760 It uses the same syntax as L<DBIx::Class::ResultSet/order_by>
 761
 762   'order_siblings_by' => 'firstname ASC'
 763
 764   # SELECT
 765   #     me.persionid me.firstname, me.lastname, me.parentid
 766   # FROM
 767   #     person me
 768   # CONNECT BY
 769   #     parentid = prior persionid
 770   # ORDER SIBLINGS BY
 771   #     firstname ASC
 772
 773 =head1 FURTHER QUESTIONS?
 774
 775 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 776
 777 =head1 COPYRIGHT AND LICENSE
 778
 779 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 780 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 781 redistribute it and/or modify it under the same terms as the
 782 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 783
 784 =cut
 785
 786 1;
 787 # vim:sts=2 sw=2: