lib/DBIx/Class/Storage/DBI/ODBC/Firebird.pm

   1 package DBIx::Class::Storage::DBI::ODBC::Firebird;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6   DBIx::Class::Storage::DBI::ODBC
   7   DBIx::Class::Storage::DBI::Firebird::Common
   8 /;
   9 use mro 'c3';
  10 use Try::Tiny;
  11 use namespace::clean;
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Storage::DBI::ODBC::Firebird - Driver for using the Firebird RDBMS
  16 through ODBC
  17
  18 =head1 DESCRIPTION
  19
  20 Most functionality is provided by
  21 L<DBIx::Class::Storage::DBI::Firebird::Common>, see that driver for details.
  22
  23 To build the ODBC driver for Firebird on Linux for unixODBC, see:
  24
  25 L<http://www.firebirdnews.org/?p=1324>
  26
  27 This driver does not suffer from the nested statement handles across commits
  28 issue that the L<DBD::InterBase|DBIx::Class::Storage::DBI::InterBase> or the
  29 L<DBD::Firebird|DBIx::Class::Storage::DBI::Firebird> based driver does. This
  30 makes it more suitable for long running processes such as under L<Catalyst>.
  31
  32 =cut
  33
  34 # batch operations in DBD::ODBC 1.35 do not work with the official ODBC driver
  35 sub _run_connection_actions {
  36   my $self = shift;
  37
  38   if ($self->_dbh_get_info('SQL_DRIVER_NAME') eq 'OdbcFb') {
  39     $self->_disable_odbc_array_ops;
  40   }
  41
  42   return $self->next::method(@_);
  43 }
  44
  45 # releasing savepoints doesn't work for some reason, but that shouldn't matter
  46 sub _exec_svp_release { 1 }
  47
  48 sub _exec_svp_rollback {
  49   my ($self, $name) = @_;
  50
  51   try {
  52     $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
  53   }
  54   catch {
  55     # Firebird ODBC driver bug, ignore
  56     if (not /Unable to fetch information about the error/) {
  57       $self->throw_exception($_);
  58     }
  59   };
  60 }
  61
  62 =head1 AUTHOR
  63
  64 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
  65
  66 =head1 LICENSE
  67
  68 You may distribute this code under the same terms as Perl itself.
  69
  70 =cut
  71 # vim:sts=2 sw=2: