lib/DBIx/Class/Storage/DBI/MSSQL.pm

   1 package DBIx::Class::Storage::DBI::MSSQL;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::UniqueIdentifier
   8   DBIx::Class::Storage::DBI::IdentityInsert
   9 /;
  10 use mro 'c3';
  11
  12 use Try::Tiny;
  13 use List::Util 'first';
  14 use namespace::clean;
  15
  16 __PACKAGE__->mk_group_accessors(simple => qw/
  17   _identity _identity_method _no_scope_identity_query
  18 /);
  19
  20 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::MSSQL');
  21
  22 __PACKAGE__->sql_quote_char([qw/[ ]/]);
  23
  24 __PACKAGE__->datetime_parser_type (
  25   'DBIx::Class::Storage::DBI::MSSQL::DateTime::Format'
  26 );
  27
  28 __PACKAGE__->new_guid('NEWID()');
  29
  30 sub __sql_server_x_or_higher {
  31   my ($self, $version) = @_;
  32
  33   if (exists $_[0]->_server_info->{normalized_dbms_version}) {
  34     if ($_[0]->_server_info->{normalized_dbms_version} >= $version) {
  35        return 1
  36     } else {
  37        return 0
  38     }
  39   }
  40   return undef;
  41 }
  42
  43 sub __offset_bindtype { +{ dbd_attrs => DBI::SQL_INTEGER() } }
  44 sub __rows_bindtype   { +{ dbd_attrs => DBI::SQL_INTEGER() } }
  45
  46 sub _sql_server_2005_or_higher { shift->__sql_server_x_or_higher(9) }
  47 sub _sql_server_2012_or_higher { shift->__sql_server_x_or_higher(11) }
  48
  49 sub _prep_for_execute {
  50   my $self = shift;
  51   my ($op, $ident, $args) = @_;
  52
  53 # cast MONEY values properly
  54   if ($op eq 'insert' || $op eq 'update') {
  55     my $fields = $args->[0];
  56
  57     my $colinfo = $ident->columns_info([keys %$fields]);
  58
  59     for my $col (keys %$fields) {
  60       # $ident is a result source object with INSERT/UPDATE ops
  61       if (
  62         $colinfo->{$col}{data_type}
  63           &&
  64         $colinfo->{$col}{data_type} =~ /^money\z/i
  65       ) {
  66         my $val = $fields->{$col};
  67         $fields->{$col} = \['CAST(? AS MONEY)', [ $col => $val ]];
  68       }
  69     }
  70   }
  71
  72   my ($sql, $bind) = $self->next::method (@_);
  73
  74   # SELECT SCOPE_IDENTITY only works within a statement scope. We
  75   # must try to always use this particular idiom first, as it is the
  76   # only one that guarantees retrieving the correct id under high
  77   # concurrency. When this fails we will fall back to whatever secondary
  78   # retrieval method is specified in _identity_method, but at this
  79   # point we don't have many guarantees we will get what we expected.
  80   # http://msdn.microsoft.com/en-us/library/ms190315.aspx
  81   # http://davidhayden.com/blog/dave/archive/2006/01/17/2736.aspx
  82   if ($self->_perform_autoinc_retrieval and not $self->_no_scope_identity_query) {
  83     $sql .= "\nSELECT SCOPE_IDENTITY()";
  84   }
  85
  86   return ($sql, $bind);
  87 }
  88
  89 sub _execute {
  90   my $self = shift;
  91
  92   # always list ctx - we need the $sth
  93   my ($rv, $sth, @bind) = $self->next::method(@_);
  94
  95   if ($self->_perform_autoinc_retrieval) {
  96
  97     # attempt to bring back the result of SELECT SCOPE_IDENTITY() we tacked
  98     # on in _prep_for_execute above
  99     my $identity;
 100
 101     # we didn't even try on ftds
 102     unless ($self->_no_scope_identity_query) {
 103       ($identity) = try { $sth->fetchrow_array };
 104       $sth->finish;
 105     }
 106
 107     # SCOPE_IDENTITY failed, but we can do something else
 108     if ( (! $identity) && $self->_identity_method) {
 109       ($identity) = $self->_dbh->selectrow_array(
 110         'select ' . $self->_identity_method
 111       );
 112     }
 113
 114     $self->_identity($identity);
 115   }
 116
 117   return wantarray ? ($rv, $sth, @bind) : $rv;
 118 }
 119
 120 sub last_insert_id { shift->_identity }
 121
 122 #
 123 # MSSQL is retarded wrt ordered subselects. One needs to add a TOP
 124 # to *all* subqueries, but one also *can't* use TOP 100 PERCENT
 125 # http://sqladvice.com/forums/permalink/18496/22931/ShowThread.aspx#22931
 126 #
 127 sub _select_args_to_query {
 128   #my ($self, $ident, $select, $cond, $attrs) = @_;
 129   my $self = shift;
 130   my $attrs = $_[3];
 131
 132   my $sql_bind = $self->next::method (@_);
 133
 134   # see if this is an ordered subquery
 135   if (
 136     $$sql_bind->[0] !~ /^ \s* \( \s* SELECT \s+ TOP \s+ \d+ \s+ /xi
 137       and
 138     scalar $self->_extract_order_criteria ($attrs->{order_by})
 139   ) {
 140     $self->throw_exception(
 141       'An ordered subselect encountered - this is not safe! Please see "Ordered Subselects" in DBIx::Class::Storage::DBI::MSSQL'
 142     ) unless $attrs->{unsafe_subselect_ok};
 143
 144     $$sql_bind->[0] =~ s/^ \s* \( \s* SELECT (?=\s) / '(SELECT TOP ' . $self->sql_maker->__max_int /exi;
 145   }
 146
 147   $sql_bind;
 148 }
 149
 150
 151 # savepoint syntax is the same as in Sybase ASE
 152
 153 sub _exec_svp_begin {
 154   my ($self, $name) = @_;
 155
 156   $self->_dbh->do("SAVE TRANSACTION $name");
 157 }
 158
 159 # A new SAVE TRANSACTION with the same name releases the previous one.
 160 sub _exec_svp_release { 1 }
 161
 162 sub _exec_svp_rollback {
 163   my ($self, $name) = @_;
 164
 165   $self->_dbh->do("ROLLBACK TRANSACTION $name");
 166 }
 167
 168 sub sqlt_type { 'SQLServer' }
 169
 170 sub sql_limit_dialect {
 171   my $self = shift;
 172
 173   my $supports_rno = $self->_sql_server_2005_or_higher;
 174
 175   unless (defined $supports_rno) {
 176     # User is connecting via DBD::Sybase and has no permission to run
 177     # stored procedures like xp_msver, or version detection failed for some
 178     # other reason.
 179     # So, we use a query to check if RNO is implemented.
 180     try {
 181       $self->_get_dbh->selectrow_array('SELECT row_number() OVER (ORDER BY rand())');
 182       $supports_rno = 1;
 183     };
 184   }
 185
 186   return $supports_rno ? 'RowNumberOver' : 'Top';
 187 }
 188
 189 sub _ping {
 190   my $self = shift;
 191
 192   my $dbh = $self->_dbh or return 0;
 193
 194   local $dbh->{RaiseError} = 1;
 195   local $dbh->{PrintError} = 0;
 196
 197   return try {
 198     $dbh->do('select 1');
 199     1;
 200   } catch {
 201     0;
 202   };
 203 }
 204
 205 package # hide from PAUSE
 206   DBIx::Class::Storage::DBI::MSSQL::DateTime::Format;
 207
 208 my $datetime_format      = '%Y-%m-%d %H:%M:%S.%3N'; # %F %T
 209 my $smalldatetime_format = '%Y-%m-%d %H:%M:%S';
 210
 211 my ($datetime_parser, $smalldatetime_parser);
 212
 213 sub parse_datetime {
 214   shift;
 215   require DateTime::Format::Strptime;
 216   $datetime_parser ||= DateTime::Format::Strptime->new(
 217     pattern  => $datetime_format,
 218     on_error => 'croak',
 219   );
 220   return $datetime_parser->parse_datetime(shift);
 221 }
 222
 223 sub format_datetime {
 224   shift;
 225   require DateTime::Format::Strptime;
 226   $datetime_parser ||= DateTime::Format::Strptime->new(
 227     pattern  => $datetime_format,
 228     on_error => 'croak',
 229   );
 230   return $datetime_parser->format_datetime(shift);
 231 }
 232
 233 sub parse_smalldatetime {
 234   shift;
 235   require DateTime::Format::Strptime;
 236   $smalldatetime_parser ||= DateTime::Format::Strptime->new(
 237     pattern  => $smalldatetime_format,
 238     on_error => 'croak',
 239   );
 240   return $smalldatetime_parser->parse_datetime(shift);
 241 }
 242
 243 sub format_smalldatetime {
 244   shift;
 245   require DateTime::Format::Strptime;
 246   $smalldatetime_parser ||= DateTime::Format::Strptime->new(
 247     pattern  => $smalldatetime_format,
 248     on_error => 'croak',
 249   );
 250   return $smalldatetime_parser->format_datetime(shift);
 251 }
 252
 253 1;
 254
 255 =head1 NAME
 256
 257 DBIx::Class::Storage::DBI::MSSQL - Base Class for Microsoft SQL Server support
 258 in DBIx::Class
 259
 260 =head1 SYNOPSIS
 261
 262 This is the base class for Microsoft SQL Server support, used by
 263 L<DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server> and
 264 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 265
 266 =head1 IMPLEMENTATION NOTES
 267
 268 =head2 IDENTITY information
 269
 270 Microsoft SQL Server supports three methods of retrieving the IDENTITY
 271 value for inserted row: IDENT_CURRENT, @@IDENTITY, and SCOPE_IDENTITY().
 272 SCOPE_IDENTITY is used here because it is the safest.  However, it must
 273 be called is the same execute statement, not just the same connection.
 274
 275 So, this implementation appends a SELECT SCOPE_IDENTITY() statement
 276 onto each INSERT to accommodate that requirement.
 277
 278 C<SELECT @@IDENTITY> can also be used by issuing:
 279
 280   $self->_identity_method('@@identity');
 281
 282 it will only be used if SCOPE_IDENTITY() fails.
 283
 284 This is more dangerous, as inserting into a table with an on insert trigger that
 285 inserts into another table with an identity will give erroneous results on
 286 recent versions of SQL Server.
 287
 288 =head2 identity insert
 289
 290 Be aware that we have tried to make things as simple as possible for our users.
 291 For MSSQL that means that when a user tries to create a row, while supplying an
 292 explicit value for an autoincrementing column, we will try to issue the
 293 appropriate database call to make this possible, namely C<SET IDENTITY_INSERT
 294 $table_name ON>. Unfortunately this operation in MSSQL requires the
 295 C<db_ddladmin> privilege, which is normally not included in the standard
 296 write-permissions.
 297
 298 =head2 Ordered Subselects
 299
 300 If you attempted the following query (among many others) in Microsoft SQL
 301 Server
 302
 303  $rs->search ({}, {
 304   prefetch => 'relation',
 305   rows => 2,
 306   offset => 3,
 307  });
 308
 309 You may be surprised to receive an exception. The reason for this is a quirk
 310 in the MSSQL engine itself, and sadly doesn't have a sensible workaround due
 311 to the way DBIC is built. DBIC can do truly wonderful things with the aid of
 312 subselects, and does so automatically when necessary. The list of situations
 313 when a subselect is necessary is long and still changes often, so it can not
 314 be exhaustively enumerated here. The general rule of thumb is a joined
 315 L<has_many|DBIx::Class::Relationship/has_many> relationship with limit/group
 316 applied to the left part of the join.
 317
 318 In its "pursuit of standards" Microsft SQL Server goes to great lengths to
 319 forbid the use of ordered subselects. This breaks a very useful group of
 320 searches like "Give me things number 4 to 6 (ordered by name), and prefetch
 321 all their relations, no matter how many". While there is a hack which fools
 322 the syntax checker, the optimizer may B<still elect to break the subselect>.
 323 Testing has determined that while such breakage does occur (the test suite
 324 contains an explicit test which demonstrates the problem), it is relative
 325 rare. The benefits of ordered subselects are on the other hand too great to be
 326 outright disabled for MSSQL.
 327
 328 Thus compromise between usability and perfection is the MSSQL-specific
 329 L<resultset attribute|DBIx::Class::ResultSet/ATTRIBUTES> C<unsafe_subselect_ok>.
 330 It is deliberately not possible to set this on the Storage level, as the user
 331 should inspect (and preferably regression-test) the return of every such
 332 ResultSet individually. The example above would work if written like:
 333
 334  $rs->search ({}, {
 335   unsafe_subselect_ok => 1,
 336   prefetch => 'relation',
 337   rows => 2,
 338   offset => 3,
 339  });
 340
 341 If it is possible to rewrite the search() in a way that will avoid the need
 342 for this flag - you are urged to do so. If DBIC internals insist that an
 343 ordered subselect is necessary for an operation, and you believe there is a
 344 different/better way to get the same result - please file a bugreport.
 345
 346 =head1 AUTHOR
 347
 348 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 349
 350 =head1 LICENSE
 351
 352 You may distribute this code under the same terms as Perl itself.
 353
 354 =cut