lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Carp::Clan qw/DBIx::Class/;
  14 BEGIN {
  15
  16 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  17
  18 use base qw/SQL::Abstract::Limit/;
  19
  20 sub select {
  21   my ($self, $table, $fields, $where, $order, @rest) = @_;
  22   $table = $self->_quote($table) unless ref($table);
  23   @rest = (-1) unless defined $rest[0];
  24   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  25     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  26   local $self->{having_bind} = [];
  27   my ($sql, @ret) = $self->SUPER::select(
  28     $table, $self->_recurse_fields($fields), $where, $order, @rest
  29   );
  30   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  31 }
  32
  33 sub insert {
  34   my $self = shift;
  35   my $table = shift;
  36   $table = $self->_quote($table) unless ref($table);
  37   $self->SUPER::insert($table, @_);
  38 }
  39
  40 sub update {
  41   my $self = shift;
  42   my $table = shift;
  43   $table = $self->_quote($table) unless ref($table);
  44   $self->SUPER::update($table, @_);
  45 }
  46
  47 sub delete {
  48   my $self = shift;
  49   my $table = shift;
  50   $table = $self->_quote($table) unless ref($table);
  51   $self->SUPER::delete($table, @_);
  52 }
  53
  54 sub _emulate_limit {
  55   my $self = shift;
  56   if ($_[3] == -1) {
  57     return $_[1].$self->_order_by($_[2]);
  58   } else {
  59     return $self->SUPER::_emulate_limit(@_);
  60   }
  61 }
  62
  63 sub _recurse_fields {
  64   my ($self, $fields) = @_;
  65   my $ref = ref $fields;
  66   return $self->_quote($fields) unless $ref;
  67   return $$fields if $ref eq 'SCALAR';
  68
  69   if ($ref eq 'ARRAY') {
  70     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  71   } elsif ($ref eq 'HASH') {
  72     foreach my $func (keys %$fields) {
  73       return $self->_sqlcase($func)
  74         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  75     }
  76   }
  77 }
  78
  79 sub _order_by {
  80   my $self = shift;
  81   my $ret = '';
  82   my @extra;
  83   if (ref $_[0] eq 'HASH') {
  84     if (defined $_[0]->{group_by}) {
  85       $ret = $self->_sqlcase(' group by ')
  86                .$self->_recurse_fields($_[0]->{group_by});
  87     }
  88     if (defined $_[0]->{having}) {
  89       my $frag;
  90       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  91       push(@{$self->{having_bind}}, @extra);
  92       $ret .= $self->_sqlcase(' having ').$frag;
  93     }
  94     if (defined $_[0]->{order_by}) {
  95       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  96     }
  97   } elsif(ref $_[0] eq 'SCALAR') {
  98     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  99   } else {
 100     $ret = $self->SUPER::_order_by(@_);
 101   }
 102   return $ret;
 103 }
 104
 105 sub _order_directions {
 106   my ($self, $order) = @_;
 107   $order = $order->{order_by} if ref $order eq 'HASH';
 108   return $self->SUPER::_order_directions($order);
 109 }
 110
 111 sub _table {
 112   my ($self, $from) = @_;
 113   if (ref $from eq 'ARRAY') {
 114     return $self->_recurse_from(@$from);
 115   } elsif (ref $from eq 'HASH') {
 116     return $self->_make_as($from);
 117   } else {
 118     return $from; # would love to quote here but _table ends up getting called
 119                   # twice during an ->select without a limit clause due to
 120                   # the way S::A::Limit->select works. should maybe consider
 121                   # bypassing this and doing S::A::select($self, ...) in
 122                   # our select method above. meantime, quoting shims have
 123                   # been added to select/insert/update/delete here
 124   }
 125 }
 126
 127 sub _recurse_from {
 128   my ($self, $from, @join) = @_;
 129   my @sqlf;
 130   push(@sqlf, $self->_make_as($from));
 131   foreach my $j (@join) {
 132     my ($to, $on) = @$j;
 133
 134     # check whether a join type exists
 135     my $join_clause = '';
 136     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 137       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 138     } else {
 139       $join_clause = ' JOIN ';
 140     }
 141     push(@sqlf, $join_clause);
 142
 143     if (ref $to eq 'ARRAY') {
 144       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 145     } else {
 146       push(@sqlf, $self->_make_as($to));
 147     }
 148     push(@sqlf, ' ON ', $self->_join_condition($on));
 149   }
 150   return join('', @sqlf);
 151 }
 152
 153 sub _make_as {
 154   my ($self, $from) = @_;
 155   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 156                      reverse each %{$self->_skip_options($from)});
 157 }
 158
 159 sub _skip_options {
 160   my ($self, $hash) = @_;
 161   my $clean_hash = {};
 162   $clean_hash->{$_} = $hash->{$_}
 163     for grep {!/^-/} keys %$hash;
 164   return $clean_hash;
 165 }
 166
 167 sub _join_condition {
 168   my ($self, $cond) = @_;
 169   if (ref $cond eq 'HASH') {
 170     my %j;
 171     for (keys %$cond) {
 172       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 173     };
 174     return $self->_recurse_where(\%j);
 175   } elsif (ref $cond eq 'ARRAY') {
 176     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 177   } else {
 178     die "Can't handle this yet!";
 179   }
 180 }
 181
 182 sub _quote {
 183   my ($self, $label) = @_;
 184   return '' unless defined $label;
 185   return "*" if $label eq '*';
 186   return $label unless $self->{quote_char};
 187   if(ref $self->{quote_char} eq "ARRAY"){
 188     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 189       if !defined $self->{name_sep};
 190     my $sep = $self->{name_sep};
 191     return join($self->{name_sep},
 192         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 193        split(/\Q$sep\E/,$label));
 194   }
 195   return $self->SUPER::_quote($label);
 196 }
 197
 198 sub _RowNum {
 199    my $self = shift;
 200    my $c;
 201    $_[0] =~ s/SELECT (.*?) FROM/
 202      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 203    $self->SUPER::_RowNum(@_);
 204 }
 205
 206 # Accessor for setting limit dialect. This is useful
 207 # for JDBC-bridge among others where the remote SQL-dialect cannot
 208 # be determined by the name of the driver alone.
 209 #
 210 sub limit_dialect {
 211     my $self = shift;
 212     $self->{limit_dialect} = shift if @_;
 213     return $self->{limit_dialect};
 214 }
 215
 216 sub quote_char {
 217     my $self = shift;
 218     $self->{quote_char} = shift if @_;
 219     return $self->{quote_char};
 220 }
 221
 222 sub name_sep {
 223     my $self = shift;
 224     $self->{name_sep} = shift if @_;
 225     return $self->{name_sep};
 226 }
 227
 228 } # End of BEGIN block
 229
 230 use base qw/DBIx::Class/;
 231
 232 __PACKAGE__->load_components(qw/AccessorGroup/);
 233
 234 __PACKAGE__->mk_group_accessors('simple' =>
 235   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugobj
 236      cursor on_connect_do transaction_depth/);
 237
 238 sub new {
 239   my $new = bless({}, ref $_[0] || $_[0]);
 240   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 241   $new->transaction_depth(0);
 242
 243   $new->debugobj(new DBIx::Class::Storage::Statistics());
 244
 245   my $fh;
 246   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 247      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 248     $fh = IO::File->new($1, 'w')
 249       or $new->throw_exception("Cannot open trace file $1");
 250   } else {
 251     $fh = IO::File->new('>&STDERR');
 252   }
 253   $new->debugobj->debugfh($fh);
 254   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 255   return $new;
 256 }
 257
 258 sub throw_exception {
 259   my ($self, $msg) = @_;
 260   croak($msg);
 261 }
 262
 263 =head1 NAME
 264
 265 DBIx::Class::Storage::DBI - DBI storage handler
 266
 267 =head1 SYNOPSIS
 268
 269 =head1 DESCRIPTION
 270
 271 This class represents the connection to the database
 272
 273 =head1 METHODS
 274
 275 =cut
 276
 277 =head2 connect_info
 278
 279 Connection information arrayref.  Can either be the same arguments
 280 one would pass to DBI->connect, or a code-reference which returns
 281 a connected database handle.  In either case, there is an optional
 282 final element in the arrayref, which can hold a hashref of
 283 connection-specific Storage::DBI options.  These include
 284 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 285 C<quote_char>, and C<name_sep>.  Examples:
 286
 287   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 288   ->connect_info(sub { DBI->connect(...) });
 289   ->connect_info([ 'dbi:Pg:dbname=foo',
 290                    'postgres',
 291                    '',
 292                    { AutoCommit => 0 },
 293                    { quote_char => q{`}, name_sep => q{@} },
 294                  ]);
 295
 296 =head2 on_connect_do
 297
 298 Executes the sql statements given as a listref on every db connect.
 299
 300 =head2 debug
 301
 302 Causes SQL trace information to be emitted on the C<debugobj> object.
 303 (or C<STDERR> if C<debugobj> has not specifically been set).
 304
 305 =head2 debugfh
 306
 307 Set or retrieve the filehandle used for trace/debug output.  This should be
 308 an IO::Handle compatible ojbect (only the C<print> method is used.  Initially
 309 set to be STDERR - although see information on the
 310 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 311
 312 =head2 debugobj
 313
 314 Sets or retrieves the object used for metric collection. Defaults to an instance
 315 of L<DBIx::Class::Storage::Statistics> that is campatible with the original
 316 method of using a coderef as a callback.  See the aforementioned Statistics
 317 class for more information.
 318
 319 =head2 debugcb
 320
 321 Sets a callback to be executed each time a statement is run; takes a sub
 322 reference.  Callback is executed as $sub->($op, $info) where $op is
 323 SELECT/INSERT/UPDATE/DELETE and $info is what would normally be printed.
 324
 325 See L<debugobj> for a better way.
 326
 327 =cut
 328 sub debugcb {
 329     my $self = shift();
 330
 331     if($self->debugobj()->can('callback')) {
 332         $self->debugobj()->callback(shift());
 333     }
 334 }
 335
 336 sub disconnect {
 337   my ($self) = @_;
 338
 339   if( $self->connected ) {
 340     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 341     $self->_dbh->disconnect;
 342     $self->_dbh(undef);
 343   }
 344 }
 345
 346 sub connected {
 347   my ($self) = @_;
 348
 349   if(my $dbh = $self->_dbh) {
 350       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 351           $self->_sql_maker(undef);
 352           return $self->_dbh(undef);
 353       }
 354       elsif($self->_conn_pid != $$) {
 355           $self->_dbh->{InactiveDestroy} = 1;
 356           $self->_sql_maker(undef);
 357           return $self->_dbh(undef)
 358       }
 359       return ($dbh->FETCH('Active') && $dbh->ping);
 360   }
 361
 362   return 0;
 363 }
 364
 365 sub ensure_connected {
 366   my ($self) = @_;
 367
 368   unless ($self->connected) {
 369     $self->_populate_dbh;
 370   }
 371 }
 372
 373 =head2 dbh
 374
 375 Returns the dbh - a data base handle of class L<DBI>.
 376
 377 =cut
 378
 379 sub dbh {
 380   my ($self) = @_;
 381
 382   $self->ensure_connected;
 383   return $self->_dbh;
 384 }
 385
 386 sub _sql_maker_args {
 387     my ($self) = @_;
 388
 389     return ( limit_dialect => $self->dbh );
 390 }
 391
 392 sub sql_maker {
 393   my ($self) = @_;
 394   unless ($self->_sql_maker) {
 395     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 396   }
 397   return $self->_sql_maker;
 398 }
 399
 400 sub connect_info {
 401     my ($self, $info_arg) = @_;
 402
 403     if($info_arg) {
 404         my $info = [ @$info_arg ]; # copy because we can alter it
 405         my $last_info = $info->[-1];
 406         if(ref $last_info eq 'HASH') {
 407             my $used;
 408             if(my $on_connect_do = $last_info->{on_connect_do}) {
 409                $used = 1;
 410                $self->on_connect_do($on_connect_do);
 411             }
 412             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 413                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 414                     $used = 1;
 415                     $self->sql_maker->$sql_maker_opt($opt_val);
 416                 }
 417             }
 418
 419             # remove our options hashref if it was there, to avoid confusing
 420             #   DBI in the case the user didn't use all 4 DBI options, as in:
 421             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 422             pop(@$info) if $used;
 423         }
 424
 425         $self->_connect_info($info);
 426     }
 427
 428     $self->_connect_info;
 429 }
 430
 431 sub _populate_dbh {
 432   my ($self) = @_;
 433   my @info = @{$self->_connect_info || []};
 434   $self->_dbh($self->_connect(@info));
 435   my $driver = $self->_dbh->{Driver}->{Name};
 436   eval "require DBIx::Class::Storage::DBI::${driver}";
 437   unless ($@) {
 438     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 439     $self->_rebless() if $self->can('_rebless');
 440   }
 441   # if on-connect sql statements are given execute them
 442   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 443     $self->debugobj->query_start($sql_statement) if $self->debug();
 444     $self->_dbh->do($sql_statement);
 445     $self->debugobj->query_end($sql_statement) if $self->debug();
 446   }
 447
 448   $self->_conn_pid($$);
 449   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 450 }
 451
 452 sub _connect {
 453   my ($self, @info) = @_;
 454
 455   $self->throw_exception("You failed to provide any connection info")
 456       if !@info;
 457
 458   my ($old_connect_via, $dbh);
 459
 460   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 461       $old_connect_via = $DBI::connect_via;
 462       $DBI::connect_via = 'connect';
 463   }
 464
 465   eval {
 466     if(ref $info[0] eq 'CODE') {
 467         $dbh = &{$info[0]};
 468     }
 469     else {
 470         $dbh = DBI->connect(@info);
 471     }
 472   };
 473
 474   $DBI::connect_via = $old_connect_via if $old_connect_via;
 475
 476   if (!$dbh || $@) {
 477     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 478   }
 479
 480   $dbh;
 481 }
 482
 483 =head2 txn_begin
 484
 485 Calls begin_work on the current dbh.
 486
 487 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 488 an entire code block to be executed transactionally.
 489
 490 =cut
 491
 492 sub txn_begin {
 493   my $self = shift;
 494   if ($self->{transaction_depth}++ == 0) {
 495     my $dbh = $self->dbh;
 496     if ($dbh->{AutoCommit}) {
 497       $self->debugobj->txn_begin()
 498         if ($self->debug);
 499       $dbh->begin_work;
 500     }
 501   }
 502 }
 503
 504 =head2 txn_commit
 505
 506 Issues a commit against the current dbh.
 507
 508 =cut
 509
 510 sub txn_commit {
 511   my $self = shift;
 512   my $dbh = $self->dbh;
 513   if ($self->{transaction_depth} == 0) {
 514     unless ($dbh->{AutoCommit}) {
 515       $self->debugobj->txn_commit()
 516         if ($self->debug);
 517       $dbh->commit;
 518     }
 519   }
 520   else {
 521     if (--$self->{transaction_depth} == 0) {
 522       $self->debugobj->txn_commit()
 523         if ($self->debug);
 524       $dbh->commit;
 525     }
 526   }
 527 }
 528
 529 =head2 txn_rollback
 530
 531 Issues a rollback against the current dbh. A nested rollback will
 532 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 533 which allows the rollback to propagate to the outermost transaction.
 534
 535 =cut
 536
 537 sub txn_rollback {
 538   my $self = shift;
 539
 540   eval {
 541     my $dbh = $self->dbh;
 542     if ($self->{transaction_depth} == 0) {
 543       unless ($dbh->{AutoCommit}) {
 544         $self->debugobj->txn_rollback()
 545           if ($self->debug);
 546         $dbh->rollback;
 547       }
 548     }
 549     else {
 550       if (--$self->{transaction_depth} == 0) {
 551         $self->debugobj->txn_rollback()
 552           if ($self->debug);
 553         $dbh->rollback;
 554       }
 555       else {
 556         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 557       }
 558     }
 559   };
 560
 561   if ($@) {
 562     my $error = $@;
 563     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 564     $error =~ /$exception_class/ and $self->throw_exception($error);
 565     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 566     $self->throw_exception($error);          # resets the transaction depth
 567   }
 568 }
 569
 570 sub _execute {
 571   my ($self, $op, $extra_bind, $ident, @args) = @_;
 572   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 573   unshift(@bind, @$extra_bind) if $extra_bind;
 574   if ($self->debug) {
 575       my @debug_bind = map { defined $_ ? qq{'$_'} : q{'NULL'} } @bind;
 576       $self->debugobj->query_start($sql, @debug_bind);
 577   }
 578   my $sth = eval { $self->sth($sql,$op) };
 579
 580   if (!$sth || $@) {
 581     $self->throw_exception(
 582       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 583     );
 584   }
 585   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 586   my $rv;
 587   if ($sth) {
 588     my $time = time();
 589     $rv = eval { $sth->execute(@bind) };
 590
 591     if ($@ || !$rv) {
 592       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 593     }
 594   } else {
 595     $self->throw_exception("'$sql' did not generate a statement.");
 596   }
 597   if ($self->debug) {
 598       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 599       $self->debugobj->query_end($sql, @debug_bind);
 600   }
 601   return (wantarray ? ($rv, $sth, @bind) : $rv);
 602 }
 603
 604 sub insert {
 605   my ($self, $ident, $to_insert) = @_;
 606   $self->throw_exception(
 607     "Couldn't insert ".join(', ',
 608       map "$_ => $to_insert->{$_}", keys %$to_insert
 609     )." into ${ident}"
 610   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 611   return $to_insert;
 612 }
 613
 614 sub update {
 615   return shift->_execute('update' => [], @_);
 616 }
 617
 618 sub delete {
 619   return shift->_execute('delete' => [], @_);
 620 }
 621
 622 sub _select {
 623   my ($self, $ident, $select, $condition, $attrs) = @_;
 624   my $order = $attrs->{order_by};
 625   if (ref $condition eq 'SCALAR') {
 626     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 627   }
 628   if (exists $attrs->{group_by} || $attrs->{having}) {
 629     $order = {
 630       group_by => $attrs->{group_by},
 631       having => $attrs->{having},
 632       ($order ? (order_by => $order) : ())
 633     };
 634   }
 635   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 636   if ($attrs->{software_limit} ||
 637       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 638         $attrs->{software_limit} = 1;
 639   } else {
 640     $self->throw_exception("rows attribute must be positive if present")
 641       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
 642     push @args, $attrs->{rows}, $attrs->{offset};
 643   }
 644   return $self->_execute(@args);
 645 }
 646
 647 sub select {
 648   my $self = shift;
 649   my ($ident, $select, $condition, $attrs) = @_;
 650   return $self->cursor->new($self, \@_, $attrs);
 651 }
 652
 653 # Need to call finish() to work round broken DBDs
 654
 655 sub select_single {
 656   my $self = shift;
 657   my ($rv, $sth, @bind) = $self->_select(@_);
 658   my @row = $sth->fetchrow_array;
 659   $sth->finish();
 660   return @row;
 661 }
 662
 663 sub sth {
 664   my ($self, $sql) = @_;
 665   # 3 is the if_active parameter which avoids active sth re-use
 666   return $self->dbh->prepare_cached($sql, {}, 3);
 667 }
 668
 669 =head2 columns_info_for
 670
 671 Returns database type info for a given table columns.
 672
 673 =cut
 674
 675 sub columns_info_for {
 676   my ($self, $table) = @_;
 677
 678   my $dbh = $self->dbh;
 679
 680   if ($dbh->can('column_info')) {
 681     my %result;
 682     my $old_raise_err = $dbh->{RaiseError};
 683     my $old_print_err = $dbh->{PrintError};
 684     $dbh->{RaiseError} = 1;
 685     $dbh->{PrintError} = 0;
 686     eval {
 687       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
 688       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
 689       $sth->execute();
 690       while ( my $info = $sth->fetchrow_hashref() ){
 691         my %column_info;
 692         $column_info{data_type}   = $info->{TYPE_NAME};
 693         $column_info{size}      = $info->{COLUMN_SIZE};
 694         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 695         $column_info{default_value} = $info->{COLUMN_DEF};
 696         my $col_name = $info->{COLUMN_NAME};
 697         $col_name =~ s/^\"(.*)\"$/$1/;
 698
 699         $result{$col_name} = \%column_info;
 700       }
 701     };
 702     $dbh->{RaiseError} = $old_raise_err;
 703     $dbh->{PrintError} = $old_print_err;
 704     return \%result if !$@;
 705   }
 706
 707   my %result;
 708   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 709   $sth->execute;
 710   my @columns = @{$sth->{NAME_lc}};
 711   for my $i ( 0 .. $#columns ){
 712     my %column_info;
 713     my $type_num = $sth->{TYPE}->[$i];
 714     my $type_name;
 715     if(defined $type_num && $dbh->can('type_info')) {
 716       my $type_info = $dbh->type_info($type_num);
 717       $type_name = $type_info->{TYPE_NAME} if $type_info;
 718     }
 719     $column_info{data_type} = $type_name ? $type_name : $type_num;
 720     $column_info{size} = $sth->{PRECISION}->[$i];
 721     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 722
 723     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 724       $column_info{data_type} = $1;
 725       $column_info{size}    = $2;
 726     }
 727
 728     $result{$columns[$i]} = \%column_info;
 729   }
 730
 731   return \%result;
 732 }
 733
 734 sub last_insert_id {
 735   my ($self, $row) = @_;
 736
 737   return $self->dbh->func('last_insert_rowid');
 738
 739 }
 740
 741 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 742
 743 sub create_ddl_dir
 744 {
 745   my ($self, $schema, $databases, $version, $dir, $sqltargs) = @_;
 746
 747   if(!$dir || !-d $dir)
 748   {
 749     warn "No directory given, using ./\n";
 750     $dir = "./";
 751   }
 752   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
 753   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
 754   $version ||= $schema->VERSION || '1.x';
 755
 756   eval "use SQL::Translator";
 757   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 758
 759   my $sqlt = SQL::Translator->new({
 760 #      debug => 1,
 761       add_drop_table => 1,
 762   });
 763   foreach my $db (@$databases)
 764   {
 765     $sqlt->reset();
 766     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 767 #    $sqlt->parser_args({'DBIx::Class' => $schema);
 768     $sqlt->data($schema);
 769     $sqlt->producer($db);
 770
 771     my $file;
 772     my $filename = $schema->ddl_filename($db, $dir, $version);
 773     if(-e $filename)
 774     {
 775       $self->throw_exception("$filename already exists, skipping $db");
 776       next;
 777     }
 778     open($file, ">$filename")
 779       or $self->throw_exception("Can't open $filename for writing ($!)");
 780     my $output = $sqlt->translate;
 781 #use Data::Dumper;
 782 #    print join(":", keys %{$schema->source_registrations});
 783 #    print Dumper($sqlt->schema);
 784     if(!$output)
 785     {
 786       $self->throw_exception("Failed to translate to $db. (" . $sqlt->error . ")");
 787       next;
 788     }
 789     print $file $output;
 790     close($file);
 791   }
 792
 793 }
 794
 795 sub deployment_statements {
 796   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
 797   $type ||= $self->sqlt_type;
 798   $version ||= $schema->VERSION || '1.x';
 799   $dir ||= './';
 800   eval "use SQL::Translator";
 801   if(!$@)
 802   {
 803     eval "use SQL::Translator::Parser::DBIx::Class;";
 804     $self->throw_exception($@) if $@;
 805     eval "use SQL::Translator::Producer::${type};";
 806     $self->throw_exception($@) if $@;
 807     my $tr = SQL::Translator->new(%$sqltargs);
 808     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 809     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 810   }
 811
 812   my $filename = $schema->ddl_filename($type, $dir, $version);
 813   if(!-f $filename)
 814   {
 815 #      $schema->create_ddl_dir([ $type ], $version, $dir, $sqltargs);
 816       $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
 817       return;
 818   }
 819   my $file;
 820   open($file, "<$filename")
 821       or $self->throw_exception("Can't open $filename ($!)");
 822   my @rows = <$file>;
 823   close($file);
 824
 825   return join('', @rows);
 826
 827 }
 828
 829 sub deploy {
 830   my ($self, $schema, $type, $sqltargs) = @_;
 831   foreach my $statement ( $self->deployment_statements($schema, $type, undef, undef, $sqltargs) ) {
 832     for ( split(";\n", $statement)) {
 833       next if($_ =~ /^--/);
 834       next if(!$_);
 835 #      next if($_ =~ /^DROP/m);
 836       next if($_ =~ /^BEGIN TRANSACTION/m);
 837       next if($_ =~ /^COMMIT/m);
 838       $self->debugobj->query_begin($_) if $self->debug;
 839       $self->dbh->do($_) or warn "SQL was:\n $_";
 840       $self->debugobj->query_end($_) if $self->debug;
 841     }
 842   }
 843 }
 844
 845 sub datetime_parser {
 846   my $self = shift;
 847   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
 848 }
 849
 850 sub datetime_parser_type { "DateTime::Format::MySQL"; }
 851
 852 sub build_datetime_parser {
 853   my $self = shift;
 854   my $type = $self->datetime_parser_type(@_);
 855   eval "use ${type}";
 856   $self->throw_exception("Couldn't load ${type}: $@") if $@;
 857   return $type;
 858 }
 859
 860 sub DESTROY { shift->disconnect }
 861
 862 1;
 863
 864 =head1 ENVIRONMENT VARIABLES
 865
 866 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 867
 868 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 869 is produced (as when the L<debug> method is set).
 870
 871 If the value is of the form C<1=/path/name> then the trace output is
 872 written to the file C</path/name>.
 873
 874 This environment variable is checked when the storage object is first
 875 created (when you call connect on your schema).  So, run-time changes
 876 to this environment variable will not take effect unless you also
 877 re-connect on your schema.
 878
 879 =head1 AUTHORS
 880
 881 Matt S. Trout <mst@shadowcatsystems.co.uk>
 882
 883 Andy Grundman <andy@hybridized.org>
 884
 885 =head1 LICENSE
 886
 887 You may distribute this code under the same terms as Perl itself.
 888
 889 =cut
 890