lib/DBIx/Class/Storage/DBI/Cursor.pm

   1 package DBIx::Class::Storage::DBI::Cursor;
   2
   3 use base qw/DBIx::Class::Cursor/;
   4
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::Storage::DBI::Cursor - Object representing a query cursor on a
  11 resultset.
  12
  13 =head1 SYNOPSIS
  14
  15   my $cursor = $schema->resultset('CD')->cursor();
  16   my $first_cd = $cursor->next;
  17
  18 =head1 DESCRIPTION
  19
  20 A Cursor represents a query cursor on a L<DBIx::Class::ResultSet> object. It
  21 allows for traversing the result set with L</next>, retrieving all results with
  22 L</all> and resetting the cursor with L</reset>.
  23
  24 Usually, you would use the cursor methods built into L<DBIx::Class::ResultSet>
  25 to traverse it. See L<DBIx::Class::ResultSet/next>,
  26 L<DBIx::Class::ResultSet/reset> and L<DBIx::Class::ResultSet/all> for more
  27 information.
  28
  29 =head1 METHODS
  30
  31 =head2 new
  32
  33 Returns a new L<DBIx::Class::Storage::DBI::Cursor> object.
  34
  35 =cut
  36
  37 sub new {
  38   my ($class, $storage, $args, $attrs) = @_;
  39   #use Data::Dumper; warn Dumper(@_);
  40   $class = ref $class if ref $class;
  41   my $new = {
  42     storage => $storage,
  43     args => $args,
  44     pos => 0,
  45     attrs => $attrs,
  46     _dbh_gen => $storage->{_dbh_gen},
  47   };
  48
  49   return bless ($new, $class);
  50 }
  51
  52 =head2 as_query
  53
  54 =over 4
  55
  56 =item Arguments: See L<DBIx::Class::ResultSet/as_query>
  57
  58 =item Return Value: \[ $sql, @bind ]
  59
  60 =back
  61
  62 Returns the SQL statement and bind vars associated with the invocant.
  63
  64 =cut
  65
  66 sub as_query {
  67   my ( $self, $opts ) = @_;
  68
  69   $self->throw_exception( "as_query needs a hashref" )
  70     if defined $opts and ref $opts ne 'HASH';
  71
  72   $opts->{skip_parens} ||= 0;
  73
  74   my $storage = $self->{storage};
  75   my $sql_maker = $storage->sql_maker;
  76   local $sql_maker->{for};
  77
  78   my @args = $storage->_select_args(@{$self->{args}});
  79   my ($sql, $bind)  = $storage->_prep_for_execute(@args[0 .. 2], [@args[4 .. $#args]]);
  80   $sql = "($sql)" unless $opts->{skip_parens};
  81   return \[ $sql, @$bind ];
  82 }
  83
  84 =head2 next
  85
  86 =over 4
  87
  88 =item Arguments: none
  89
  90 =item Return Value: \@row_columns
  91
  92 =back
  93
  94 Advances the cursor to the next row and returns an array of column
  95 values (the result of L<DBI/fetchrow_array> method).
  96
  97 =cut
  98
  99 sub _dbh_next {
 100   my ($storage, $dbh, $self) = @_;
 101
 102   $self->_check_dbh_gen;
 103   if ($self->{attrs}{rows} && $self->{pos} >= $self->{attrs}{rows}) {
 104     $self->{sth}->finish if $self->{sth}->{Active};
 105     delete $self->{sth};
 106     $self->{done} = 1;
 107   }
 108   return if $self->{done};
 109   unless ($self->{sth}) {
 110     $self->{sth} = ($storage->_select(@{$self->{args}}))[1];
 111     if ($self->{attrs}{software_limit}) {
 112       if (my $offset = $self->{attrs}{offset}) {
 113         $self->{sth}->fetch for 1 .. $offset;
 114       }
 115     }
 116   }
 117   my @row = $self->{sth}->fetchrow_array;
 118   if (@row) {
 119     $self->{pos}++;
 120   } else {
 121     delete $self->{sth};
 122     $self->{done} = 1;
 123   }
 124   return @row;
 125 }
 126
 127 sub next {
 128   my ($self) = @_;
 129   $self->{storage}->dbh_do($self->can('_dbh_next'), $self);
 130 }
 131
 132 =head2 all
 133
 134 =over 4
 135
 136 =item Arguments: none
 137
 138 =item Return Value: \@row_columns+
 139
 140 =back
 141
 142 Returns a list of arrayrefs of column values for all rows in the
 143 L<DBIx::Class::ResultSet>.
 144
 145 =cut
 146
 147 sub _dbh_all {
 148   my ($storage, $dbh, $self) = @_;
 149
 150   $self->_check_dbh_gen;
 151   $self->{sth}->finish if $self->{sth}->{Active};
 152   delete $self->{sth};
 153   my ($rv, $sth) = $storage->_select(@{$self->{args}});
 154   return @{$sth->fetchall_arrayref};
 155 }
 156
 157 sub all {
 158   my ($self) = @_;
 159   if ($self->{attrs}{software_limit}
 160         && ($self->{attrs}{offset} || $self->{attrs}{rows})) {
 161     return $self->SUPER::all;
 162   }
 163   $self->{storage}->dbh_do($self->can('_dbh_all'), $self);
 164 }
 165
 166 =head2 reset
 167
 168 Resets the cursor to the beginning of the L<DBIx::Class::ResultSet>.
 169
 170 =cut
 171
 172 sub reset {
 173   my ($self) = @_;
 174
 175   # No need to care about failures here
 176   eval { $self->{sth}->finish if $self->{sth} && $self->{sth}->{Active} };
 177   $self->_soft_reset;
 178 }
 179
 180 sub _soft_reset {
 181   my ($self) = @_;
 182
 183   delete $self->{sth};
 184   delete $self->{done};
 185   $self->{pos} = 0;
 186   return $self;
 187 }
 188
 189 sub _check_dbh_gen {
 190   my ($self) = @_;
 191
 192   if($self->{_dbh_gen} != $self->{storage}->{_dbh_gen}) {
 193     $self->{_dbh_gen} = $self->{storage}->{_dbh_gen};
 194     $self->_soft_reset;
 195   }
 196 }
 197
 198 sub DESTROY {
 199   my ($self) = @_;
 200
 201   # None of the reasons this would die matter if we're in DESTROY anyways
 202   local $@;
 203   eval { $self->{sth}->finish if $self->{sth} && $self->{sth}->{Active} };
 204 }
 205
 206 1;