lib/DBIx/Class/Storage/DBI/Firebird/Common.pm

   1 package DBIx::Class::Storage::DBI::Firebird::Common;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Storage::DBI/;
   6 use mro 'c3';
   7 use List::Util 'first';
   8 use namespace::clean;
   9
  10 =head1 NAME
  11
  12 DBIx::Class::Storage::DBI::Firebird::Common - Driver Base Class for the Firebird RDBMS
  13
  14 =head1 DESCRIPTION
  15
  16 This class implements autoincrements for Firebird using C<RETURNING> as well as
  17 L<auto_nextval|DBIx::Class::ResultSource/auto_nextval>, savepoints and server
  18 version detection.
  19
  20 =cut
  21
  22 # set default
  23 __PACKAGE__->_use_insert_returning (1);
  24 __PACKAGE__->sql_limit_dialect ('FirstSkip');
  25 __PACKAGE__->sql_quote_char ('"');
  26
  27 __PACKAGE__->datetime_parser_type(
  28   'DBIx::Class::Storage::DBI::InterBase::DateTime::Format'
  29 );
  30
  31 sub sqlt_type {
  32   return 'Firebird';
  33 }
  34
  35 sub _sequence_fetch {
  36   my ($self, $nextval, $sequence) = @_;
  37
  38   $self->throw_exception("Can only fetch 'nextval' for a sequence")
  39     if $nextval !~ /^nextval$/i;
  40
  41   $self->throw_exception('No sequence to fetch') unless $sequence;
  42
  43   my ($val) = $self->_get_dbh->selectrow_array(sprintf
  44     'SELECT GEN_ID(%s, 1) FROM rdb$database',
  45     $self->sql_maker->_quote($sequence)
  46   );
  47
  48   return $val;
  49 }
  50
  51 sub _dbh_get_autoinc_seq {
  52   my ($self, $dbh, $source, $col) = @_;
  53
  54   my $table_name = $source->from;
  55   $table_name    = $$table_name if ref $table_name;
  56   $table_name    = $self->sql_maker->quote_char ? $table_name : uc($table_name);
  57
  58   local $dbh->{LongReadLen} = 100000;
  59   local $dbh->{LongTruncOk} = 1;
  60
  61   my $sth = $dbh->prepare(<<'EOF');
  62 SELECT t.rdb$trigger_source
  63 FROM rdb$triggers t
  64 WHERE t.rdb$relation_name = ?
  65 AND t.rdb$system_flag = 0 -- user defined
  66 AND t.rdb$trigger_type = 1 -- BEFORE INSERT
  67 EOF
  68   $sth->execute($table_name);
  69
  70   while (my ($trigger) = $sth->fetchrow_array) {
  71     my @trig_cols = map
  72       { /^"([^"]+)/ ? $1 : uc($_) }
  73       $trigger =~ /new\.("?\w+"?)/ig
  74     ;
  75
  76     my ($quoted, $generator) = $trigger =~
  77 /(?:gen_id\s* \( \s* |next \s* value \s* for \s*)(")?(\w+)/ix;
  78
  79     if ($generator) {
  80       $generator = uc $generator unless $quoted;
  81
  82       return $generator
  83         if first {
  84           $self->sql_maker->quote_char ? ($_ eq $col) : (uc($_) eq uc($col))
  85         } @trig_cols;
  86     }
  87   }
  88
  89   return undef;
  90 }
  91
  92 sub _exec_svp_begin {
  93   my ($self, $name) = @_;
  94
  95   $self->_dbh->do("SAVEPOINT $name");
  96 }
  97
  98 sub _exec_svp_release {
  99   my ($self, $name) = @_;
 100
 101   $self->_dbh->do("RELEASE SAVEPOINT $name");
 102 }
 103
 104 sub _exec_svp_rollback {
 105   my ($self, $name) = @_;
 106
 107   $self->_dbh->do("ROLLBACK TO SAVEPOINT $name")
 108 }
 109
 110 # http://www.firebirdfaq.org/faq223/
 111 sub _get_server_version {
 112   my $self = shift;
 113
 114   return $self->_get_dbh->selectrow_array(q{
 115 SELECT rdb$get_context('SYSTEM', 'ENGINE_VERSION') FROM rdb$database
 116   });
 117 }
 118
 119 package # hide from PAUSE
 120   DBIx::Class::Storage::DBI::InterBase::DateTime::Format;
 121
 122 my $timestamp_format = '%Y-%m-%d %H:%M:%S.%4N'; # %F %T
 123 my $date_format      = '%Y-%m-%d';
 124
 125 my ($timestamp_parser, $date_parser);
 126
 127 sub parse_datetime {
 128   shift;
 129   require DateTime::Format::Strptime;
 130   $timestamp_parser ||= DateTime::Format::Strptime->new(
 131     pattern  => $timestamp_format,
 132     on_error => 'croak',
 133   );
 134   return $timestamp_parser->parse_datetime(shift);
 135 }
 136
 137 sub format_datetime {
 138   shift;
 139   require DateTime::Format::Strptime;
 140   $timestamp_parser ||= DateTime::Format::Strptime->new(
 141     pattern  => $timestamp_format,
 142     on_error => 'croak',
 143   );
 144   return $timestamp_parser->format_datetime(shift);
 145 }
 146
 147 sub parse_date {
 148   shift;
 149   require DateTime::Format::Strptime;
 150   $date_parser ||= DateTime::Format::Strptime->new(
 151     pattern  => $date_format,
 152     on_error => 'croak',
 153   );
 154   return $date_parser->parse_datetime(shift);
 155 }
 156
 157 sub format_date {
 158   shift;
 159   require DateTime::Format::Strptime;
 160   $date_parser ||= DateTime::Format::Strptime->new(
 161     pattern  => $date_format,
 162     on_error => 'croak',
 163   );
 164   return $date_parser->format_datetime(shift);
 165 }
 166
 167 1;
 168
 169 =head1 CAVEATS
 170
 171 =over 4
 172
 173 =item *
 174
 175 C<last_insert_id> support by default only works for Firebird versions 2 or
 176 greater, L<auto_nextval|DBIx::Class::ResultSource/auto_nextval> however should
 177 work with earlier versions.
 178
 179 =back
 180
 181 =head1 AUTHOR
 182
 183 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 184
 185 =head1 LICENSE
 186
 187 You may distribute this code under the same terms as Perl itself.
 188
 189 =cut
 190 # vim:sts=2 sw=2: