lib/DBIx/Class/Storage/DBI/InterBase.pm

   1 package DBIx::Class::Storage::DBI::InterBase;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use List::Util();
   8
   9 =head1 NAME
  10
  11 DBIx::Class::Storage::DBI::InterBase - Driver for the Firebird RDBMS
  12
  13 =head1 DESCRIPTION
  14
  15 This class implements autoincrements for Firebird using C<RETURNING> as well as
  16 L<auto_nextval|DBIx::Class::ResultSource/auto_nextval> sets the limit dialect to
  17 C<FIRST X SKIP X> and provides L<DBIx::Class::InflateColumn::DateTime> support.
  18
  19 You need to use either the
  20 L<disable_sth_caching|DBIx::Class::Storage::DBI/disable_sth_caching> option or
  21 L</connect_call_use_softcommit> (see L</CAVEATS>) for your code to function
  22 correctly with this driver. Otherwise you will likely get bizarre error messages
  23 such as C<no statement executing>. The alternative is to use the
  24 L<ODBC|DBIx::Class::Storage::DBI::ODBC::Firebird> driver, which is more suitable
  25 for long running processes such as under L<Catalyst>.
  26
  27 To turn on L<DBIx::Class::InflateColumn::DateTime> support, see
  28 L</connect_call_datetime_setup>.
  29
  30 =cut
  31
  32 sub can_insert_returning { 1 }
  33
  34 sub _sequence_fetch {
  35   my ($self, $nextval, $sequence) = @_;
  36
  37   if ($nextval ne 'nextval') {
  38     $self->throw_exception("Can only fetch 'nextval' for a sequence");
  39   }
  40
  41   $self->throw_exception('No sequence to fetch') unless $sequence;
  42
  43   my ($val) = $self->_get_dbh->selectrow_array(
  44 'SELECT GEN_ID(' . $self->sql_maker->_quote($sequence) .
  45 ', 1) FROM rdb$database');
  46
  47   return $val;
  48 }
  49
  50 sub _dbh_get_autoinc_seq {
  51   my ($self, $dbh, $source, $col) = @_;
  52
  53   my $table_name = $source->from;
  54   $table_name    = $$table_name if ref $table_name;
  55   $table_name    = $self->sql_maker->quote_char ? $table_name : uc($table_name);
  56
  57   local $dbh->{LongReadLen} = 100000;
  58   local $dbh->{LongTruncOk} = 1;
  59
  60   my $sth = $dbh->prepare(<<'EOF');
  61 SELECT t.rdb$trigger_source
  62 FROM rdb$triggers t
  63 WHERE t.rdb$relation_name = ?
  64 AND t.rdb$system_flag = 0 -- user defined
  65 AND t.rdb$trigger_type = 1 -- BEFORE INSERT
  66 EOF
  67   $sth->execute($table_name);
  68
  69   while (my ($trigger) = $sth->fetchrow_array) {
  70     my @trig_cols = map {
  71       /^"([^"]+)/ ? $1 : uc($1)
  72     } $trigger =~ /new\.("?\w+"?)/ig;
  73
  74     my ($quoted, $generator) = $trigger =~
  75 /(?:gen_id\s* \( \s* |next \s* value \s* for \s*)(")?(\w+)/ix;
  76
  77     if ($generator) {
  78       $generator = uc $generator unless $quoted;
  79
  80       return $generator
  81         if List::Util::first {
  82           $self->sql_maker->quote_char ? ($_ eq $col) : (uc($_) eq uc($col))
  83         } @trig_cols;
  84     }
  85   }
  86
  87   return undef;
  88 }
  89
  90 # this sub stolen from DB2
  91
  92 sub _sql_maker_opts {
  93   my ( $self, $opts ) = @_;
  94
  95   if ( $opts ) {
  96     $self->{_sql_maker_opts} = { %$opts };
  97   }
  98
  99   return { limit_dialect => 'FirstSkip', %{$self->{_sql_maker_opts}||{}} };
 100 }
 101
 102 sub _svp_begin {
 103     my ($self, $name) = @_;
 104
 105     $self->_get_dbh->do("SAVEPOINT $name");
 106 }
 107
 108 sub _svp_release {
 109     my ($self, $name) = @_;
 110
 111     $self->_get_dbh->do("RELEASE SAVEPOINT $name");
 112 }
 113
 114 sub _svp_rollback {
 115     my ($self, $name) = @_;
 116
 117     $self->_get_dbh->do("ROLLBACK TO SAVEPOINT $name")
 118 }
 119
 120 sub _ping {
 121   my $self = shift;
 122
 123   my $dbh = $self->_dbh or return 0;
 124
 125   local $dbh->{RaiseError} = 1;
 126   local $dbh->{PrintError} = 0;
 127
 128   eval {
 129     $dbh->do('select 1 from rdb$database');
 130   };
 131
 132   return $@ ? 0 : 1;
 133 }
 134
 135 # We want dialect 3 for new features and quoting to work, DBD::InterBase uses
 136 # dialect 1 (interbase compat) by default.
 137 sub _init {
 138   my $self = shift;
 139   $self->_set_sql_dialect(3);
 140 }
 141
 142 sub _set_sql_dialect {
 143   my $self = shift;
 144   my $val  = shift || 3;
 145
 146   my $dsn = $self->_dbi_connect_info->[0];
 147
 148   return if ref($dsn) eq 'CODE';
 149
 150   if ($dsn !~ /ib_dialect=/) {
 151     $self->_dbi_connect_info->[0] = "$dsn;ib_dialect=$val";
 152     my $connected = defined $self->_dbh;
 153     $self->disconnect;
 154     $self->ensure_connected if $connected;
 155   }
 156 }
 157
 158 sub _populate_server_info {
 159   my $self = shift;
 160
 161   local $SIG{__WARN__} = sub {}; # silence warning due to bug in DBD::InterBase
 162
 163   return $self->next::method(@_);
 164 }
 165
 166 =head2 connect_call_use_softcommit
 167
 168 Used as:
 169
 170   on_connect_call => 'use_softcommit'
 171
 172 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the
 173 L<DBD::InterBase> C<ib_softcommit> option.
 174
 175 You need either this option or C<< disable_sth_caching => 1 >> for
 176 L<DBIx::Class> code to function correctly (otherwise you may get C<no statement
 177 executing> errors.) Or use the L<ODBC|DBIx::Class::Storage::DBI::ODBC::Firebird>
 178 driver.
 179
 180 The downside of using this option is that your process will B<NOT> see UPDATEs,
 181 INSERTs and DELETEs from other processes for already open statements.
 182
 183 =cut
 184
 185 sub connect_call_use_softcommit {
 186   my $self = shift;
 187
 188   $self->_dbh->{ib_softcommit} = 1;
 189 }
 190
 191 =head2 connect_call_datetime_setup
 192
 193 Used as:
 194
 195   on_connect_call => 'datetime_setup'
 196
 197 In L<connect_info|DBIx::Class::Storage::DBI/connect_info> to set the date and
 198 timestamp formats using:
 199
 200   $dbh->{ib_time_all} = 'ISO';
 201
 202 See L<DBD::InterBase> for more details.
 203
 204 The C<TIMESTAMP> data type supports up to 4 digits after the decimal point for
 205 second precision. The full precision is used.
 206
 207 The C<DATE> data type stores the date portion only, and it B<MUST> be declared
 208 with:
 209
 210   data_type => 'date'
 211
 212 in your Result class.
 213
 214 Timestamp columns can be declared with either C<datetime> or C<timestamp>.
 215
 216 You will need the L<DateTime::Format::Strptime> module for inflation to work.
 217
 218 For L<DBIx::Class::Storage::DBI::ODBC::Firebird>, this is a noop and sub-second
 219 precision is not currently available.
 220
 221 =cut
 222
 223 sub connect_call_datetime_setup {
 224   my $self = shift;
 225
 226   $self->_get_dbh->{ib_time_all} = 'ISO';
 227 }
 228
 229 sub datetime_parser_type {
 230   'DBIx::Class::Storage::DBI::InterBase::DateTime::Format'
 231 }
 232
 233 package # hide from PAUSE
 234   DBIx::Class::Storage::DBI::InterBase::DateTime::Format;
 235
 236 my $timestamp_format = '%Y-%m-%d %H:%M:%S.%4N'; # %F %T
 237 my $date_format      = '%Y-%m-%d';
 238
 239 my ($timestamp_parser, $date_parser);
 240
 241 sub parse_datetime {
 242   shift;
 243   require DateTime::Format::Strptime;
 244   $timestamp_parser ||= DateTime::Format::Strptime->new(
 245     pattern  => $timestamp_format,
 246     on_error => 'croak',
 247   );
 248   return $timestamp_parser->parse_datetime(shift);
 249 }
 250
 251 sub format_datetime {
 252   shift;
 253   require DateTime::Format::Strptime;
 254   $timestamp_parser ||= DateTime::Format::Strptime->new(
 255     pattern  => $timestamp_format,
 256     on_error => 'croak',
 257   );
 258   return $timestamp_parser->format_datetime(shift);
 259 }
 260
 261 sub parse_date {
 262   shift;
 263   require DateTime::Format::Strptime;
 264   $date_parser ||= DateTime::Format::Strptime->new(
 265     pattern  => $date_format,
 266     on_error => 'croak',
 267   );
 268   return $date_parser->parse_datetime(shift);
 269 }
 270
 271 sub format_date {
 272   shift;
 273   require DateTime::Format::Strptime;
 274   $date_parser ||= DateTime::Format::Strptime->new(
 275     pattern  => $date_format,
 276     on_error => 'croak',
 277   );
 278   return $date_parser->format_datetime(shift);
 279 }
 280
 281 1;
 282
 283 =head1 CAVEATS
 284
 285 =over 4
 286
 287 =item *
 288
 289 with L</connect_call_use_softcommit>, you will not be able to see changes made
 290 to data in other processes. If this is an issue, use
 291 L<disable_sth_caching|DBIx::Class::Storage::DBI/disable_sth_caching> as a
 292 workaround for the C<no statement executing> errors, this of course adversely
 293 affects performance.
 294
 295 Alternately, use the L<ODBC|DBIx::Class::Storage::DBI::ODBC::Firebird> driver.
 296
 297 =item *
 298
 299 C<last_insert_id> support by default only works for Firebird versions 2 or
 300 greater, L<auto_nextval|DBIx::Class::ResultSource/auto_nextval> however should
 301 work with earlier versions.
 302
 303 =item *
 304
 305 Sub-second precision for TIMESTAMPs is not currently available when using the
 306 L<ODBC|DBIx::Class::Storage::DBI::ODBC::Firebird> driver.
 307
 308 =back
 309
 310 =head1 AUTHOR
 311
 312 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 313
 314 =head1 LICENSE
 315
 316 You may distribute this code under the same terms as Perl itself.
 317
 318 =cut