lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   $self->SUPER::select($table, $self->_recurse_fields($fields),
  21                          $where, $order, @rest);
  22 }
  23
  24 sub _emulate_limit {
  25   my $self = shift;
  26   if ($_[3] == -1) {
  27     return $_[1].$self->_order_by($_[2]);
  28   } else {
  29     return $self->SUPER::_emulate_limit(@_);
  30   }
  31 }
  32
  33 sub _recurse_fields {
  34   my ($self, $fields) = @_;
  35   my $ref = ref $fields;
  36   return $self->_quote($fields) unless $ref;
  37   return $$fields if $ref eq 'SCALAR';
  38
  39   if ($ref eq 'ARRAY') {
  40     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  41   } elsif ($ref eq 'HASH') {
  42     foreach my $func (keys %$fields) {
  43       return $self->_sqlcase($func)
  44         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  45     }
  46   }
  47 }
  48
  49 sub _order_by {
  50   my $self = shift;
  51   my $ret = '';
  52   if (ref $_[0] eq 'HASH') {
  53     if (defined $_[0]->{group_by}) {
  54       $ret = $self->_sqlcase(' group by ')
  55                .$self->_recurse_fields($_[0]->{group_by});
  56     }
  57     if (defined $_[0]->{order_by}) {
  58       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  59     }
  60   } else {
  61     $ret = $self->SUPER::_order_by(@_);
  62   }
  63   return $ret;
  64 }
  65
  66 sub _table {
  67   my ($self, $from) = @_;
  68   if (ref $from eq 'ARRAY') {
  69     return $self->_recurse_from(@$from);
  70   } elsif (ref $from eq 'HASH') {
  71     return $self->_make_as($from);
  72   } else {
  73     return $from;
  74   }
  75 }
  76
  77 sub _recurse_from {
  78   my ($self, $from, @join) = @_;
  79   my @sqlf;
  80   push(@sqlf, $self->_make_as($from));
  81   foreach my $j (@join) {
  82     my ($to, $on) = @$j;
  83
  84     # check whether a join type exists
  85     my $join_clause = '';
  86     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  87       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  88     } else {
  89       $join_clause = ' JOIN ';
  90     }
  91     push(@sqlf, $join_clause);
  92
  93     if (ref $to eq 'ARRAY') {
  94       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  95     } else {
  96       push(@sqlf, $self->_make_as($to));
  97     }
  98     push(@sqlf, ' ON ', $self->_join_condition($on));
  99   }
 100   return join('', @sqlf);
 101 }
 102
 103 sub _make_as {
 104   my ($self, $from) = @_;
 105   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 106                            reverse each %{$self->_skip_options($from)});
 107 }
 108
 109 sub _skip_options {
 110   my ($self, $hash) = @_;
 111   my $clean_hash = {};
 112   $clean_hash->{$_} = $hash->{$_}
 113     for grep {!/^-/} keys %$hash;
 114   return $clean_hash;
 115 }
 116
 117 sub _join_condition {
 118   my ($self, $cond) = @_;
 119   if (ref $cond eq 'HASH') {
 120     my %j;
 121     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 122     return $self->_recurse_where(\%j);
 123   } elsif (ref $cond eq 'ARRAY') {
 124     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 125   } else {
 126     die "Can't handle this yet!";
 127   }
 128 }
 129
 130 sub _quote {
 131   my ($self, $label) = @_;
 132   return '' unless defined $label;
 133   return $self->SUPER::_quote($label);
 134 }
 135
 136 # Accessor for setting limit dialect. This is useful
 137 # for JDBC-bridge among others where the remote SQL-dialect cannot
 138 # be determined by the name of the driver alone.
 139 #
 140 sub limit_dialect {
 141     my $self = shift;
 142     $self->{limit_dialect} = shift if @_;
 143     return $self->{limit_dialect};
 144 }
 145
 146 package DBIx::Class::Storage::DBI::DebugCallback;
 147
 148 sub print {
 149   my ($self, $string) = @_;
 150   $string =~ m/^(\w+)/;
 151   ${$self}->($1, $string);
 152 }
 153
 154 } # End of BEGIN block
 155
 156 use base qw/DBIx::Class/;
 157
 158 __PACKAGE__->load_components(qw/AccessorGroup/);
 159
 160 __PACKAGE__->mk_group_accessors('simple' =>
 161   qw/connect_info _dbh _sql_maker debug debugfh cursor on_connect_do transaction_depth/);
 162
 163 sub new {
 164   my $new = bless({}, ref $_[0] || $_[0]);
 165   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 166   $new->transaction_depth(0);
 167   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 168      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 169     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 170   } else {
 171     $new->debugfh(IO::File->new('>&STDERR'));
 172   }
 173   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 174   return $new;
 175 }
 176
 177 =head1 NAME
 178
 179 DBIx::Class::Storage::DBI - DBI storage handler
 180
 181 =head1 SYNOPSIS
 182
 183 =head1 DESCRIPTION
 184
 185 This class represents the connection to the database
 186
 187 =head1 METHODS
 188
 189 =cut
 190
 191 =head2 on_connect_do
 192
 193 Executes the sql statements given as a listref on every db connect.
 194
 195 =head2 debug
 196
 197 Causes SQL trace information to be emitted on C<debugfh> filehandle
 198 (or C<STDERR> if C<debugfh> has not specifically been set).
 199
 200 =head2 debugfh
 201
 202 Sets or retrieves the filehandle used for trace/debug output.  This
 203 should be an IO::Handle compatible object (only the C<print> method is
 204 used).  Initially set to be STDERR - although see information on the
 205 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 206
 207 =head2 debugcb
 208
 209 Sets a callback to be executed each time a statement is run; takes a sub
 210 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 211 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 212 be printed.
 213
 214 =cut
 215
 216 sub debugcb {
 217   my ($self, $cb) = @_;
 218   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 219   $self->debugfh($cb_obj);
 220 }
 221
 222 sub disconnect {
 223   my ($self) = @_;
 224
 225   $self->_dbh->disconnect if $self->_dbh;
 226 }
 227
 228 sub connected {
 229   my ($self) = @_;
 230
 231   my $dbh;
 232   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 233 }
 234
 235 sub ensure_connected {
 236   my ($self) = @_;
 237
 238   unless ($self->connected) {
 239     $self->_populate_dbh;
 240   }
 241 }
 242
 243 sub dbh {
 244   my ($self) = @_;
 245
 246   $self->ensure_connected;
 247   return $self->_dbh;
 248 }
 249
 250 sub sql_maker {
 251   my ($self) = @_;
 252   unless ($self->_sql_maker) {
 253     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 254   }
 255   return $self->_sql_maker;
 256 }
 257
 258 sub _populate_dbh {
 259   my ($self) = @_;
 260   my @info = @{$self->connect_info || []};
 261   $self->_dbh($self->_connect(@info));
 262
 263   # if on-connect sql statements are given execute them
 264   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 265     $self->_dbh->do($sql_statement);
 266   }
 267 }
 268
 269 sub _connect {
 270   my ($self, @info) = @_;
 271   return DBI->connect(@info);
 272 }
 273
 274 =head2 txn_begin
 275
 276 Calls begin_work on the current dbh.
 277
 278 =cut
 279
 280 sub txn_begin {
 281   my $self = shift;
 282   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 283 }
 284
 285 =head2 txn_commit
 286
 287 Issues a commit against the current dbh.
 288
 289 =cut
 290
 291 sub txn_commit {
 292   my $self = shift;
 293   if ($self->{transaction_depth} == 0) {
 294     $self->dbh->commit unless $self->dbh->{AutoCommit};
 295   }
 296   else {
 297     $self->dbh->commit if --$self->{transaction_depth} == 0;
 298   }
 299 }
 300
 301 =head2 txn_rollback
 302
 303 Issues a rollback against the current dbh.
 304
 305 =cut
 306
 307 sub txn_rollback {
 308   my $self = shift;
 309   if ($self->{transaction_depth} == 0) {
 310     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 311   }
 312   else {
 313     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 314   }
 315 }
 316
 317 sub _execute {
 318   my ($self, $op, $extra_bind, $ident, @args) = @_;
 319   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 320   unshift(@bind, @$extra_bind) if $extra_bind;
 321   if ($self->debug) {
 322       my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
 323       $self->debugfh->print("$sql: @debug_bind\n");
 324   }
 325   my $sth = $self->sth($sql,$op);
 326   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 327   my $rv;
 328   if ($sth) {
 329     $rv = $sth->execute(@bind);
 330   } else {
 331     croak "'$sql' did not generate a statement.";
 332   }
 333   return (wantarray ? ($rv, $sth, @bind) : $rv);
 334 }
 335
 336 sub insert {
 337   my ($self, $ident, $to_insert) = @_;
 338   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 339     unless ($self->_execute('insert' => [], $ident, $to_insert));
 340   return $to_insert;
 341 }
 342
 343 sub update {
 344   return shift->_execute('update' => [], @_);
 345 }
 346
 347 sub delete {
 348   return shift->_execute('delete' => [], @_);
 349 }
 350
 351 sub _select {
 352   my ($self, $ident, $select, $condition, $attrs) = @_;
 353   my $order = $attrs->{order_by};
 354   if (ref $condition eq 'SCALAR') {
 355     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 356   }
 357   if (exists $attrs->{group_by}) {
 358     $order = { group_by => $attrs->{group_by},
 359                ($order ? (order_by => $order) : ()) };
 360   }
 361   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 362   if ($attrs->{software_limit} ||
 363       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 364         $attrs->{software_limit} = 1;
 365   } else {
 366     push @args, $attrs->{rows}, $attrs->{offset};
 367   }
 368   return $self->_execute(@args);
 369 }
 370
 371 sub select {
 372   my $self = shift;
 373   my ($ident, $select, $condition, $attrs) = @_;
 374   return $self->cursor->new($self, \@_, $attrs);
 375 }
 376
 377 # Need to call finish() to work round broken DBDs
 378
 379 sub select_single {
 380   my $self = shift;
 381   my ($rv, $sth, @bind) = $self->_select(@_);
 382   my @row = $sth->fetchrow_array;
 383   $sth->finish();
 384   return @row;
 385 }
 386
 387 sub sth {
 388   my ($self, $sql) = @_;
 389   # 3 is the if_active parameter which avoids active sth re-use
 390   return $self->dbh->prepare_cached($sql, {}, 3);
 391 }
 392
 393 =head2 columns_info_for
 394
 395 Returns database type info for a given table columns.
 396
 397 =cut
 398
 399 sub columns_info_for {
 400     my ($self, $table) = @_;
 401     my %result;
 402     if ( $self->dbh->can( 'column_info' ) ){
 403         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 404         $sth->execute();
 405         while ( my $info = $sth->fetchrow_hashref() ){
 406             my %column_info;
 407             $column_info{data_type} = $info->{TYPE_NAME};
 408             $column_info{size} = $info->{COLUMN_SIZE};
 409             $column_info{is_nullable} = $info->{NULLABLE};
 410             $result{$info->{COLUMN_NAME}} = \%column_info;
 411         }
 412     }else{
 413         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 414         $sth->execute;
 415         my @columns = @{$sth->{NAME}};
 416         for my $i ( 0 .. $#columns ){
 417             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 418         }
 419     }
 420     return \%result;
 421 }
 422
 423 1;
 424
 425 =head1 ENVIRONMENT VARIABLES
 426
 427 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 428
 429 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 430 is produced (as when the L<debug> method is set).
 431
 432 If the value is of the form C<1=/path/name> then the trace output is
 433 written to the file C</path/name>.
 434
 435 =head1 AUTHORS
 436
 437 Matt S. Trout <mst@shadowcatsystems.co.uk>
 438
 439 Andy Grundman <andy@hybridized.org>
 440
 441 =head1 LICENSE
 442
 443 You may distribute this code under the same terms as Perl itself.
 444
 445 =cut
 446