lib/DBIx/Class/Storage/DBI/Cursor.pm

   1 package DBIx::Class::Storage::DBI::Cursor;
   2
   3 use base qw/DBIx::Class::Cursor/;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::Storage::DBI::Cursor - Object representing a query cursor on a
  11 resultset.
  12
  13 =head1 SYNOPSIS
  14
  15   my $cursor = $schema->resultset('CD')->cursor();
  16   my $first_cd = $cursor->next;
  17
  18 =head1 DESCRIPTION
  19
  20 A Cursor represents a query cursor on a L<DBIx::Class::ResultSet> object. It
  21 allows for traversing the result set with L</next>, retrieving all results with
  22 L</all> and resetting the cursor with L</reset>.
  23
  24 Usually, you would use the cursor methods built into L<DBIx::Class::ResultSet>
  25 to traverse it. See L<DBIx::Class::ResultSet/next>,
  26 L<DBIx::Class::ResultSet/reset> and L<DBIx::Class::ResultSet/all> for more
  27 information.
  28
  29 =head1 METHODS
  30
  31 =head2 new
  32
  33 Returns a new L<DBIx::Class::Storage::DBI::Cursor> object.
  34
  35 =cut
  36
  37 sub new {
  38   my ($class, $storage, $args, $attrs) = @_;
  39   #use Data::Dumper; warn Dumper(@_);
  40   $class = ref $class if ref $class;
  41   my $new = {
  42     storage => $storage,
  43     args => $args,
  44     pos => 0,
  45     attrs => $attrs,
  46     _dbh_gen => $storage->{_dbh_gen},
  47   };
  48
  49   return bless ($new, $class);
  50 }
  51
  52 =head2 as_query
  53
  54 =over 4
  55
  56 =item Arguments: none
  57
  58 =item Return Value: \[ $sql, @bind ]
  59
  60 =back
  61
  62 Returns the SQL statement and bind vars associated with the invocant.
  63
  64 =cut
  65
  66 sub as_query {
  67   my $self = shift;
  68
  69   my $storage = $self->{storage};
  70   my $sql_maker = $storage->sql_maker;
  71   local $sql_maker->{for};
  72
  73   my @args = $storage->_select_args(@{$self->{args}});
  74   my ($sql, $bind)  = $storage->_prep_for_execute(@args[0 .. 2], [@args[4 .. $#args]]);
  75   return \[ "($sql)", @$bind ];
  76 }
  77
  78 =head2 next
  79
  80 =over 4
  81
  82 =item Arguments: none
  83
  84 =item Return Value: \@row_columns
  85
  86 =back
  87
  88 Advances the cursor to the next row and returns an array of column
  89 values (the result of L<DBI/fetchrow_array> method).
  90
  91 =cut
  92
  93 sub _dbh_next {
  94   my ($storage, $dbh, $self) = @_;
  95
  96   $self->_check_dbh_gen;
  97   if ($self->{attrs}{rows} && $self->{pos} >= $self->{attrs}{rows}) {
  98     $self->{sth}->finish if $self->{sth}->{Active};
  99     delete $self->{sth};
 100     $self->{done} = 1;
 101   }
 102   return if $self->{done};
 103   unless ($self->{sth}) {
 104     $self->{sth} = ($storage->_select(@{$self->{args}}))[1];
 105     if ($self->{attrs}{software_limit}) {
 106       if (my $offset = $self->{attrs}{offset}) {
 107         $self->{sth}->fetch for 1 .. $offset;
 108       }
 109     }
 110   }
 111   my @row = $self->{sth}->fetchrow_array;
 112   if (@row) {
 113     $self->{pos}++;
 114   } else {
 115     delete $self->{sth};
 116     $self->{done} = 1;
 117   }
 118   return @row;
 119 }
 120
 121 sub next {
 122   my ($self) = @_;
 123   $self->{storage}->dbh_do($self->can('_dbh_next'), $self);
 124 }
 125
 126 =head2 all
 127
 128 =over 4
 129
 130 =item Arguments: none
 131
 132 =item Return Value: \@row_columns+
 133
 134 =back
 135
 136 Returns a list of arrayrefs of column values for all rows in the
 137 L<DBIx::Class::ResultSet>.
 138
 139 =cut
 140
 141 sub _dbh_all {
 142   my ($storage, $dbh, $self) = @_;
 143
 144   $self->_check_dbh_gen;
 145   $self->{sth}->finish if $self->{sth}->{Active};
 146   delete $self->{sth};
 147   my ($rv, $sth) = $storage->_select(@{$self->{args}});
 148   return @{$sth->fetchall_arrayref};
 149 }
 150
 151 sub all {
 152   my ($self) = @_;
 153   if ($self->{attrs}{software_limit}
 154         && ($self->{attrs}{offset} || $self->{attrs}{rows})) {
 155     return $self->SUPER::all;
 156   }
 157   $self->{storage}->dbh_do($self->can('_dbh_all'), $self);
 158 }
 159
 160 =head2 reset
 161
 162 Resets the cursor to the beginning of the L<DBIx::Class::ResultSet>.
 163
 164 =cut
 165
 166 sub reset {
 167   my ($self) = @_;
 168
 169   # No need to care about failures here
 170   eval { $self->{sth}->finish if $self->{sth} && $self->{sth}->{Active} };
 171   $self->_soft_reset;
 172 }
 173
 174 sub _soft_reset {
 175   my ($self) = @_;
 176
 177   delete $self->{sth};
 178   delete $self->{done};
 179   $self->{pos} = 0;
 180   return $self;
 181 }
 182
 183 sub _check_dbh_gen {
 184   my ($self) = @_;
 185
 186   if($self->{_dbh_gen} != $self->{storage}->{_dbh_gen}) {
 187     $self->{_dbh_gen} = $self->{storage}->{_dbh_gen};
 188     $self->_soft_reset;
 189   }
 190 }
 191
 192 sub DESTROY {
 193   my ($self) = @_;
 194
 195   # None of the reasons this would die matter if we're in DESTROY anyways
 196   local $@;
 197   eval { $self->{sth}->finish if $self->{sth} && $self->{sth}->{Active} };
 198 }
 199
 200 1;