lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $is_getter = $storage_accessor_idx->{$meth} ? 0 : 1;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $is_getter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # only fire when invoked on an instance, a valid class-based invocation
 129       # would e.g. be setting a default for an inherited accessor
 130       ref $_[0]
 131         and
 132       ! $_[0]->{_driver_determined}
 133         and
 134       ! $_[0]->{_in_determine_driver}
 135         and
 136       # if this is a known *setter* - just set it, no need to connect
 137       # and determine the driver
 138       ( %1$s or @_ <= 1 )
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227     local $?; # just in case the DBI destructor changes it somehow
 228
 229     # destroy just the object if not native to this process
 230     $_->_verify_pid for (grep
 231       { defined $_ }
 232       values %seek_and_destroy
 233     );
 234   }
 235
 236   sub CLONE {
 237     # As per DBI's recommendation, DBIC disconnects all handles as
 238     # soon as possible (DBIC will reconnect only on demand from within
 239     # the thread)
 240     my @instances = grep { defined $_ } values %seek_and_destroy;
 241     %seek_and_destroy = ();
 242
 243     for (@instances) {
 244       $_->_dbh(undef);
 245
 246       $_->transaction_depth(0);
 247       $_->savepoints([]);
 248
 249       # properly renumber existing refs
 250       $_->_arm_global_destructor
 251     }
 252   }
 253 }
 254
 255 sub DESTROY {
 256   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 257   # some databases spew warnings on implicit disconnect
 258   local $SIG{__WARN__} = sub {};
 259   $_[0]->_dbh(undef);
 260
 261   # this op is necessary, since the very last perl runtime statement
 262   # triggers a global destruction shootout, and the $SIG localization
 263   # may very well be destroyed before perl actually gets to do the
 264   # $dbh undef
 265   1;
 266 }
 267
 268 # handle pid changes correctly - do not destroy parent's connection
 269 sub _verify_pid {
 270
 271   my $pid = $_[0]->_conn_pid;
 272
 273   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 274     $dbh->{InactiveDestroy} = 1;
 275     $_[0]->_dbh(undef);
 276     $_[0]->transaction_depth(0);
 277     $_[0]->savepoints([]);
 278   }
 279
 280   return;
 281 }
 282
 283 =head2 connect_info
 284
 285 This method is normally called by L<DBIx::Class::Schema/connection>, which
 286 encapsulates its argument list in an arrayref before passing them here.
 287
 288 The argument list may contain:
 289
 290 =over
 291
 292 =item *
 293
 294 The same 4-element argument set one would normally pass to
 295 L<DBI/connect>, optionally followed by
 296 L<extra attributes|/DBIx::Class specific connection attributes>
 297 recognized by DBIx::Class:
 298
 299   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 300
 301 =item *
 302
 303 A single code reference which returns a connected
 304 L<DBI database handle|DBI/connect> optionally followed by
 305 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 306 by DBIx::Class:
 307
 308   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 309
 310 =item *
 311
 312 A single hashref with all the attributes and the dsn/user/password
 313 mixed together:
 314
 315   $connect_info_args = [{
 316     dsn => $dsn,
 317     user => $user,
 318     password => $pass,
 319     %dbi_attributes,
 320     %extra_attributes,
 321   }];
 322
 323   $connect_info_args = [{
 324     dbh_maker => sub { DBI->connect (...) },
 325     %dbi_attributes,
 326     %extra_attributes,
 327   }];
 328
 329 This is particularly useful for L<Catalyst> based applications, allowing the
 330 following config (L<Config::General> style):
 331
 332   <Model::DB>
 333     schema_class   App::DB
 334     <connect_info>
 335       dsn          dbi:mysql:database=test
 336       user         testuser
 337       password     TestPass
 338       AutoCommit   1
 339     </connect_info>
 340   </Model::DB>
 341
 342 The C<dsn>/C<user>/C<password> combination can be substituted by the
 343 C<dbh_maker> key whose value is a coderef that returns a connected
 344 L<DBI database handle|DBI/connect>
 345
 346 =back
 347
 348 Please note that the L<DBI> docs recommend that you always explicitly
 349 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 350 recommends that it be set to I<1>, and that you perform transactions
 351 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 352 to I<1> if you do not do explicitly set it to zero.  This is the default
 353 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 354
 355 =head3 DBIx::Class specific connection attributes
 356
 357 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 358 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 359 the following connection options. These options can be mixed in with your other
 360 L<DBI> connection attributes, or placed in a separate hashref
 361 (C<\%extra_attributes>) as shown above.
 362
 363 Every time C<connect_info> is invoked, any previous settings for
 364 these options will be cleared before setting the new ones, regardless of
 365 whether any options are specified in the new C<connect_info>.
 366
 367
 368 =over
 369
 370 =item on_connect_do
 371
 372 Specifies things to do immediately after connecting or re-connecting to
 373 the database.  Its value may contain:
 374
 375 =over
 376
 377 =item a scalar
 378
 379 This contains one SQL statement to execute.
 380
 381 =item an array reference
 382
 383 This contains SQL statements to execute in order.  Each element contains
 384 a string or a code reference that returns a string.
 385
 386 =item a code reference
 387
 388 This contains some code to execute.  Unlike code references within an
 389 array reference, its return value is ignored.
 390
 391 =back
 392
 393 =item on_disconnect_do
 394
 395 Takes arguments in the same form as L</on_connect_do> and executes them
 396 immediately before disconnecting from the database.
 397
 398 Note, this only runs if you explicitly call L</disconnect> on the
 399 storage object.
 400
 401 =item on_connect_call
 402
 403 A more generalized form of L</on_connect_do> that calls the specified
 404 C<connect_call_METHOD> methods in your storage driver.
 405
 406   on_connect_do => 'select 1'
 407
 408 is equivalent to:
 409
 410   on_connect_call => [ [ do_sql => 'select 1' ] ]
 411
 412 Its values may contain:
 413
 414 =over
 415
 416 =item a scalar
 417
 418 Will call the C<connect_call_METHOD> method.
 419
 420 =item a code reference
 421
 422 Will execute C<< $code->($storage) >>
 423
 424 =item an array reference
 425
 426 Each value can be a method name or code reference.
 427
 428 =item an array of arrays
 429
 430 For each array, the first item is taken to be the C<connect_call_> method name
 431 or code reference, and the rest are parameters to it.
 432
 433 =back
 434
 435 Some predefined storage methods you may use:
 436
 437 =over
 438
 439 =item do_sql
 440
 441 Executes a SQL string or a code reference that returns a SQL string. This is
 442 what L</on_connect_do> and L</on_disconnect_do> use.
 443
 444 It can take:
 445
 446 =over
 447
 448 =item a scalar
 449
 450 Will execute the scalar as SQL.
 451
 452 =item an arrayref
 453
 454 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 455 attributes hashref and bind values.
 456
 457 =item a code reference
 458
 459 Will execute C<< $code->($storage) >> and execute the return array refs as
 460 above.
 461
 462 =back
 463
 464 =item datetime_setup
 465
 466 Execute any statements necessary to initialize the database session to return
 467 and accept datetime/timestamp values used with
 468 L<DBIx::Class::InflateColumn::DateTime>.
 469
 470 Only necessary for some databases, see your specific storage driver for
 471 implementation details.
 472
 473 =back
 474
 475 =item on_disconnect_call
 476
 477 Takes arguments in the same form as L</on_connect_call> and executes them
 478 immediately before disconnecting from the database.
 479
 480 Calls the C<disconnect_call_METHOD> methods as opposed to the
 481 C<connect_call_METHOD> methods called by L</on_connect_call>.
 482
 483 Note, this only runs if you explicitly call L</disconnect> on the
 484 storage object.
 485
 486 =item disable_sth_caching
 487
 488 If set to a true value, this option will disable the caching of
 489 statement handles via L<DBI/prepare_cached>.
 490
 491 =item limit_dialect
 492
 493 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 494 default L</sql_limit_dialect> setting of the storage (if any). For a list
 495 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 496
 497 =item quote_names
 498
 499 When true automatically sets L</quote_char> and L</name_sep> to the characters
 500 appropriate for your particular RDBMS. This option is preferred over specifying
 501 L</quote_char> directly.
 502
 503 =item quote_char
 504
 505 Specifies what characters to use to quote table and column names.
 506
 507 C<quote_char> expects either a single character, in which case is it
 508 is placed on either side of the table/column name, or an arrayref of length
 509 2 in which case the table/column name is placed between the elements.
 510
 511 For example under MySQL you should use C<< quote_char => '`' >>, and for
 512 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 513
 514 =item name_sep
 515
 516 This parameter is only useful in conjunction with C<quote_char>, and is used to
 517 specify the character that separates elements (schemas, tables, columns) from
 518 each other. If unspecified it defaults to the most commonly used C<.>.
 519
 520 =item unsafe
 521
 522 This Storage driver normally installs its own C<HandleError>, sets
 523 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 524 all database handles, including those supplied by a coderef.  It does this
 525 so that it can have consistent and useful error behavior.
 526
 527 If you set this option to a true value, Storage will not do its usual
 528 modifications to the database handle's attributes, and instead relies on
 529 the settings in your connect_info DBI options (or the values you set in
 530 your connection coderef, in the case that you are connecting via coderef).
 531
 532 Note that your custom settings can cause Storage to malfunction,
 533 especially if you set a C<HandleError> handler that suppresses exceptions
 534 and/or disable C<RaiseError>.
 535
 536 =item auto_savepoint
 537
 538 If this option is true, L<DBIx::Class> will use savepoints when nesting
 539 transactions, making it possible to recover from failure in the inner
 540 transaction without having to abort all outer transactions.
 541
 542 =item cursor_class
 543
 544 Use this argument to supply a cursor class other than the default
 545 L<DBIx::Class::Storage::DBI::Cursor>.
 546
 547 =back
 548
 549 Some real-life examples of arguments to L</connect_info> and
 550 L<DBIx::Class::Schema/connect>
 551
 552   # Simple SQLite connection
 553   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 554
 555   # Connect via subref
 556   ->connect_info([ sub { DBI->connect(...) } ]);
 557
 558   # Connect via subref in hashref
 559   ->connect_info([{
 560     dbh_maker => sub { DBI->connect(...) },
 561     on_connect_do => 'alter session ...',
 562   }]);
 563
 564   # A bit more complicated
 565   ->connect_info(
 566     [
 567       'dbi:Pg:dbname=foo',
 568       'postgres',
 569       'my_pg_password',
 570       { AutoCommit => 1 },
 571       { quote_char => q{"} },
 572     ]
 573   );
 574
 575   # Equivalent to the previous example
 576   ->connect_info(
 577     [
 578       'dbi:Pg:dbname=foo',
 579       'postgres',
 580       'my_pg_password',
 581       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 582     ]
 583   );
 584
 585   # Same, but with hashref as argument
 586   # See parse_connect_info for explanation
 587   ->connect_info(
 588     [{
 589       dsn         => 'dbi:Pg:dbname=foo',
 590       user        => 'postgres',
 591       password    => 'my_pg_password',
 592       AutoCommit  => 1,
 593       quote_char  => q{"},
 594       name_sep    => q{.},
 595     }]
 596   );
 597
 598   # Subref + DBIx::Class-specific connection options
 599   ->connect_info(
 600     [
 601       sub { DBI->connect(...) },
 602       {
 603           quote_char => q{`},
 604           name_sep => q{@},
 605           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 606           disable_sth_caching => 1,
 607       },
 608     ]
 609   );
 610
 611
 612
 613 =cut
 614
 615 sub connect_info {
 616   my ($self, $info) = @_;
 617
 618   return $self->_connect_info if !$info;
 619
 620   $self->_connect_info($info); # copy for _connect_info
 621
 622   $info = $self->_normalize_connect_info($info)
 623     if ref $info eq 'ARRAY';
 624
 625   my %attrs = (
 626     %{ $self->_default_dbi_connect_attributes || {} },
 627     %{ $info->{attributes} || {} },
 628   );
 629
 630   my @args = @{ $info->{arguments} };
 631
 632   if (keys %attrs and ref $args[0] ne 'CODE') {
 633     carp_unique (
 634         'You provided explicit AutoCommit => 0 in your connection_info. '
 635       . 'This is almost universally a bad idea (see the footnotes of '
 636       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 637       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 638       . 'this warning.'
 639     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 640
 641     push @args, \%attrs if keys %attrs;
 642   }
 643
 644   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 645   # OR a single-element coderef-based $dbh factory
 646   $self->_dbi_connect_info(\@args);
 647
 648   # extract the individual storage options
 649   for my $storage_opt (keys %{ $info->{storage_options} }) {
 650     my $value = $info->{storage_options}{$storage_opt};
 651
 652     $self->$storage_opt($value);
 653   }
 654
 655   # Extract the individual sqlmaker options
 656   #
 657   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 658   #  the new set of options
 659   $self->_sql_maker(undef);
 660   $self->_sql_maker_opts({});
 661
 662   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 663     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 664
 665     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 666   }
 667
 668   # FIXME - dirty:
 669   # save attributes in a separate accessor so they are always
 670   # introspectable, even in case of a CODE $dbhmaker
 671   $self->_dbic_connect_attributes (\%attrs);
 672
 673   return $self->_connect_info;
 674 }
 675
 676 sub _dbi_connect_info {
 677   my $self = shift;
 678
 679   return $self->{_dbi_connect_info} = $_[0]
 680     if @_;
 681
 682   my $conninfo = $self->{_dbi_connect_info} || [];
 683
 684   # last ditch effort to grab a DSN
 685   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 686     my @new_conninfo = @$conninfo;
 687     $new_conninfo[0] = $ENV{DBI_DSN};
 688     $conninfo = \@new_conninfo;
 689   }
 690
 691   return $conninfo;
 692 }
 693
 694
 695 sub _normalize_connect_info {
 696   my ($self, $info_arg) = @_;
 697   my %info;
 698
 699   my @args = @$info_arg;  # take a shallow copy for further mutilation
 700
 701   # combine/pre-parse arguments depending on invocation style
 702
 703   my %attrs;
 704   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 705     %attrs = %{ $args[1] || {} };
 706     @args = $args[0];
 707   }
 708   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 709     %attrs = %{$args[0]};
 710     @args = ();
 711     if (my $code = delete $attrs{dbh_maker}) {
 712       @args = $code;
 713
 714       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 715       if (@ignored) {
 716         carp sprintf (
 717             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 718           . "to the result of 'dbh_maker'",
 719
 720           join (', ', map { "'$_'" } (@ignored) ),
 721         );
 722       }
 723     }
 724     else {
 725       @args = delete @attrs{qw/dsn user password/};
 726     }
 727   }
 728   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 729     %attrs = (
 730       % { $args[3] || {} },
 731       % { $args[4] || {} },
 732     );
 733     @args = @args[0,1,2];
 734   }
 735
 736   $info{arguments} = \@args;
 737
 738   my @storage_opts = grep exists $attrs{$_},
 739     @storage_options, 'cursor_class';
 740
 741   @{ $info{storage_options} }{@storage_opts} =
 742     delete @attrs{@storage_opts} if @storage_opts;
 743
 744   my @sql_maker_opts = grep exists $attrs{$_},
 745     qw/limit_dialect quote_char name_sep quote_names/;
 746
 747   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 748     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 749
 750   $info{attributes} = \%attrs if %attrs;
 751
 752   return \%info;
 753 }
 754
 755 sub _default_dbi_connect_attributes () {
 756   +{
 757     AutoCommit => 1,
 758     PrintError => 0,
 759     RaiseError => 1,
 760     ShowErrorStatement => 1,
 761   };
 762 }
 763
 764 =head2 on_connect_do
 765
 766 This method is deprecated in favour of setting via L</connect_info>.
 767
 768 =cut
 769
 770 =head2 on_disconnect_do
 771
 772 This method is deprecated in favour of setting via L</connect_info>.
 773
 774 =cut
 775
 776 sub _parse_connect_do {
 777   my ($self, $type) = @_;
 778
 779   my $val = $self->$type;
 780   return () if not defined $val;
 781
 782   my @res;
 783
 784   if (not ref($val)) {
 785     push @res, [ 'do_sql', $val ];
 786   } elsif (ref($val) eq 'CODE') {
 787     push @res, $val;
 788   } elsif (ref($val) eq 'ARRAY') {
 789     push @res, map { [ 'do_sql', $_ ] } @$val;
 790   } else {
 791     $self->throw_exception("Invalid type for $type: ".ref($val));
 792   }
 793
 794   return \@res;
 795 }
 796
 797 =head2 dbh_do
 798
 799 Arguments: ($subref | $method_name), @extra_coderef_args?
 800
 801 Execute the given $subref or $method_name using the new exception-based
 802 connection management.
 803
 804 The first two arguments will be the storage object that C<dbh_do> was called
 805 on and a database handle to use.  Any additional arguments will be passed
 806 verbatim to the called subref as arguments 2 and onwards.
 807
 808 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 809 exception handling and reconnection (or failover in future subclasses).
 810
 811 Your subref should have no side-effects outside of the database, as
 812 there is the potential for your subref to be partially double-executed
 813 if the database connection was stale/dysfunctional.
 814
 815 Example:
 816
 817   my @stuff = $schema->storage->dbh_do(
 818     sub {
 819       my ($storage, $dbh, @cols) = @_;
 820       my $cols = join(q{, }, @cols);
 821       $dbh->selectrow_array("SELECT $cols FROM foo");
 822     },
 823     @column_list
 824   );
 825
 826 =cut
 827
 828 sub dbh_do {
 829   my $self = shift;
 830   my $run_target = shift; # either a coderef or a method name
 831
 832   # short circuit when we know there is no need for a runner
 833   #
 834   # FIXME - assumption may be wrong
 835   # the rationale for the txn_depth check is that if this block is a part
 836   # of a larger transaction, everything up to that point is screwed anyway
 837   return $self->$run_target($self->_get_dbh, @_)
 838     if $self->{_in_do_block} or $self->transaction_depth;
 839
 840   # take a ref instead of a copy, to preserve @_ aliasing
 841   # semantics within the coderef, but only if needed
 842   # (pseudoforking doesn't like this trick much)
 843   my $args = @_ ? \@_ : [];
 844
 845   DBIx::Class::Storage::BlockRunner->new(
 846     storage => $self,
 847     wrap_txn => 0,
 848     retry_handler => sub {
 849       $_[0]->failed_attempt_count == 1
 850         and
 851       ! $_[0]->storage->connected
 852     },
 853   )->run(sub {
 854     $self->$run_target ($self->_get_dbh, @$args )
 855   });
 856 }
 857
 858 sub txn_do {
 859   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 860   shift->next::method(@_);
 861 }
 862
 863 =head2 disconnect
 864
 865 Our C<disconnect> method also performs a rollback first if the
 866 database is not in C<AutoCommit> mode.
 867
 868 =cut
 869
 870 sub disconnect {
 871
 872   if( my $dbh = $_[0]->_dbh ) {
 873
 874     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 875       ( $_[0]->on_disconnect_call || () ),
 876       $_[0]->_parse_connect_do ('on_disconnect_do')
 877     );
 878
 879     # stops the "implicit rollback on disconnect" warning
 880     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 881
 882     %{ $dbh->{CachedKids} } = ();
 883     $dbh->disconnect;
 884     $_[0]->_dbh(undef);
 885   }
 886 }
 887
 888 =head2 with_deferred_fk_checks
 889
 890 =over 4
 891
 892 =item Arguments: C<$coderef>
 893
 894 =item Return Value: The return value of $coderef
 895
 896 =back
 897
 898 Storage specific method to run the code ref with FK checks deferred or
 899 in MySQL's case disabled entirely.
 900
 901 =cut
 902
 903 # Storage subclasses should override this
 904 sub with_deferred_fk_checks {
 905   #my ($self, $sub) = @_;
 906   $_[1]->();
 907 }
 908
 909 =head2 connected
 910
 911 =over
 912
 913 =item Arguments: none
 914
 915 =item Return Value: 1|0
 916
 917 =back
 918
 919 Verifies that the current database handle is active and ready to execute
 920 an SQL statement (e.g. the connection did not get stale, server is still
 921 answering, etc.) This method is used internally by L</dbh>.
 922
 923 =cut
 924
 925 sub connected {
 926   return 0 unless $_[0]->_seems_connected;
 927
 928   #be on the safe side
 929   local $_[0]->_dbh->{RaiseError} = 1;
 930
 931   return $_[0]->_ping;
 932 }
 933
 934 sub _seems_connected {
 935   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 936
 937   ($_[0]->_dbh || return 0)->FETCH('Active');
 938 }
 939
 940 sub _ping {
 941   ($_[0]->_dbh || return 0)->ping;
 942 }
 943
 944 sub ensure_connected {
 945   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 946 }
 947
 948 =head2 dbh
 949
 950 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 951 is guaranteed to be healthy by implicitly calling L</connected>, and if
 952 necessary performing a reconnection before returning. Keep in mind that this
 953 is very B<expensive> on some database engines. Consider using L</dbh_do>
 954 instead.
 955
 956 =cut
 957
 958 sub dbh {
 959   # maybe save a ping call
 960   $_[0]->_dbh
 961     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 962     : $_[0]->_populate_dbh
 963   ;
 964 }
 965
 966 # this is the internal "get dbh or connect (don't check)" method
 967 sub _get_dbh {
 968   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 969   $_[0]->_dbh || $_[0]->_populate_dbh;
 970 }
 971
 972 # *DELIBERATELY* not a setter (for the time being)
 973 # Too intertwined with everything else for any kind of sanity
 974 sub sql_maker {
 975   my $self = shift;
 976
 977   $self->throw_exception('sql_maker() is not a setter method') if @_;
 978
 979   unless ($self->_sql_maker) {
 980     my $sql_maker_class = $self->sql_maker_class;
 981
 982     my %opts = %{$self->_sql_maker_opts||{}};
 983     my $dialect =
 984       $opts{limit_dialect}
 985         ||
 986       $self->sql_limit_dialect
 987         ||
 988       do {
 989         my $s_class = (ref $self) || $self;
 990         carp_unique (
 991           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 992         . 'have not supplied an explicit limit_dialect in your connection_info. '
 993         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 994         . 'databases but can be (and often is) painfully slow. '
 995         . "Please file an RT ticket against '$s_class'"
 996         ) if $self->_dbi_connect_info->[0];
 997
 998         'GenericSubQ';
 999       }
1000     ;
1001
1002     my ($quote_char, $name_sep);
1003
1004     if ($opts{quote_names}) {
1005       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1006         my $s_class = (ref $self) || $self;
1007         carp_unique (
1008           "You requested 'quote_names' but your storage class ($s_class) does "
1009         . 'not explicitly define a default sql_quote_char and you have not '
1010         . 'supplied a quote_char as part of your connection_info. DBIC will '
1011         .q{default to the ANSI SQL standard quote '"', which works most of }
1012         . "the time. Please file an RT ticket against '$s_class'."
1013         );
1014
1015         '"'; # RV
1016       };
1017
1018       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1019     }
1020
1021     $self->_sql_maker($sql_maker_class->new(
1022       bindtype=>'columns',
1023       array_datatypes => 1,
1024       limit_dialect => $dialect,
1025       ($quote_char ? (quote_char => $quote_char) : ()),
1026       name_sep => ($name_sep || '.'),
1027       %opts,
1028     ));
1029   }
1030   return $self->_sql_maker;
1031 }
1032
1033 # nothing to do by default
1034 sub _rebless {}
1035 sub _init {}
1036
1037 sub _populate_dbh {
1038
1039   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1040
1041   $_[0]->_dbh_details({}); # reset everything we know
1042
1043   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1044   #$_[0]->_sql_maker(undef); # this may also end up being different
1045
1046   $_[0]->_dbh($_[0]->_connect);
1047
1048   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1049
1050   $_[0]->_determine_driver;
1051
1052   # Always set the transaction depth on connect, since
1053   #  there is no transaction in progress by definition
1054   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1055
1056   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1057
1058   $_[0]->_dbh;
1059 }
1060
1061 sub _run_connection_actions {
1062
1063   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1064     ( $_[0]->on_connect_call || () ),
1065     $_[0]->_parse_connect_do ('on_connect_do'),
1066   );
1067 }
1068
1069
1070
1071 sub set_use_dbms_capability {
1072   $_[0]->set_inherited ($_[1], $_[2]);
1073 }
1074
1075 sub get_use_dbms_capability {
1076   my ($self, $capname) = @_;
1077
1078   my $use = $self->get_inherited ($capname);
1079   return defined $use
1080     ? $use
1081     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1082   ;
1083 }
1084
1085 sub set_dbms_capability {
1086   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1087 }
1088
1089 sub get_dbms_capability {
1090   my ($self, $capname) = @_;
1091
1092   my $cap = $self->_dbh_details->{capability}{$capname};
1093
1094   unless (defined $cap) {
1095     if (my $meth = $self->can ("_determine$capname")) {
1096       $cap = $self->$meth ? 1 : 0;
1097     }
1098     else {
1099       $cap = 0;
1100     }
1101
1102     $self->set_dbms_capability ($capname, $cap);
1103   }
1104
1105   return $cap;
1106 }
1107
1108 sub _server_info {
1109   my $self = shift;
1110
1111   my $info;
1112   unless ($info = $self->_dbh_details->{info}) {
1113
1114     $info = {};
1115
1116     my $server_version = try {
1117       $self->_get_server_version
1118     } catch {
1119       # driver determination *may* use this codepath
1120       # in which case we must rethrow
1121       $self->throw_exception($_) if $self->{_in_determine_driver};
1122
1123       # $server_version on failure
1124       undef;
1125     };
1126
1127     if (defined $server_version) {
1128       $info->{dbms_version} = $server_version;
1129
1130       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1131       my @verparts = split (/\./, $numeric_version);
1132       if (
1133         @verparts
1134           &&
1135         $verparts[0] <= 999
1136       ) {
1137         # consider only up to 3 version parts, iff not more than 3 digits
1138         my @use_parts;
1139         while (@verparts && @use_parts < 3) {
1140           my $p = shift @verparts;
1141           last if $p > 999;
1142           push @use_parts, $p;
1143         }
1144         push @use_parts, 0 while @use_parts < 3;
1145
1146         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1147       }
1148     }
1149
1150     $self->_dbh_details->{info} = $info;
1151   }
1152
1153   return $info;
1154 }
1155
1156 sub _get_server_version {
1157   shift->_dbh_get_info('SQL_DBMS_VER');
1158 }
1159
1160 sub _dbh_get_info {
1161   my ($self, $info) = @_;
1162
1163   if ($info =~ /[^0-9]/) {
1164     require DBI::Const::GetInfoType;
1165     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1166     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1167       unless defined $info;
1168   }
1169
1170   $self->_get_dbh->get_info($info);
1171 }
1172
1173 sub _describe_connection {
1174   require DBI::Const::GetInfoReturn;
1175
1176   my $self = shift;
1177
1178   my $drv;
1179   try {
1180     $drv = $self->_extract_driver_from_connect_info;
1181     $self->ensure_connected;
1182   };
1183
1184   $drv = "DBD::$drv" if $drv;
1185
1186   my $res = {
1187     DBIC_DSN => $self->_dbi_connect_info->[0],
1188     DBI_VER => DBI->VERSION,
1189     DBIC_VER => DBIx::Class->VERSION,
1190     DBIC_DRIVER => ref $self,
1191     $drv ? (
1192       DBD => $drv,
1193       DBD_VER => try { $drv->VERSION },
1194     ) : (),
1195   };
1196
1197   # try to grab data even if we never managed to connect
1198   # will cover us in cases of an oddly broken half-connect
1199   for my $inf (
1200     #keys %DBI::Const::GetInfoType::GetInfoType,
1201     qw/
1202       SQL_CURSOR_COMMIT_BEHAVIOR
1203       SQL_CURSOR_ROLLBACK_BEHAVIOR
1204       SQL_CURSOR_SENSITIVITY
1205       SQL_DATA_SOURCE_NAME
1206       SQL_DBMS_NAME
1207       SQL_DBMS_VER
1208       SQL_DEFAULT_TXN_ISOLATION
1209       SQL_DM_VER
1210       SQL_DRIVER_NAME
1211       SQL_DRIVER_ODBC_VER
1212       SQL_DRIVER_VER
1213       SQL_EXPRESSIONS_IN_ORDERBY
1214       SQL_GROUP_BY
1215       SQL_IDENTIFIER_CASE
1216       SQL_IDENTIFIER_QUOTE_CHAR
1217       SQL_MAX_CATALOG_NAME_LEN
1218       SQL_MAX_COLUMN_NAME_LEN
1219       SQL_MAX_IDENTIFIER_LEN
1220       SQL_MAX_TABLE_NAME_LEN
1221       SQL_MULTIPLE_ACTIVE_TXN
1222       SQL_MULT_RESULT_SETS
1223       SQL_NEED_LONG_DATA_LEN
1224       SQL_NON_NULLABLE_COLUMNS
1225       SQL_ODBC_VER
1226       SQL_QUALIFIER_NAME_SEPARATOR
1227       SQL_QUOTED_IDENTIFIER_CASE
1228       SQL_TXN_CAPABLE
1229       SQL_TXN_ISOLATION_OPTION
1230     /
1231   ) {
1232     # some drivers barf on things they do not know about instead
1233     # of returning undef
1234     my $v = try { $self->_dbh_get_info($inf) };
1235     next unless defined $v;
1236
1237     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1238     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1239     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1240   }
1241
1242   $res;
1243 }
1244
1245 sub _determine_driver {
1246   my ($self) = @_;
1247
1248   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1249     my $started_connected = 0;
1250     local $self->{_in_determine_driver} = 1;
1251
1252     if (ref($self) eq __PACKAGE__) {
1253       my $driver;
1254       if ($self->_dbh) { # we are connected
1255         $driver = $self->_dbh->{Driver}{Name};
1256         $started_connected = 1;
1257       }
1258       else {
1259         $driver = $self->_extract_driver_from_connect_info;
1260       }
1261
1262       if ($driver) {
1263         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1264         if ($self->load_optional_class($storage_class)) {
1265           mro::set_mro($storage_class, 'c3');
1266           bless $self, $storage_class;
1267           $self->_rebless();
1268         }
1269         else {
1270           $self->_warn_undetermined_driver(
1271             'This version of DBIC does not yet seem to supply a driver for '
1272           . "your particular RDBMS and/or connection method ('$driver')."
1273           );
1274         }
1275       }
1276       else {
1277         $self->_warn_undetermined_driver(
1278           'Unable to extract a driver name from connect info - this '
1279         . 'should not have happened.'
1280         );
1281       }
1282     }
1283
1284     $self->_driver_determined(1);
1285
1286     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1287
1288     if ($self->can('source_bind_attributes')) {
1289       $self->throw_exception(
1290         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1291       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1292       . 'If you are not sure how to proceed please contact the development team via '
1293       . DBIx::Class::_ENV_::HELP_URL
1294       );
1295     }
1296
1297     $self->_init; # run driver-specific initializations
1298
1299     $self->_run_connection_actions
1300         if !$started_connected && defined $self->_dbh;
1301   }
1302 }
1303
1304 sub _extract_driver_from_connect_info {
1305   my $self = shift;
1306
1307   my $drv;
1308
1309   # if connect_info is a CODEREF, we have no choice but to connect
1310   if (
1311     ref $self->_dbi_connect_info->[0]
1312       and
1313     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1314   ) {
1315     $self->_populate_dbh;
1316     $drv = $self->_dbh->{Driver}{Name};
1317   }
1318   else {
1319     # try to use dsn to not require being connected, the driver may still
1320     # force a connection later in _rebless to determine version
1321     # (dsn may not be supplied at all if all we do is make a mock-schema)
1322     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1323     $drv ||= $ENV{DBI_DRIVER};
1324   }
1325
1326   return $drv;
1327 }
1328
1329 sub _determine_connector_driver {
1330   my ($self, $conn) = @_;
1331
1332   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1333
1334   if (not $dbtype) {
1335     $self->_warn_undetermined_driver(
1336       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1337     . "$conn connector - this should not have happened."
1338     );
1339     return;
1340   }
1341
1342   $dbtype =~ s/\W/_/gi;
1343
1344   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1345   return if $self->isa($subclass);
1346
1347   if ($self->load_optional_class($subclass)) {
1348     bless $self, $subclass;
1349     $self->_rebless;
1350   }
1351   else {
1352     $self->_warn_undetermined_driver(
1353       'This version of DBIC does not yet seem to supply a driver for '
1354     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1355     );
1356   }
1357 }
1358
1359 sub _warn_undetermined_driver {
1360   my ($self, $msg) = @_;
1361
1362   require Data::Dumper::Concise;
1363
1364   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1365   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1366   . "does not go away, file a bugreport including the following info:\n"
1367   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1368   );
1369 }
1370
1371 sub _do_connection_actions {
1372   my $self          = shift;
1373   my $method_prefix = shift;
1374   my $call          = shift;
1375
1376   if (not ref($call)) {
1377     my $method = $method_prefix . $call;
1378     $self->$method(@_);
1379   } elsif (ref($call) eq 'CODE') {
1380     $self->$call(@_);
1381   } elsif (ref($call) eq 'ARRAY') {
1382     if (ref($call->[0]) ne 'ARRAY') {
1383       $self->_do_connection_actions($method_prefix, $_) for @$call;
1384     } else {
1385       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1386     }
1387   } else {
1388     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1389   }
1390
1391   return $self;
1392 }
1393
1394 sub connect_call_do_sql {
1395   my $self = shift;
1396   $self->_do_query(@_);
1397 }
1398
1399 sub disconnect_call_do_sql {
1400   my $self = shift;
1401   $self->_do_query(@_);
1402 }
1403
1404 =head2 connect_call_datetime_setup
1405
1406 A no-op stub method, provided so that one can always safely supply the
1407 L<connection option|/DBIx::Class specific connection attributes>
1408
1409  on_connect_call => 'datetime_setup'
1410
1411 This way one does not need to know in advance whether the underlying
1412 storage requires any sort of hand-holding when dealing with calendar
1413 data.
1414
1415 =cut
1416
1417 sub connect_call_datetime_setup { 1 }
1418
1419 sub _do_query {
1420   my ($self, $action) = @_;
1421
1422   if (ref $action eq 'CODE') {
1423     $action = $action->($self);
1424     $self->_do_query($_) foreach @$action;
1425   }
1426   else {
1427     # Most debuggers expect ($sql, @bind), so we need to exclude
1428     # the attribute hash which is the second argument to $dbh->do
1429     # furthermore the bind values are usually to be presented
1430     # as named arrayref pairs, so wrap those here too
1431     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1432     my $sql = shift @do_args;
1433     my $attrs = shift @do_args;
1434     my @bind = map { [ undef, $_ ] } @do_args;
1435
1436     $self->dbh_do(sub {
1437       $_[0]->_query_start($sql, \@bind);
1438       $_[1]->do($sql, $attrs, @do_args);
1439       $_[0]->_query_end($sql, \@bind);
1440     });
1441   }
1442
1443   return $self;
1444 }
1445
1446 sub _connect {
1447   my $self = shift;
1448
1449   my $info = $self->_dbi_connect_info;
1450
1451   $self->throw_exception("You did not provide any connection_info")
1452     unless defined $info->[0];
1453
1454   my ($old_connect_via, $dbh);
1455
1456   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1457
1458   # this odd anonymous coderef dereference is in fact really
1459   # necessary to avoid the unwanted effect described in perl5
1460   # RT#75792
1461   #
1462   # in addition the coderef itself can't reside inside the try{} block below
1463   # as it somehow triggers a leak under perl -d
1464   my $dbh_error_handler_installer = sub {
1465     weaken (my $weak_self = $_[0]);
1466
1467     # the coderef is blessed so we can distinguish it from externally
1468     # supplied handles (which must be preserved)
1469     $_[1]->{HandleError} = bless sub {
1470       if ($weak_self) {
1471         $weak_self->throw_exception("DBI Exception: $_[0]");
1472       }
1473       else {
1474         # the handler may be invoked by something totally out of
1475         # the scope of DBIC
1476         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1477       }
1478     }, '__DBIC__DBH__ERROR__HANDLER__';
1479   };
1480
1481   try {
1482     if(ref $info->[0] eq 'CODE') {
1483       $dbh = $info->[0]->();
1484     }
1485     else {
1486       require DBI;
1487       $dbh = DBI->connect(@$info);
1488     }
1489
1490     die $DBI::errstr unless $dbh;
1491
1492     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1493       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1494       . 'not continue',
1495       ref $info->[0] eq 'CODE'
1496         ? "Connection coderef $info->[0] returned a"
1497         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1498     ) unless $dbh->FETCH('Active');
1499
1500     # sanity checks unless asked otherwise
1501     unless ($self->unsafe) {
1502
1503       $self->throw_exception(
1504         'Refusing clobbering of {HandleError} installed on externally supplied '
1505        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1506       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1507
1508       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1509       # request, or an external handle. Complain and set anyway
1510       unless ($dbh->{RaiseError}) {
1511         carp( ref $info->[0] eq 'CODE'
1512
1513           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1514            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1515            .'attribute has been supplied'
1516
1517           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1518            .'unsafe => 1. Toggling RaiseError back to true'
1519         );
1520
1521         $dbh->{RaiseError} = 1;
1522       }
1523
1524       $dbh_error_handler_installer->($self, $dbh);
1525     }
1526   }
1527   catch {
1528     $self->throw_exception("DBI Connection failed: $_")
1529   };
1530
1531   $self->_dbh_autocommit($dbh->{AutoCommit});
1532   return $dbh;
1533 }
1534
1535 sub txn_begin {
1536   # this means we have not yet connected and do not know the AC status
1537   # (e.g. coderef $dbh), need a full-fledged connection check
1538   if (! defined $_[0]->_dbh_autocommit) {
1539     $_[0]->ensure_connected;
1540   }
1541   # Otherwise simply connect or re-connect on pid changes
1542   else {
1543     $_[0]->_get_dbh;
1544   }
1545
1546   shift->next::method(@_);
1547 }
1548
1549 sub _exec_txn_begin {
1550   my $self = shift;
1551
1552   # if the user is utilizing txn_do - good for him, otherwise we need to
1553   # ensure that the $dbh is healthy on BEGIN.
1554   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1555   # will be replaced by a failure of begin_work itself (which will be
1556   # then retried on reconnect)
1557   if ($self->{_in_do_block}) {
1558     $self->_dbh->begin_work;
1559   } else {
1560     $self->dbh_do(sub { $_[1]->begin_work });
1561   }
1562 }
1563
1564 sub txn_commit {
1565   my $self = shift;
1566
1567   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1568     unless $self->_seems_connected;
1569
1570   # esoteric case for folks using external $dbh handles
1571   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1572     carp "Storage transaction_depth 0 does not match "
1573         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1574     $self->transaction_depth(1);
1575   }
1576
1577   $self->next::method(@_);
1578
1579   # if AutoCommit is disabled txn_depth never goes to 0
1580   # as a new txn is started immediately on commit
1581   $self->transaction_depth(1) if (
1582     !$self->transaction_depth
1583       and
1584     defined $self->_dbh_autocommit
1585       and
1586     ! $self->_dbh_autocommit
1587   );
1588 }
1589
1590 sub _exec_txn_commit {
1591   shift->_dbh->commit;
1592 }
1593
1594 sub txn_rollback {
1595   my $self = shift;
1596
1597   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1598     unless $self->_seems_connected;
1599
1600   # esoteric case for folks using external $dbh handles
1601   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1602     carp "Storage transaction_depth 0 does not match "
1603         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1604     $self->transaction_depth(1);
1605   }
1606
1607   $self->next::method(@_);
1608
1609   # if AutoCommit is disabled txn_depth never goes to 0
1610   # as a new txn is started immediately on commit
1611   $self->transaction_depth(1) if (
1612     !$self->transaction_depth
1613       and
1614     defined $self->_dbh_autocommit
1615       and
1616     ! $self->_dbh_autocommit
1617   );
1618 }
1619
1620 sub _exec_txn_rollback {
1621   shift->_dbh->rollback;
1622 }
1623
1624 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1625 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1626   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1627     unless $_[0]->_seems_connected;
1628   shift->next::method(@_);
1629 EOS
1630
1631 # This used to be the top-half of _execute.  It was split out to make it
1632 #  easier to override in NoBindVars without duping the rest.  It takes up
1633 #  all of _execute's args, and emits $sql, @bind.
1634 sub _prep_for_execute {
1635   #my ($self, $op, $ident, $args) = @_;
1636   return shift->_gen_sql_bind(@_)
1637 }
1638
1639 sub _gen_sql_bind {
1640   my ($self, $op, $ident, $args) = @_;
1641
1642   my ($colinfos, $from);
1643   if ( blessed($ident) ) {
1644     $from = $ident->from;
1645     $colinfos = $ident->columns_info;
1646   }
1647
1648   my ($sql, $bind);
1649   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1650
1651   $bind = $self->_resolve_bindattrs(
1652     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1653   );
1654
1655   if (
1656     ! $ENV{DBIC_DT_SEARCH_OK}
1657       and
1658     $op eq 'select'
1659       and
1660     first {
1661       length ref $_->[1]
1662         and
1663       blessed($_->[1])
1664         and
1665       $_->[1]->isa('DateTime')
1666     } @$bind
1667   ) {
1668     carp_unique 'DateTime objects passed to search() are not supported '
1669       . 'properly (InflateColumn::DateTime formats and settings are not '
1670       . 'respected.) See "Formatting DateTime objects in queries" in '
1671       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1672       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1673   }
1674
1675   return( $sql, $bind );
1676 }
1677
1678 sub _resolve_bindattrs {
1679   my ($self, $ident, $bind, $colinfos) = @_;
1680
1681   my $resolve_bindinfo = sub {
1682     #my $infohash = shift;
1683
1684     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1685
1686     my $ret;
1687     if (my $col = $_[0]->{dbic_colname}) {
1688       $ret = { %{$_[0]} };
1689
1690       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1691         if $colinfos->{$col}{data_type};
1692
1693       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1694         if $colinfos->{$col}{size};
1695     }
1696
1697     $ret || $_[0];
1698   };
1699
1700   return [ map {
1701     my $resolved =
1702       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1703     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1704     : (ref $_->[0] eq 'HASH')           ? [(
1705                                             ! keys %{$_->[0]}
1706                                               or
1707                                             exists $_->[0]{dbd_attrs}
1708                                               or
1709                                             $_->[0]{sqlt_datatype}
1710                                            ) ? $_->[0]
1711                                              : $resolve_bindinfo->($_->[0])
1712                                            , $_->[1]
1713                                           ]
1714     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1715     :                                     [ $resolve_bindinfo->(
1716                                               { dbic_colname => $_->[0] }
1717                                             ), $_->[1] ]
1718     ;
1719
1720     if (
1721       ! exists $resolved->[0]{dbd_attrs}
1722         and
1723       ! $resolved->[0]{sqlt_datatype}
1724         and
1725       length ref $resolved->[1]
1726         and
1727       ! is_plain_value $resolved->[1]
1728     ) {
1729       require Data::Dumper;
1730       local $Data::Dumper::Maxdepth = 1;
1731       local $Data::Dumper::Terse = 1;
1732       local $Data::Dumper::Useqq = 1;
1733       local $Data::Dumper::Indent = 0;
1734       local $Data::Dumper::Pad = ' ';
1735       $self->throw_exception(
1736         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1737       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1738       );
1739     }
1740
1741     $resolved;
1742
1743   } @$bind ];
1744 }
1745
1746 sub _format_for_trace {
1747   #my ($self, $bind) = @_;
1748
1749   ### Turn @bind from something like this:
1750   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1751   ### to this:
1752   ###   ( "'1'", "'3'" )
1753
1754   map {
1755     defined( $_ && $_->[1] )
1756       ? qq{'$_->[1]'}
1757       : q{NULL}
1758   } @{$_[1] || []};
1759 }
1760
1761 sub _query_start {
1762   my ( $self, $sql, $bind ) = @_;
1763
1764   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1765     if $self->debug;
1766 }
1767
1768 sub _query_end {
1769   my ( $self, $sql, $bind ) = @_;
1770
1771   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1772     if $self->debug;
1773 }
1774
1775 sub _dbi_attrs_for_bind {
1776   #my ($self, $ident, $bind) = @_;
1777
1778   return [ map {
1779
1780     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1781
1782   : ! $_->{sqlt_datatype}   ? undef
1783
1784   :                           do {
1785
1786     # cache the result in the dbh_details hash, as it (usually) can not change
1787     # unless we connect to something else
1788     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1789     # the LOB storage
1790     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1791
1792     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1793       if ! exists $cache->{$_->{sqlt_datatype}};
1794
1795     $cache->{$_->{sqlt_datatype}};
1796
1797   } } map { $_->[0] } @{$_[2]} ];
1798 }
1799
1800 sub _execute {
1801   my ($self, $op, $ident, @args) = @_;
1802
1803   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1804
1805   # not even a PID check - we do not care about the state of the _dbh.
1806   # All we need is to get the appropriate drivers loaded if they aren't
1807   # already so that the assumption in ad7c50fc26e holds
1808   $self->_populate_dbh unless $self->_dbh;
1809
1810   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1811     $sql,
1812     $bind,
1813     $self->_dbi_attrs_for_bind($ident, $bind),
1814   );
1815 }
1816
1817 sub _dbh_execute {
1818   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1819
1820   $self->_query_start( $sql, $bind );
1821
1822   my $sth = $self->_bind_sth_params(
1823     $self->_prepare_sth($dbh, $sql),
1824     $bind,
1825     $bind_attrs,
1826   );
1827
1828   # Can this fail without throwing an exception anyways???
1829   my $rv = $sth->execute();
1830   $self->throw_exception(
1831     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1832   ) if !$rv;
1833
1834   $self->_query_end( $sql, $bind );
1835
1836   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1837 }
1838
1839 sub _prepare_sth {
1840   my ($self, $dbh, $sql) = @_;
1841
1842   # 3 is the if_active parameter which avoids active sth re-use
1843   my $sth = $self->disable_sth_caching
1844     ? $dbh->prepare($sql)
1845     : $dbh->prepare_cached($sql, {}, 3);
1846
1847   # XXX You would think RaiseError would make this impossible,
1848   #  but apparently that's not true :(
1849   $self->throw_exception(
1850     $dbh->errstr
1851       ||
1852     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1853             .'an exception and/or setting $dbh->errstr',
1854       length ($sql) > 20
1855         ? substr($sql, 0, 20) . '...'
1856         : $sql
1857       ,
1858       'DBD::' . $dbh->{Driver}{Name},
1859     )
1860   ) if !$sth;
1861
1862   $sth;
1863 }
1864
1865 sub _bind_sth_params {
1866   my ($self, $sth, $bind, $bind_attrs) = @_;
1867
1868   for my $i (0 .. $#$bind) {
1869     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1870       $sth->bind_param_inout(
1871         $i + 1, # bind params counts are 1-based
1872         $bind->[$i][1],
1873         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1874         $bind_attrs->[$i],
1875       );
1876     }
1877     else {
1878       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1879       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1880         ? "$bind->[$i][1]"
1881         : $bind->[$i][1]
1882       ;
1883
1884       $sth->bind_param(
1885         $i + 1,
1886         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1887         $v,
1888         $bind_attrs->[$i],
1889       );
1890     }
1891   }
1892
1893   $sth;
1894 }
1895
1896 sub _prefetch_autovalues {
1897   my ($self, $source, $colinfo, $to_insert) = @_;
1898
1899   my %values;
1900   for my $col (keys %$colinfo) {
1901     if (
1902       $colinfo->{$col}{auto_nextval}
1903         and
1904       (
1905         ! exists $to_insert->{$col}
1906           or
1907         is_literal_value($to_insert->{$col})
1908       )
1909     ) {
1910       $values{$col} = $self->_sequence_fetch(
1911         'NEXTVAL',
1912         ( $colinfo->{$col}{sequence} ||=
1913             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1914         ),
1915       );
1916     }
1917   }
1918
1919   \%values;
1920 }
1921
1922 sub insert {
1923   my ($self, $source, $to_insert) = @_;
1924
1925   my $col_infos = $source->columns_info;
1926
1927   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1928
1929   # fuse the values, but keep a separate list of prefetched_values so that
1930   # they can be fused once again with the final return
1931   $to_insert = { %$to_insert, %$prefetched_values };
1932
1933   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1934   # Investigate what does it take to s/defined/exists/
1935   my %pcols = map { $_ => 1 } $source->primary_columns;
1936   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1937   for my $col ($source->columns) {
1938     if ($col_infos->{$col}{is_auto_increment}) {
1939       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1940       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1941     }
1942
1943     # nothing to retrieve when explicit values are supplied
1944     next if (
1945       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1946     );
1947
1948     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1949     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1950       $pcols{$col}
1951         or
1952       $col_infos->{$col}{retrieve_on_insert}
1953     );
1954   };
1955
1956   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1957   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1958
1959   my ($sqla_opts, @ir_container);
1960   if (%retrieve_cols and $self->_use_insert_returning) {
1961     $sqla_opts->{returning_container} = \@ir_container
1962       if $self->_use_insert_returning_bound;
1963
1964     $sqla_opts->{returning} = [
1965       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1966     ];
1967   }
1968
1969   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1970
1971   my %returned_cols = %$to_insert;
1972   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1973     @ir_container = try {
1974       local $SIG{__WARN__} = sub {};
1975       my @r = $sth->fetchrow_array;
1976       $sth->finish;
1977       @r;
1978     } unless @ir_container;
1979
1980     @returned_cols{@$retlist} = @ir_container if @ir_container;
1981   }
1982   else {
1983     # pull in PK if needed and then everything else
1984     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1985
1986       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1987         unless $self->can('last_insert_id');
1988
1989       my @pri_values = $self->last_insert_id($source, @missing_pri);
1990
1991       $self->throw_exception( "Can't get last insert id" )
1992         unless (@pri_values == @missing_pri);
1993
1994       @returned_cols{@missing_pri} = @pri_values;
1995       delete @retrieve_cols{@missing_pri};
1996     }
1997
1998     # if there is more left to pull
1999     if (%retrieve_cols) {
2000       $self->throw_exception(
2001         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2002       ) unless %pcols;
2003
2004       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2005
2006       my $cur = DBIx::Class::ResultSet->new($source, {
2007         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2008         select => \@left_to_fetch,
2009       })->cursor;
2010
2011       @returned_cols{@left_to_fetch} = $cur->next;
2012
2013       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2014         if scalar $cur->next;
2015     }
2016   }
2017
2018   return { %$prefetched_values, %returned_cols };
2019 }
2020
2021 sub insert_bulk {
2022   carp_unique(
2023     'insert_bulk() should have never been exposed as a public method and '
2024   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2025   . 'use for this method please contact the development team via '
2026   . DBIx::Class::_ENV_::HELP_URL
2027   );
2028
2029   return '0E0' unless @{$_[3]||[]};
2030
2031   shift->_insert_bulk(@_);
2032 }
2033
2034 sub _insert_bulk {
2035   my ($self, $source, $cols, $data) = @_;
2036
2037   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2038     unless @{$data||[]};
2039
2040   my $colinfos = $source->columns_info($cols);
2041
2042   local $self->{_autoinc_supplied_for_op} =
2043     (grep { $_->{is_auto_increment} } values %$colinfos)
2044       ? 1
2045       : 0
2046   ;
2047
2048   # get a slice type index based on first row of data
2049   # a "column" in this context may refer to more than one bind value
2050   # e.g. \[ '?, ?', [...], [...] ]
2051   #
2052   # construct the value type index - a description of values types for every
2053   # per-column slice of $data:
2054   #
2055   # nonexistent - nonbind literal
2056   # 0 - regular value
2057   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2058   #
2059   # also construct the column hash to pass to the SQL generator. For plain
2060   # (non literal) values - convert the members of the first row into a
2061   # literal+bind combo, with extra positional info in the bind attr hashref.
2062   # This will allow us to match the order properly, and is so contrived
2063   # because a user-supplied literal/bind (or something else specific to a
2064   # resultsource and/or storage driver) can inject extra binds along the
2065   # way, so one can't rely on "shift positions" ordering at all. Also we
2066   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2067   # can be later matched up by address), because we want to supply a real
2068   # value on which perhaps e.g. datatype checks will be performed
2069   my ($proto_data, $serialized_bind_type_by_col_idx);
2070   for my $col_idx (0..$#$cols) {
2071     my $colname = $cols->[$col_idx];
2072     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2073       # no bind value at all - no type
2074
2075       $proto_data->{$colname} = $data->[0][$col_idx];
2076     }
2077     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2078       # repack, so we don't end up mangling the original \[]
2079       my ($sql, @bind) = @${$data->[0][$col_idx]};
2080
2081       # normalization of user supplied stuff
2082       my $resolved_bind = $self->_resolve_bindattrs(
2083         $source, \@bind, $colinfos,
2084       );
2085
2086       # store value-less (attrs only) bind info - we will be comparing all
2087       # supplied binds against this for sanity
2088       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2089
2090       $proto_data->{$colname} = \[ $sql, map { [
2091         # inject slice order to use for $proto_bind construction
2092           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2093             =>
2094           $resolved_bind->[$_][1]
2095         ] } (0 .. $#bind)
2096       ];
2097     }
2098     else {
2099       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2100
2101       $proto_data->{$colname} = \[ '?', [
2102         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2103           =>
2104         $data->[0][$col_idx]
2105       ] ];
2106     }
2107   }
2108
2109   my ($sql, $proto_bind) = $self->_prep_for_execute (
2110     'insert',
2111     $source,
2112     [ $proto_data ],
2113   );
2114
2115   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2116     # if the bindlist is empty and we had some dynamic binds, this means the
2117     # storage ate them away (e.g. the NoBindVars component) and interpolated
2118     # them directly into the SQL. This obviously can't be good for multi-inserts
2119     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2120   }
2121
2122   # sanity checks
2123   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2124   #
2125   # use an error reporting closure for convenience (less to pass)
2126   my $bad_slice_report_cref = sub {
2127     my ($msg, $r_idx, $c_idx) = @_;
2128     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2129       $msg,
2130       $cols->[$c_idx],
2131       do {
2132         require Data::Dumper::Concise;
2133         local $Data::Dumper::Maxdepth = 5;
2134         Data::Dumper::Concise::Dumper ({
2135           map { $cols->[$_] =>
2136             $data->[$r_idx][$_]
2137           } 0..$#$cols
2138         }),
2139       }
2140     );
2141   };
2142
2143   for my $col_idx (0..$#$cols) {
2144     my $reference_val = $data->[0][$col_idx];
2145
2146     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2147       my $val = $data->[$row_idx][$col_idx];
2148
2149       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2150         if (ref $val ne 'SCALAR') {
2151           $bad_slice_report_cref->(
2152             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2153             $row_idx,
2154             $col_idx,
2155           );
2156         }
2157         elsif ($$val ne $$reference_val) {
2158           $bad_slice_report_cref->(
2159             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2160             $row_idx,
2161             $col_idx,
2162           );
2163         }
2164       }
2165       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2166         if (is_literal_value($val)) {
2167           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2168         }
2169       }
2170       else {  # binds from a \[], compare type and attrs
2171         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2172           $bad_slice_report_cref->(
2173             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2174             $row_idx,
2175             $col_idx,
2176           );
2177         }
2178         # start drilling down and bail out early on identical refs
2179         elsif (
2180           $reference_val != $val
2181             or
2182           $$reference_val != $$val
2183         ) {
2184           if (${$val}->[0] ne ${$reference_val}->[0]) {
2185             $bad_slice_report_cref->(
2186               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2187               $row_idx,
2188               $col_idx,
2189             );
2190           }
2191           # need to check the bind attrs - a bind will happen only once for
2192           # the entire dataset, so any changes further down will be ignored.
2193           elsif (
2194             $serialized_bind_type_by_col_idx->{$col_idx}
2195               ne
2196             serialize [
2197               map
2198               { $_->[0] }
2199               @{$self->_resolve_bindattrs(
2200                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2201               )}
2202             ]
2203           ) {
2204             $bad_slice_report_cref->(
2205               'Differing bind attributes on literal/bind values not supported',
2206               $row_idx,
2207               $col_idx,
2208             );
2209           }
2210         }
2211       }
2212     }
2213   }
2214
2215   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2216   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2217   # scope guard
2218   my $guard = $self->txn_scope_guard;
2219
2220   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2221   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2222   my $rv = do {
2223     if (@$proto_bind) {
2224       # proto bind contains the information on which pieces of $data to pull
2225       # $cols is passed in only for prettier error-reporting
2226       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2227     }
2228     else {
2229       # bind_param_array doesn't work if there are no binds
2230       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2231     }
2232   };
2233
2234   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2235
2236   $guard->commit;
2237
2238   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2239 }
2240
2241 # execute_for_fetch is capable of returning data just fine (it means it
2242 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2243 # is the void-populate fast-path we will just ignore this altogether
2244 # for the time being.
2245 sub _dbh_execute_for_fetch {
2246   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2247
2248   # If we have any bind attributes to take care of, we will bind the
2249   # proto-bind data (which will never be used by execute_for_fetch)
2250   # However since column bindtypes are "sticky", this is sufficient
2251   # to get the DBD to apply the bindtype to all values later on
2252   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2253
2254   for my $i (0 .. $#$proto_bind) {
2255     $sth->bind_param (
2256       $i+1, # DBI bind indexes are 1-based
2257       $proto_bind->[$i][1],
2258       $bind_attrs->[$i],
2259     ) if defined $bind_attrs->[$i];
2260   }
2261
2262   # At this point $data slots named in the _bind_data_slice_idx of
2263   # each piece of $proto_bind are either \[]s or plain values to be
2264   # passed in. Construct the dispensing coderef. *NOTE* the order
2265   # of $data will differ from this of the ?s in the SQL (due to
2266   # alphabetical ordering by colname). We actually do want to
2267   # preserve this behavior so that prepare_cached has a better
2268   # chance of matching on unrelated calls
2269
2270   my $fetch_row_idx = -1; # saner loop this way
2271   my $fetch_tuple = sub {
2272     return undef if ++$fetch_row_idx > $#$data;
2273
2274     return [ map {
2275       my $v = ! defined $_->{_literal_bind_subindex}
2276
2277         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2278
2279         # There are no attributes to resolve here - we already did everything
2280         # when we constructed proto_bind. However we still want to sanity-check
2281         # what the user supplied, so pass stuff through to the resolver *anyway*
2282         : $self->_resolve_bindattrs (
2283             undef,  # a fake rsrc
2284             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2285             {},     # a fake column_info bag
2286           )->[0][1]
2287       ;
2288
2289       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2290       # For the time being forcibly stringify whatever is stringifiable
2291       (length ref $v and is_plain_value $v)
2292         ? "$v"
2293         : $v
2294       ;
2295     } map { $_->[0] } @$proto_bind ];
2296   };
2297
2298   my $tuple_status = [];
2299   my ($rv, $err);
2300   try {
2301     $rv = $sth->execute_for_fetch(
2302       $fetch_tuple,
2303       $tuple_status,
2304     );
2305   }
2306   catch {
2307     $err = shift;
2308   };
2309
2310   # Not all DBDs are create equal. Some throw on error, some return
2311   # an undef $rv, and some set $sth->err - try whatever we can
2312   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2313     ! defined $err
2314       and
2315     ( !defined $rv or $sth->err )
2316   );
2317
2318   # Statement must finish even if there was an exception.
2319   try {
2320     $sth->finish
2321   }
2322   catch {
2323     $err = shift unless defined $err
2324   };
2325
2326   if (defined $err) {
2327     my $i = 0;
2328     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2329
2330     $self->throw_exception("Unexpected populate error: $err")
2331       if ($i > $#$tuple_status);
2332
2333     require Data::Dumper::Concise;
2334     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2335       ($tuple_status->[$i][1] || $err),
2336       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2337     );
2338   }
2339
2340   return $rv;
2341 }
2342
2343 sub _dbh_execute_inserts_with_no_binds {
2344   my ($self, $sth, $count) = @_;
2345
2346   my $err;
2347   try {
2348     my $dbh = $self->_get_dbh;
2349     local $dbh->{RaiseError} = 1;
2350     local $dbh->{PrintError} = 0;
2351
2352     $sth->execute foreach 1..$count;
2353   }
2354   catch {
2355     $err = shift;
2356   };
2357
2358   # Make sure statement is finished even if there was an exception.
2359   try {
2360     $sth->finish
2361   }
2362   catch {
2363     $err = shift unless defined $err;
2364   };
2365
2366   $self->throw_exception($err) if defined $err;
2367
2368   return $count;
2369 }
2370
2371 sub update {
2372   #my ($self, $source, @args) = @_;
2373   shift->_execute('update', @_);
2374 }
2375
2376
2377 sub delete {
2378   #my ($self, $source, @args) = @_;
2379   shift->_execute('delete', @_);
2380 }
2381
2382 sub _select {
2383   my $self = shift;
2384   $self->_execute($self->_select_args(@_));
2385 }
2386
2387 sub _select_args_to_query {
2388   my $self = shift;
2389
2390   $self->throw_exception(
2391     "Unable to generate limited query representation with 'software_limit' enabled"
2392   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2393
2394   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2395   #  = $self->_select_args($ident, $select, $cond, $attrs);
2396   my ($op, $ident, @args) =
2397     $self->_select_args(@_);
2398
2399   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2400   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2401
2402   # reuse the bind arrayref
2403   unshift @{$bind}, "($sql)";
2404   \$bind;
2405 }
2406
2407 sub _select_args {
2408   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2409
2410   # FIXME - that kind of caching would be nice to have
2411   # however currently we *may* pass the same $orig_attrs
2412   # with different ident/select/where
2413   # the whole interface needs to be rethought, since it
2414   # was centered around the flawed SQLA API. We can do
2415   # soooooo much better now. But that is also another
2416   # battle...
2417   #return (
2418   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2419   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2420
2421   my $sql_maker = $self->sql_maker;
2422
2423   my $attrs = {
2424     %$orig_attrs,
2425     select => $select,
2426     from => $ident,
2427     where => $where,
2428   };
2429
2430   # Sanity check the attributes (SQLMaker does it too, but
2431   # in case of a software_limit we'll never reach there)
2432   if (defined $attrs->{offset}) {
2433     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2434       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2435   }
2436
2437   if (defined $attrs->{rows}) {
2438     $self->throw_exception("The rows attribute must be a positive integer if present")
2439       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2440   }
2441   elsif ($attrs->{offset}) {
2442     # MySQL actually recommends this approach.  I cringe.
2443     $attrs->{rows} = $sql_maker->__max_int;
2444   }
2445
2446   # see if we will need to tear the prefetch apart to satisfy group_by == select
2447   # this is *extremely tricky* to get right, I am still not sure I did
2448   #
2449   my ($prefetch_needs_subquery, @limit_args);
2450
2451   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2452     # we already know there is a valid group_by (we made it) and we know it is
2453     # intended to be based *only* on non-multi stuff
2454     # short circuit the group_by parsing below
2455     $prefetch_needs_subquery = 1;
2456   }
2457   elsif (
2458     # The rationale is that even if we do *not* have collapse, we still
2459     # need to wrap the core grouped select/group_by in a subquery
2460     # so that databases that care about group_by/select equivalence
2461     # are happy (this includes MySQL in strict_mode)
2462     # If any of the other joined tables are referenced in the group_by
2463     # however - the user is on their own
2464     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2465       and
2466     $attrs->{group_by}
2467       and
2468     @{$attrs->{group_by}}
2469       and
2470     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2471       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2472     }
2473   ) {
2474     # no aliases other than our own in group_by
2475     # if there are - do not allow subquery even if limit is present
2476     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2477   }
2478   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2479     # active collapse with a limit - that one is a no-brainer unless
2480     # overruled by a group_by above
2481     $prefetch_needs_subquery = 1;
2482   }
2483
2484   if ($prefetch_needs_subquery) {
2485     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2486   }
2487   elsif (! $attrs->{software_limit} ) {
2488     push @limit_args, (
2489       $attrs->{rows} || (),
2490       $attrs->{offset} || (),
2491     );
2492   }
2493
2494   # try to simplify the joinmap further (prune unreferenced type-single joins)
2495   if (
2496     ! $prefetch_needs_subquery  # already pruned
2497       and
2498     ref $attrs->{from}
2499       and
2500     reftype $attrs->{from} eq 'ARRAY'
2501       and
2502     @{$attrs->{from}} != 1
2503   ) {
2504     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2505   }
2506
2507   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2508   # during the result inflation stage we *need* to know what was the aliastype
2509   # map as sqla saw it when the final pieces of SQL were being assembled
2510   # Originally we simply carried around the entirety of $attrs, but this
2511   # resulted in resultsets that are being reused growing continuously, as
2512   # the hash in question grew deeper and deeper.
2513   # Instead hand-pick what to take with us here (we actually don't need much
2514   # at this point just the map itself)
2515   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2516
2517 ###
2518   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2519   #
2520   # This would be the point to deflate anything found in $attrs->{where}
2521   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2522   # expect a result object. And all we have is a resultsource (it is trivial
2523   # to extract deflator coderefs via $alias2source above).
2524   #
2525   # I don't see a way forward other than changing the way deflators are
2526   # invoked, and that's just bad...
2527 ###
2528
2529   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2530 }
2531
2532 # Returns a counting SELECT for a simple count
2533 # query. Abstracted so that a storage could override
2534 # this to { count => 'firstcol' } or whatever makes
2535 # sense as a performance optimization
2536 sub _count_select {
2537   #my ($self, $source, $rs_attrs) = @_;
2538   return { count => '*' };
2539 }
2540
2541 =head2 select
2542
2543 =over 4
2544
2545 =item Arguments: $ident, $select, $condition, $attrs
2546
2547 =back
2548
2549 Handle a SQL select statement.
2550
2551 =cut
2552
2553 sub select {
2554   my $self = shift;
2555   my ($ident, $select, $condition, $attrs) = @_;
2556   return $self->cursor_class->new($self, \@_, $attrs);
2557 }
2558
2559 sub select_single {
2560   my $self = shift;
2561   my ($rv, $sth, @bind) = $self->_select(@_);
2562   my @row = $sth->fetchrow_array;
2563   my @nextrow = $sth->fetchrow_array if @row;
2564   if(@row && @nextrow) {
2565     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2566   }
2567   # Need to call finish() to work round broken DBDs
2568   $sth->finish();
2569   return @row;
2570 }
2571
2572 =head2 sql_limit_dialect
2573
2574 This is an accessor for the default SQL limit dialect used by a particular
2575 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2576 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2577 see L<DBIx::Class::SQLMaker::LimitDialects>.
2578
2579 =cut
2580
2581 sub _dbh_columns_info_for {
2582   my ($self, $dbh, $table) = @_;
2583
2584   my %result;
2585
2586   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2587     try {
2588       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2589       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2590       $sth->execute();
2591       while ( my $info = $sth->fetchrow_hashref() ){
2592         my %column_info;
2593         $column_info{data_type}   = $info->{TYPE_NAME};
2594         $column_info{size}      = $info->{COLUMN_SIZE};
2595         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2596         $column_info{default_value} = $info->{COLUMN_DEF};
2597         my $col_name = $info->{COLUMN_NAME};
2598         $col_name =~ s/^\"(.*)\"$/$1/;
2599
2600         $result{$col_name} = \%column_info;
2601       }
2602     } catch {
2603       %result = ();
2604     };
2605
2606     return \%result if keys %result;
2607   }
2608
2609   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2610   $sth->execute;
2611
2612 ### The acrobatics with lc names is necessary to support both the legacy
2613 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2614 ### with column names differing in cas eonly (thanks pg!)
2615
2616   my ($columns, $seen_lcs);
2617
2618   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2619     idx => scalar keys %$columns,
2620     name => $_,
2621     lc_name => lc($_),
2622   } for @{$sth->{NAME}};
2623
2624   $seen_lcs->{$_->{lc_name}} == 1
2625     and
2626   $_->{name} = $_->{lc_name}
2627     for values %$columns;
2628
2629   for ( values %$columns ) {
2630     my $inf = {
2631       data_type => $sth->{TYPE}->[$_->{idx}],
2632       size => $sth->{PRECISION}->[$_->{idx}],
2633       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2634     };
2635
2636     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2637       @{$inf}{qw( data_type  size)} = ($1, $2);
2638     }
2639
2640     $result{$_->{name}} = $inf;
2641   }
2642
2643   $sth->finish;
2644
2645   if ($dbh->can('type_info')) {
2646     for my $inf (values %result) {
2647       next if ! defined $inf->{data_type};
2648
2649       $inf->{data_type} = (
2650         (
2651           (
2652             $dbh->type_info( $inf->{data_type} )
2653               ||
2654             next
2655           )
2656             ||
2657           next
2658         )->{TYPE_NAME}
2659           ||
2660         next
2661       );
2662
2663       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2664       # needs more testing in the future...
2665       $inf->{size} -= 4 if (
2666         ( $inf->{size}||0 > 4 )
2667           and
2668         $inf->{data_type} =~ qr/^text$/i
2669       );
2670     }
2671
2672   }
2673
2674   return \%result;
2675 }
2676
2677 sub columns_info_for {
2678   my ($self, $table) = @_;
2679   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2680 }
2681
2682 =head2 last_insert_id
2683
2684 Return the row id of the last insert.
2685
2686 =cut
2687
2688 sub _dbh_last_insert_id {
2689     my ($self, $dbh, $source, $col) = @_;
2690
2691     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2692
2693     return $id if defined $id;
2694
2695     my $class = ref $self;
2696     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2697 }
2698
2699 sub last_insert_id {
2700   my $self = shift;
2701   $self->_dbh_last_insert_id ($self->_dbh, @_);
2702 }
2703
2704 =head2 _native_data_type
2705
2706 =over 4
2707
2708 =item Arguments: $type_name
2709
2710 =back
2711
2712 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2713 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2714 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2715
2716 The default implementation returns C<undef>, implement in your Storage driver if
2717 you need this functionality.
2718
2719 Should map types from other databases to the native RDBMS type, for example
2720 C<VARCHAR2> to C<VARCHAR>.
2721
2722 Types with modifiers should map to the underlying data type. For example,
2723 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2724
2725 Composite types should map to the container type, for example
2726 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2727
2728 =cut
2729
2730 sub _native_data_type {
2731   #my ($self, $data_type) = @_;
2732   return undef
2733 }
2734
2735 # Check if placeholders are supported at all
2736 sub _determine_supports_placeholders {
2737   my $self = shift;
2738   my $dbh  = $self->_get_dbh;
2739
2740   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2741   # but it is inaccurate more often than not
2742   return try {
2743     local $dbh->{PrintError} = 0;
2744     local $dbh->{RaiseError} = 1;
2745     $dbh->do('select ?', {}, 1);
2746     1;
2747   }
2748   catch {
2749     0;
2750   };
2751 }
2752
2753 # Check if placeholders bound to non-string types throw exceptions
2754 #
2755 sub _determine_supports_typeless_placeholders {
2756   my $self = shift;
2757   my $dbh  = $self->_get_dbh;
2758
2759   return try {
2760     local $dbh->{PrintError} = 0;
2761     local $dbh->{RaiseError} = 1;
2762     # this specifically tests a bind that is NOT a string
2763     $dbh->do('select 1 where 1 = ?', {}, 1);
2764     1;
2765   }
2766   catch {
2767     0;
2768   };
2769 }
2770
2771 =head2 sqlt_type
2772
2773 Returns the database driver name.
2774
2775 =cut
2776
2777 sub sqlt_type {
2778   shift->_get_dbh->{Driver}->{Name};
2779 }
2780
2781 =head2 bind_attribute_by_data_type
2782
2783 Given a datatype from column info, returns a database specific bind
2784 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2785 let the database planner just handle it.
2786
2787 This method is always called after the driver has been determined and a DBI
2788 connection has been established. Therefore you can refer to C<DBI::$constant>
2789 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2790 the correct modules.
2791
2792 =cut
2793
2794 sub bind_attribute_by_data_type {
2795     return;
2796 }
2797
2798 =head2 is_datatype_numeric
2799
2800 Given a datatype from column_info, returns a boolean value indicating if
2801 the current RDBMS considers it a numeric value. This controls how
2802 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2803 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2804 be performed instead of the usual C<eq>.
2805
2806 =cut
2807
2808 sub is_datatype_numeric {
2809   #my ($self, $dt) = @_;
2810
2811   return 0 unless $_[1];
2812
2813   $_[1] =~ /^ (?:
2814     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2815   ) $/ix;
2816 }
2817
2818
2819 =head2 create_ddl_dir
2820
2821 =over 4
2822
2823 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2824
2825 =back
2826
2827 Creates a SQL file based on the Schema, for each of the specified
2828 database engines in C<\@databases> in the given directory.
2829 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2830
2831 Given a previous version number, this will also create a file containing
2832 the ALTER TABLE statements to transform the previous schema into the
2833 current one. Note that these statements may contain C<DROP TABLE> or
2834 C<DROP COLUMN> statements that can potentially destroy data.
2835
2836 The file names are created using the C<ddl_filename> method below, please
2837 override this method in your schema if you would like a different file
2838 name format. For the ALTER file, the same format is used, replacing
2839 $version in the name with "$preversion-$version".
2840
2841 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2842 The most common value for this would be C<< { add_drop_table => 1 } >>
2843 to have the SQL produced include a C<DROP TABLE> statement for each table
2844 created. For quoting purposes supply C<quote_identifiers>.
2845
2846 If no arguments are passed, then the following default values are assumed:
2847
2848 =over 4
2849
2850 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2851
2852 =item version    - $schema->schema_version
2853
2854 =item directory  - './'
2855
2856 =item preversion - <none>
2857
2858 =back
2859
2860 By default, C<\%sqlt_args> will have
2861
2862  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2863
2864 merged with the hash passed in. To disable any of those features, pass in a
2865 hashref like the following
2866
2867  { ignore_constraint_names => 0, # ... other options }
2868
2869
2870 WARNING: You are strongly advised to check all SQL files created, before applying
2871 them.
2872
2873 =cut
2874
2875 sub create_ddl_dir {
2876   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2877
2878   unless ($dir) {
2879     carp "No directory given, using ./\n";
2880     $dir = './';
2881   } else {
2882       -d $dir
2883         or
2884       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2885         or
2886       $self->throw_exception(
2887         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2888       );
2889   }
2890
2891   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2892
2893   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2894   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2895
2896   my $schema_version = $schema->schema_version || '1.x';
2897   $version ||= $schema_version;
2898
2899   $sqltargs = {
2900     add_drop_table => 1,
2901     ignore_constraint_names => 1,
2902     ignore_index_names => 1,
2903     quote_identifiers => $self->sql_maker->_quoting_enabled,
2904     %{$sqltargs || {}}
2905   };
2906
2907   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2908     $self->throw_exception("Can't create a ddl file without $missing");
2909   }
2910
2911   my $sqlt = SQL::Translator->new( $sqltargs );
2912
2913   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2914   my $sqlt_schema = $sqlt->translate({ data => $schema })
2915     or $self->throw_exception ($sqlt->error);
2916
2917   foreach my $db (@$databases) {
2918     $sqlt->reset();
2919     $sqlt->{schema} = $sqlt_schema;
2920     $sqlt->producer($db);
2921
2922     my $file;
2923     my $filename = $schema->ddl_filename($db, $version, $dir);
2924     if (-e $filename && ($version eq $schema_version )) {
2925       # if we are dumping the current version, overwrite the DDL
2926       carp "Overwriting existing DDL file - $filename";
2927       unlink($filename);
2928     }
2929
2930     my $output = $sqlt->translate;
2931     if(!$output) {
2932       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2933       next;
2934     }
2935     if(!open($file, ">$filename")) {
2936       $self->throw_exception("Can't open $filename for writing ($!)");
2937       next;
2938     }
2939     print $file $output;
2940     close($file);
2941
2942     next unless ($preversion);
2943
2944     require SQL::Translator::Diff;
2945
2946     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2947     if(!-e $prefilename) {
2948       carp("No previous schema file found ($prefilename)");
2949       next;
2950     }
2951
2952     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2953     if(-e $difffile) {
2954       carp("Overwriting existing diff file - $difffile");
2955       unlink($difffile);
2956     }
2957
2958     my $source_schema;
2959     {
2960       my $t = SQL::Translator->new($sqltargs);
2961       $t->debug( 0 );
2962       $t->trace( 0 );
2963
2964       $t->parser( $db )
2965         or $self->throw_exception ($t->error);
2966
2967       my $out = $t->translate( $prefilename )
2968         or $self->throw_exception ($t->error);
2969
2970       $source_schema = $t->schema;
2971
2972       $source_schema->name( $prefilename )
2973         unless ( $source_schema->name );
2974     }
2975
2976     # The "new" style of producers have sane normalization and can support
2977     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2978     # And we have to diff parsed SQL against parsed SQL.
2979     my $dest_schema = $sqlt_schema;
2980
2981     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2982       my $t = SQL::Translator->new($sqltargs);
2983       $t->debug( 0 );
2984       $t->trace( 0 );
2985
2986       $t->parser( $db )
2987         or $self->throw_exception ($t->error);
2988
2989       my $out = $t->translate( $filename )
2990         or $self->throw_exception ($t->error);
2991
2992       $dest_schema = $t->schema;
2993
2994       $dest_schema->name( $filename )
2995         unless $dest_schema->name;
2996     }
2997
2998     my $diff = do {
2999       # FIXME - this is a terrible workaround for
3000       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3001       # Fixing it in this sloppy manner so that we don't hve to
3002       # lockstep an SQLT release as well. Needs to be removed at
3003       # some point, and SQLT dep bumped
3004       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3005         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3006
3007       SQL::Translator::Diff::schema_diff($source_schema, $db,
3008                                          $dest_schema,   $db,
3009                                          $sqltargs
3010                                        );
3011     };
3012
3013     if(!open $file, ">$difffile") {
3014       $self->throw_exception("Can't write to $difffile ($!)");
3015       next;
3016     }
3017     print $file $diff;
3018     close($file);
3019   }
3020 }
3021
3022 =head2 deployment_statements
3023
3024 =over 4
3025
3026 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3027
3028 =back
3029
3030 Returns the statements used by L<DBIx::Class::Storage/deploy>
3031 and L<DBIx::Class::Schema/deploy>.
3032
3033 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3034 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3035
3036 C<$directory> is used to return statements from files in a previously created
3037 L</create_ddl_dir> directory and is optional. The filenames are constructed
3038 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3039
3040 If no C<$directory> is specified then the statements are constructed on the
3041 fly using L<SQL::Translator> and C<$version> is ignored.
3042
3043 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3044
3045 =cut
3046
3047 sub deployment_statements {
3048   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3049   $type ||= $self->sqlt_type;
3050   $version ||= $schema->schema_version || '1.x';
3051   $dir ||= './';
3052   my $filename = $schema->ddl_filename($type, $version, $dir);
3053   if(-f $filename)
3054   {
3055       # FIXME replace this block when a proper sane sql parser is available
3056       my $file;
3057       open($file, "<$filename")
3058         or $self->throw_exception("Can't open $filename ($!)");
3059       my @rows = <$file>;
3060       close($file);
3061       return join('', @rows);
3062   }
3063
3064   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3065     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3066   }
3067
3068   # sources needs to be a parser arg, but for simplicity allow at top level
3069   # coming in
3070   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3071       if exists $sqltargs->{sources};
3072
3073   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3074     unless exists $sqltargs->{quote_identifiers};
3075
3076   my $tr = SQL::Translator->new(
3077     producer => "SQL::Translator::Producer::${type}",
3078     %$sqltargs,
3079     parser => 'SQL::Translator::Parser::DBIx::Class',
3080     data => $schema,
3081   );
3082
3083   return preserve_context {
3084     $tr->translate
3085   } after => sub {
3086     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3087       unless defined $_[0];
3088   };
3089 }
3090
3091 # FIXME deploy() currently does not accurately report sql errors
3092 # Will always return true while errors are warned
3093 sub deploy {
3094   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3095   my $deploy = sub {
3096     my $line = shift;
3097     return if(!$line);
3098     return if($line =~ /^--/);
3099     # next if($line =~ /^DROP/m);
3100     return if($line =~ /^BEGIN TRANSACTION/m);
3101     return if($line =~ /^COMMIT/m);
3102     return if $line =~ /^\s+$/; # skip whitespace only
3103     $self->_query_start($line);
3104     try {
3105       # do a dbh_do cycle here, as we need some error checking in
3106       # place (even though we will ignore errors)
3107       $self->dbh_do (sub { $_[1]->do($line) });
3108     } catch {
3109       carp qq{$_ (running "${line}")};
3110     };
3111     $self->_query_end($line);
3112   };
3113   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3114   if (@statements > 1) {
3115     foreach my $statement (@statements) {
3116       $deploy->( $statement );
3117     }
3118   }
3119   elsif (@statements == 1) {
3120     # split on single line comments and end of statements
3121     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3122       $deploy->( $line );
3123     }
3124   }
3125 }
3126
3127 =head2 datetime_parser
3128
3129 Returns the datetime parser class
3130
3131 =cut
3132
3133 sub datetime_parser {
3134   my $self = shift;
3135   return $self->{datetime_parser} ||= do {
3136     $self->build_datetime_parser(@_);
3137   };
3138 }
3139
3140 =head2 datetime_parser_type
3141
3142 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3143
3144 =head2 build_datetime_parser
3145
3146 See L</datetime_parser>
3147
3148 =cut
3149
3150 sub build_datetime_parser {
3151   my $self = shift;
3152   my $type = $self->datetime_parser_type(@_);
3153   return $type;
3154 }
3155
3156
3157 =head2 is_replicating
3158
3159 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3160 replicate from a master database.  Default is undef, which is the result
3161 returned by databases that don't support replication.
3162
3163 =cut
3164
3165 sub is_replicating {
3166     return;
3167
3168 }
3169
3170 =head2 lag_behind_master
3171
3172 Returns a number that represents a certain amount of lag behind a master db
3173 when a given storage is replicating.  The number is database dependent, but
3174 starts at zero and increases with the amount of lag. Default in undef
3175
3176 =cut
3177
3178 sub lag_behind_master {
3179     return;
3180 }
3181
3182 =head2 relname_to_table_alias
3183
3184 =over 4
3185
3186 =item Arguments: $relname, $join_count
3187
3188 =item Return Value: $alias
3189
3190 =back
3191
3192 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3193 queries.
3194
3195 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3196 way these aliases are named.
3197
3198 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3199 otherwise C<"$relname">.
3200
3201 =cut
3202
3203 sub relname_to_table_alias {
3204   my ($self, $relname, $join_count) = @_;
3205
3206   my $alias = ($join_count && $join_count > 1 ?
3207     join('_', $relname, $join_count) : $relname);
3208
3209   return $alias;
3210 }
3211
3212 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3213 # version and it may be necessary to amend or override it for a specific storage
3214 # if such binds are necessary.
3215 sub _max_column_bytesize {
3216   my ($self, $attr) = @_;
3217
3218   my $max_size;
3219
3220   if ($attr->{sqlt_datatype}) {
3221     my $data_type = lc($attr->{sqlt_datatype});
3222
3223     if ($attr->{sqlt_size}) {
3224
3225       # String/sized-binary types
3226       if ($data_type =~ /^(?:
3227           l? (?:var)? char(?:acter)? (?:\s*varying)?
3228             |
3229           (?:var)? binary (?:\s*varying)?
3230             |
3231           raw
3232         )\b/x
3233       ) {
3234         $max_size = $attr->{sqlt_size};
3235       }
3236       # Other charset/unicode types, assume scale of 4
3237       elsif ($data_type =~ /^(?:
3238           national \s* character (?:\s*varying)?
3239             |
3240           nchar
3241             |
3242           univarchar
3243             |
3244           nvarchar
3245         )\b/x
3246       ) {
3247         $max_size = $attr->{sqlt_size} * 4;
3248       }
3249     }
3250
3251     if (!$max_size and !$self->_is_lob_type($data_type)) {
3252       $max_size = 100 # for all other (numeric?) datatypes
3253     }
3254   }
3255
3256   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3257 }
3258
3259 # Determine if a data_type is some type of BLOB
3260 sub _is_lob_type {
3261   my ($self, $data_type) = @_;
3262   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3263     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3264                                   |varchar|character\s*varying|nvarchar
3265                                   |national\s*character\s*varying))?\z/xi);
3266 }
3267
3268 sub _is_binary_lob_type {
3269   my ($self, $data_type) = @_;
3270   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3271     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3272 }
3273
3274 sub _is_text_lob_type {
3275   my ($self, $data_type) = @_;
3276   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3277     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3278                         |national\s*character\s*varying))\z/xi);
3279 }
3280
3281 # Determine if a data_type is some type of a binary type
3282 sub _is_binary_type {
3283   my ($self, $data_type) = @_;
3284   $data_type && ($self->_is_binary_lob_type($data_type)
3285     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3286 }
3287
3288 1;
3289
3290 =head1 USAGE NOTES
3291
3292 =head2 DBIx::Class and AutoCommit
3293
3294 DBIx::Class can do some wonderful magic with handling exceptions,
3295 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3296 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3297 transaction support.
3298
3299 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3300 in an assumed transaction between commits, and you're telling us you'd
3301 like to manage that manually.  A lot of the magic protections offered by
3302 this module will go away.  We can't protect you from exceptions due to database
3303 disconnects because we don't know anything about how to restart your
3304 transactions.  You're on your own for handling all sorts of exceptional
3305 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3306 be with raw DBI.
3307
3308 =head1 FURTHER QUESTIONS?
3309
3310 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3311
3312 =head1 COPYRIGHT AND LICENSE
3313
3314 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3315 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3316 redistribute it and/or modify it under the same terms as the
3317 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.