lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching on_connect_do
  17        transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 BEGIN {
  23
  24 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  25
  26 use base qw/SQL::Abstract::Limit/;
  27
  28 # This prevents the caching of $dbh in S::A::L, I believe
  29 sub new {
  30   my $self = shift->SUPER::new(@_);
  31
  32   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  33   #   it with what it resolves to:
  34   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  35     if ref $self->{limit_dialect};
  36
  37   $self;
  38 }
  39
  40 sub _RowNumberOver {
  41   my ($self, $sql, $order, $rows, $offset ) = @_;
  42
  43   $offset += 1;
  44   my $last = $rows + $offset;
  45   my ( $order_by ) = $self->_order_by( $order );
  46
  47   $sql = <<"";
  48 SELECT * FROM
  49 (
  50    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  51       $sql
  52       $order_by
  53    ) Q1
  54 ) Q2
  55 WHERE ROW_NUM BETWEEN $offset AND $last
  56
  57   return $sql;
  58 }
  59
  60
  61 # While we're at it, this should make LIMIT queries more efficient,
  62 #  without digging into things too deeply
  63 use Scalar::Util 'blessed';
  64 sub _find_syntax {
  65   my ($self, $syntax) = @_;
  66   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  67   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  68     return 'RowNumberOver';
  69   }
  70
  71   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  72 }
  73
  74 sub select {
  75   my ($self, $table, $fields, $where, $order, @rest) = @_;
  76   $table = $self->_quote($table) unless ref($table);
  77   local $self->{rownum_hack_count} = 1
  78     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  79   @rest = (-1) unless defined $rest[0];
  80   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  81     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  82   local $self->{having_bind} = [];
  83   my ($sql, @ret) = $self->SUPER::select(
  84     $table, $self->_recurse_fields($fields), $where, $order, @rest
  85   );
  86   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  87 }
  88
  89 sub insert {
  90   my $self = shift;
  91   my $table = shift;
  92   $table = $self->_quote($table) unless ref($table);
  93   $self->SUPER::insert($table, @_);
  94 }
  95
  96 sub update {
  97   my $self = shift;
  98   my $table = shift;
  99   $table = $self->_quote($table) unless ref($table);
 100   $self->SUPER::update($table, @_);
 101 }
 102
 103 sub delete {
 104   my $self = shift;
 105   my $table = shift;
 106   $table = $self->_quote($table) unless ref($table);
 107   $self->SUPER::delete($table, @_);
 108 }
 109
 110 sub _emulate_limit {
 111   my $self = shift;
 112   if ($_[3] == -1) {
 113     return $_[1].$self->_order_by($_[2]);
 114   } else {
 115     return $self->SUPER::_emulate_limit(@_);
 116   }
 117 }
 118
 119 sub _recurse_fields {
 120   my ($self, $fields, $params) = @_;
 121   my $ref = ref $fields;
 122   return $self->_quote($fields) unless $ref;
 123   return $$fields if $ref eq 'SCALAR';
 124
 125   if ($ref eq 'ARRAY') {
 126     return join(', ', map {
 127       $self->_recurse_fields($_)
 128         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 129           ? ' AS col'.$self->{rownum_hack_count}++
 130           : '')
 131       } @$fields);
 132   } elsif ($ref eq 'HASH') {
 133     foreach my $func (keys %$fields) {
 134       return $self->_sqlcase($func)
 135         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 136     }
 137   }
 138 }
 139
 140 sub _order_by {
 141   my $self = shift;
 142   my $ret = '';
 143   my @extra;
 144   if (ref $_[0] eq 'HASH') {
 145     if (defined $_[0]->{group_by}) {
 146       $ret = $self->_sqlcase(' group by ')
 147         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 148     }
 149     if (defined $_[0]->{having}) {
 150       my $frag;
 151       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 152       push(@{$self->{having_bind}}, @extra);
 153       $ret .= $self->_sqlcase(' having ').$frag;
 154     }
 155     if (defined $_[0]->{order_by}) {
 156       $ret .= $self->_order_by($_[0]->{order_by});
 157     }
 158   } elsif (ref $_[0] eq 'SCALAR') {
 159     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 160   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 161     my @order = @{+shift};
 162     $ret = $self->_sqlcase(' order by ')
 163           .join(', ', map {
 164                         my $r = $self->_order_by($_, @_);
 165                         $r =~ s/^ ?ORDER BY //i;
 166                         $r;
 167                       } @order);
 168   } else {
 169     $ret = $self->SUPER::_order_by(@_);
 170   }
 171   return $ret;
 172 }
 173
 174 sub _order_directions {
 175   my ($self, $order) = @_;
 176   $order = $order->{order_by} if ref $order eq 'HASH';
 177   return $self->SUPER::_order_directions($order);
 178 }
 179
 180 sub _table {
 181   my ($self, $from) = @_;
 182   if (ref $from eq 'ARRAY') {
 183     return $self->_recurse_from(@$from);
 184   } elsif (ref $from eq 'HASH') {
 185     return $self->_make_as($from);
 186   } else {
 187     return $from; # would love to quote here but _table ends up getting called
 188                   # twice during an ->select without a limit clause due to
 189                   # the way S::A::Limit->select works. should maybe consider
 190                   # bypassing this and doing S::A::select($self, ...) in
 191                   # our select method above. meantime, quoting shims have
 192                   # been added to select/insert/update/delete here
 193   }
 194 }
 195
 196 sub _recurse_from {
 197   my ($self, $from, @join) = @_;
 198   my @sqlf;
 199   push(@sqlf, $self->_make_as($from));
 200   foreach my $j (@join) {
 201     my ($to, $on) = @$j;
 202
 203     # check whether a join type exists
 204     my $join_clause = '';
 205     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 206     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 207       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 208     } else {
 209       $join_clause = ' JOIN ';
 210     }
 211     push(@sqlf, $join_clause);
 212
 213     if (ref $to eq 'ARRAY') {
 214       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 215     } else {
 216       push(@sqlf, $self->_make_as($to));
 217     }
 218     push(@sqlf, ' ON ', $self->_join_condition($on));
 219   }
 220   return join('', @sqlf);
 221 }
 222
 223 sub _make_as {
 224   my ($self, $from) = @_;
 225   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 226                      reverse each %{$self->_skip_options($from)});
 227 }
 228
 229 sub _skip_options {
 230   my ($self, $hash) = @_;
 231   my $clean_hash = {};
 232   $clean_hash->{$_} = $hash->{$_}
 233     for grep {!/^-/} keys %$hash;
 234   return $clean_hash;
 235 }
 236
 237 sub _join_condition {
 238   my ($self, $cond) = @_;
 239   if (ref $cond eq 'HASH') {
 240     my %j;
 241     for (keys %$cond) {
 242       my $v = $cond->{$_};
 243       if (ref $v) {
 244         # XXX no throw_exception() in this package and croak() fails with strange results
 245         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 246             if ref($v) ne 'SCALAR';
 247         $j{$_} = $v;
 248       }
 249       else {
 250         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 251       }
 252     };
 253     return scalar($self->_recurse_where(\%j));
 254   } elsif (ref $cond eq 'ARRAY') {
 255     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 256   } else {
 257     die "Can't handle this yet!";
 258   }
 259 }
 260
 261 sub _quote {
 262   my ($self, $label) = @_;
 263   return '' unless defined $label;
 264   return "*" if $label eq '*';
 265   return $label unless $self->{quote_char};
 266   if(ref $self->{quote_char} eq "ARRAY"){
 267     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 268       if !defined $self->{name_sep};
 269     my $sep = $self->{name_sep};
 270     return join($self->{name_sep},
 271         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 272        split(/\Q$sep\E/,$label));
 273   }
 274   return $self->SUPER::_quote($label);
 275 }
 276
 277 sub limit_dialect {
 278     my $self = shift;
 279     $self->{limit_dialect} = shift if @_;
 280     return $self->{limit_dialect};
 281 }
 282
 283 sub quote_char {
 284     my $self = shift;
 285     $self->{quote_char} = shift if @_;
 286     return $self->{quote_char};
 287 }
 288
 289 sub name_sep {
 290     my $self = shift;
 291     $self->{name_sep} = shift if @_;
 292     return $self->{name_sep};
 293 }
 294
 295 } # End of BEGIN block
 296
 297 =head1 NAME
 298
 299 DBIx::Class::Storage::DBI - DBI storage handler
 300
 301 =head1 SYNOPSIS
 302
 303 =head1 DESCRIPTION
 304
 305 This class represents the connection to an RDBMS via L<DBI>.  See
 306 L<DBIx::Class::Storage> for general information.  This pod only
 307 documents DBI-specific methods and behaviors.
 308
 309 =head1 METHODS
 310
 311 =cut
 312
 313 sub new {
 314   my $new = shift->next::method(@_);
 315
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 This can be set to an arrayref of literal sql statements, which will
 351 be executed immediately after making the connection to the database
 352 every time we [re-]connect.
 353
 354 =item disable_sth_caching
 355
 356 If set to a true value, this option will disable the caching of
 357 statement handles via L<DBI/prepare_cached>.
 358
 359 =item limit_dialect
 360
 361 Sets the limit dialect. This is useful for JDBC-bridge among others
 362 where the remote SQL-dialect cannot be determined by the name of the
 363 driver alone.
 364
 365 =item quote_char
 366
 367 Specifies what characters to use to quote table and column names. If
 368 you use this you will want to specify L<name_sep> as well.
 369
 370 quote_char expects either a single character, in which case is it is placed
 371 on either side of the table/column, or an arrayref of length 2 in which case the
 372 table/column name is placed between the elements.
 373
 374 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 375 use C<quote_char =E<gt> [qw/[ ]/]>.
 376
 377 =item name_sep
 378
 379 This only needs to be used in conjunction with L<quote_char>, and is used to
 380 specify the charecter that seperates elements (schemas, tables, columns) from
 381 each other. In most cases this is simply a C<.>.
 382
 383 =item unsafe
 384
 385 This Storage driver normally installs its own C<HandleError>, sets
 386 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 387 all database handles, including those supplied by a coderef.  It does this
 388 so that it can have consistent and useful error behavior.
 389
 390 If you set this option to a true value, Storage will not do its usual
 391 modifications to the database handle's attributes, and instead relies on
 392 the settings in your connect_info DBI options (or the values you set in
 393 your connection coderef, in the case that you are connecting via coderef).
 394
 395 Note that your custom settings can cause Storage to malfunction,
 396 especially if you set a C<HandleError> handler that suppresses exceptions
 397 and/or disable C<RaiseError>.
 398
 399 =back
 400
 401 These options can be mixed in with your other L<DBI> connection attributes,
 402 or placed in a seperate hashref after all other normal L<DBI> connection
 403 arguments.
 404
 405 Every time C<connect_info> is invoked, any previous settings for
 406 these options will be cleared before setting the new ones, regardless of
 407 whether any options are specified in the new C<connect_info>.
 408
 409 Another Important Note:
 410
 411 DBIC can do some wonderful magic with handling exceptions,
 412 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 413 combined with C<txn_do> for transaction support.
 414
 415 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 416 in an assumed transaction between commits, and you're telling us you'd
 417 like to manage that manually.  A lot of DBIC's magic protections
 418 go away.  We can't protect you from exceptions due to database
 419 disconnects because we don't know anything about how to restart your
 420 transactions.  You're on your own for handling all sorts of exceptional
 421 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 422 be with raw DBI.
 423
 424 Examples:
 425
 426   # Simple SQLite connection
 427   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 428
 429   # Connect via subref
 430   ->connect_info([ sub { DBI->connect(...) } ]);
 431
 432   # A bit more complicated
 433   ->connect_info(
 434     [
 435       'dbi:Pg:dbname=foo',
 436       'postgres',
 437       'my_pg_password',
 438       { AutoCommit => 1 },
 439       { quote_char => q{"}, name_sep => q{.} },
 440     ]
 441   );
 442
 443   # Equivalent to the previous example
 444   ->connect_info(
 445     [
 446       'dbi:Pg:dbname=foo',
 447       'postgres',
 448       'my_pg_password',
 449       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 450     ]
 451   );
 452
 453   # Subref + DBIC-specific connection options
 454   ->connect_info(
 455     [
 456       sub { DBI->connect(...) },
 457       {
 458           quote_char => q{`},
 459           name_sep => q{@},
 460           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 461           disable_sth_caching => 1,
 462       },
 463     ]
 464   );
 465
 466 =cut
 467
 468 sub connect_info {
 469   my ($self, $info_arg) = @_;
 470
 471   return $self->_connect_info if !$info_arg;
 472
 473   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 474   #  the new set of options
 475   $self->_sql_maker(undef);
 476   $self->_sql_maker_opts({});
 477   $self->_connect_info([@$info_arg]); # copy for _connect_info
 478
 479   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 480
 481   my $last_info = $dbi_info->[-1];
 482   if(ref $last_info eq 'HASH') {
 483     $last_info = { %$last_info }; # so delete is non-destructive
 484     for my $storage_opt (
 485         qw/on_connect_do disable_sth_caching unsafe cursor_class/
 486       ) {
 487       if(my $value = delete $last_info->{$storage_opt}) {
 488         $self->$storage_opt($value);
 489       }
 490     }
 491     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 492       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 493         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 494       }
 495     }
 496     # re-insert modified hashref
 497     $dbi_info->[-1] = $last_info;
 498
 499     # Get rid of any trailing empty hashref
 500     pop(@$dbi_info) if !keys %$last_info;
 501   }
 502   $self->_dbi_connect_info($dbi_info);
 503
 504   $self->_connect_info;
 505 }
 506
 507 =head2 on_connect_do
 508
 509 This method is deprecated in favor of setting via L</connect_info>.
 510
 511 =head2 dbh_do
 512
 513 Arguments: $subref, @extra_coderef_args?
 514
 515 Execute the given subref using the new exception-based connection management.
 516
 517 The first two arguments will be the storage object that C<dbh_do> was called
 518 on and a database handle to use.  Any additional arguments will be passed
 519 verbatim to the called subref as arguments 2 and onwards.
 520
 521 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 522 exception handling and reconnection (or failover in future subclasses).
 523
 524 Your subref should have no side-effects outside of the database, as
 525 there is the potential for your subref to be partially double-executed
 526 if the database connection was stale/dysfunctional.
 527
 528 Example:
 529
 530   my @stuff = $schema->storage->dbh_do(
 531     sub {
 532       my ($storage, $dbh, @cols) = @_;
 533       my $cols = join(q{, }, @cols);
 534       $dbh->selectrow_array("SELECT $cols FROM foo");
 535     },
 536     @column_list
 537   );
 538
 539 =cut
 540
 541 sub dbh_do {
 542   my $self = shift;
 543   my $coderef = shift;
 544
 545   ref $coderef eq 'CODE' or $self->throw_exception
 546     ('$coderef must be a CODE reference');
 547
 548   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 549       || $self->{transaction_depth};
 550
 551   local $self->{_in_dbh_do} = 1;
 552
 553   my @result;
 554   my $want_array = wantarray;
 555
 556   eval {
 557     $self->_verify_pid if $self->_dbh;
 558     $self->_populate_dbh if !$self->_dbh;
 559     if($want_array) {
 560         @result = $coderef->($self, $self->_dbh, @_);
 561     }
 562     elsif(defined $want_array) {
 563         $result[0] = $coderef->($self, $self->_dbh, @_);
 564     }
 565     else {
 566         $coderef->($self, $self->_dbh, @_);
 567     }
 568   };
 569
 570   my $exception = $@;
 571   if(!$exception) { return $want_array ? @result : $result[0] }
 572
 573   $self->throw_exception($exception) if $self->connected;
 574
 575   # We were not connected - reconnect and retry, but let any
 576   #  exception fall right through this time
 577   $self->_populate_dbh;
 578   $coderef->($self, $self->_dbh, @_);
 579 }
 580
 581 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 582 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 583 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 584 sub txn_do {
 585   my $self = shift;
 586   my $coderef = shift;
 587
 588   ref $coderef eq 'CODE' or $self->throw_exception
 589     ('$coderef must be a CODE reference');
 590
 591   return $coderef->(@_) if $self->{transaction_depth};
 592
 593   local $self->{_in_dbh_do} = 1;
 594
 595   my @result;
 596   my $want_array = wantarray;
 597
 598   my $tried = 0;
 599   while(1) {
 600     eval {
 601       $self->_verify_pid if $self->_dbh;
 602       $self->_populate_dbh if !$self->_dbh;
 603
 604       $self->txn_begin;
 605       if($want_array) {
 606           @result = $coderef->(@_);
 607       }
 608       elsif(defined $want_array) {
 609           $result[0] = $coderef->(@_);
 610       }
 611       else {
 612           $coderef->(@_);
 613       }
 614       $self->txn_commit;
 615     };
 616
 617     my $exception = $@;
 618     if(!$exception) { return $want_array ? @result : $result[0] }
 619
 620     if($tried++ > 0 || $self->connected) {
 621       eval { $self->txn_rollback };
 622       my $rollback_exception = $@;
 623       if($rollback_exception) {
 624         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 625         $self->throw_exception($exception)  # propagate nested rollback
 626           if $rollback_exception =~ /$exception_class/;
 627
 628         $self->throw_exception(
 629           "Transaction aborted: ${exception}. "
 630           . "Rollback failed: ${rollback_exception}"
 631         );
 632       }
 633       $self->throw_exception($exception)
 634     }
 635
 636     # We were not connected, and was first try - reconnect and retry
 637     # via the while loop
 638     $self->_populate_dbh;
 639   }
 640 }
 641
 642 =head2 disconnect
 643
 644 Our C<disconnect> method also performs a rollback first if the
 645 database is not in C<AutoCommit> mode.
 646
 647 =cut
 648
 649 sub disconnect {
 650   my ($self) = @_;
 651
 652   if( $self->connected ) {
 653     $self->_dbh->rollback unless $self->_dbh_autocommit;
 654     $self->_dbh->disconnect;
 655     $self->_dbh(undef);
 656     $self->{_dbh_gen}++;
 657   }
 658 }
 659
 660 sub connected {
 661   my ($self) = @_;
 662
 663   if(my $dbh = $self->_dbh) {
 664       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 665           $self->_dbh(undef);
 666           $self->{_dbh_gen}++;
 667           return;
 668       }
 669       else {
 670           $self->_verify_pid;
 671           return 0 if !$self->_dbh;
 672       }
 673       return ($dbh->FETCH('Active') && $dbh->ping);
 674   }
 675
 676   return 0;
 677 }
 678
 679 # handle pid changes correctly
 680 #  NOTE: assumes $self->_dbh is a valid $dbh
 681 sub _verify_pid {
 682   my ($self) = @_;
 683
 684   return if $self->_conn_pid == $$;
 685
 686   $self->_dbh->{InactiveDestroy} = 1;
 687   $self->_dbh(undef);
 688   $self->{_dbh_gen}++;
 689
 690   return;
 691 }
 692
 693 sub ensure_connected {
 694   my ($self) = @_;
 695
 696   unless ($self->connected) {
 697     $self->_populate_dbh;
 698   }
 699 }
 700
 701 =head2 dbh
 702
 703 Returns the dbh - a data base handle of class L<DBI>.
 704
 705 =cut
 706
 707 sub dbh {
 708   my ($self) = @_;
 709
 710   $self->ensure_connected;
 711   return $self->_dbh;
 712 }
 713
 714 sub _sql_maker_args {
 715     my ($self) = @_;
 716
 717     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 718 }
 719
 720 sub sql_maker {
 721   my ($self) = @_;
 722   unless ($self->_sql_maker) {
 723     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 724   }
 725   return $self->_sql_maker;
 726 }
 727
 728 sub _populate_dbh {
 729   my ($self) = @_;
 730   my @info = @{$self->_dbi_connect_info || []};
 731   $self->_dbh($self->_connect(@info));
 732
 733   # Always set the transaction depth on connect, since
 734   #  there is no transaction in progress by definition
 735   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 736
 737   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 738     my $driver = $self->_dbh->{Driver}->{Name};
 739     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 740       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 741       $self->_rebless() if $self->can('_rebless');
 742     }
 743   }
 744
 745   # if on-connect sql statements are given execute them
 746   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 747     $self->_query_start($sql_statement);
 748     $self->_dbh->do($sql_statement);
 749     $self->_query_end($sql_statement);
 750   }
 751
 752   $self->_conn_pid($$);
 753   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 754 }
 755
 756 sub _connect {
 757   my ($self, @info) = @_;
 758
 759   $self->throw_exception("You failed to provide any connection info")
 760     if !@info;
 761
 762   my ($old_connect_via, $dbh);
 763
 764   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 765     $old_connect_via = $DBI::connect_via;
 766     $DBI::connect_via = 'connect';
 767   }
 768
 769   eval {
 770     if(ref $info[0] eq 'CODE') {
 771        $dbh = &{$info[0]}
 772     }
 773     else {
 774        $dbh = DBI->connect(@info);
 775     }
 776
 777     if($dbh && !$self->unsafe) {
 778       my $weak_self = $self;
 779       weaken($weak_self);
 780       $dbh->{HandleError} = sub {
 781           $weak_self->throw_exception("DBI Exception: $_[0]")
 782       };
 783       $dbh->{ShowErrorStatement} = 1;
 784       $dbh->{RaiseError} = 1;
 785       $dbh->{PrintError} = 0;
 786     }
 787   };
 788
 789   $DBI::connect_via = $old_connect_via if $old_connect_via;
 790
 791   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 792     if !$dbh || $@;
 793
 794   $self->_dbh_autocommit($dbh->{AutoCommit});
 795
 796   $dbh;
 797 }
 798
 799
 800 sub txn_begin {
 801   my $self = shift;
 802   $self->ensure_connected();
 803   if($self->{transaction_depth} == 0) {
 804     $self->debugobj->txn_begin()
 805       if $self->debug;
 806     # this isn't ->_dbh-> because
 807     #  we should reconnect on begin_work
 808     #  for AutoCommit users
 809     $self->dbh->begin_work;
 810   }
 811   $self->{transaction_depth}++;
 812 }
 813
 814 sub txn_commit {
 815   my $self = shift;
 816   if ($self->{transaction_depth} == 1) {
 817     my $dbh = $self->_dbh;
 818     $self->debugobj->txn_commit()
 819       if ($self->debug);
 820     $dbh->commit;
 821     $self->{transaction_depth} = 0
 822       if $self->_dbh_autocommit;
 823   }
 824   elsif($self->{transaction_depth} > 1) {
 825     $self->{transaction_depth}--
 826   }
 827 }
 828
 829 sub txn_rollback {
 830   my $self = shift;
 831   my $dbh = $self->_dbh;
 832   eval {
 833     if ($self->{transaction_depth} == 1) {
 834       $self->debugobj->txn_rollback()
 835         if ($self->debug);
 836       $self->{transaction_depth} = 0
 837         if $self->_dbh_autocommit;
 838       $dbh->rollback;
 839     }
 840     elsif($self->{transaction_depth} > 1) {
 841       $self->{transaction_depth}--;
 842     }
 843     else {
 844       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 845     }
 846   };
 847   if ($@) {
 848     my $error = $@;
 849     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 850     $error =~ /$exception_class/ and $self->throw_exception($error);
 851     # ensure that a failed rollback resets the transaction depth
 852     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 853     $self->throw_exception($error);
 854   }
 855 }
 856
 857 # This used to be the top-half of _execute.  It was split out to make it
 858 #  easier to override in NoBindVars without duping the rest.  It takes up
 859 #  all of _execute's args, and emits $sql, @bind.
 860 sub _prep_for_execute {
 861   my ($self, $op, $extra_bind, $ident, $args) = @_;
 862
 863   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 864   unshift(@bind,
 865     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 866       if $extra_bind;
 867
 868   return ($sql, \@bind);
 869 }
 870
 871 sub _fix_bind_params {
 872     my ($self, @bind) = @_;
 873
 874     ### Turn @bind from something like this:
 875     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 876     ### to this:
 877     ###   ( "'1'", "'1'", "'3'" )
 878     return
 879         map {
 880             if ( defined( $_ && $_->[1] ) ) {
 881                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 882             }
 883             else { q{'NULL'}; }
 884         } @bind;
 885 }
 886
 887 sub _query_start {
 888     my ( $self, $sql, @bind ) = @_;
 889
 890     if ( $self->debug ) {
 891         @bind = $self->_fix_bind_params(@bind);
 892         $self->debugobj->query_start( $sql, @bind );
 893     }
 894 }
 895
 896 sub _query_end {
 897     my ( $self, $sql, @bind ) = @_;
 898
 899     if ( $self->debug ) {
 900         @bind = $self->_fix_bind_params(@bind);
 901         $self->debugobj->query_end( $sql, @bind );
 902     }
 903 }
 904
 905 sub _dbh_execute {
 906   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 907
 908   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 909     $ident = $ident->from();
 910   }
 911
 912   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 913
 914   $self->_query_start( $sql, @$bind );
 915
 916   my $sth = $self->sth($sql,$op);
 917
 918   my $placeholder_index = 1;
 919
 920   foreach my $bound (@$bind) {
 921     my $attributes = {};
 922     my($column_name, @data) = @$bound;
 923
 924     if ($bind_attributes) {
 925       $attributes = $bind_attributes->{$column_name}
 926       if defined $bind_attributes->{$column_name};
 927     }
 928
 929     foreach my $data (@data) {
 930       $data = ref $data ? ''.$data : $data; # stringify args
 931
 932       $sth->bind_param($placeholder_index, $data, $attributes);
 933       $placeholder_index++;
 934     }
 935   }
 936
 937   # Can this fail without throwing an exception anyways???
 938   my $rv = $sth->execute();
 939   $self->throw_exception($sth->errstr) if !$rv;
 940
 941   $self->_query_end( $sql, @$bind );
 942
 943   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 944 }
 945
 946 sub _execute {
 947     my $self = shift;
 948     $self->dbh_do($self->can('_dbh_execute'), @_)
 949 }
 950
 951 sub insert {
 952   my ($self, $source, $to_insert) = @_;
 953
 954   my $ident = $source->from;
 955   my $bind_attributes = $self->source_bind_attributes($source);
 956
 957   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 958
 959   return $to_insert;
 960 }
 961
 962 ## Still not quite perfect, and EXPERIMENTAL
 963 ## Currently it is assumed that all values passed will be "normal", i.e. not
 964 ## scalar refs, or at least, all the same type as the first set, the statement is
 965 ## only prepped once.
 966 sub insert_bulk {
 967   my ($self, $source, $cols, $data) = @_;
 968   my %colvalues;
 969   my $table = $source->from;
 970   @colvalues{@$cols} = (0..$#$cols);
 971   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 972
 973   $self->_query_start( $sql, @bind );
 974   my $sth = $self->sth($sql);
 975
 976 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 977
 978   ## This must be an arrayref, else nothing works!
 979
 980   my $tuple_status = [];
 981
 982   ##use Data::Dumper;
 983   ##print STDERR Dumper( $data, $sql, [@bind] );
 984
 985   my $time = time();
 986
 987   ## Get the bind_attributes, if any exist
 988   my $bind_attributes = $self->source_bind_attributes($source);
 989
 990   ## Bind the values and execute
 991   my $placeholder_index = 1;
 992
 993   foreach my $bound (@bind) {
 994
 995     my $attributes = {};
 996     my ($column_name, $data_index) = @$bound;
 997
 998     if( $bind_attributes ) {
 999       $attributes = $bind_attributes->{$column_name}
1000       if defined $bind_attributes->{$column_name};
1001     }
1002
1003     my @data = map { $_->[$data_index] } @$data;
1004
1005     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1006     $placeholder_index++;
1007   }
1008   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1009   $self->throw_exception($sth->errstr) if !$rv;
1010
1011   $self->_query_end( $sql, @bind );
1012   return (wantarray ? ($rv, $sth, @bind) : $rv);
1013 }
1014
1015 sub update {
1016   my $self = shift @_;
1017   my $source = shift @_;
1018   my $bind_attributes = $self->source_bind_attributes($source);
1019
1020   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1021 }
1022
1023
1024 sub delete {
1025   my $self = shift @_;
1026   my $source = shift @_;
1027
1028   my $bind_attrs = {}; ## If ever it's needed...
1029
1030   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1031 }
1032
1033 sub _select {
1034   my ($self, $ident, $select, $condition, $attrs) = @_;
1035   my $order = $attrs->{order_by};
1036   if (ref $condition eq 'SCALAR') {
1037     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1038   }
1039   if (exists $attrs->{group_by} || $attrs->{having}) {
1040     $order = {
1041       group_by => $attrs->{group_by},
1042       having => $attrs->{having},
1043       ($order ? (order_by => $order) : ())
1044     };
1045   }
1046   my $bind_attrs = {}; ## Future support
1047   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1048   if ($attrs->{software_limit} ||
1049       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1050         $attrs->{software_limit} = 1;
1051   } else {
1052     $self->throw_exception("rows attribute must be positive if present")
1053       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1054
1055     # MySQL actually recommends this approach.  I cringe.
1056     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1057     push @args, $attrs->{rows}, $attrs->{offset};
1058   }
1059   return $self->_execute(@args);
1060 }
1061
1062 sub source_bind_attributes {
1063   my ($self, $source) = @_;
1064
1065   my $bind_attributes;
1066   foreach my $column ($source->columns) {
1067
1068     my $data_type = $source->column_info($column)->{data_type} || '';
1069     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1070      if $data_type;
1071   }
1072
1073   return $bind_attributes;
1074 }
1075
1076 =head2 select
1077
1078 =over 4
1079
1080 =item Arguments: $ident, $select, $condition, $attrs
1081
1082 =back
1083
1084 Handle a SQL select statement.
1085
1086 =cut
1087
1088 sub select {
1089   my $self = shift;
1090   my ($ident, $select, $condition, $attrs) = @_;
1091   return $self->cursor_class->new($self, \@_, $attrs);
1092 }
1093
1094 sub select_single {
1095   my $self = shift;
1096   my ($rv, $sth, @bind) = $self->_select(@_);
1097   my @row = $sth->fetchrow_array;
1098   # Need to call finish() to work round broken DBDs
1099   $sth->finish();
1100   return @row;
1101 }
1102
1103 =head2 sth
1104
1105 =over 4
1106
1107 =item Arguments: $sql
1108
1109 =back
1110
1111 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1112
1113 =cut
1114
1115 sub _dbh_sth {
1116   my ($self, $dbh, $sql) = @_;
1117
1118   # 3 is the if_active parameter which avoids active sth re-use
1119   my $sth = $self->disable_sth_caching
1120     ? $dbh->prepare($sql)
1121     : $dbh->prepare_cached($sql, {}, 3);
1122
1123   # XXX You would think RaiseError would make this impossible,
1124   #  but apparently that's not true :(
1125   $self->throw_exception($dbh->errstr) if !$sth;
1126
1127   $sth;
1128 }
1129
1130 sub sth {
1131   my ($self, $sql) = @_;
1132   $self->dbh_do($self->can('_dbh_sth'), $sql);
1133 }
1134
1135 sub _dbh_columns_info_for {
1136   my ($self, $dbh, $table) = @_;
1137
1138   if ($dbh->can('column_info')) {
1139     my %result;
1140     eval {
1141       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1142       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1143       $sth->execute();
1144       while ( my $info = $sth->fetchrow_hashref() ){
1145         my %column_info;
1146         $column_info{data_type}   = $info->{TYPE_NAME};
1147         $column_info{size}      = $info->{COLUMN_SIZE};
1148         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1149         $column_info{default_value} = $info->{COLUMN_DEF};
1150         my $col_name = $info->{COLUMN_NAME};
1151         $col_name =~ s/^\"(.*)\"$/$1/;
1152
1153         $result{$col_name} = \%column_info;
1154       }
1155     };
1156     return \%result if !$@ && scalar keys %result;
1157   }
1158
1159   my %result;
1160   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1161   $sth->execute;
1162   my @columns = @{$sth->{NAME_lc}};
1163   for my $i ( 0 .. $#columns ){
1164     my %column_info;
1165     $column_info{data_type} = $sth->{TYPE}->[$i];
1166     $column_info{size} = $sth->{PRECISION}->[$i];
1167     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1168
1169     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1170       $column_info{data_type} = $1;
1171       $column_info{size}    = $2;
1172     }
1173
1174     $result{$columns[$i]} = \%column_info;
1175   }
1176   $sth->finish;
1177
1178   foreach my $col (keys %result) {
1179     my $colinfo = $result{$col};
1180     my $type_num = $colinfo->{data_type};
1181     my $type_name;
1182     if(defined $type_num && $dbh->can('type_info')) {
1183       my $type_info = $dbh->type_info($type_num);
1184       $type_name = $type_info->{TYPE_NAME} if $type_info;
1185       $colinfo->{data_type} = $type_name if $type_name;
1186     }
1187   }
1188
1189   return \%result;
1190 }
1191
1192 sub columns_info_for {
1193   my ($self, $table) = @_;
1194   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1195 }
1196
1197 =head2 last_insert_id
1198
1199 Return the row id of the last insert.
1200
1201 =cut
1202
1203 sub _dbh_last_insert_id {
1204     my ($self, $dbh, $source, $col) = @_;
1205     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1206     $dbh->func('last_insert_rowid');
1207 }
1208
1209 sub last_insert_id {
1210   my $self = shift;
1211   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1212 }
1213
1214 =head2 sqlt_type
1215
1216 Returns the database driver name.
1217
1218 =cut
1219
1220 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1221
1222 =head2 bind_attribute_by_data_type
1223
1224 Given a datatype from column info, returns a database specific bind attribute for
1225 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1226 just handle it.
1227
1228 Generally only needed for special case column types, like bytea in postgres.
1229
1230 =cut
1231
1232 sub bind_attribute_by_data_type {
1233     return;
1234 }
1235
1236 =head2 create_ddl_dir
1237
1238 =over 4
1239
1240 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1241
1242 =back
1243
1244 Creates a SQL file based on the Schema, for each of the specified
1245 database types, in the given directory.
1246
1247 =cut
1248
1249 sub create_ddl_dir
1250 {
1251   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1252
1253   if(!$dir || !-d $dir)
1254   {
1255     warn "No directory given, using ./\n";
1256     $dir = "./";
1257   }
1258   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1259   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1260   $version ||= $schema->VERSION || '1.x';
1261   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1262
1263   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1264       . $self->_check_sqlt_message . q{'})
1265           if !$self->_check_sqlt_version;
1266
1267   my $sqlt = SQL::Translator->new({
1268 #      debug => 1,
1269       add_drop_table => 1,
1270   });
1271   foreach my $db (@$databases)
1272   {
1273     $sqlt->reset();
1274     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1275 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1276     $sqlt = $self->configure_sqlt($sqlt, $db);
1277     $sqlt->data($schema);
1278     $sqlt->producer($db);
1279
1280     my $file;
1281     my $filename = $schema->ddl_filename($db, $dir, $version);
1282     if(-e $filename)
1283     {
1284       warn("$filename already exists, skipping $db");
1285       next;
1286     }
1287
1288     my $output = $sqlt->translate;
1289     if(!$output)
1290     {
1291       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1292       next;
1293     }
1294     if(!open($file, ">$filename"))
1295     {
1296         $self->throw_exception("Can't open $filename for writing ($!)");
1297         next;
1298     }
1299     print $file $output;
1300     close($file);
1301
1302     if($preversion)
1303     {
1304       require SQL::Translator::Diff;
1305
1306       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1307 #      print "Previous version $prefilename\n";
1308       if(!-e $prefilename)
1309       {
1310         warn("No previous schema file found ($prefilename)");
1311         next;
1312       }
1313       #### We need to reparse the SQLite file we just wrote, so that
1314       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1315       ##   FIXME: rip Diff to pieces!
1316 #      my $target_schema = $sqlt->schema;
1317 #      unless ( $target_schema->name ) {
1318 #        $target_schema->name( $filename );
1319 #      }
1320       my @input;
1321       push @input, {file => $prefilename, parser => $db};
1322       push @input, {file => $filename, parser => $db};
1323       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1324         my $file   = $_->{'file'};
1325         my $parser = $_->{'parser'};
1326
1327         my $t = SQL::Translator->new;
1328         $t->debug( 0 );
1329         $t->trace( 0 );
1330         $t->parser( $parser )            or die $t->error;
1331         my $out = $t->translate( $file ) or die $t->error;
1332         my $schema = $t->schema;
1333         unless ( $schema->name ) {
1334           $schema->name( $file );
1335         }
1336         ($schema, $parser);
1337       } @input;
1338
1339       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1340                                                     $target_schema, $db,
1341                                                     {}
1342                                                    );
1343       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1344       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1345       if(-e $difffile)
1346       {
1347         warn("$difffile already exists, skipping");
1348         next;
1349       }
1350       if(!open $file, ">$difffile")
1351       {
1352         $self->throw_exception("Can't write to $difffile ($!)");
1353         next;
1354       }
1355       print $file $diff;
1356       close($file);
1357     }
1358   }
1359 }
1360
1361 sub configure_sqlt() {
1362   my $self = shift;
1363   my $tr = shift;
1364   my $db = shift || $self->sqlt_type;
1365   if ($db eq 'PostgreSQL') {
1366     $tr->quote_table_names(0);
1367     $tr->quote_field_names(0);
1368   }
1369   return $tr;
1370 }
1371
1372 =head2 deployment_statements
1373
1374 =over 4
1375
1376 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1377
1378 =back
1379
1380 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1381 The database driver name is given by C<$type>, though the value from
1382 L</sqlt_type> is used if it is not specified.
1383
1384 C<$directory> is used to return statements from files in a previously created
1385 L</create_ddl_dir> directory and is optional. The filenames are constructed
1386 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1387
1388 If no C<$directory> is specified then the statements are constructed on the
1389 fly using L<SQL::Translator> and C<$version> is ignored.
1390
1391 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1392
1393 =cut
1394
1395 sub deployment_statements {
1396   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1397   # Need to be connected to get the correct sqlt_type
1398   $self->ensure_connected() unless $type;
1399   $type ||= $self->sqlt_type;
1400   $version ||= $schema->VERSION || '1.x';
1401   $dir ||= './';
1402   my $filename = $schema->ddl_filename($type, $dir, $version);
1403   if(-f $filename)
1404   {
1405       my $file;
1406       open($file, "<$filename")
1407         or $self->throw_exception("Can't open $filename ($!)");
1408       my @rows = <$file>;
1409       close($file);
1410       return join('', @rows);
1411   }
1412
1413   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1414       . $self->_check_sqlt_message . q{'})
1415           if !$self->_check_sqlt_version;
1416
1417   require SQL::Translator::Parser::DBIx::Class;
1418   eval qq{use SQL::Translator::Producer::${type}};
1419   $self->throw_exception($@) if $@;
1420
1421   # sources needs to be a parser arg, but for simplicty allow at top level
1422   # coming in
1423   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1424       if exists $sqltargs->{sources};
1425
1426   my $tr = SQL::Translator->new(%$sqltargs);
1427   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1428   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1429
1430   return;
1431
1432 }
1433
1434 sub deploy {
1435   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1436   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1437     foreach my $line ( split(";\n", $statement)) {
1438       next if($line =~ /^--/);
1439       next if(!$line);
1440 #      next if($line =~ /^DROP/m);
1441       next if($line =~ /^BEGIN TRANSACTION/m);
1442       next if($line =~ /^COMMIT/m);
1443       next if $line =~ /^\s+$/; # skip whitespace only
1444       $self->_query_start($line);
1445       eval {
1446         $self->dbh->do($line); # shouldn't be using ->dbh ?
1447       };
1448       if ($@) {
1449         warn qq{$@ (running "${line}")};
1450       }
1451       $self->_query_end($line);
1452     }
1453   }
1454 }
1455
1456 =head2 datetime_parser
1457
1458 Returns the datetime parser class
1459
1460 =cut
1461
1462 sub datetime_parser {
1463   my $self = shift;
1464   return $self->{datetime_parser} ||= do {
1465     $self->ensure_connected;
1466     $self->build_datetime_parser(@_);
1467   };
1468 }
1469
1470 =head2 datetime_parser_type
1471
1472 Defines (returns) the datetime parser class - currently hardwired to
1473 L<DateTime::Format::MySQL>
1474
1475 =cut
1476
1477 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1478
1479 =head2 build_datetime_parser
1480
1481 See L</datetime_parser>
1482
1483 =cut
1484
1485 sub build_datetime_parser {
1486   my $self = shift;
1487   my $type = $self->datetime_parser_type(@_);
1488   eval "use ${type}";
1489   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1490   return $type;
1491 }
1492
1493 {
1494     my $_check_sqlt_version; # private
1495     my $_check_sqlt_message; # private
1496     sub _check_sqlt_version {
1497         return $_check_sqlt_version if defined $_check_sqlt_version;
1498         eval 'use SQL::Translator 0.08';
1499         $_check_sqlt_message = $@ ? $@ : '';
1500         $_check_sqlt_version = $@ ? 0 : 1;
1501     }
1502
1503     sub _check_sqlt_message {
1504         _check_sqlt_version if !defined $_check_sqlt_message;
1505         $_check_sqlt_message;
1506     }
1507 }
1508
1509 sub DESTROY {
1510   my $self = shift;
1511   return if !$self->_dbh;
1512   $self->_verify_pid;
1513   $self->_dbh(undef);
1514 }
1515
1516 1;
1517
1518 =head1 SQL METHODS
1519
1520 The module defines a set of methods within the DBIC::SQL::Abstract
1521 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1522 SQL query functions.
1523
1524 The following methods are extended:-
1525
1526 =over 4
1527
1528 =item delete
1529
1530 =item insert
1531
1532 =item select
1533
1534 =item update
1535
1536 =item limit_dialect
1537
1538 See L</connect_info> for details.
1539 For setting, this method is deprecated in favor of L</connect_info>.
1540
1541 =item quote_char
1542
1543 See L</connect_info> for details.
1544 For setting, this method is deprecated in favor of L</connect_info>.
1545
1546 =item name_sep
1547
1548 See L</connect_info> for details.
1549 For setting, this method is deprecated in favor of L</connect_info>.
1550
1551 =back
1552
1553 =head1 AUTHORS
1554
1555 Matt S. Trout <mst@shadowcatsystems.co.uk>
1556
1557 Andy Grundman <andy@hybridized.org>
1558
1559 =head1 LICENSE
1560
1561 You may distribute this code under the same terms as Perl itself.
1562
1563 =cut