lib/DBIx/Class/Storage/DBI/ODBC/Microsoft_SQL_Server.pm

   1 package DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server;
   2 use strict;
   3 use warnings;
   4
   5 use base qw/DBIx::Class::Storage::DBI::MSSQL/;
   6 use mro 'c3';
   7
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use List::Util();
  10 use Scalar::Util ();
  11
  12 __PACKAGE__->mk_group_accessors(simple => qw/
  13   _using_dynamic_cursors
  14 /);
  15
  16 =head1 NAME
  17
  18 DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server - Support specific
  19 to Microsoft SQL Server over ODBC
  20
  21 =head1 DESCRIPTION
  22
  23 This class implements support specific to Microsoft SQL Server over ODBC.  It is
  24 loaded automatically by by DBIx::Class::Storage::DBI::ODBC when it detects a
  25 MSSQL back-end.
  26
  27 Most of the functionality is provided from the superclass
  28 L<DBIx::Class::Storage::DBI::MSSQL>.
  29
  30 =head1 MULTIPLE ACTIVE STATEMENTS
  31
  32 The following options are alternative ways to enable concurrent executing
  33 statement support. Each has its own advantages and drawbacks.
  34
  35 =head2 connect_call_use_dynamic_cursors
  36
  37 Use as:
  38
  39   on_connect_call => 'use_dynamic_cursors'
  40
  41 in your L<DBIx::Class::Storage::DBI/connect_info> as one way to enable multiple
  42 concurrent statements.
  43
  44 Will add C<< odbc_cursortype => 2 >> to your DBI connection attributes. See
  45 L<DBD::ODBC/odbc_cursortype> for more information.
  46
  47 Alternatively, you can add it yourself and dynamic cursor support will be
  48 automatically enabled.
  49
  50 If you're using FreeTDS, C<tds_version> must be set to at least C<8.0>.
  51
  52 This will not work with CODE ref connect_info's.
  53
  54 B<WARNING:> this will break C<SCOPE_IDENTITY()>, and C<SELECT @@IDENTITY> will
  55 be used instead, which on SQL Server 2005 and later will return erroneous
  56 results on tables which have an on insert trigger that inserts into another
  57 table with an C<IDENTITY> column.
  58
  59 =cut
  60
  61 sub connect_call_use_dynamic_cursors {
  62   my $self = shift;
  63
  64   if (ref($self->_dbi_connect_info->[0]) eq 'CODE') {
  65     croak 'cannot set DBI attributes on a CODE ref connect_info';
  66   }
  67
  68   my $dbi_attrs = $self->_dbi_connect_info->[-1];
  69
  70   unless (ref($dbi_attrs) && Scalar::Util::reftype($dbi_attrs) eq 'HASH') {
  71     $dbi_attrs = {};
  72     push @{ $self->_dbi_connect_info }, $dbi_attrs;
  73   }
  74
  75   if (not exists $dbi_attrs->{odbc_cursortype}) {
  76     # turn on support for multiple concurrent statements, unless overridden
  77     $dbi_attrs->{odbc_cursortype} = 2;
  78     $self->disconnect; # resetting dbi attrs, so have to reconnect
  79     $self->ensure_connected;
  80     $self->_set_dynamic_cursors;
  81   }
  82 }
  83
  84 sub _set_dynamic_cursors {
  85   my $self = shift;
  86   my $dbh  = $self->_get_dbh;
  87
  88   eval {
  89     local $dbh->{RaiseError} = 1;
  90     local $dbh->{PrintError} = 0;
  91     $dbh->do('SELECT @@IDENTITY');
  92   };
  93   if ($@) {
  94     croak <<'EOF';
  95
  96 Your drivers do not seem to support dynamic cursors (odbc_cursortype => 2),
  97 if you're using FreeTDS, make sure to set tds_version to 8.0 or greater.
  98 EOF
  99   }
 100
 101   $self->_using_dynamic_cursors(1);
 102   $self->_identity_method('@@identity');
 103 }
 104
 105 sub _init {
 106   my $self = shift;
 107
 108   if (ref($self->_dbi_connect_info->[0]) ne 'CODE' &&
 109       eval { $self->_dbi_connect_info->[-1]{odbc_cursortype} } == 2) {
 110     $self->_set_dynamic_cursors;
 111     return;
 112   }
 113
 114   $self->_using_dynamic_cursors(0);
 115 }
 116
 117 =head2 connect_call_use_server_cursors
 118
 119 Use as:
 120
 121   on_connect_call => 'use_server_cursors'
 122
 123 May allow multiple active select statements. See
 124 L<DBD::ODBC/odbc_SQL_ROWSET_SIZE> for more information.
 125
 126 Takes an optional parameter for the value to set the attribute to, default is
 127 C<2>.
 128
 129 B<WARNING>: this does not work on all versions of SQL Server, and may lock up
 130 your database!
 131
 132 =cut
 133
 134 sub connect_call_use_server_cursors {
 135   my $self            = shift;
 136   my $sql_rowset_size = shift || 2;
 137
 138   $self->_get_dbh->{odbc_SQL_ROWSET_SIZE} = $sql_rowset_size;
 139 }
 140
 141 =head2 connect_call_use_MARS
 142
 143 Use as:
 144
 145   on_connect_call => 'use_MARS'
 146
 147 Use to enable a feature of SQL Server 2005 and later, "Multiple Active Result
 148 Sets". See L<DBD::ODBC::FAQ/Does DBD::ODBC support Multiple Active Statements?>
 149 for more information.
 150
 151 B<WARNING>: This has implications for the way transactions are handled.
 152
 153 =cut
 154
 155 sub connect_call_use_MARS {
 156   my $self = shift;
 157
 158   my $dsn = $self->_dbi_connect_info->[0];
 159
 160   if (ref($dsn) eq 'CODE') {
 161     croak 'cannot change the DBI DSN on a CODE ref connect_info';
 162   }
 163
 164   if ($dsn !~ /MARS_Connection=/) {
 165     $self->_dbi_connect_info->[0] = "$dsn;MARS_Connection=Yes";
 166     my $was_connected = defined $self->_dbh;
 167     $self->disconnect;
 168     $self->ensure_connected if $was_connected;
 169   }
 170 }
 171
 172 1;
 173
 174 =head1 AUTHOR
 175
 176 See L<DBIx::Class/CONTRIBUTORS>.
 177
 178 =head1 LICENSE
 179
 180 You may distribute this code under the same terms as Perl itself.
 181
 182 =cut
 183 # vim: sw=2 sts=2