lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util();
  15 use List::Util();
  16 use Data::Dumper::Concise();
  17 use Sub::Name ();
  18 use Try::Tiny;
  19
  20 use File::Path ();
  21
  22 __PACKAGE__->mk_group_accessors('simple' =>
  23   qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid
  24      _conn_tid transaction_depth _dbh_autocommit _driver_determined savepoints
  25      _server_info_hash/
  26 );
  27
  28 # the values for these accessors are picked out (and deleted) from
  29 # the attribute hashref passed to connect_info
  30 my @storage_options = qw/
  31   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  32   disable_sth_caching unsafe auto_savepoint
  33 /;
  34 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  35
  36
  37 # default cursor class, overridable in connect_info attributes
  38 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  39
  40 __PACKAGE__->mk_group_accessors('inherited' => qw/
  41   sql_maker_class
  42   _supports_insert_returning
  43 /);
  44 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  45
  46 # Each of these methods need _determine_driver called before itself
  47 # in order to function reliably. This is a purely DRY optimization
  48 my @rdbms_specific_methods = qw/
  49   deployment_statements
  50   sqlt_type
  51   build_datetime_parser
  52   datetime_parser_type
  53
  54   insert
  55   insert_bulk
  56   update
  57   delete
  58   select
  59   select_single
  60 /;
  61
  62 for my $meth (@rdbms_specific_methods) {
  63
  64   my $orig = __PACKAGE__->can ($meth)
  65     or next;
  66
  67   no strict qw/refs/;
  68   no warnings qw/redefine/;
  69   *{__PACKAGE__ ."::$meth"} = Sub::Name::subname $meth => sub {
  70     if (not $_[0]->_driver_determined) {
  71       $_[0]->_determine_driver;
  72       goto $_[0]->can($meth);
  73     }
  74     $orig->(@_);
  75   };
  76 }
  77
  78
  79 =head1 NAME
  80
  81 DBIx::Class::Storage::DBI - DBI storage handler
  82
  83 =head1 SYNOPSIS
  84
  85   my $schema = MySchema->connect('dbi:SQLite:my.db');
  86
  87   $schema->storage->debug(1);
  88
  89   my @stuff = $schema->storage->dbh_do(
  90     sub {
  91       my ($storage, $dbh, @args) = @_;
  92       $dbh->do("DROP TABLE authors");
  93     },
  94     @column_list
  95   );
  96
  97   $schema->resultset('Book')->search({
  98      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
  99   });
 100
 101 =head1 DESCRIPTION
 102
 103 This class represents the connection to an RDBMS via L<DBI>.  See
 104 L<DBIx::Class::Storage> for general information.  This pod only
 105 documents DBI-specific methods and behaviors.
 106
 107 =head1 METHODS
 108
 109 =cut
 110
 111 sub new {
 112   my $new = shift->next::method(@_);
 113
 114   $new->transaction_depth(0);
 115   $new->_sql_maker_opts({});
 116   $new->{savepoints} = [];
 117   $new->{_in_dbh_do} = 0;
 118   $new->{_dbh_gen} = 0;
 119
 120   # read below to see what this does
 121   $new->_arm_global_destructor;
 122
 123   $new;
 124 }
 125
 126 # This is hack to work around perl shooting stuff in random
 127 # order on exit(). If we do not walk the remaining storage
 128 # objects in an END block, there is a *small but real* chance
 129 # of a fork()ed child to kill the parent's shared DBI handle,
 130 # *before perl reaches the DESTROY in this package*
 131 # Yes, it is ugly and effective.
 132 {
 133   my %seek_and_destroy;
 134
 135   sub _arm_global_destructor {
 136     my $self = shift;
 137     my $key = Scalar::Util::refaddr ($self);
 138     $seek_and_destroy{$key} = $self;
 139     Scalar::Util::weaken ($seek_and_destroy{$key});
 140   }
 141
 142   END {
 143     local $?; # just in case the DBI destructor changes it somehow
 144
 145     # destroy just the object if not native to this process/thread
 146     $_->_preserve_foreign_dbh for (grep
 147       { defined $_ }
 148       values %seek_and_destroy
 149     );
 150   }
 151 }
 152
 153 sub DESTROY {
 154   my $self = shift;
 155
 156   # destroy just the object if not native to this process/thread
 157   $self->_preserve_foreign_dbh;
 158
 159   # some databases need this to stop spewing warnings
 160   if (my $dbh = $self->_dbh) {
 161     try {
 162       %{ $dbh->{CachedKids} } = ();
 163       $dbh->disconnect;
 164     };
 165   }
 166
 167   $self->_dbh(undef);
 168 }
 169
 170 sub _preserve_foreign_dbh {
 171   my $self = shift;
 172
 173   return unless $self->_dbh;
 174
 175   $self->_verify_tid;
 176
 177   return unless $self->_dbh;
 178
 179   $self->_verify_pid;
 180
 181 }
 182
 183 # handle pid changes correctly - do not destroy parent's connection
 184 sub _verify_pid {
 185   my $self = shift;
 186
 187   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 188
 189   $self->_dbh->{InactiveDestroy} = 1;
 190   $self->_dbh(undef);
 191   $self->{_dbh_gen}++;
 192
 193   return;
 194 }
 195
 196 # very similar to above, but seems to FAIL if I set InactiveDestroy
 197 sub _verify_tid {
 198   my $self = shift;
 199
 200   if ( ! defined $self->_conn_tid ) {
 201     return; # no threads
 202   }
 203   elsif ( $self->_conn_tid == threads->tid ) {
 204     return; # same thread
 205   }
 206
 207   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 208   $self->_dbh(undef);
 209   $self->{_dbh_gen}++;
 210
 211   return;
 212 }
 213
 214
 215 =head2 connect_info
 216
 217 This method is normally called by L<DBIx::Class::Schema/connection>, which
 218 encapsulates its argument list in an arrayref before passing them here.
 219
 220 The argument list may contain:
 221
 222 =over
 223
 224 =item *
 225
 226 The same 4-element argument set one would normally pass to
 227 L<DBI/connect>, optionally followed by
 228 L<extra attributes|/DBIx::Class specific connection attributes>
 229 recognized by DBIx::Class:
 230
 231   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 232
 233 =item *
 234
 235 A single code reference which returns a connected
 236 L<DBI database handle|DBI/connect> optionally followed by
 237 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 238 by DBIx::Class:
 239
 240   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 241
 242 =item *
 243
 244 A single hashref with all the attributes and the dsn/user/password
 245 mixed together:
 246
 247   $connect_info_args = [{
 248     dsn => $dsn,
 249     user => $user,
 250     password => $pass,
 251     %dbi_attributes,
 252     %extra_attributes,
 253   }];
 254
 255   $connect_info_args = [{
 256     dbh_maker => sub { DBI->connect (...) },
 257     %dbi_attributes,
 258     %extra_attributes,
 259   }];
 260
 261 This is particularly useful for L<Catalyst> based applications, allowing the
 262 following config (L<Config::General> style):
 263
 264   <Model::DB>
 265     schema_class   App::DB
 266     <connect_info>
 267       dsn          dbi:mysql:database=test
 268       user         testuser
 269       password     TestPass
 270       AutoCommit   1
 271     </connect_info>
 272   </Model::DB>
 273
 274 The C<dsn>/C<user>/C<password> combination can be substituted by the
 275 C<dbh_maker> key whose value is a coderef that returns a connected
 276 L<DBI database handle|DBI/connect>
 277
 278 =back
 279
 280 Please note that the L<DBI> docs recommend that you always explicitly
 281 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 282 recommends that it be set to I<1>, and that you perform transactions
 283 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 284 to I<1> if you do not do explicitly set it to zero.  This is the default
 285 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 286
 287 =head3 DBIx::Class specific connection attributes
 288
 289 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 290 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 291 the following connection options. These options can be mixed in with your other
 292 L<DBI> connection attributes, or placed in a separate hashref
 293 (C<\%extra_attributes>) as shown above.
 294
 295 Every time C<connect_info> is invoked, any previous settings for
 296 these options will be cleared before setting the new ones, regardless of
 297 whether any options are specified in the new C<connect_info>.
 298
 299
 300 =over
 301
 302 =item on_connect_do
 303
 304 Specifies things to do immediately after connecting or re-connecting to
 305 the database.  Its value may contain:
 306
 307 =over
 308
 309 =item a scalar
 310
 311 This contains one SQL statement to execute.
 312
 313 =item an array reference
 314
 315 This contains SQL statements to execute in order.  Each element contains
 316 a string or a code reference that returns a string.
 317
 318 =item a code reference
 319
 320 This contains some code to execute.  Unlike code references within an
 321 array reference, its return value is ignored.
 322
 323 =back
 324
 325 =item on_disconnect_do
 326
 327 Takes arguments in the same form as L</on_connect_do> and executes them
 328 immediately before disconnecting from the database.
 329
 330 Note, this only runs if you explicitly call L</disconnect> on the
 331 storage object.
 332
 333 =item on_connect_call
 334
 335 A more generalized form of L</on_connect_do> that calls the specified
 336 C<connect_call_METHOD> methods in your storage driver.
 337
 338   on_connect_do => 'select 1'
 339
 340 is equivalent to:
 341
 342   on_connect_call => [ [ do_sql => 'select 1' ] ]
 343
 344 Its values may contain:
 345
 346 =over
 347
 348 =item a scalar
 349
 350 Will call the C<connect_call_METHOD> method.
 351
 352 =item a code reference
 353
 354 Will execute C<< $code->($storage) >>
 355
 356 =item an array reference
 357
 358 Each value can be a method name or code reference.
 359
 360 =item an array of arrays
 361
 362 For each array, the first item is taken to be the C<connect_call_> method name
 363 or code reference, and the rest are parameters to it.
 364
 365 =back
 366
 367 Some predefined storage methods you may use:
 368
 369 =over
 370
 371 =item do_sql
 372
 373 Executes a SQL string or a code reference that returns a SQL string. This is
 374 what L</on_connect_do> and L</on_disconnect_do> use.
 375
 376 It can take:
 377
 378 =over
 379
 380 =item a scalar
 381
 382 Will execute the scalar as SQL.
 383
 384 =item an arrayref
 385
 386 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 387 attributes hashref and bind values.
 388
 389 =item a code reference
 390
 391 Will execute C<< $code->($storage) >> and execute the return array refs as
 392 above.
 393
 394 =back
 395
 396 =item datetime_setup
 397
 398 Execute any statements necessary to initialize the database session to return
 399 and accept datetime/timestamp values used with
 400 L<DBIx::Class::InflateColumn::DateTime>.
 401
 402 Only necessary for some databases, see your specific storage driver for
 403 implementation details.
 404
 405 =back
 406
 407 =item on_disconnect_call
 408
 409 Takes arguments in the same form as L</on_connect_call> and executes them
 410 immediately before disconnecting from the database.
 411
 412 Calls the C<disconnect_call_METHOD> methods as opposed to the
 413 C<connect_call_METHOD> methods called by L</on_connect_call>.
 414
 415 Note, this only runs if you explicitly call L</disconnect> on the
 416 storage object.
 417
 418 =item disable_sth_caching
 419
 420 If set to a true value, this option will disable the caching of
 421 statement handles via L<DBI/prepare_cached>.
 422
 423 =item limit_dialect
 424
 425 Sets the limit dialect. This is useful for JDBC-bridge among others
 426 where the remote SQL-dialect cannot be determined by the name of the
 427 driver alone. See also L<SQL::Abstract::Limit>.
 428
 429 =item quote_char
 430
 431 Specifies what characters to use to quote table and column names. If
 432 you use this you will want to specify L</name_sep> as well.
 433
 434 C<quote_char> expects either a single character, in which case is it
 435 is placed on either side of the table/column name, or an arrayref of length
 436 2 in which case the table/column name is placed between the elements.
 437
 438 For example under MySQL you should use C<< quote_char => '`' >>, and for
 439 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 440
 441 =item name_sep
 442
 443 This only needs to be used in conjunction with C<quote_char>, and is used to
 444 specify the character that separates elements (schemas, tables, columns) from
 445 each other. In most cases this is simply a C<.>.
 446
 447 The consequences of not supplying this value is that L<SQL::Abstract>
 448 will assume DBIx::Class' uses of aliases to be complete column
 449 names. The output will look like I<"me.name"> when it should actually
 450 be I<"me"."name">.
 451
 452 =item unsafe
 453
 454 This Storage driver normally installs its own C<HandleError>, sets
 455 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 456 all database handles, including those supplied by a coderef.  It does this
 457 so that it can have consistent and useful error behavior.
 458
 459 If you set this option to a true value, Storage will not do its usual
 460 modifications to the database handle's attributes, and instead relies on
 461 the settings in your connect_info DBI options (or the values you set in
 462 your connection coderef, in the case that you are connecting via coderef).
 463
 464 Note that your custom settings can cause Storage to malfunction,
 465 especially if you set a C<HandleError> handler that suppresses exceptions
 466 and/or disable C<RaiseError>.
 467
 468 =item auto_savepoint
 469
 470 If this option is true, L<DBIx::Class> will use savepoints when nesting
 471 transactions, making it possible to recover from failure in the inner
 472 transaction without having to abort all outer transactions.
 473
 474 =item cursor_class
 475
 476 Use this argument to supply a cursor class other than the default
 477 L<DBIx::Class::Storage::DBI::Cursor>.
 478
 479 =back
 480
 481 Some real-life examples of arguments to L</connect_info> and
 482 L<DBIx::Class::Schema/connect>
 483
 484   # Simple SQLite connection
 485   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 486
 487   # Connect via subref
 488   ->connect_info([ sub { DBI->connect(...) } ]);
 489
 490   # Connect via subref in hashref
 491   ->connect_info([{
 492     dbh_maker => sub { DBI->connect(...) },
 493     on_connect_do => 'alter session ...',
 494   }]);
 495
 496   # A bit more complicated
 497   ->connect_info(
 498     [
 499       'dbi:Pg:dbname=foo',
 500       'postgres',
 501       'my_pg_password',
 502       { AutoCommit => 1 },
 503       { quote_char => q{"}, name_sep => q{.} },
 504     ]
 505   );
 506
 507   # Equivalent to the previous example
 508   ->connect_info(
 509     [
 510       'dbi:Pg:dbname=foo',
 511       'postgres',
 512       'my_pg_password',
 513       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 514     ]
 515   );
 516
 517   # Same, but with hashref as argument
 518   # See parse_connect_info for explanation
 519   ->connect_info(
 520     [{
 521       dsn         => 'dbi:Pg:dbname=foo',
 522       user        => 'postgres',
 523       password    => 'my_pg_password',
 524       AutoCommit  => 1,
 525       quote_char  => q{"},
 526       name_sep    => q{.},
 527     }]
 528   );
 529
 530   # Subref + DBIx::Class-specific connection options
 531   ->connect_info(
 532     [
 533       sub { DBI->connect(...) },
 534       {
 535           quote_char => q{`},
 536           name_sep => q{@},
 537           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 538           disable_sth_caching => 1,
 539       },
 540     ]
 541   );
 542
 543
 544
 545 =cut
 546
 547 sub connect_info {
 548   my ($self, $info) = @_;
 549
 550   return $self->_connect_info if !$info;
 551
 552   $self->_connect_info($info); # copy for _connect_info
 553
 554   $info = $self->_normalize_connect_info($info)
 555     if ref $info eq 'ARRAY';
 556
 557   for my $storage_opt (keys %{ $info->{storage_options} }) {
 558     my $value = $info->{storage_options}{$storage_opt};
 559
 560     $self->$storage_opt($value);
 561   }
 562
 563   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 564   #  the new set of options
 565   $self->_sql_maker(undef);
 566   $self->_sql_maker_opts({});
 567
 568   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 569     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 570
 571     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 572   }
 573
 574   my %attrs = (
 575     %{ $self->_default_dbi_connect_attributes || {} },
 576     %{ $info->{attributes} || {} },
 577   );
 578
 579   my @args = @{ $info->{arguments} };
 580
 581   $self->_dbi_connect_info([@args,
 582     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 583
 584   return $self->_connect_info;
 585 }
 586
 587 sub _normalize_connect_info {
 588   my ($self, $info_arg) = @_;
 589   my %info;
 590
 591   my @args = @$info_arg;  # take a shallow copy for further mutilation
 592
 593   # combine/pre-parse arguments depending on invocation style
 594
 595   my %attrs;
 596   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 597     %attrs = %{ $args[1] || {} };
 598     @args = $args[0];
 599   }
 600   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 601     %attrs = %{$args[0]};
 602     @args = ();
 603     if (my $code = delete $attrs{dbh_maker}) {
 604       @args = $code;
 605
 606       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 607       if (@ignored) {
 608         carp sprintf (
 609             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 610           . "to the result of 'dbh_maker'",
 611
 612           join (', ', map { "'$_'" } (@ignored) ),
 613         );
 614       }
 615     }
 616     else {
 617       @args = delete @attrs{qw/dsn user password/};
 618     }
 619   }
 620   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 621     %attrs = (
 622       % { $args[3] || {} },
 623       % { $args[4] || {} },
 624     );
 625     @args = @args[0,1,2];
 626   }
 627
 628   $info{arguments} = \@args;
 629
 630   my @storage_opts = grep exists $attrs{$_},
 631     @storage_options, 'cursor_class';
 632
 633   @{ $info{storage_options} }{@storage_opts} =
 634     delete @attrs{@storage_opts} if @storage_opts;
 635
 636   my @sql_maker_opts = grep exists $attrs{$_},
 637     qw/limit_dialect quote_char name_sep/;
 638
 639   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 640     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 641
 642   $info{attributes} = \%attrs if %attrs;
 643
 644   return \%info;
 645 }
 646
 647 sub _default_dbi_connect_attributes {
 648   return {
 649     AutoCommit => 1,
 650     RaiseError => 1,
 651     PrintError => 0,
 652   };
 653 }
 654
 655 =head2 on_connect_do
 656
 657 This method is deprecated in favour of setting via L</connect_info>.
 658
 659 =cut
 660
 661 =head2 on_disconnect_do
 662
 663 This method is deprecated in favour of setting via L</connect_info>.
 664
 665 =cut
 666
 667 sub _parse_connect_do {
 668   my ($self, $type) = @_;
 669
 670   my $val = $self->$type;
 671   return () if not defined $val;
 672
 673   my @res;
 674
 675   if (not ref($val)) {
 676     push @res, [ 'do_sql', $val ];
 677   } elsif (ref($val) eq 'CODE') {
 678     push @res, $val;
 679   } elsif (ref($val) eq 'ARRAY') {
 680     push @res, map { [ 'do_sql', $_ ] } @$val;
 681   } else {
 682     $self->throw_exception("Invalid type for $type: ".ref($val));
 683   }
 684
 685   return \@res;
 686 }
 687
 688 =head2 dbh_do
 689
 690 Arguments: ($subref | $method_name), @extra_coderef_args?
 691
 692 Execute the given $subref or $method_name using the new exception-based
 693 connection management.
 694
 695 The first two arguments will be the storage object that C<dbh_do> was called
 696 on and a database handle to use.  Any additional arguments will be passed
 697 verbatim to the called subref as arguments 2 and onwards.
 698
 699 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 700 exception handling and reconnection (or failover in future subclasses).
 701
 702 Your subref should have no side-effects outside of the database, as
 703 there is the potential for your subref to be partially double-executed
 704 if the database connection was stale/dysfunctional.
 705
 706 Example:
 707
 708   my @stuff = $schema->storage->dbh_do(
 709     sub {
 710       my ($storage, $dbh, @cols) = @_;
 711       my $cols = join(q{, }, @cols);
 712       $dbh->selectrow_array("SELECT $cols FROM foo");
 713     },
 714     @column_list
 715   );
 716
 717 =cut
 718
 719 sub dbh_do {
 720   my $self = shift;
 721   my $code = shift;
 722
 723   my $dbh = $self->_get_dbh;
 724
 725   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 726       || $self->{transaction_depth};
 727
 728   local $self->{_in_dbh_do} = 1;
 729
 730   my @result;
 731   my $want_array = wantarray;
 732
 733   eval {
 734
 735     if($want_array) {
 736         @result = $self->$code($dbh, @_);
 737     }
 738     elsif(defined $want_array) {
 739         $result[0] = $self->$code($dbh, @_);
 740     }
 741     else {
 742         $self->$code($dbh, @_);
 743     }
 744   };
 745
 746   # ->connected might unset $@ - copy
 747   my $exception = $@;
 748   if(!$exception) { return $want_array ? @result : $result[0] }
 749
 750   $self->throw_exception($exception) if $self->connected;
 751
 752   # We were not connected - reconnect and retry, but let any
 753   #  exception fall right through this time
 754   carp "Retrying $code after catching disconnected exception: $exception"
 755     if $ENV{DBIC_DBIRETRY_DEBUG};
 756   $self->_populate_dbh;
 757   $self->$code($self->_dbh, @_);
 758 }
 759
 760 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 761 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 762 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 763 sub txn_do {
 764   my $self = shift;
 765   my $coderef = shift;
 766
 767   ref $coderef eq 'CODE' or $self->throw_exception
 768     ('$coderef must be a CODE reference');
 769
 770   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 771
 772   local $self->{_in_dbh_do} = 1;
 773
 774   my @result;
 775   my $want_array = wantarray;
 776
 777   my $tried = 0;
 778   while(1) {
 779     eval {
 780       $self->_get_dbh;
 781
 782       $self->txn_begin;
 783       if($want_array) {
 784           @result = $coderef->(@_);
 785       }
 786       elsif(defined $want_array) {
 787           $result[0] = $coderef->(@_);
 788       }
 789       else {
 790           $coderef->(@_);
 791       }
 792       $self->txn_commit;
 793     };
 794
 795     # ->connected might unset $@ - copy
 796     my $exception = $@;
 797     if(!$exception) { return $want_array ? @result : $result[0] }
 798
 799     if($tried++ || $self->connected) {
 800       eval { $self->txn_rollback };
 801       my $rollback_exception = $@;
 802       if($rollback_exception) {
 803         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 804         $self->throw_exception($exception)  # propagate nested rollback
 805           if $rollback_exception =~ /$exception_class/;
 806
 807         $self->throw_exception(
 808           "Transaction aborted: ${exception}. "
 809           . "Rollback failed: ${rollback_exception}"
 810         );
 811       }
 812       $self->throw_exception($exception)
 813     }
 814
 815     # We were not connected, and was first try - reconnect and retry
 816     # via the while loop
 817     carp "Retrying $coderef after catching disconnected exception: $exception"
 818       if $ENV{DBIC_DBIRETRY_DEBUG};
 819     $self->_populate_dbh;
 820   }
 821 }
 822
 823 =head2 disconnect
 824
 825 Our C<disconnect> method also performs a rollback first if the
 826 database is not in C<AutoCommit> mode.
 827
 828 =cut
 829
 830 sub disconnect {
 831   my ($self) = @_;
 832
 833   if( $self->_dbh ) {
 834     my @actions;
 835
 836     push @actions, ( $self->on_disconnect_call || () );
 837     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 838
 839     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 840
 841     $self->_dbh_rollback unless $self->_dbh_autocommit;
 842
 843     %{ $self->_dbh->{CachedKids} } = ();
 844     $self->_dbh->disconnect;
 845     $self->_dbh(undef);
 846     $self->{_dbh_gen}++;
 847   }
 848 }
 849
 850 =head2 with_deferred_fk_checks
 851
 852 =over 4
 853
 854 =item Arguments: C<$coderef>
 855
 856 =item Return Value: The return value of $coderef
 857
 858 =back
 859
 860 Storage specific method to run the code ref with FK checks deferred or
 861 in MySQL's case disabled entirely.
 862
 863 =cut
 864
 865 # Storage subclasses should override this
 866 sub with_deferred_fk_checks {
 867   my ($self, $sub) = @_;
 868   $sub->();
 869 }
 870
 871 =head2 connected
 872
 873 =over
 874
 875 =item Arguments: none
 876
 877 =item Return Value: 1|0
 878
 879 =back
 880
 881 Verifies that the current database handle is active and ready to execute
 882 an SQL statement (e.g. the connection did not get stale, server is still
 883 answering, etc.) This method is used internally by L</dbh>.
 884
 885 =cut
 886
 887 sub connected {
 888   my $self = shift;
 889   return 0 unless $self->_seems_connected;
 890
 891   #be on the safe side
 892   local $self->_dbh->{RaiseError} = 1;
 893
 894   return $self->_ping;
 895 }
 896
 897 sub _seems_connected {
 898   my $self = shift;
 899
 900   $self->_preserve_foreign_dbh;
 901
 902   my $dbh = $self->_dbh
 903     or return 0;
 904
 905   return $dbh->FETCH('Active');
 906 }
 907
 908 sub _ping {
 909   my $self = shift;
 910
 911   my $dbh = $self->_dbh or return 0;
 912
 913   return $dbh->ping;
 914 }
 915
 916 sub ensure_connected {
 917   my ($self) = @_;
 918
 919   unless ($self->connected) {
 920     $self->_populate_dbh;
 921   }
 922 }
 923
 924 =head2 dbh
 925
 926 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 927 is guaranteed to be healthy by implicitly calling L</connected>, and if
 928 necessary performing a reconnection before returning. Keep in mind that this
 929 is very B<expensive> on some database engines. Consider using L</dbh_do>
 930 instead.
 931
 932 =cut
 933
 934 sub dbh {
 935   my ($self) = @_;
 936
 937   if (not $self->_dbh) {
 938     $self->_populate_dbh;
 939   } else {
 940     $self->ensure_connected;
 941   }
 942   return $self->_dbh;
 943 }
 944
 945 # this is the internal "get dbh or connect (don't check)" method
 946 sub _get_dbh {
 947   my $self = shift;
 948   $self->_preserve_foreign_dbh;
 949   $self->_populate_dbh unless $self->_dbh;
 950   return $self->_dbh;
 951 }
 952
 953 sub _sql_maker_args {
 954     my ($self) = @_;
 955
 956     return (
 957       bindtype=>'columns',
 958       array_datatypes => 1,
 959       limit_dialect => $self->_get_dbh,
 960       %{$self->_sql_maker_opts}
 961     );
 962 }
 963
 964 sub sql_maker {
 965   my ($self) = @_;
 966   unless ($self->_sql_maker) {
 967     my $sql_maker_class = $self->sql_maker_class;
 968     $self->ensure_class_loaded ($sql_maker_class);
 969     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 970   }
 971   return $self->_sql_maker;
 972 }
 973
 974 # nothing to do by default
 975 sub _rebless {}
 976 sub _init {}
 977
 978 sub _populate_dbh {
 979   my ($self) = @_;
 980
 981   my @info = @{$self->_dbi_connect_info || []};
 982   $self->_dbh(undef); # in case ->connected failed we might get sent here
 983   $self->_server_info_hash (undef);
 984   $self->_dbh($self->_connect(@info));
 985
 986   $self->_conn_pid($$);
 987   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 988
 989   $self->_determine_driver;
 990
 991   # Always set the transaction depth on connect, since
 992   #  there is no transaction in progress by definition
 993   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 994
 995   $self->_run_connection_actions unless $self->{_in_determine_driver};
 996 }
 997
 998 sub _run_connection_actions {
 999   my $self = shift;
1000   my @actions;
1001
1002   push @actions, ( $self->on_connect_call || () );
1003   push @actions, $self->_parse_connect_do ('on_connect_do');
1004
1005   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1006 }
1007
1008 sub _server_info {
1009   my $self = shift;
1010
1011   unless ($self->_server_info_hash) {
1012
1013     my %info;
1014
1015     my $server_version = do {
1016       local $@; # might be happenin in some sort of destructor
1017       try { $self->_get_server_version };
1018     };
1019
1020     if (defined $server_version) {
1021       $info{dbms_version} = $server_version;
1022
1023       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1024       my @verparts = split (/\./, $numeric_version);
1025       if (
1026         @verparts
1027           &&
1028         $verparts[0] <= 999
1029       ) {
1030         # consider only up to 3 version parts, iff not more than 3 digits
1031         my @use_parts;
1032         while (@verparts && @use_parts < 3) {
1033           my $p = shift @verparts;
1034           last if $p > 999;
1035           push @use_parts, $p;
1036         }
1037         push @use_parts, 0 while @use_parts < 3;
1038
1039         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1040       }
1041     }
1042
1043     $self->_server_info_hash(\%info);
1044   }
1045
1046   return $self->_server_info_hash
1047 }
1048
1049 sub _get_server_version {
1050   shift->_get_dbh->get_info(18);
1051 }
1052
1053 sub _determine_driver {
1054   my ($self) = @_;
1055
1056   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1057     my $started_connected = 0;
1058     local $self->{_in_determine_driver} = 1;
1059
1060     if (ref($self) eq __PACKAGE__) {
1061       my $driver;
1062       if ($self->_dbh) { # we are connected
1063         $driver = $self->_dbh->{Driver}{Name};
1064         $started_connected = 1;
1065       } else {
1066         # if connect_info is a CODEREF, we have no choice but to connect
1067         if (ref $self->_dbi_connect_info->[0] &&
1068             Scalar::Util::reftype($self->_dbi_connect_info->[0]) eq 'CODE') {
1069           $self->_populate_dbh;
1070           $driver = $self->_dbh->{Driver}{Name};
1071         }
1072         else {
1073           # try to use dsn to not require being connected, the driver may still
1074           # force a connection in _rebless to determine version
1075           # (dsn may not be supplied at all if all we do is make a mock-schema)
1076           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1077           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1078           $driver ||= $ENV{DBI_DRIVER};
1079         }
1080       }
1081
1082       if ($driver) {
1083         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1084         if ($self->load_optional_class($storage_class)) {
1085           mro::set_mro($storage_class, 'c3');
1086           bless $self, $storage_class;
1087           $self->_rebless();
1088         }
1089       }
1090     }
1091
1092     $self->_driver_determined(1);
1093
1094     $self->_init; # run driver-specific initializations
1095
1096     $self->_run_connection_actions
1097         if !$started_connected && defined $self->_dbh;
1098   }
1099 }
1100
1101 sub _do_connection_actions {
1102   my $self          = shift;
1103   my $method_prefix = shift;
1104   my $call          = shift;
1105
1106   if (not ref($call)) {
1107     my $method = $method_prefix . $call;
1108     $self->$method(@_);
1109   } elsif (ref($call) eq 'CODE') {
1110     $self->$call(@_);
1111   } elsif (ref($call) eq 'ARRAY') {
1112     if (ref($call->[0]) ne 'ARRAY') {
1113       $self->_do_connection_actions($method_prefix, $_) for @$call;
1114     } else {
1115       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1116     }
1117   } else {
1118     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1119   }
1120
1121   return $self;
1122 }
1123
1124 sub connect_call_do_sql {
1125   my $self = shift;
1126   $self->_do_query(@_);
1127 }
1128
1129 sub disconnect_call_do_sql {
1130   my $self = shift;
1131   $self->_do_query(@_);
1132 }
1133
1134 # override in db-specific backend when necessary
1135 sub connect_call_datetime_setup { 1 }
1136
1137 sub _do_query {
1138   my ($self, $action) = @_;
1139
1140   if (ref $action eq 'CODE') {
1141     $action = $action->($self);
1142     $self->_do_query($_) foreach @$action;
1143   }
1144   else {
1145     # Most debuggers expect ($sql, @bind), so we need to exclude
1146     # the attribute hash which is the second argument to $dbh->do
1147     # furthermore the bind values are usually to be presented
1148     # as named arrayref pairs, so wrap those here too
1149     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1150     my $sql = shift @do_args;
1151     my $attrs = shift @do_args;
1152     my @bind = map { [ undef, $_ ] } @do_args;
1153
1154     $self->_query_start($sql, @bind);
1155     $self->_get_dbh->do($sql, $attrs, @do_args);
1156     $self->_query_end($sql, @bind);
1157   }
1158
1159   return $self;
1160 }
1161
1162 sub _connect {
1163   my ($self, @info) = @_;
1164
1165   $self->throw_exception("You failed to provide any connection info")
1166     if !@info;
1167
1168   my ($old_connect_via, $dbh);
1169
1170   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1171     $old_connect_via = $DBI::connect_via;
1172     $DBI::connect_via = 'connect';
1173   }
1174
1175   my $caught;
1176   try {
1177     if(ref $info[0] eq 'CODE') {
1178        $dbh = $info[0]->();
1179     }
1180     else {
1181        $dbh = DBI->connect(@info);
1182     }
1183
1184     if($dbh && !$self->unsafe) {
1185       my $weak_self = $self;
1186       Scalar::Util::weaken($weak_self);
1187       $dbh->{HandleError} = sub {
1188           if ($weak_self) {
1189             $weak_self->throw_exception("DBI Exception: $_[0]");
1190           }
1191           else {
1192             # the handler may be invoked by something totally out of
1193             # the scope of DBIC
1194             croak ("DBI Exception: $_[0]");
1195           }
1196       };
1197       $dbh->{ShowErrorStatement} = 1;
1198       $dbh->{RaiseError} = 1;
1199       $dbh->{PrintError} = 0;
1200     }
1201   } catch {
1202     $caught = 1;
1203   };
1204
1205   $DBI::connect_via = $old_connect_via if $old_connect_via;
1206
1207   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1208     if !$dbh || $caught;
1209
1210   $self->_dbh_autocommit($dbh->{AutoCommit});
1211
1212   $dbh;
1213 }
1214
1215 sub svp_begin {
1216   my ($self, $name) = @_;
1217
1218   $name = $self->_svp_generate_name
1219     unless defined $name;
1220
1221   $self->throw_exception ("You can't use savepoints outside a transaction")
1222     if $self->{transaction_depth} == 0;
1223
1224   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1225     unless $self->can('_svp_begin');
1226
1227   push @{ $self->{savepoints} }, $name;
1228
1229   $self->debugobj->svp_begin($name) if $self->debug;
1230
1231   return $self->_svp_begin($name);
1232 }
1233
1234 sub svp_release {
1235   my ($self, $name) = @_;
1236
1237   $self->throw_exception ("You can't use savepoints outside a transaction")
1238     if $self->{transaction_depth} == 0;
1239
1240   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1241     unless $self->can('_svp_release');
1242
1243   if (defined $name) {
1244     $self->throw_exception ("Savepoint '$name' does not exist")
1245       unless grep { $_ eq $name } @{ $self->{savepoints} };
1246
1247     # Dig through the stack until we find the one we are releasing.  This keeps
1248     # the stack up to date.
1249     my $svp;
1250
1251     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1252   } else {
1253     $name = pop @{ $self->{savepoints} };
1254   }
1255
1256   $self->debugobj->svp_release($name) if $self->debug;
1257
1258   return $self->_svp_release($name);
1259 }
1260
1261 sub svp_rollback {
1262   my ($self, $name) = @_;
1263
1264   $self->throw_exception ("You can't use savepoints outside a transaction")
1265     if $self->{transaction_depth} == 0;
1266
1267   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1268     unless $self->can('_svp_rollback');
1269
1270   if (defined $name) {
1271       # If they passed us a name, verify that it exists in the stack
1272       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1273           $self->throw_exception("Savepoint '$name' does not exist!");
1274       }
1275
1276       # Dig through the stack until we find the one we are releasing.  This keeps
1277       # the stack up to date.
1278       while(my $s = pop(@{ $self->{savepoints} })) {
1279           last if($s eq $name);
1280       }
1281       # Add the savepoint back to the stack, as a rollback doesn't remove the
1282       # named savepoint, only everything after it.
1283       push(@{ $self->{savepoints} }, $name);
1284   } else {
1285       # We'll assume they want to rollback to the last savepoint
1286       $name = $self->{savepoints}->[-1];
1287   }
1288
1289   $self->debugobj->svp_rollback($name) if $self->debug;
1290
1291   return $self->_svp_rollback($name);
1292 }
1293
1294 sub _svp_generate_name {
1295     my ($self) = @_;
1296
1297     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1298 }
1299
1300 sub txn_begin {
1301   my $self = shift;
1302
1303   # this means we have not yet connected and do not know the AC status
1304   # (e.g. coderef $dbh)
1305   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1306
1307   if($self->{transaction_depth} == 0) {
1308     $self->debugobj->txn_begin()
1309       if $self->debug;
1310     $self->_dbh_begin_work;
1311   }
1312   elsif ($self->auto_savepoint) {
1313     $self->svp_begin;
1314   }
1315   $self->{transaction_depth}++;
1316 }
1317
1318 sub _dbh_begin_work {
1319   my $self = shift;
1320
1321   # if the user is utilizing txn_do - good for him, otherwise we need to
1322   # ensure that the $dbh is healthy on BEGIN.
1323   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1324   # will be replaced by a failure of begin_work itself (which will be
1325   # then retried on reconnect)
1326   if ($self->{_in_dbh_do}) {
1327     $self->_dbh->begin_work;
1328   } else {
1329     $self->dbh_do(sub { $_[1]->begin_work });
1330   }
1331 }
1332
1333 sub txn_commit {
1334   my $self = shift;
1335   if ($self->{transaction_depth} == 1) {
1336     $self->debugobj->txn_commit()
1337       if ($self->debug);
1338     $self->_dbh_commit;
1339     $self->{transaction_depth} = 0
1340       if $self->_dbh_autocommit;
1341   }
1342   elsif($self->{transaction_depth} > 1) {
1343     $self->{transaction_depth}--;
1344     $self->svp_release
1345       if $self->auto_savepoint;
1346   }
1347 }
1348
1349 sub _dbh_commit {
1350   my $self = shift;
1351   my $dbh  = $self->_dbh
1352     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1353   $dbh->commit;
1354 }
1355
1356 sub txn_rollback {
1357   my $self = shift;
1358   my $dbh = $self->_dbh;
1359   eval {
1360     if ($self->{transaction_depth} == 1) {
1361       $self->debugobj->txn_rollback()
1362         if ($self->debug);
1363       $self->{transaction_depth} = 0
1364         if $self->_dbh_autocommit;
1365       $self->_dbh_rollback;
1366     }
1367     elsif($self->{transaction_depth} > 1) {
1368       $self->{transaction_depth}--;
1369       if ($self->auto_savepoint) {
1370         $self->svp_rollback;
1371         $self->svp_release;
1372       }
1373     }
1374     else {
1375       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1376     }
1377   };
1378   if ($@) {
1379     my $error = $@;
1380     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1381     $error =~ /$exception_class/ and $self->throw_exception($error);
1382     # ensure that a failed rollback resets the transaction depth
1383     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1384     $self->throw_exception($error);
1385   }
1386 }
1387
1388 sub _dbh_rollback {
1389   my $self = shift;
1390   my $dbh  = $self->_dbh
1391     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1392   $dbh->rollback;
1393 }
1394
1395 # This used to be the top-half of _execute.  It was split out to make it
1396 #  easier to override in NoBindVars without duping the rest.  It takes up
1397 #  all of _execute's args, and emits $sql, @bind.
1398 sub _prep_for_execute {
1399   my ($self, $op, $extra_bind, $ident, $args) = @_;
1400
1401   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1402     $ident = $ident->from();
1403   }
1404
1405   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1406
1407   unshift(@bind,
1408     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1409       if $extra_bind;
1410   return ($sql, \@bind);
1411 }
1412
1413
1414 sub _fix_bind_params {
1415     my ($self, @bind) = @_;
1416
1417     ### Turn @bind from something like this:
1418     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1419     ### to this:
1420     ###   ( "'1'", "'1'", "'3'" )
1421     return
1422         map {
1423             if ( defined( $_ && $_->[1] ) ) {
1424                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1425             }
1426             else { q{'NULL'}; }
1427         } @bind;
1428 }
1429
1430 sub _query_start {
1431     my ( $self, $sql, @bind ) = @_;
1432
1433     if ( $self->debug ) {
1434         @bind = $self->_fix_bind_params(@bind);
1435
1436         $self->debugobj->query_start( $sql, @bind );
1437     }
1438 }
1439
1440 sub _query_end {
1441     my ( $self, $sql, @bind ) = @_;
1442
1443     if ( $self->debug ) {
1444         @bind = $self->_fix_bind_params(@bind);
1445         $self->debugobj->query_end( $sql, @bind );
1446     }
1447 }
1448
1449 sub _dbh_execute {
1450   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1451
1452   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1453
1454   $self->_query_start( $sql, @$bind );
1455
1456   my $sth = $self->sth($sql,$op);
1457
1458   my $placeholder_index = 1;
1459
1460   foreach my $bound (@$bind) {
1461     my $attributes = {};
1462     my($column_name, @data) = @$bound;
1463
1464     if ($bind_attributes) {
1465       $attributes = $bind_attributes->{$column_name}
1466       if defined $bind_attributes->{$column_name};
1467     }
1468
1469     foreach my $data (@data) {
1470       my $ref = ref $data;
1471       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1472
1473       $sth->bind_param($placeholder_index, $data, $attributes);
1474       $placeholder_index++;
1475     }
1476   }
1477
1478   # Can this fail without throwing an exception anyways???
1479   my $rv = $sth->execute();
1480   $self->throw_exception($sth->errstr) if !$rv;
1481
1482   $self->_query_end( $sql, @$bind );
1483
1484   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1485 }
1486
1487 sub _execute {
1488     my $self = shift;
1489     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1490 }
1491
1492 sub _prefetch_insert_auto_nextvals {
1493   my ($self, $source, $to_insert) = @_;
1494
1495   my $upd = {};
1496
1497   foreach my $col ( $source->columns ) {
1498     if ( !defined $to_insert->{$col} ) {
1499       my $col_info = $source->column_info($col);
1500
1501       if ( $col_info->{auto_nextval} ) {
1502         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1503           'nextval',
1504           $col_info->{sequence} ||=
1505             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1506         );
1507       }
1508     }
1509   }
1510
1511   return $upd;
1512 }
1513
1514 sub insert {
1515   my $self = shift;
1516   my ($source, $to_insert, $opts) = @_;
1517
1518   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1519
1520   my $bind_attributes = $self->source_bind_attributes($source);
1521
1522   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1523
1524   if ($opts->{returning}) {
1525     my @ret_cols = @{$opts->{returning}};
1526
1527     my @ret_vals = eval {
1528       local $SIG{__WARN__} = sub {};
1529       my @r = $sth->fetchrow_array;
1530       $sth->finish;
1531       @r;
1532     };
1533
1534     my %ret;
1535     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1536
1537     $updated_cols = {
1538       %$updated_cols,
1539       %ret,
1540     };
1541   }
1542
1543   return $updated_cols;
1544 }
1545
1546 ## Currently it is assumed that all values passed will be "normal", i.e. not
1547 ## scalar refs, or at least, all the same type as the first set, the statement is
1548 ## only prepped once.
1549 sub insert_bulk {
1550   my ($self, $source, $cols, $data) = @_;
1551
1552   my %colvalues;
1553   @colvalues{@$cols} = (0..$#$cols);
1554
1555   for my $i (0..$#$cols) {
1556     my $first_val = $data->[0][$i];
1557     next unless ref $first_val eq 'SCALAR';
1558
1559     $colvalues{ $cols->[$i] } = $first_val;
1560   }
1561
1562   # check for bad data and stringify stringifiable objects
1563   my $bad_slice = sub {
1564     my ($msg, $col_idx, $slice_idx) = @_;
1565     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1566       $msg,
1567       $cols->[$col_idx],
1568       do {
1569         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1570         Data::Dumper::Concise::Dumper({
1571           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1572         }),
1573       }
1574     );
1575   };
1576
1577   for my $datum_idx (0..$#$data) {
1578     my $datum = $data->[$datum_idx];
1579
1580     for my $col_idx (0..$#$cols) {
1581       my $val            = $datum->[$col_idx];
1582       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1583       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1584
1585       if ($is_literal_sql) {
1586         if (not ref $val) {
1587           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1588         }
1589         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1590           $bad_slice->("$reftype reference found where literal SQL expected",
1591             $col_idx, $datum_idx);
1592         }
1593         elsif ($$val ne $$sqla_bind){
1594           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1595             $col_idx, $datum_idx);
1596         }
1597       }
1598       elsif (my $reftype = ref $val) {
1599         require overload;
1600         if (overload::Method($val, '""')) {
1601           $datum->[$col_idx] = "".$val;
1602         }
1603         else {
1604           $bad_slice->("$reftype reference found where bind expected",
1605             $col_idx, $datum_idx);
1606         }
1607       }
1608     }
1609   }
1610
1611   my ($sql, $bind) = $self->_prep_for_execute (
1612     'insert', undef, $source, [\%colvalues]
1613   );
1614   my @bind = @$bind;
1615
1616   my $empty_bind = 1 if (not @bind) &&
1617     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1618
1619   if ((not @bind) && (not $empty_bind)) {
1620     $self->throw_exception(
1621       'Cannot insert_bulk without support for placeholders'
1622     );
1623   }
1624
1625   # neither _execute_array, nor _execute_inserts_with_no_binds are
1626   # atomic (even if _execute _array is a single call). Thus a safety
1627   # scope guard
1628   my $guard = $self->txn_scope_guard;
1629
1630   $self->_query_start( $sql, ['__BULK__'] );
1631   my $sth = $self->sth($sql);
1632   my $rv = do {
1633     if ($empty_bind) {
1634       # bind_param_array doesn't work if there are no binds
1635       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1636     }
1637     else {
1638 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1639       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1640     }
1641   };
1642
1643   $self->_query_end( $sql, ['__BULK__'] );
1644
1645   $guard->commit;
1646
1647   return (wantarray ? ($rv, $sth, @bind) : $rv);
1648 }
1649
1650 sub _execute_array {
1651   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1652
1653   ## This must be an arrayref, else nothing works!
1654   my $tuple_status = [];
1655
1656   ## Get the bind_attributes, if any exist
1657   my $bind_attributes = $self->source_bind_attributes($source);
1658
1659   ## Bind the values and execute
1660   my $placeholder_index = 1;
1661
1662   foreach my $bound (@$bind) {
1663
1664     my $attributes = {};
1665     my ($column_name, $data_index) = @$bound;
1666
1667     if( $bind_attributes ) {
1668       $attributes = $bind_attributes->{$column_name}
1669       if defined $bind_attributes->{$column_name};
1670     }
1671
1672     my @data = map { $_->[$data_index] } @$data;
1673
1674     $sth->bind_param_array(
1675       $placeholder_index,
1676       [@data],
1677       (%$attributes ?  $attributes : ()),
1678     );
1679     $placeholder_index++;
1680   }
1681
1682   my $rv = eval {
1683     $self->_dbh_execute_array($sth, $tuple_status, @extra);
1684   };
1685   my $err = $@ || $sth->errstr;
1686
1687 # Statement must finish even if there was an exception.
1688   eval { $sth->finish };
1689   $err = $@ unless $err;
1690
1691   if ($err) {
1692     my $i = 0;
1693     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1694
1695     $self->throw_exception("Unexpected populate error: $err")
1696       if ($i > $#$tuple_status);
1697
1698     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1699       ($tuple_status->[$i][1] || $err),
1700       Data::Dumper::Concise::Dumper({
1701         map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols)
1702       }),
1703     );
1704   }
1705   return $rv;
1706 }
1707
1708 sub _dbh_execute_array {
1709     my ($self, $sth, $tuple_status, @extra) = @_;
1710
1711     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1712 }
1713
1714 sub _dbh_execute_inserts_with_no_binds {
1715   my ($self, $sth, $count) = @_;
1716
1717   eval {
1718     my $dbh = $self->_get_dbh;
1719     local $dbh->{RaiseError} = 1;
1720     local $dbh->{PrintError} = 0;
1721
1722     $sth->execute foreach 1..$count;
1723   };
1724   my $exception = $@;
1725
1726 # Make sure statement is finished even if there was an exception.
1727   eval { $sth->finish };
1728   $exception = $@ unless $exception;
1729
1730   $self->throw_exception($exception) if $exception;
1731
1732   return $count;
1733 }
1734
1735 sub update {
1736   my ($self, $source, @args) = @_;
1737
1738   my $bind_attrs = $self->source_bind_attributes($source);
1739
1740   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1741 }
1742
1743
1744 sub delete {
1745   my ($self, $source, @args) = @_;
1746
1747   my $bind_attrs = $self->source_bind_attributes($source);
1748
1749   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1750 }
1751
1752 # We were sent here because the $rs contains a complex search
1753 # which will require a subquery to select the correct rows
1754 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1755 #
1756 # Generating a single PK column subquery is trivial and supported
1757 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1758 # Look at _multipk_update_delete()
1759 sub _subq_update_delete {
1760   my $self = shift;
1761   my ($rs, $op, $values) = @_;
1762
1763   my $rsrc = $rs->result_source;
1764
1765   # quick check if we got a sane rs on our hands
1766   my @pcols = $rsrc->_pri_cols;
1767
1768   my $sel = $rs->_resolved_attrs->{select};
1769   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1770
1771   if (
1772       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1773         ne
1774       join ("\x00", sort @$sel )
1775   ) {
1776     $self->throw_exception (
1777       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1778     );
1779   }
1780
1781   if (@pcols == 1) {
1782     return $self->$op (
1783       $rsrc,
1784       $op eq 'update' ? $values : (),
1785       { $pcols[0] => { -in => $rs->as_query } },
1786     );
1787   }
1788
1789   else {
1790     return $self->_multipk_update_delete (@_);
1791   }
1792 }
1793
1794 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1795 # resultset update/delete involving subqueries. So by default resort
1796 # to simple (and inefficient) delete_all style per-row opearations,
1797 # while allowing specific storages to override this with a faster
1798 # implementation.
1799 #
1800 sub _multipk_update_delete {
1801   return shift->_per_row_update_delete (@_);
1802 }
1803
1804 # This is the default loop used to delete/update rows for multi PK
1805 # resultsets, and used by mysql exclusively (because it can't do anything
1806 # else).
1807 #
1808 # We do not use $row->$op style queries, because resultset update/delete
1809 # is not expected to cascade (this is what delete_all/update_all is for).
1810 #
1811 # There should be no race conditions as the entire operation is rolled
1812 # in a transaction.
1813 #
1814 sub _per_row_update_delete {
1815   my $self = shift;
1816   my ($rs, $op, $values) = @_;
1817
1818   my $rsrc = $rs->result_source;
1819   my @pcols = $rsrc->_pri_cols;
1820
1821   my $guard = $self->txn_scope_guard;
1822
1823   # emulate the return value of $sth->execute for non-selects
1824   my $row_cnt = '0E0';
1825
1826   my $subrs_cur = $rs->cursor;
1827   my @all_pk = $subrs_cur->all;
1828   for my $pks ( @all_pk) {
1829
1830     my $cond;
1831     for my $i (0.. $#pcols) {
1832       $cond->{$pcols[$i]} = $pks->[$i];
1833     }
1834
1835     $self->$op (
1836       $rsrc,
1837       $op eq 'update' ? $values : (),
1838       $cond,
1839     );
1840
1841     $row_cnt++;
1842   }
1843
1844   $guard->commit;
1845
1846   return $row_cnt;
1847 }
1848
1849 sub _select {
1850   my $self = shift;
1851   $self->_execute($self->_select_args(@_));
1852 }
1853
1854 sub _select_args_to_query {
1855   my $self = shift;
1856
1857   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1858   #  = $self->_select_args($ident, $select, $cond, $attrs);
1859   my ($op, $bind, $ident, $bind_attrs, @args) =
1860     $self->_select_args(@_);
1861
1862   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1863   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1864   $prepared_bind ||= [];
1865
1866   return wantarray
1867     ? ($sql, $prepared_bind, $bind_attrs)
1868     : \[ "($sql)", @$prepared_bind ]
1869   ;
1870 }
1871
1872 sub _select_args {
1873   my ($self, $ident, $select, $where, $attrs) = @_;
1874
1875   my $sql_maker = $self->sql_maker;
1876   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1877
1878   $attrs = {
1879     %$attrs,
1880     select => $select,
1881     from => $ident,
1882     where => $where,
1883     $rs_alias && $alias2source->{$rs_alias}
1884       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1885       : ()
1886     ,
1887   };
1888
1889   # calculate bind_attrs before possible $ident mangling
1890   my $bind_attrs = {};
1891   for my $alias (keys %$alias2source) {
1892     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1893     for my $col (keys %$bindtypes) {
1894
1895       my $fqcn = join ('.', $alias, $col);
1896       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1897
1898       # Unqialified column names are nice, but at the same time can be
1899       # rather ambiguous. What we do here is basically go along with
1900       # the loop, adding an unqualified column slot to $bind_attrs,
1901       # alongside the fully qualified name. As soon as we encounter
1902       # another column by that name (which would imply another table)
1903       # we unset the unqualified slot and never add any info to it
1904       # to avoid erroneous type binding. If this happens the users
1905       # only choice will be to fully qualify his column name
1906
1907       if (exists $bind_attrs->{$col}) {
1908         $bind_attrs->{$col} = {};
1909       }
1910       else {
1911         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1912       }
1913     }
1914   }
1915
1916   # adjust limits
1917   if (
1918     $attrs->{software_limit}
1919       ||
1920     $sql_maker->_default_limit_syntax eq "GenericSubQ"
1921   ) {
1922     $attrs->{software_limit} = 1;
1923   }
1924   else {
1925     $self->throw_exception("rows attribute must be positive if present")
1926       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1927
1928     # MySQL actually recommends this approach.  I cringe.
1929     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1930   }
1931
1932   my @limit;
1933
1934   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1935   # storage, unless software limit was requested
1936   if (
1937     #limited has_many
1938     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1939        ||
1940     # grouped prefetch (to satisfy group_by == select)
1941     ( $attrs->{group_by}
1942         &&
1943       @{$attrs->{group_by}}
1944         &&
1945       $attrs->{_prefetch_select}
1946         &&
1947       @{$attrs->{_prefetch_select}}
1948     )
1949   ) {
1950     ($ident, $select, $where, $attrs)
1951       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1952   }
1953   elsif (! $attrs->{software_limit} ) {
1954     push @limit, $attrs->{rows}, $attrs->{offset};
1955   }
1956
1957   # try to simplify the joinmap further (prune unreferenced type-single joins)
1958   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1959
1960 ###
1961   # This would be the point to deflate anything found in $where
1962   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1963   # expect a row object. And all we have is a resultsource (it is trivial
1964   # to extract deflator coderefs via $alias2source above).
1965   #
1966   # I don't see a way forward other than changing the way deflators are
1967   # invoked, and that's just bad...
1968 ###
1969
1970   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
1971 }
1972
1973 # Returns a counting SELECT for a simple count
1974 # query. Abstracted so that a storage could override
1975 # this to { count => 'firstcol' } or whatever makes
1976 # sense as a performance optimization
1977 sub _count_select {
1978   #my ($self, $source, $rs_attrs) = @_;
1979   return { count => '*' };
1980 }
1981
1982
1983 sub source_bind_attributes {
1984   my ($self, $source) = @_;
1985
1986   my $bind_attributes;
1987   foreach my $column ($source->columns) {
1988
1989     my $data_type = $source->column_info($column)->{data_type} || '';
1990     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1991      if $data_type;
1992   }
1993
1994   return $bind_attributes;
1995 }
1996
1997 =head2 select
1998
1999 =over 4
2000
2001 =item Arguments: $ident, $select, $condition, $attrs
2002
2003 =back
2004
2005 Handle a SQL select statement.
2006
2007 =cut
2008
2009 sub select {
2010   my $self = shift;
2011   my ($ident, $select, $condition, $attrs) = @_;
2012   return $self->cursor_class->new($self, \@_, $attrs);
2013 }
2014
2015 sub select_single {
2016   my $self = shift;
2017   my ($rv, $sth, @bind) = $self->_select(@_);
2018   my @row = $sth->fetchrow_array;
2019   my @nextrow = $sth->fetchrow_array if @row;
2020   if(@row && @nextrow) {
2021     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2022   }
2023   # Need to call finish() to work round broken DBDs
2024   $sth->finish();
2025   return @row;
2026 }
2027
2028 =head2 sth
2029
2030 =over 4
2031
2032 =item Arguments: $sql
2033
2034 =back
2035
2036 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2037
2038 =cut
2039
2040 sub _dbh_sth {
2041   my ($self, $dbh, $sql) = @_;
2042
2043   # 3 is the if_active parameter which avoids active sth re-use
2044   my $sth = $self->disable_sth_caching
2045     ? $dbh->prepare($sql)
2046     : $dbh->prepare_cached($sql, {}, 3);
2047
2048   # XXX You would think RaiseError would make this impossible,
2049   #  but apparently that's not true :(
2050   $self->throw_exception($dbh->errstr) if !$sth;
2051
2052   $sth;
2053 }
2054
2055 sub sth {
2056   my ($self, $sql) = @_;
2057   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2058 }
2059
2060 sub _dbh_columns_info_for {
2061   my ($self, $dbh, $table) = @_;
2062
2063   if ($dbh->can('column_info')) {
2064     my %result;
2065     eval {
2066       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2067       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2068       $sth->execute();
2069       while ( my $info = $sth->fetchrow_hashref() ){
2070         my %column_info;
2071         $column_info{data_type}   = $info->{TYPE_NAME};
2072         $column_info{size}      = $info->{COLUMN_SIZE};
2073         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2074         $column_info{default_value} = $info->{COLUMN_DEF};
2075         my $col_name = $info->{COLUMN_NAME};
2076         $col_name =~ s/^\"(.*)\"$/$1/;
2077
2078         $result{$col_name} = \%column_info;
2079       }
2080     };
2081     return \%result if !$@ && scalar keys %result;
2082   }
2083
2084   my %result;
2085   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2086   $sth->execute;
2087   my @columns = @{$sth->{NAME_lc}};
2088   for my $i ( 0 .. $#columns ){
2089     my %column_info;
2090     $column_info{data_type} = $sth->{TYPE}->[$i];
2091     $column_info{size} = $sth->{PRECISION}->[$i];
2092     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2093
2094     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2095       $column_info{data_type} = $1;
2096       $column_info{size}    = $2;
2097     }
2098
2099     $result{$columns[$i]} = \%column_info;
2100   }
2101   $sth->finish;
2102
2103   foreach my $col (keys %result) {
2104     my $colinfo = $result{$col};
2105     my $type_num = $colinfo->{data_type};
2106     my $type_name;
2107     if(defined $type_num && $dbh->can('type_info')) {
2108       my $type_info = $dbh->type_info($type_num);
2109       $type_name = $type_info->{TYPE_NAME} if $type_info;
2110       $colinfo->{data_type} = $type_name if $type_name;
2111     }
2112   }
2113
2114   return \%result;
2115 }
2116
2117 sub columns_info_for {
2118   my ($self, $table) = @_;
2119   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2120 }
2121
2122 =head2 last_insert_id
2123
2124 Return the row id of the last insert.
2125
2126 =cut
2127
2128 sub _dbh_last_insert_id {
2129     my ($self, $dbh, $source, $col) = @_;
2130
2131     my $id = eval { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2132
2133     return $id if defined $id;
2134
2135     my $class = ref $self;
2136     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2137 }
2138
2139 sub last_insert_id {
2140   my $self = shift;
2141   $self->_dbh_last_insert_id ($self->_dbh, @_);
2142 }
2143
2144 =head2 _native_data_type
2145
2146 =over 4
2147
2148 =item Arguments: $type_name
2149
2150 =back
2151
2152 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2153 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2154 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2155
2156 The default implementation returns C<undef>, implement in your Storage driver if
2157 you need this functionality.
2158
2159 Should map types from other databases to the native RDBMS type, for example
2160 C<VARCHAR2> to C<VARCHAR>.
2161
2162 Types with modifiers should map to the underlying data type. For example,
2163 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2164
2165 Composite types should map to the container type, for example
2166 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2167
2168 =cut
2169
2170 sub _native_data_type {
2171   #my ($self, $data_type) = @_;
2172   return undef
2173 }
2174
2175 # Check if placeholders are supported at all
2176 sub _placeholders_supported {
2177   my $self = shift;
2178   my $dbh  = $self->_get_dbh;
2179
2180   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2181   # but it is inaccurate more often than not
2182   eval {
2183     local $dbh->{PrintError} = 0;
2184     local $dbh->{RaiseError} = 1;
2185     $dbh->do('select ?', {}, 1);
2186   };
2187   return $@ ? 0 : 1;
2188 }
2189
2190 # Check if placeholders bound to non-string types throw exceptions
2191 #
2192 sub _typeless_placeholders_supported {
2193   my $self = shift;
2194   my $dbh  = $self->_get_dbh;
2195
2196   eval {
2197     local $dbh->{PrintError} = 0;
2198     local $dbh->{RaiseError} = 1;
2199     # this specifically tests a bind that is NOT a string
2200     $dbh->do('select 1 where 1 = ?', {}, 1);
2201   };
2202   return $@ ? 0 : 1;
2203 }
2204
2205 =head2 sqlt_type
2206
2207 Returns the database driver name.
2208
2209 =cut
2210
2211 sub sqlt_type {
2212   shift->_get_dbh->{Driver}->{Name};
2213 }
2214
2215 =head2 bind_attribute_by_data_type
2216
2217 Given a datatype from column info, returns a database specific bind
2218 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2219 let the database planner just handle it.
2220
2221 Generally only needed for special case column types, like bytea in postgres.
2222
2223 =cut
2224
2225 sub bind_attribute_by_data_type {
2226     return;
2227 }
2228
2229 =head2 is_datatype_numeric
2230
2231 Given a datatype from column_info, returns a boolean value indicating if
2232 the current RDBMS considers it a numeric value. This controls how
2233 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2234 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2235 be performed instead of the usual C<eq>.
2236
2237 =cut
2238
2239 sub is_datatype_numeric {
2240   my ($self, $dt) = @_;
2241
2242   return 0 unless $dt;
2243
2244   return $dt =~ /^ (?:
2245     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2246   ) $/ix;
2247 }
2248
2249
2250 =head2 create_ddl_dir
2251
2252 =over 4
2253
2254 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2255
2256 =back
2257
2258 Creates a SQL file based on the Schema, for each of the specified
2259 database engines in C<\@databases> in the given directory.
2260 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2261
2262 Given a previous version number, this will also create a file containing
2263 the ALTER TABLE statements to transform the previous schema into the
2264 current one. Note that these statements may contain C<DROP TABLE> or
2265 C<DROP COLUMN> statements that can potentially destroy data.
2266
2267 The file names are created using the C<ddl_filename> method below, please
2268 override this method in your schema if you would like a different file
2269 name format. For the ALTER file, the same format is used, replacing
2270 $version in the name with "$preversion-$version".
2271
2272 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2273 The most common value for this would be C<< { add_drop_table => 1 } >>
2274 to have the SQL produced include a C<DROP TABLE> statement for each table
2275 created. For quoting purposes supply C<quote_table_names> and
2276 C<quote_field_names>.
2277
2278 If no arguments are passed, then the following default values are assumed:
2279
2280 =over 4
2281
2282 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2283
2284 =item version    - $schema->schema_version
2285
2286 =item directory  - './'
2287
2288 =item preversion - <none>
2289
2290 =back
2291
2292 By default, C<\%sqlt_args> will have
2293
2294  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2295
2296 merged with the hash passed in. To disable any of those features, pass in a
2297 hashref like the following
2298
2299  { ignore_constraint_names => 0, # ... other options }
2300
2301
2302 WARNING: You are strongly advised to check all SQL files created, before applying
2303 them.
2304
2305 =cut
2306
2307 sub create_ddl_dir {
2308   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2309
2310   unless ($dir) {
2311     carp "No directory given, using ./\n";
2312     $dir = './';
2313   } else {
2314       -d $dir or File::Path::mkpath($dir)
2315           or $self->throw_exception("create_ddl_dir: $! creating dir '$dir'");
2316   }
2317
2318   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2319
2320   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2321   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2322
2323   my $schema_version = $schema->schema_version || '1.x';
2324   $version ||= $schema_version;
2325
2326   $sqltargs = {
2327     add_drop_table => 1,
2328     ignore_constraint_names => 1,
2329     ignore_index_names => 1,
2330     %{$sqltargs || {}}
2331   };
2332
2333   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2334     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2335   }
2336
2337   my $sqlt = SQL::Translator->new( $sqltargs );
2338
2339   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2340   my $sqlt_schema = $sqlt->translate({ data => $schema })
2341     or $self->throw_exception ($sqlt->error);
2342
2343   foreach my $db (@$databases) {
2344     $sqlt->reset();
2345     $sqlt->{schema} = $sqlt_schema;
2346     $sqlt->producer($db);
2347
2348     my $file;
2349     my $filename = $schema->ddl_filename($db, $version, $dir);
2350     if (-e $filename && ($version eq $schema_version )) {
2351       # if we are dumping the current version, overwrite the DDL
2352       carp "Overwriting existing DDL file - $filename";
2353       unlink($filename);
2354     }
2355
2356     my $output = $sqlt->translate;
2357     if(!$output) {
2358       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2359       next;
2360     }
2361     if(!open($file, ">$filename")) {
2362       $self->throw_exception("Can't open $filename for writing ($!)");
2363       next;
2364     }
2365     print $file $output;
2366     close($file);
2367
2368     next unless ($preversion);
2369
2370     require SQL::Translator::Diff;
2371
2372     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2373     if(!-e $prefilename) {
2374       carp("No previous schema file found ($prefilename)");
2375       next;
2376     }
2377
2378     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2379     if(-e $difffile) {
2380       carp("Overwriting existing diff file - $difffile");
2381       unlink($difffile);
2382     }
2383
2384     my $source_schema;
2385     {
2386       my $t = SQL::Translator->new($sqltargs);
2387       $t->debug( 0 );
2388       $t->trace( 0 );
2389
2390       $t->parser( $db )
2391         or $self->throw_exception ($t->error);
2392
2393       my $out = $t->translate( $prefilename )
2394         or $self->throw_exception ($t->error);
2395
2396       $source_schema = $t->schema;
2397
2398       $source_schema->name( $prefilename )
2399         unless ( $source_schema->name );
2400     }
2401
2402     # The "new" style of producers have sane normalization and can support
2403     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2404     # And we have to diff parsed SQL against parsed SQL.
2405     my $dest_schema = $sqlt_schema;
2406
2407     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2408       my $t = SQL::Translator->new($sqltargs);
2409       $t->debug( 0 );
2410       $t->trace( 0 );
2411
2412       $t->parser( $db )
2413         or $self->throw_exception ($t->error);
2414
2415       my $out = $t->translate( $filename )
2416         or $self->throw_exception ($t->error);
2417
2418       $dest_schema = $t->schema;
2419
2420       $dest_schema->name( $filename )
2421         unless $dest_schema->name;
2422     }
2423
2424     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2425                                                   $dest_schema,   $db,
2426                                                   $sqltargs
2427                                                  );
2428     if(!open $file, ">$difffile") {
2429       $self->throw_exception("Can't write to $difffile ($!)");
2430       next;
2431     }
2432     print $file $diff;
2433     close($file);
2434   }
2435 }
2436
2437 =head2 deployment_statements
2438
2439 =over 4
2440
2441 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2442
2443 =back
2444
2445 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2446
2447 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2448 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2449
2450 C<$directory> is used to return statements from files in a previously created
2451 L</create_ddl_dir> directory and is optional. The filenames are constructed
2452 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2453
2454 If no C<$directory> is specified then the statements are constructed on the
2455 fly using L<SQL::Translator> and C<$version> is ignored.
2456
2457 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2458
2459 =cut
2460
2461 sub deployment_statements {
2462   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2463   $type ||= $self->sqlt_type;
2464   $version ||= $schema->schema_version || '1.x';
2465   $dir ||= './';
2466   my $filename = $schema->ddl_filename($type, $version, $dir);
2467   if(-f $filename)
2468   {
2469       my $file;
2470       open($file, "<$filename")
2471         or $self->throw_exception("Can't open $filename ($!)");
2472       my @rows = <$file>;
2473       close($file);
2474       return join('', @rows);
2475   }
2476
2477   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2478     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2479   }
2480
2481   # sources needs to be a parser arg, but for simplicty allow at top level
2482   # coming in
2483   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2484       if exists $sqltargs->{sources};
2485
2486   my $tr = SQL::Translator->new(
2487     producer => "SQL::Translator::Producer::${type}",
2488     %$sqltargs,
2489     parser => 'SQL::Translator::Parser::DBIx::Class',
2490     data => $schema,
2491   );
2492
2493   my @ret;
2494   my $wa = wantarray;
2495   if ($wa) {
2496     @ret = $tr->translate;
2497   }
2498   else {
2499     $ret[0] = $tr->translate;
2500   }
2501
2502   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2503     unless (@ret && defined $ret[0]);
2504
2505   return $wa ? @ret : $ret[0];
2506 }
2507
2508 sub deploy {
2509   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2510   my $deploy = sub {
2511     my $line = shift;
2512     return if($line =~ /^--/);
2513     return if(!$line);
2514     # next if($line =~ /^DROP/m);
2515     return if($line =~ /^BEGIN TRANSACTION/m);
2516     return if($line =~ /^COMMIT/m);
2517     return if $line =~ /^\s+$/; # skip whitespace only
2518     $self->_query_start($line);
2519     eval {
2520       # do a dbh_do cycle here, as we need some error checking in
2521       # place (even though we will ignore errors)
2522       $self->dbh_do (sub { $_[1]->do($line) });
2523     };
2524     if ($@) {
2525       carp qq{$@ (running "${line}")};
2526     }
2527     $self->_query_end($line);
2528   };
2529   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2530   if (@statements > 1) {
2531     foreach my $statement (@statements) {
2532       $deploy->( $statement );
2533     }
2534   }
2535   elsif (@statements == 1) {
2536     foreach my $line ( split(";\n", $statements[0])) {
2537       $deploy->( $line );
2538     }
2539   }
2540 }
2541
2542 =head2 datetime_parser
2543
2544 Returns the datetime parser class
2545
2546 =cut
2547
2548 sub datetime_parser {
2549   my $self = shift;
2550   return $self->{datetime_parser} ||= do {
2551     $self->build_datetime_parser(@_);
2552   };
2553 }
2554
2555 =head2 datetime_parser_type
2556
2557 Defines (returns) the datetime parser class - currently hardwired to
2558 L<DateTime::Format::MySQL>
2559
2560 =cut
2561
2562 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2563
2564 =head2 build_datetime_parser
2565
2566 See L</datetime_parser>
2567
2568 =cut
2569
2570 sub build_datetime_parser {
2571   my $self = shift;
2572   my $type = $self->datetime_parser_type(@_);
2573   $self->ensure_class_loaded ($type);
2574   return $type;
2575 }
2576
2577
2578 =head2 is_replicating
2579
2580 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2581 replicate from a master database.  Default is undef, which is the result
2582 returned by databases that don't support replication.
2583
2584 =cut
2585
2586 sub is_replicating {
2587     return;
2588
2589 }
2590
2591 =head2 lag_behind_master
2592
2593 Returns a number that represents a certain amount of lag behind a master db
2594 when a given storage is replicating.  The number is database dependent, but
2595 starts at zero and increases with the amount of lag. Default in undef
2596
2597 =cut
2598
2599 sub lag_behind_master {
2600     return;
2601 }
2602
2603 =head2 relname_to_table_alias
2604
2605 =over 4
2606
2607 =item Arguments: $relname, $join_count
2608
2609 =back
2610
2611 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2612 queries.
2613
2614 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2615 way these aliases are named.
2616
2617 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2618 otherwise C<"$relname">.
2619
2620 =cut
2621
2622 sub relname_to_table_alias {
2623   my ($self, $relname, $join_count) = @_;
2624
2625   my $alias = ($join_count && $join_count > 1 ?
2626     join('_', $relname, $join_count) : $relname);
2627
2628   return $alias;
2629 }
2630
2631 1;
2632
2633 =head1 USAGE NOTES
2634
2635 =head2 DBIx::Class and AutoCommit
2636
2637 DBIx::Class can do some wonderful magic with handling exceptions,
2638 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2639 (the default) combined with C<txn_do> for transaction support.
2640
2641 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2642 in an assumed transaction between commits, and you're telling us you'd
2643 like to manage that manually.  A lot of the magic protections offered by
2644 this module will go away.  We can't protect you from exceptions due to database
2645 disconnects because we don't know anything about how to restart your
2646 transactions.  You're on your own for handling all sorts of exceptional
2647 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2648 be with raw DBI.
2649
2650
2651 =head1 AUTHORS
2652
2653 Matt S. Trout <mst@shadowcatsystems.co.uk>
2654
2655 Andy Grundman <andy@hybridized.org>
2656
2657 =head1 LICENSE
2658
2659 You may distribute this code under the same terms as Perl itself.
2660
2661 =cut