lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util();
  15 use List::Util();
  16 use Data::Dumper::Concise();
  17 use Sub::Name ();
  18 use Try::Tiny;
  19
  20 use File::Path ();
  21
  22 __PACKAGE__->mk_group_accessors('simple' =>
  23   qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid
  24      _conn_tid transaction_depth _dbh_autocommit _driver_determined savepoints
  25      _server_info_hash/
  26 );
  27
  28 # the values for these accessors are picked out (and deleted) from
  29 # the attribute hashref passed to connect_info
  30 my @storage_options = qw/
  31   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  32   disable_sth_caching unsafe auto_savepoint
  33 /;
  34 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  35
  36
  37 # default cursor class, overridable in connect_info attributes
  38 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  39
  40 __PACKAGE__->mk_group_accessors('inherited' => qw/
  41   sql_maker_class
  42   _supports_insert_returning
  43 /);
  44 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  45
  46 # Each of these methods need _determine_driver called before itself
  47 # in order to function reliably. This is a purely DRY optimization
  48 my @rdbms_specific_methods = qw/
  49   deployment_statements
  50   sqlt_type
  51   sql_maker
  52   build_datetime_parser
  53   datetime_parser_type
  54
  55   insert
  56   insert_bulk
  57   update
  58   delete
  59   select
  60   select_single
  61 /;
  62
  63 for my $meth (@rdbms_specific_methods) {
  64
  65   my $orig = __PACKAGE__->can ($meth)
  66     or next;
  67
  68   no strict qw/refs/;
  69   no warnings qw/redefine/;
  70   *{__PACKAGE__ ."::$meth"} = Sub::Name::subname $meth => sub {
  71     if (not $_[0]->_driver_determined) {
  72       $_[0]->_determine_driver;
  73       goto $_[0]->can($meth);
  74     }
  75     $orig->(@_);
  76   };
  77 }
  78
  79
  80 =head1 NAME
  81
  82 DBIx::Class::Storage::DBI - DBI storage handler
  83
  84 =head1 SYNOPSIS
  85
  86   my $schema = MySchema->connect('dbi:SQLite:my.db');
  87
  88   $schema->storage->debug(1);
  89
  90   my @stuff = $schema->storage->dbh_do(
  91     sub {
  92       my ($storage, $dbh, @args) = @_;
  93       $dbh->do("DROP TABLE authors");
  94     },
  95     @column_list
  96   );
  97
  98   $schema->resultset('Book')->search({
  99      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 100   });
 101
 102 =head1 DESCRIPTION
 103
 104 This class represents the connection to an RDBMS via L<DBI>.  See
 105 L<DBIx::Class::Storage> for general information.  This pod only
 106 documents DBI-specific methods and behaviors.
 107
 108 =head1 METHODS
 109
 110 =cut
 111
 112 sub new {
 113   my $new = shift->next::method(@_);
 114
 115   $new->transaction_depth(0);
 116   $new->_sql_maker_opts({});
 117   $new->{savepoints} = [];
 118   $new->{_in_dbh_do} = 0;
 119   $new->{_dbh_gen} = 0;
 120
 121   # read below to see what this does
 122   $new->_arm_global_destructor;
 123
 124   $new;
 125 }
 126
 127 # This is hack to work around perl shooting stuff in random
 128 # order on exit(). If we do not walk the remaining storage
 129 # objects in an END block, there is a *small but real* chance
 130 # of a fork()ed child to kill the parent's shared DBI handle,
 131 # *before perl reaches the DESTROY in this package*
 132 # Yes, it is ugly and effective.
 133 {
 134   my %seek_and_destroy;
 135
 136   sub _arm_global_destructor {
 137     my $self = shift;
 138     my $key = Scalar::Util::refaddr ($self);
 139     $seek_and_destroy{$key} = $self;
 140     Scalar::Util::weaken ($seek_and_destroy{$key});
 141   }
 142
 143   END {
 144     local $?; # just in case the DBI destructor changes it somehow
 145
 146     # destroy just the object if not native to this process/thread
 147     $_->_preserve_foreign_dbh for (grep
 148       { defined $_ }
 149       values %seek_and_destroy
 150     );
 151   }
 152 }
 153
 154 sub DESTROY {
 155   my $self = shift;
 156
 157   # destroy just the object if not native to this process/thread
 158   $self->_preserve_foreign_dbh;
 159
 160   # some databases need this to stop spewing warnings
 161   if (my $dbh = $self->_dbh) {
 162     try {
 163       %{ $dbh->{CachedKids} } = ();
 164       $dbh->disconnect;
 165     };
 166   }
 167
 168   $self->_dbh(undef);
 169 }
 170
 171 sub _preserve_foreign_dbh {
 172   my $self = shift;
 173
 174   return unless $self->_dbh;
 175
 176   $self->_verify_tid;
 177
 178   return unless $self->_dbh;
 179
 180   $self->_verify_pid;
 181
 182 }
 183
 184 # handle pid changes correctly - do not destroy parent's connection
 185 sub _verify_pid {
 186   my $self = shift;
 187
 188   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 189
 190   $self->_dbh->{InactiveDestroy} = 1;
 191   $self->_dbh(undef);
 192   $self->{_dbh_gen}++;
 193
 194   return;
 195 }
 196
 197 # very similar to above, but seems to FAIL if I set InactiveDestroy
 198 sub _verify_tid {
 199   my $self = shift;
 200
 201   if ( ! defined $self->_conn_tid ) {
 202     return; # no threads
 203   }
 204   elsif ( $self->_conn_tid == threads->tid ) {
 205     return; # same thread
 206   }
 207
 208   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 209   $self->_dbh(undef);
 210   $self->{_dbh_gen}++;
 211
 212   return;
 213 }
 214
 215
 216 =head2 connect_info
 217
 218 This method is normally called by L<DBIx::Class::Schema/connection>, which
 219 encapsulates its argument list in an arrayref before passing them here.
 220
 221 The argument list may contain:
 222
 223 =over
 224
 225 =item *
 226
 227 The same 4-element argument set one would normally pass to
 228 L<DBI/connect>, optionally followed by
 229 L<extra attributes|/DBIx::Class specific connection attributes>
 230 recognized by DBIx::Class:
 231
 232   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 233
 234 =item *
 235
 236 A single code reference which returns a connected
 237 L<DBI database handle|DBI/connect> optionally followed by
 238 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 239 by DBIx::Class:
 240
 241   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 242
 243 =item *
 244
 245 A single hashref with all the attributes and the dsn/user/password
 246 mixed together:
 247
 248   $connect_info_args = [{
 249     dsn => $dsn,
 250     user => $user,
 251     password => $pass,
 252     %dbi_attributes,
 253     %extra_attributes,
 254   }];
 255
 256   $connect_info_args = [{
 257     dbh_maker => sub { DBI->connect (...) },
 258     %dbi_attributes,
 259     %extra_attributes,
 260   }];
 261
 262 This is particularly useful for L<Catalyst> based applications, allowing the
 263 following config (L<Config::General> style):
 264
 265   <Model::DB>
 266     schema_class   App::DB
 267     <connect_info>
 268       dsn          dbi:mysql:database=test
 269       user         testuser
 270       password     TestPass
 271       AutoCommit   1
 272     </connect_info>
 273   </Model::DB>
 274
 275 The C<dsn>/C<user>/C<password> combination can be substituted by the
 276 C<dbh_maker> key whose value is a coderef that returns a connected
 277 L<DBI database handle|DBI/connect>
 278
 279 =back
 280
 281 Please note that the L<DBI> docs recommend that you always explicitly
 282 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 283 recommends that it be set to I<1>, and that you perform transactions
 284 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 285 to I<1> if you do not do explicitly set it to zero.  This is the default
 286 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 287
 288 =head3 DBIx::Class specific connection attributes
 289
 290 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 291 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 292 the following connection options. These options can be mixed in with your other
 293 L<DBI> connection attributes, or placed in a separate hashref
 294 (C<\%extra_attributes>) as shown above.
 295
 296 Every time C<connect_info> is invoked, any previous settings for
 297 these options will be cleared before setting the new ones, regardless of
 298 whether any options are specified in the new C<connect_info>.
 299
 300
 301 =over
 302
 303 =item on_connect_do
 304
 305 Specifies things to do immediately after connecting or re-connecting to
 306 the database.  Its value may contain:
 307
 308 =over
 309
 310 =item a scalar
 311
 312 This contains one SQL statement to execute.
 313
 314 =item an array reference
 315
 316 This contains SQL statements to execute in order.  Each element contains
 317 a string or a code reference that returns a string.
 318
 319 =item a code reference
 320
 321 This contains some code to execute.  Unlike code references within an
 322 array reference, its return value is ignored.
 323
 324 =back
 325
 326 =item on_disconnect_do
 327
 328 Takes arguments in the same form as L</on_connect_do> and executes them
 329 immediately before disconnecting from the database.
 330
 331 Note, this only runs if you explicitly call L</disconnect> on the
 332 storage object.
 333
 334 =item on_connect_call
 335
 336 A more generalized form of L</on_connect_do> that calls the specified
 337 C<connect_call_METHOD> methods in your storage driver.
 338
 339   on_connect_do => 'select 1'
 340
 341 is equivalent to:
 342
 343   on_connect_call => [ [ do_sql => 'select 1' ] ]
 344
 345 Its values may contain:
 346
 347 =over
 348
 349 =item a scalar
 350
 351 Will call the C<connect_call_METHOD> method.
 352
 353 =item a code reference
 354
 355 Will execute C<< $code->($storage) >>
 356
 357 =item an array reference
 358
 359 Each value can be a method name or code reference.
 360
 361 =item an array of arrays
 362
 363 For each array, the first item is taken to be the C<connect_call_> method name
 364 or code reference, and the rest are parameters to it.
 365
 366 =back
 367
 368 Some predefined storage methods you may use:
 369
 370 =over
 371
 372 =item do_sql
 373
 374 Executes a SQL string or a code reference that returns a SQL string. This is
 375 what L</on_connect_do> and L</on_disconnect_do> use.
 376
 377 It can take:
 378
 379 =over
 380
 381 =item a scalar
 382
 383 Will execute the scalar as SQL.
 384
 385 =item an arrayref
 386
 387 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 388 attributes hashref and bind values.
 389
 390 =item a code reference
 391
 392 Will execute C<< $code->($storage) >> and execute the return array refs as
 393 above.
 394
 395 =back
 396
 397 =item datetime_setup
 398
 399 Execute any statements necessary to initialize the database session to return
 400 and accept datetime/timestamp values used with
 401 L<DBIx::Class::InflateColumn::DateTime>.
 402
 403 Only necessary for some databases, see your specific storage driver for
 404 implementation details.
 405
 406 =back
 407
 408 =item on_disconnect_call
 409
 410 Takes arguments in the same form as L</on_connect_call> and executes them
 411 immediately before disconnecting from the database.
 412
 413 Calls the C<disconnect_call_METHOD> methods as opposed to the
 414 C<connect_call_METHOD> methods called by L</on_connect_call>.
 415
 416 Note, this only runs if you explicitly call L</disconnect> on the
 417 storage object.
 418
 419 =item disable_sth_caching
 420
 421 If set to a true value, this option will disable the caching of
 422 statement handles via L<DBI/prepare_cached>.
 423
 424 =item limit_dialect
 425
 426 Sets the limit dialect. This is useful for JDBC-bridge among others
 427 where the remote SQL-dialect cannot be determined by the name of the
 428 driver alone. See also L<SQL::Abstract::Limit>.
 429
 430 =item quote_char
 431
 432 Specifies what characters to use to quote table and column names. If
 433 you use this you will want to specify L</name_sep> as well.
 434
 435 C<quote_char> expects either a single character, in which case is it
 436 is placed on either side of the table/column name, or an arrayref of length
 437 2 in which case the table/column name is placed between the elements.
 438
 439 For example under MySQL you should use C<< quote_char => '`' >>, and for
 440 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 441
 442 =item name_sep
 443
 444 This only needs to be used in conjunction with C<quote_char>, and is used to
 445 specify the character that separates elements (schemas, tables, columns) from
 446 each other. In most cases this is simply a C<.>.
 447
 448 The consequences of not supplying this value is that L<SQL::Abstract>
 449 will assume DBIx::Class' uses of aliases to be complete column
 450 names. The output will look like I<"me.name"> when it should actually
 451 be I<"me"."name">.
 452
 453 =item unsafe
 454
 455 This Storage driver normally installs its own C<HandleError>, sets
 456 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 457 all database handles, including those supplied by a coderef.  It does this
 458 so that it can have consistent and useful error behavior.
 459
 460 If you set this option to a true value, Storage will not do its usual
 461 modifications to the database handle's attributes, and instead relies on
 462 the settings in your connect_info DBI options (or the values you set in
 463 your connection coderef, in the case that you are connecting via coderef).
 464
 465 Note that your custom settings can cause Storage to malfunction,
 466 especially if you set a C<HandleError> handler that suppresses exceptions
 467 and/or disable C<RaiseError>.
 468
 469 =item auto_savepoint
 470
 471 If this option is true, L<DBIx::Class> will use savepoints when nesting
 472 transactions, making it possible to recover from failure in the inner
 473 transaction without having to abort all outer transactions.
 474
 475 =item cursor_class
 476
 477 Use this argument to supply a cursor class other than the default
 478 L<DBIx::Class::Storage::DBI::Cursor>.
 479
 480 =back
 481
 482 Some real-life examples of arguments to L</connect_info> and
 483 L<DBIx::Class::Schema/connect>
 484
 485   # Simple SQLite connection
 486   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 487
 488   # Connect via subref
 489   ->connect_info([ sub { DBI->connect(...) } ]);
 490
 491   # Connect via subref in hashref
 492   ->connect_info([{
 493     dbh_maker => sub { DBI->connect(...) },
 494     on_connect_do => 'alter session ...',
 495   }]);
 496
 497   # A bit more complicated
 498   ->connect_info(
 499     [
 500       'dbi:Pg:dbname=foo',
 501       'postgres',
 502       'my_pg_password',
 503       { AutoCommit => 1 },
 504       { quote_char => q{"}, name_sep => q{.} },
 505     ]
 506   );
 507
 508   # Equivalent to the previous example
 509   ->connect_info(
 510     [
 511       'dbi:Pg:dbname=foo',
 512       'postgres',
 513       'my_pg_password',
 514       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 515     ]
 516   );
 517
 518   # Same, but with hashref as argument
 519   # See parse_connect_info for explanation
 520   ->connect_info(
 521     [{
 522       dsn         => 'dbi:Pg:dbname=foo',
 523       user        => 'postgres',
 524       password    => 'my_pg_password',
 525       AutoCommit  => 1,
 526       quote_char  => q{"},
 527       name_sep    => q{.},
 528     }]
 529   );
 530
 531   # Subref + DBIx::Class-specific connection options
 532   ->connect_info(
 533     [
 534       sub { DBI->connect(...) },
 535       {
 536           quote_char => q{`},
 537           name_sep => q{@},
 538           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 539           disable_sth_caching => 1,
 540       },
 541     ]
 542   );
 543
 544
 545
 546 =cut
 547
 548 sub connect_info {
 549   my ($self, $info) = @_;
 550
 551   return $self->_connect_info if !$info;
 552
 553   $self->_connect_info($info); # copy for _connect_info
 554
 555   $info = $self->_normalize_connect_info($info)
 556     if ref $info eq 'ARRAY';
 557
 558   for my $storage_opt (keys %{ $info->{storage_options} }) {
 559     my $value = $info->{storage_options}{$storage_opt};
 560
 561     $self->$storage_opt($value);
 562   }
 563
 564   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 565   #  the new set of options
 566   $self->_sql_maker(undef);
 567   $self->_sql_maker_opts({});
 568
 569   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 570     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 571
 572     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 573   }
 574
 575   my %attrs = (
 576     %{ $self->_default_dbi_connect_attributes || {} },
 577     %{ $info->{attributes} || {} },
 578   );
 579
 580   my @args = @{ $info->{arguments} };
 581
 582   $self->_dbi_connect_info([@args,
 583     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 584
 585   return $self->_connect_info;
 586 }
 587
 588 sub _normalize_connect_info {
 589   my ($self, $info_arg) = @_;
 590   my %info;
 591
 592   my @args = @$info_arg;  # take a shallow copy for further mutilation
 593
 594   # combine/pre-parse arguments depending on invocation style
 595
 596   my %attrs;
 597   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 598     %attrs = %{ $args[1] || {} };
 599     @args = $args[0];
 600   }
 601   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 602     %attrs = %{$args[0]};
 603     @args = ();
 604     if (my $code = delete $attrs{dbh_maker}) {
 605       @args = $code;
 606
 607       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 608       if (@ignored) {
 609         carp sprintf (
 610             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 611           . "to the result of 'dbh_maker'",
 612
 613           join (', ', map { "'$_'" } (@ignored) ),
 614         );
 615       }
 616     }
 617     else {
 618       @args = delete @attrs{qw/dsn user password/};
 619     }
 620   }
 621   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 622     %attrs = (
 623       % { $args[3] || {} },
 624       % { $args[4] || {} },
 625     );
 626     @args = @args[0,1,2];
 627   }
 628
 629   $info{arguments} = \@args;
 630
 631   my @storage_opts = grep exists $attrs{$_},
 632     @storage_options, 'cursor_class';
 633
 634   @{ $info{storage_options} }{@storage_opts} =
 635     delete @attrs{@storage_opts} if @storage_opts;
 636
 637   my @sql_maker_opts = grep exists $attrs{$_},
 638     qw/limit_dialect quote_char name_sep/;
 639
 640   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 641     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 642
 643   $info{attributes} = \%attrs if %attrs;
 644
 645   return \%info;
 646 }
 647
 648 sub _default_dbi_connect_attributes {
 649   return {
 650     AutoCommit => 1,
 651     RaiseError => 1,
 652     PrintError => 0,
 653   };
 654 }
 655
 656 =head2 on_connect_do
 657
 658 This method is deprecated in favour of setting via L</connect_info>.
 659
 660 =cut
 661
 662 =head2 on_disconnect_do
 663
 664 This method is deprecated in favour of setting via L</connect_info>.
 665
 666 =cut
 667
 668 sub _parse_connect_do {
 669   my ($self, $type) = @_;
 670
 671   my $val = $self->$type;
 672   return () if not defined $val;
 673
 674   my @res;
 675
 676   if (not ref($val)) {
 677     push @res, [ 'do_sql', $val ];
 678   } elsif (ref($val) eq 'CODE') {
 679     push @res, $val;
 680   } elsif (ref($val) eq 'ARRAY') {
 681     push @res, map { [ 'do_sql', $_ ] } @$val;
 682   } else {
 683     $self->throw_exception("Invalid type for $type: ".ref($val));
 684   }
 685
 686   return \@res;
 687 }
 688
 689 =head2 dbh_do
 690
 691 Arguments: ($subref | $method_name), @extra_coderef_args?
 692
 693 Execute the given $subref or $method_name using the new exception-based
 694 connection management.
 695
 696 The first two arguments will be the storage object that C<dbh_do> was called
 697 on and a database handle to use.  Any additional arguments will be passed
 698 verbatim to the called subref as arguments 2 and onwards.
 699
 700 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 701 exception handling and reconnection (or failover in future subclasses).
 702
 703 Your subref should have no side-effects outside of the database, as
 704 there is the potential for your subref to be partially double-executed
 705 if the database connection was stale/dysfunctional.
 706
 707 Example:
 708
 709   my @stuff = $schema->storage->dbh_do(
 710     sub {
 711       my ($storage, $dbh, @cols) = @_;
 712       my $cols = join(q{, }, @cols);
 713       $dbh->selectrow_array("SELECT $cols FROM foo");
 714     },
 715     @column_list
 716   );
 717
 718 =cut
 719
 720 sub dbh_do {
 721   my $self = shift;
 722   my $code = shift;
 723
 724   my $dbh = $self->_get_dbh;
 725
 726   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 727       || $self->{transaction_depth};
 728
 729   local $self->{_in_dbh_do} = 1;
 730
 731   my @result;
 732   my $want_array = wantarray;
 733
 734   my $exception;
 735   my @args = @_;
 736   try {
 737
 738     if($want_array) {
 739         @result = $self->$code($dbh, @args);
 740     }
 741     elsif(defined $want_array) {
 742         $result[0] = $self->$code($dbh, @args);
 743     }
 744     else {
 745         $self->$code($dbh, @args);
 746     }
 747   } catch {
 748     $exception = shift;
 749   };
 750
 751   if(! defined $exception) { return $want_array ? @result : $result[0] }
 752
 753   $self->throw_exception($exception) if $self->connected;
 754
 755   # We were not connected - reconnect and retry, but let any
 756   #  exception fall right through this time
 757   carp "Retrying $code after catching disconnected exception: $exception"
 758     if $ENV{DBIC_DBIRETRY_DEBUG};
 759   $self->_populate_dbh;
 760   $self->$code($self->_dbh, @_);
 761 }
 762
 763 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 764 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 765 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 766 sub txn_do {
 767   my $self = shift;
 768   my $coderef = shift;
 769
 770   ref $coderef eq 'CODE' or $self->throw_exception
 771     ('$coderef must be a CODE reference');
 772
 773   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 774
 775   local $self->{_in_dbh_do} = 1;
 776
 777   my @result;
 778   my $want_array = wantarray;
 779
 780   my $tried = 0;
 781   while(1) {
 782     my $exception;
 783     my @args = @_;
 784     try {
 785       $self->_get_dbh;
 786
 787       $self->txn_begin;
 788       if($want_array) {
 789           @result = $coderef->(@args);
 790       }
 791       elsif(defined $want_array) {
 792           $result[0] = $coderef->(@args);
 793       }
 794       else {
 795           $coderef->(@args);
 796       }
 797       $self->txn_commit;
 798     } catch {
 799       $exception = $_;
 800     };
 801
 802     if(! defined $exception) { return $want_array ? @result : $result[0] }
 803
 804     if($tried++ || $self->connected) {
 805       my $rollback_exception;
 806       try { $self->txn_rollback } catch { $rollback_exception = shift };
 807       if(defined $rollback_exception) {
 808         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 809         $self->throw_exception($exception)  # propagate nested rollback
 810           if $rollback_exception =~ /$exception_class/;
 811
 812         $self->throw_exception(
 813           "Transaction aborted: ${exception}. "
 814           . "Rollback failed: ${rollback_exception}"
 815         );
 816       }
 817       $self->throw_exception($exception)
 818     }
 819
 820     # We were not connected, and was first try - reconnect and retry
 821     # via the while loop
 822     carp "Retrying $coderef after catching disconnected exception: $exception"
 823       if $ENV{DBIC_DBIRETRY_DEBUG};
 824     $self->_populate_dbh;
 825   }
 826 }
 827
 828 =head2 disconnect
 829
 830 Our C<disconnect> method also performs a rollback first if the
 831 database is not in C<AutoCommit> mode.
 832
 833 =cut
 834
 835 sub disconnect {
 836   my ($self) = @_;
 837
 838   if( $self->_dbh ) {
 839     my @actions;
 840
 841     push @actions, ( $self->on_disconnect_call || () );
 842     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 843
 844     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 845
 846     $self->_dbh_rollback unless $self->_dbh_autocommit;
 847
 848     %{ $self->_dbh->{CachedKids} } = ();
 849     $self->_dbh->disconnect;
 850     $self->_dbh(undef);
 851     $self->{_dbh_gen}++;
 852   }
 853 }
 854
 855 =head2 with_deferred_fk_checks
 856
 857 =over 4
 858
 859 =item Arguments: C<$coderef>
 860
 861 =item Return Value: The return value of $coderef
 862
 863 =back
 864
 865 Storage specific method to run the code ref with FK checks deferred or
 866 in MySQL's case disabled entirely.
 867
 868 =cut
 869
 870 # Storage subclasses should override this
 871 sub with_deferred_fk_checks {
 872   my ($self, $sub) = @_;
 873   $sub->();
 874 }
 875
 876 =head2 connected
 877
 878 =over
 879
 880 =item Arguments: none
 881
 882 =item Return Value: 1|0
 883
 884 =back
 885
 886 Verifies that the current database handle is active and ready to execute
 887 an SQL statement (e.g. the connection did not get stale, server is still
 888 answering, etc.) This method is used internally by L</dbh>.
 889
 890 =cut
 891
 892 sub connected {
 893   my $self = shift;
 894   return 0 unless $self->_seems_connected;
 895
 896   #be on the safe side
 897   local $self->_dbh->{RaiseError} = 1;
 898
 899   return $self->_ping;
 900 }
 901
 902 sub _seems_connected {
 903   my $self = shift;
 904
 905   $self->_preserve_foreign_dbh;
 906
 907   my $dbh = $self->_dbh
 908     or return 0;
 909
 910   return $dbh->FETCH('Active');
 911 }
 912
 913 sub _ping {
 914   my $self = shift;
 915
 916   my $dbh = $self->_dbh or return 0;
 917
 918   return $dbh->ping;
 919 }
 920
 921 sub ensure_connected {
 922   my ($self) = @_;
 923
 924   unless ($self->connected) {
 925     $self->_populate_dbh;
 926   }
 927 }
 928
 929 =head2 dbh
 930
 931 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 932 is guaranteed to be healthy by implicitly calling L</connected>, and if
 933 necessary performing a reconnection before returning. Keep in mind that this
 934 is very B<expensive> on some database engines. Consider using L</dbh_do>
 935 instead.
 936
 937 =cut
 938
 939 sub dbh {
 940   my ($self) = @_;
 941
 942   if (not $self->_dbh) {
 943     $self->_populate_dbh;
 944   } else {
 945     $self->ensure_connected;
 946   }
 947   return $self->_dbh;
 948 }
 949
 950 # this is the internal "get dbh or connect (don't check)" method
 951 sub _get_dbh {
 952   my $self = shift;
 953   $self->_preserve_foreign_dbh;
 954   $self->_populate_dbh unless $self->_dbh;
 955   return $self->_dbh;
 956 }
 957
 958 sub _sql_maker_args {
 959     my ($self) = @_;
 960
 961     return (
 962       bindtype=>'columns',
 963       array_datatypes => 1,
 964       limit_dialect => $self->_get_dbh,
 965       %{$self->_sql_maker_opts}
 966     );
 967 }
 968
 969 sub sql_maker {
 970   my ($self) = @_;
 971   unless ($self->_sql_maker) {
 972     my $sql_maker_class = $self->sql_maker_class;
 973     $self->ensure_class_loaded ($sql_maker_class);
 974     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 975   }
 976   return $self->_sql_maker;
 977 }
 978
 979 # nothing to do by default
 980 sub _rebless {}
 981 sub _init {}
 982
 983 sub _populate_dbh {
 984   my ($self) = @_;
 985
 986   my @info = @{$self->_dbi_connect_info || []};
 987   $self->_dbh(undef); # in case ->connected failed we might get sent here
 988   $self->_server_info_hash (undef);
 989   $self->_dbh($self->_connect(@info));
 990
 991   $self->_conn_pid($$);
 992   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 993
 994   $self->_determine_driver;
 995
 996   # Always set the transaction depth on connect, since
 997   #  there is no transaction in progress by definition
 998   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 999
1000   $self->_run_connection_actions unless $self->{_in_determine_driver};
1001 }
1002
1003 sub _run_connection_actions {
1004   my $self = shift;
1005   my @actions;
1006
1007   push @actions, ( $self->on_connect_call || () );
1008   push @actions, $self->_parse_connect_do ('on_connect_do');
1009
1010   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1011 }
1012
1013 sub _server_info {
1014   my $self = shift;
1015
1016   unless ($self->_server_info_hash) {
1017
1018     my %info;
1019
1020     my $server_version = do {
1021       local $@; # might be happenin in some sort of destructor
1022       try { $self->_get_server_version };
1023     };
1024
1025     if (defined $server_version) {
1026       $info{dbms_version} = $server_version;
1027
1028       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1029       my @verparts = split (/\./, $numeric_version);
1030       if (
1031         @verparts
1032           &&
1033         $verparts[0] <= 999
1034       ) {
1035         # consider only up to 3 version parts, iff not more than 3 digits
1036         my @use_parts;
1037         while (@verparts && @use_parts < 3) {
1038           my $p = shift @verparts;
1039           last if $p > 999;
1040           push @use_parts, $p;
1041         }
1042         push @use_parts, 0 while @use_parts < 3;
1043
1044         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1045       }
1046     }
1047
1048     $self->_server_info_hash(\%info);
1049   }
1050
1051   return $self->_server_info_hash
1052 }
1053
1054 sub _get_server_version {
1055   shift->_get_dbh->get_info(18);
1056 }
1057
1058 sub _determine_driver {
1059   my ($self) = @_;
1060
1061   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1062     my $started_connected = 0;
1063     local $self->{_in_determine_driver} = 1;
1064
1065     if (ref($self) eq __PACKAGE__) {
1066       my $driver;
1067       if ($self->_dbh) { # we are connected
1068         $driver = $self->_dbh->{Driver}{Name};
1069         $started_connected = 1;
1070       } else {
1071         # if connect_info is a CODEREF, we have no choice but to connect
1072         if (ref $self->_dbi_connect_info->[0] &&
1073             Scalar::Util::reftype($self->_dbi_connect_info->[0]) eq 'CODE') {
1074           $self->_populate_dbh;
1075           $driver = $self->_dbh->{Driver}{Name};
1076         }
1077         else {
1078           # try to use dsn to not require being connected, the driver may still
1079           # force a connection in _rebless to determine version
1080           # (dsn may not be supplied at all if all we do is make a mock-schema)
1081           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1082           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1083           $driver ||= $ENV{DBI_DRIVER};
1084         }
1085       }
1086
1087       if ($driver) {
1088         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1089         if ($self->load_optional_class($storage_class)) {
1090           mro::set_mro($storage_class, 'c3');
1091           bless $self, $storage_class;
1092           $self->_rebless();
1093         }
1094       }
1095     }
1096
1097     $self->_driver_determined(1);
1098
1099     $self->_init; # run driver-specific initializations
1100
1101     $self->_run_connection_actions
1102         if !$started_connected && defined $self->_dbh;
1103   }
1104 }
1105
1106 sub _do_connection_actions {
1107   my $self          = shift;
1108   my $method_prefix = shift;
1109   my $call          = shift;
1110
1111   if (not ref($call)) {
1112     my $method = $method_prefix . $call;
1113     $self->$method(@_);
1114   } elsif (ref($call) eq 'CODE') {
1115     $self->$call(@_);
1116   } elsif (ref($call) eq 'ARRAY') {
1117     if (ref($call->[0]) ne 'ARRAY') {
1118       $self->_do_connection_actions($method_prefix, $_) for @$call;
1119     } else {
1120       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1121     }
1122   } else {
1123     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1124   }
1125
1126   return $self;
1127 }
1128
1129 sub connect_call_do_sql {
1130   my $self = shift;
1131   $self->_do_query(@_);
1132 }
1133
1134 sub disconnect_call_do_sql {
1135   my $self = shift;
1136   $self->_do_query(@_);
1137 }
1138
1139 # override in db-specific backend when necessary
1140 sub connect_call_datetime_setup { 1 }
1141
1142 sub _do_query {
1143   my ($self, $action) = @_;
1144
1145   if (ref $action eq 'CODE') {
1146     $action = $action->($self);
1147     $self->_do_query($_) foreach @$action;
1148   }
1149   else {
1150     # Most debuggers expect ($sql, @bind), so we need to exclude
1151     # the attribute hash which is the second argument to $dbh->do
1152     # furthermore the bind values are usually to be presented
1153     # as named arrayref pairs, so wrap those here too
1154     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1155     my $sql = shift @do_args;
1156     my $attrs = shift @do_args;
1157     my @bind = map { [ undef, $_ ] } @do_args;
1158
1159     $self->_query_start($sql, @bind);
1160     $self->_get_dbh->do($sql, $attrs, @do_args);
1161     $self->_query_end($sql, @bind);
1162   }
1163
1164   return $self;
1165 }
1166
1167 sub _connect {
1168   my ($self, @info) = @_;
1169
1170   $self->throw_exception("You failed to provide any connection info")
1171     if !@info;
1172
1173   my ($old_connect_via, $dbh);
1174
1175   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1176     $old_connect_via = $DBI::connect_via;
1177     $DBI::connect_via = 'connect';
1178   }
1179
1180   my $caught;
1181   try {
1182     if(ref $info[0] eq 'CODE') {
1183        $dbh = $info[0]->();
1184     }
1185     else {
1186        $dbh = DBI->connect(@info);
1187     }
1188
1189     if($dbh && !$self->unsafe) {
1190       my $weak_self = $self;
1191       Scalar::Util::weaken($weak_self);
1192       $dbh->{HandleError} = sub {
1193           if ($weak_self) {
1194             $weak_self->throw_exception("DBI Exception: $_[0]");
1195           }
1196           else {
1197             # the handler may be invoked by something totally out of
1198             # the scope of DBIC
1199             croak ("DBI Exception: $_[0]");
1200           }
1201       };
1202       $dbh->{ShowErrorStatement} = 1;
1203       $dbh->{RaiseError} = 1;
1204       $dbh->{PrintError} = 0;
1205     }
1206   } catch {
1207     $caught = 1;
1208   };
1209
1210   $DBI::connect_via = $old_connect_via if $old_connect_via;
1211
1212   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1213     if !$dbh || $caught;
1214
1215   $self->_dbh_autocommit($dbh->{AutoCommit});
1216
1217   $dbh;
1218 }
1219
1220 sub svp_begin {
1221   my ($self, $name) = @_;
1222
1223   $name = $self->_svp_generate_name
1224     unless defined $name;
1225
1226   $self->throw_exception ("You can't use savepoints outside a transaction")
1227     if $self->{transaction_depth} == 0;
1228
1229   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1230     unless $self->can('_svp_begin');
1231
1232   push @{ $self->{savepoints} }, $name;
1233
1234   $self->debugobj->svp_begin($name) if $self->debug;
1235
1236   return $self->_svp_begin($name);
1237 }
1238
1239 sub svp_release {
1240   my ($self, $name) = @_;
1241
1242   $self->throw_exception ("You can't use savepoints outside a transaction")
1243     if $self->{transaction_depth} == 0;
1244
1245   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1246     unless $self->can('_svp_release');
1247
1248   if (defined $name) {
1249     $self->throw_exception ("Savepoint '$name' does not exist")
1250       unless grep { $_ eq $name } @{ $self->{savepoints} };
1251
1252     # Dig through the stack until we find the one we are releasing.  This keeps
1253     # the stack up to date.
1254     my $svp;
1255
1256     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1257   } else {
1258     $name = pop @{ $self->{savepoints} };
1259   }
1260
1261   $self->debugobj->svp_release($name) if $self->debug;
1262
1263   return $self->_svp_release($name);
1264 }
1265
1266 sub svp_rollback {
1267   my ($self, $name) = @_;
1268
1269   $self->throw_exception ("You can't use savepoints outside a transaction")
1270     if $self->{transaction_depth} == 0;
1271
1272   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1273     unless $self->can('_svp_rollback');
1274
1275   if (defined $name) {
1276       # If they passed us a name, verify that it exists in the stack
1277       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1278           $self->throw_exception("Savepoint '$name' does not exist!");
1279       }
1280
1281       # Dig through the stack until we find the one we are releasing.  This keeps
1282       # the stack up to date.
1283       while(my $s = pop(@{ $self->{savepoints} })) {
1284           last if($s eq $name);
1285       }
1286       # Add the savepoint back to the stack, as a rollback doesn't remove the
1287       # named savepoint, only everything after it.
1288       push(@{ $self->{savepoints} }, $name);
1289   } else {
1290       # We'll assume they want to rollback to the last savepoint
1291       $name = $self->{savepoints}->[-1];
1292   }
1293
1294   $self->debugobj->svp_rollback($name) if $self->debug;
1295
1296   return $self->_svp_rollback($name);
1297 }
1298
1299 sub _svp_generate_name {
1300     my ($self) = @_;
1301
1302     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1303 }
1304
1305 sub txn_begin {
1306   my $self = shift;
1307
1308   # this means we have not yet connected and do not know the AC status
1309   # (e.g. coderef $dbh)
1310   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1311
1312   if($self->{transaction_depth} == 0) {
1313     $self->debugobj->txn_begin()
1314       if $self->debug;
1315     $self->_dbh_begin_work;
1316   }
1317   elsif ($self->auto_savepoint) {
1318     $self->svp_begin;
1319   }
1320   $self->{transaction_depth}++;
1321 }
1322
1323 sub _dbh_begin_work {
1324   my $self = shift;
1325
1326   # if the user is utilizing txn_do - good for him, otherwise we need to
1327   # ensure that the $dbh is healthy on BEGIN.
1328   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1329   # will be replaced by a failure of begin_work itself (which will be
1330   # then retried on reconnect)
1331   if ($self->{_in_dbh_do}) {
1332     $self->_dbh->begin_work;
1333   } else {
1334     $self->dbh_do(sub { $_[1]->begin_work });
1335   }
1336 }
1337
1338 sub txn_commit {
1339   my $self = shift;
1340   if ($self->{transaction_depth} == 1) {
1341     $self->debugobj->txn_commit()
1342       if ($self->debug);
1343     $self->_dbh_commit;
1344     $self->{transaction_depth} = 0
1345       if $self->_dbh_autocommit;
1346   }
1347   elsif($self->{transaction_depth} > 1) {
1348     $self->{transaction_depth}--;
1349     $self->svp_release
1350       if $self->auto_savepoint;
1351   }
1352 }
1353
1354 sub _dbh_commit {
1355   my $self = shift;
1356   my $dbh  = $self->_dbh
1357     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1358   $dbh->commit;
1359 }
1360
1361 sub txn_rollback {
1362   my $self = shift;
1363   my $dbh = $self->_dbh;
1364   try {
1365     if ($self->{transaction_depth} == 1) {
1366       $self->debugobj->txn_rollback()
1367         if ($self->debug);
1368       $self->{transaction_depth} = 0
1369         if $self->_dbh_autocommit;
1370       $self->_dbh_rollback;
1371     }
1372     elsif($self->{transaction_depth} > 1) {
1373       $self->{transaction_depth}--;
1374       if ($self->auto_savepoint) {
1375         $self->svp_rollback;
1376         $self->svp_release;
1377       }
1378     }
1379     else {
1380       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1381     }
1382   } catch {
1383     my $error = shift;
1384     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1385     $error =~ /$exception_class/ and $self->throw_exception($error);
1386     # ensure that a failed rollback resets the transaction depth
1387     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1388     $self->throw_exception($error);
1389   }
1390 }
1391
1392 sub _dbh_rollback {
1393   my $self = shift;
1394   my $dbh  = $self->_dbh
1395     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1396   $dbh->rollback;
1397 }
1398
1399 # This used to be the top-half of _execute.  It was split out to make it
1400 #  easier to override in NoBindVars without duping the rest.  It takes up
1401 #  all of _execute's args, and emits $sql, @bind.
1402 sub _prep_for_execute {
1403   my ($self, $op, $extra_bind, $ident, $args) = @_;
1404
1405   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1406     $ident = $ident->from();
1407   }
1408
1409   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1410
1411   unshift(@bind,
1412     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1413       if $extra_bind;
1414   return ($sql, \@bind);
1415 }
1416
1417
1418 sub _fix_bind_params {
1419     my ($self, @bind) = @_;
1420
1421     ### Turn @bind from something like this:
1422     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1423     ### to this:
1424     ###   ( "'1'", "'1'", "'3'" )
1425     return
1426         map {
1427             if ( defined( $_ && $_->[1] ) ) {
1428                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1429             }
1430             else { q{'NULL'}; }
1431         } @bind;
1432 }
1433
1434 sub _query_start {
1435     my ( $self, $sql, @bind ) = @_;
1436
1437     if ( $self->debug ) {
1438         @bind = $self->_fix_bind_params(@bind);
1439
1440         $self->debugobj->query_start( $sql, @bind );
1441     }
1442 }
1443
1444 sub _query_end {
1445     my ( $self, $sql, @bind ) = @_;
1446
1447     if ( $self->debug ) {
1448         @bind = $self->_fix_bind_params(@bind);
1449         $self->debugobj->query_end( $sql, @bind );
1450     }
1451 }
1452
1453 sub _dbh_execute {
1454   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1455
1456   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1457
1458   $self->_query_start( $sql, @$bind );
1459
1460   my $sth = $self->sth($sql,$op);
1461
1462   my $placeholder_index = 1;
1463
1464   foreach my $bound (@$bind) {
1465     my $attributes = {};
1466     my($column_name, @data) = @$bound;
1467
1468     if ($bind_attributes) {
1469       $attributes = $bind_attributes->{$column_name}
1470       if defined $bind_attributes->{$column_name};
1471     }
1472
1473     foreach my $data (@data) {
1474       my $ref = ref $data;
1475       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1476
1477       $sth->bind_param($placeholder_index, $data, $attributes);
1478       $placeholder_index++;
1479     }
1480   }
1481
1482   # Can this fail without throwing an exception anyways???
1483   my $rv = $sth->execute();
1484   $self->throw_exception($sth->errstr) if !$rv;
1485
1486   $self->_query_end( $sql, @$bind );
1487
1488   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1489 }
1490
1491 sub _execute {
1492     my $self = shift;
1493     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1494 }
1495
1496 sub _prefetch_insert_auto_nextvals {
1497   my ($self, $source, $to_insert) = @_;
1498
1499   my $upd = {};
1500
1501   foreach my $col ( $source->columns ) {
1502     if ( !defined $to_insert->{$col} ) {
1503       my $col_info = $source->column_info($col);
1504
1505       if ( $col_info->{auto_nextval} ) {
1506         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1507           'nextval',
1508           $col_info->{sequence} ||=
1509             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1510         );
1511       }
1512     }
1513   }
1514
1515   return $upd;
1516 }
1517
1518 sub insert {
1519   my $self = shift;
1520   my ($source, $to_insert, $opts) = @_;
1521
1522   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1523
1524   my $bind_attributes = $self->source_bind_attributes($source);
1525
1526   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1527
1528   if ($opts->{returning}) {
1529     my @ret_cols = @{$opts->{returning}};
1530
1531     my @ret_vals = eval {
1532       local $SIG{__WARN__} = sub {};
1533       my @r = $sth->fetchrow_array;
1534       $sth->finish;
1535       @r;
1536     };
1537
1538     my %ret;
1539     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1540
1541     $updated_cols = {
1542       %$updated_cols,
1543       %ret,
1544     };
1545   }
1546
1547   return $updated_cols;
1548 }
1549
1550 ## Currently it is assumed that all values passed will be "normal", i.e. not
1551 ## scalar refs, or at least, all the same type as the first set, the statement is
1552 ## only prepped once.
1553 sub insert_bulk {
1554   my ($self, $source, $cols, $data) = @_;
1555
1556   my %colvalues;
1557   @colvalues{@$cols} = (0..$#$cols);
1558
1559   for my $i (0..$#$cols) {
1560     my $first_val = $data->[0][$i];
1561     next unless ref $first_val eq 'SCALAR';
1562
1563     $colvalues{ $cols->[$i] } = $first_val;
1564   }
1565
1566   # check for bad data and stringify stringifiable objects
1567   my $bad_slice = sub {
1568     my ($msg, $col_idx, $slice_idx) = @_;
1569     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1570       $msg,
1571       $cols->[$col_idx],
1572       do {
1573         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1574         Data::Dumper::Concise::Dumper({
1575           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1576         }),
1577       }
1578     );
1579   };
1580
1581   for my $datum_idx (0..$#$data) {
1582     my $datum = $data->[$datum_idx];
1583
1584     for my $col_idx (0..$#$cols) {
1585       my $val            = $datum->[$col_idx];
1586       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1587       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1588
1589       if ($is_literal_sql) {
1590         if (not ref $val) {
1591           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1592         }
1593         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1594           $bad_slice->("$reftype reference found where literal SQL expected",
1595             $col_idx, $datum_idx);
1596         }
1597         elsif ($$val ne $$sqla_bind){
1598           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1599             $col_idx, $datum_idx);
1600         }
1601       }
1602       elsif (my $reftype = ref $val) {
1603         require overload;
1604         if (overload::Method($val, '""')) {
1605           $datum->[$col_idx] = "".$val;
1606         }
1607         else {
1608           $bad_slice->("$reftype reference found where bind expected",
1609             $col_idx, $datum_idx);
1610         }
1611       }
1612     }
1613   }
1614
1615   my ($sql, $bind) = $self->_prep_for_execute (
1616     'insert', undef, $source, [\%colvalues]
1617   );
1618   my @bind = @$bind;
1619
1620   my $empty_bind = 1 if (not @bind) &&
1621     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1622
1623   if ((not @bind) && (not $empty_bind)) {
1624     $self->throw_exception(
1625       'Cannot insert_bulk without support for placeholders'
1626     );
1627   }
1628
1629   # neither _execute_array, nor _execute_inserts_with_no_binds are
1630   # atomic (even if _execute _array is a single call). Thus a safety
1631   # scope guard
1632   my $guard = $self->txn_scope_guard;
1633
1634   $self->_query_start( $sql, ['__BULK__'] );
1635   my $sth = $self->sth($sql);
1636   my $rv = do {
1637     if ($empty_bind) {
1638       # bind_param_array doesn't work if there are no binds
1639       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1640     }
1641     else {
1642 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1643       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1644     }
1645   };
1646
1647   $self->_query_end( $sql, ['__BULK__'] );
1648
1649   $guard->commit;
1650
1651   return (wantarray ? ($rv, $sth, @bind) : $rv);
1652 }
1653
1654 sub _execute_array {
1655   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1656
1657   ## This must be an arrayref, else nothing works!
1658   my $tuple_status = [];
1659
1660   ## Get the bind_attributes, if any exist
1661   my $bind_attributes = $self->source_bind_attributes($source);
1662
1663   ## Bind the values and execute
1664   my $placeholder_index = 1;
1665
1666   foreach my $bound (@$bind) {
1667
1668     my $attributes = {};
1669     my ($column_name, $data_index) = @$bound;
1670
1671     if( $bind_attributes ) {
1672       $attributes = $bind_attributes->{$column_name}
1673       if defined $bind_attributes->{$column_name};
1674     }
1675
1676     my @data = map { $_->[$data_index] } @$data;
1677
1678     $sth->bind_param_array(
1679       $placeholder_index,
1680       [@data],
1681       (%$attributes ?  $attributes : ()),
1682     );
1683     $placeholder_index++;
1684   }
1685
1686   my $rv;
1687   my $err;
1688   try {
1689     $rv = $self->_dbh_execute_array($sth, $tuple_status, @extra);
1690   } catch {
1691     $err = shift;
1692   };
1693   $err = defined $err ? $err : ($sth->err ? $sth->errstr : undef );
1694
1695 # Statement must finish even if there was an exception.
1696   try { $sth->finish }
1697   catch { $err = shift unless defined $err };
1698
1699   if (defined $err) {
1700     my $i = 0;
1701     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1702
1703     $self->throw_exception("Unexpected populate error: $err")
1704       if ($i > $#$tuple_status);
1705
1706     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1707       ($tuple_status->[$i][1] || $err),
1708       Data::Dumper::Concise::Dumper({
1709         map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols)
1710       }),
1711     );
1712   }
1713   return $rv;
1714 }
1715
1716 sub _dbh_execute_array {
1717     my ($self, $sth, $tuple_status, @extra) = @_;
1718
1719     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1720 }
1721
1722 sub _dbh_execute_inserts_with_no_binds {
1723   my ($self, $sth, $count) = @_;
1724
1725   my $exception;
1726   try {
1727     my $dbh = $self->_get_dbh;
1728     local $dbh->{RaiseError} = 1;
1729     local $dbh->{PrintError} = 0;
1730
1731     $sth->execute foreach 1..$count;
1732   } catch {
1733     $exception = shift;
1734   };
1735
1736 # Make sure statement is finished even if there was an exception.
1737   try {
1738     $sth->finish
1739   } catch {
1740     $exception = shift unless defined $exception;
1741   };
1742
1743   $self->throw_exception($exception) if defined $exception;
1744
1745   return $count;
1746 }
1747
1748 sub update {
1749   my ($self, $source, @args) = @_;
1750
1751   my $bind_attrs = $self->source_bind_attributes($source);
1752
1753   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1754 }
1755
1756
1757 sub delete {
1758   my ($self, $source, @args) = @_;
1759
1760   my $bind_attrs = $self->source_bind_attributes($source);
1761
1762   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1763 }
1764
1765 # We were sent here because the $rs contains a complex search
1766 # which will require a subquery to select the correct rows
1767 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1768 #
1769 # Generating a single PK column subquery is trivial and supported
1770 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1771 # Look at _multipk_update_delete()
1772 sub _subq_update_delete {
1773   my $self = shift;
1774   my ($rs, $op, $values) = @_;
1775
1776   my $rsrc = $rs->result_source;
1777
1778   # quick check if we got a sane rs on our hands
1779   my @pcols = $rsrc->_pri_cols;
1780
1781   my $sel = $rs->_resolved_attrs->{select};
1782   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1783
1784   if (
1785       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1786         ne
1787       join ("\x00", sort @$sel )
1788   ) {
1789     $self->throw_exception (
1790       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1791     );
1792   }
1793
1794   if (@pcols == 1) {
1795     return $self->$op (
1796       $rsrc,
1797       $op eq 'update' ? $values : (),
1798       { $pcols[0] => { -in => $rs->as_query } },
1799     );
1800   }
1801
1802   else {
1803     return $self->_multipk_update_delete (@_);
1804   }
1805 }
1806
1807 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1808 # resultset update/delete involving subqueries. So by default resort
1809 # to simple (and inefficient) delete_all style per-row opearations,
1810 # while allowing specific storages to override this with a faster
1811 # implementation.
1812 #
1813 sub _multipk_update_delete {
1814   return shift->_per_row_update_delete (@_);
1815 }
1816
1817 # This is the default loop used to delete/update rows for multi PK
1818 # resultsets, and used by mysql exclusively (because it can't do anything
1819 # else).
1820 #
1821 # We do not use $row->$op style queries, because resultset update/delete
1822 # is not expected to cascade (this is what delete_all/update_all is for).
1823 #
1824 # There should be no race conditions as the entire operation is rolled
1825 # in a transaction.
1826 #
1827 sub _per_row_update_delete {
1828   my $self = shift;
1829   my ($rs, $op, $values) = @_;
1830
1831   my $rsrc = $rs->result_source;
1832   my @pcols = $rsrc->_pri_cols;
1833
1834   my $guard = $self->txn_scope_guard;
1835
1836   # emulate the return value of $sth->execute for non-selects
1837   my $row_cnt = '0E0';
1838
1839   my $subrs_cur = $rs->cursor;
1840   my @all_pk = $subrs_cur->all;
1841   for my $pks ( @all_pk) {
1842
1843     my $cond;
1844     for my $i (0.. $#pcols) {
1845       $cond->{$pcols[$i]} = $pks->[$i];
1846     }
1847
1848     $self->$op (
1849       $rsrc,
1850       $op eq 'update' ? $values : (),
1851       $cond,
1852     );
1853
1854     $row_cnt++;
1855   }
1856
1857   $guard->commit;
1858
1859   return $row_cnt;
1860 }
1861
1862 sub _select {
1863   my $self = shift;
1864   $self->_execute($self->_select_args(@_));
1865 }
1866
1867 sub _select_args_to_query {
1868   my $self = shift;
1869
1870   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1871   #  = $self->_select_args($ident, $select, $cond, $attrs);
1872   my ($op, $bind, $ident, $bind_attrs, @args) =
1873     $self->_select_args(@_);
1874
1875   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1876   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1877   $prepared_bind ||= [];
1878
1879   return wantarray
1880     ? ($sql, $prepared_bind, $bind_attrs)
1881     : \[ "($sql)", @$prepared_bind ]
1882   ;
1883 }
1884
1885 sub _select_args {
1886   my ($self, $ident, $select, $where, $attrs) = @_;
1887
1888   my $sql_maker = $self->sql_maker;
1889   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1890
1891   $attrs = {
1892     %$attrs,
1893     select => $select,
1894     from => $ident,
1895     where => $where,
1896     $rs_alias && $alias2source->{$rs_alias}
1897       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1898       : ()
1899     ,
1900   };
1901
1902   # calculate bind_attrs before possible $ident mangling
1903   my $bind_attrs = {};
1904   for my $alias (keys %$alias2source) {
1905     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1906     for my $col (keys %$bindtypes) {
1907
1908       my $fqcn = join ('.', $alias, $col);
1909       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1910
1911       # Unqialified column names are nice, but at the same time can be
1912       # rather ambiguous. What we do here is basically go along with
1913       # the loop, adding an unqualified column slot to $bind_attrs,
1914       # alongside the fully qualified name. As soon as we encounter
1915       # another column by that name (which would imply another table)
1916       # we unset the unqualified slot and never add any info to it
1917       # to avoid erroneous type binding. If this happens the users
1918       # only choice will be to fully qualify his column name
1919
1920       if (exists $bind_attrs->{$col}) {
1921         $bind_attrs->{$col} = {};
1922       }
1923       else {
1924         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1925       }
1926     }
1927   }
1928
1929   # adjust limits
1930   if (
1931     $attrs->{software_limit}
1932       ||
1933     $sql_maker->_default_limit_syntax eq "GenericSubQ"
1934   ) {
1935     $attrs->{software_limit} = 1;
1936   }
1937   else {
1938     $self->throw_exception("rows attribute must be positive if present")
1939       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1940
1941     # MySQL actually recommends this approach.  I cringe.
1942     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1943   }
1944
1945   my @limit;
1946
1947   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1948   # storage, unless software limit was requested
1949   if (
1950     #limited has_many
1951     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1952        ||
1953     # grouped prefetch (to satisfy group_by == select)
1954     ( $attrs->{group_by}
1955         &&
1956       @{$attrs->{group_by}}
1957         &&
1958       $attrs->{_prefetch_select}
1959         &&
1960       @{$attrs->{_prefetch_select}}
1961     )
1962   ) {
1963     ($ident, $select, $where, $attrs)
1964       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1965   }
1966   elsif (! $attrs->{software_limit} ) {
1967     push @limit, $attrs->{rows}, $attrs->{offset};
1968   }
1969
1970   # try to simplify the joinmap further (prune unreferenced type-single joins)
1971   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1972
1973 ###
1974   # This would be the point to deflate anything found in $where
1975   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1976   # expect a row object. And all we have is a resultsource (it is trivial
1977   # to extract deflator coderefs via $alias2source above).
1978   #
1979   # I don't see a way forward other than changing the way deflators are
1980   # invoked, and that's just bad...
1981 ###
1982
1983   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
1984 }
1985
1986 # Returns a counting SELECT for a simple count
1987 # query. Abstracted so that a storage could override
1988 # this to { count => 'firstcol' } or whatever makes
1989 # sense as a performance optimization
1990 sub _count_select {
1991   #my ($self, $source, $rs_attrs) = @_;
1992   return { count => '*' };
1993 }
1994
1995
1996 sub source_bind_attributes {
1997   my ($self, $source) = @_;
1998
1999   my $bind_attributes;
2000   foreach my $column ($source->columns) {
2001
2002     my $data_type = $source->column_info($column)->{data_type} || '';
2003     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
2004      if $data_type;
2005   }
2006
2007   return $bind_attributes;
2008 }
2009
2010 =head2 select
2011
2012 =over 4
2013
2014 =item Arguments: $ident, $select, $condition, $attrs
2015
2016 =back
2017
2018 Handle a SQL select statement.
2019
2020 =cut
2021
2022 sub select {
2023   my $self = shift;
2024   my ($ident, $select, $condition, $attrs) = @_;
2025   return $self->cursor_class->new($self, \@_, $attrs);
2026 }
2027
2028 sub select_single {
2029   my $self = shift;
2030   my ($rv, $sth, @bind) = $self->_select(@_);
2031   my @row = $sth->fetchrow_array;
2032   my @nextrow = $sth->fetchrow_array if @row;
2033   if(@row && @nextrow) {
2034     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2035   }
2036   # Need to call finish() to work round broken DBDs
2037   $sth->finish();
2038   return @row;
2039 }
2040
2041 =head2 sth
2042
2043 =over 4
2044
2045 =item Arguments: $sql
2046
2047 =back
2048
2049 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2050
2051 =cut
2052
2053 sub _dbh_sth {
2054   my ($self, $dbh, $sql) = @_;
2055
2056   # 3 is the if_active parameter which avoids active sth re-use
2057   my $sth = $self->disable_sth_caching
2058     ? $dbh->prepare($sql)
2059     : $dbh->prepare_cached($sql, {}, 3);
2060
2061   # XXX You would think RaiseError would make this impossible,
2062   #  but apparently that's not true :(
2063   $self->throw_exception($dbh->errstr) if !$sth;
2064
2065   $sth;
2066 }
2067
2068 sub sth {
2069   my ($self, $sql) = @_;
2070   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2071 }
2072
2073 sub _dbh_columns_info_for {
2074   my ($self, $dbh, $table) = @_;
2075
2076   if ($dbh->can('column_info')) {
2077     my %result;
2078     my $caught;
2079     try {
2080       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2081       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2082       $sth->execute();
2083       while ( my $info = $sth->fetchrow_hashref() ){
2084         my %column_info;
2085         $column_info{data_type}   = $info->{TYPE_NAME};
2086         $column_info{size}      = $info->{COLUMN_SIZE};
2087         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2088         $column_info{default_value} = $info->{COLUMN_DEF};
2089         my $col_name = $info->{COLUMN_NAME};
2090         $col_name =~ s/^\"(.*)\"$/$1/;
2091
2092         $result{$col_name} = \%column_info;
2093       }
2094     } catch {
2095       $caught = 1;
2096     };
2097     return \%result if !$caught && scalar keys %result;
2098   }
2099
2100   my %result;
2101   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2102   $sth->execute;
2103   my @columns = @{$sth->{NAME_lc}};
2104   for my $i ( 0 .. $#columns ){
2105     my %column_info;
2106     $column_info{data_type} = $sth->{TYPE}->[$i];
2107     $column_info{size} = $sth->{PRECISION}->[$i];
2108     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2109
2110     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2111       $column_info{data_type} = $1;
2112       $column_info{size}    = $2;
2113     }
2114
2115     $result{$columns[$i]} = \%column_info;
2116   }
2117   $sth->finish;
2118
2119   foreach my $col (keys %result) {
2120     my $colinfo = $result{$col};
2121     my $type_num = $colinfo->{data_type};
2122     my $type_name;
2123     if(defined $type_num && $dbh->can('type_info')) {
2124       my $type_info = $dbh->type_info($type_num);
2125       $type_name = $type_info->{TYPE_NAME} if $type_info;
2126       $colinfo->{data_type} = $type_name if $type_name;
2127     }
2128   }
2129
2130   return \%result;
2131 }
2132
2133 sub columns_info_for {
2134   my ($self, $table) = @_;
2135   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2136 }
2137
2138 =head2 last_insert_id
2139
2140 Return the row id of the last insert.
2141
2142 =cut
2143
2144 sub _dbh_last_insert_id {
2145     my ($self, $dbh, $source, $col) = @_;
2146
2147     my $id = eval { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2148
2149     return $id if defined $id;
2150
2151     my $class = ref $self;
2152     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2153 }
2154
2155 sub last_insert_id {
2156   my $self = shift;
2157   $self->_dbh_last_insert_id ($self->_dbh, @_);
2158 }
2159
2160 =head2 _native_data_type
2161
2162 =over 4
2163
2164 =item Arguments: $type_name
2165
2166 =back
2167
2168 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2169 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2170 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2171
2172 The default implementation returns C<undef>, implement in your Storage driver if
2173 you need this functionality.
2174
2175 Should map types from other databases to the native RDBMS type, for example
2176 C<VARCHAR2> to C<VARCHAR>.
2177
2178 Types with modifiers should map to the underlying data type. For example,
2179 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2180
2181 Composite types should map to the container type, for example
2182 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2183
2184 =cut
2185
2186 sub _native_data_type {
2187   #my ($self, $data_type) = @_;
2188   return undef
2189 }
2190
2191 # Check if placeholders are supported at all
2192 sub _placeholders_supported {
2193   my $self = shift;
2194   my $dbh  = $self->_get_dbh;
2195
2196   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2197   # but it is inaccurate more often than not
2198   my $rc = 1;
2199   try {
2200     local $dbh->{PrintError} = 0;
2201     local $dbh->{RaiseError} = 1;
2202     $dbh->do('select ?', {}, 1);
2203   } catch {
2204     $rc = 0;
2205   };
2206   return $rc;
2207 }
2208
2209 # Check if placeholders bound to non-string types throw exceptions
2210 #
2211 sub _typeless_placeholders_supported {
2212   my $self = shift;
2213   my $dbh  = $self->_get_dbh;
2214
2215   my $rc = 1;
2216   try {
2217     local $dbh->{PrintError} = 0;
2218     local $dbh->{RaiseError} = 1;
2219     # this specifically tests a bind that is NOT a string
2220     $dbh->do('select 1 where 1 = ?', {}, 1);
2221   } catch {
2222     $rc = 0;
2223   };
2224   return $rc;
2225 }
2226
2227 =head2 sqlt_type
2228
2229 Returns the database driver name.
2230
2231 =cut
2232
2233 sub sqlt_type {
2234   shift->_get_dbh->{Driver}->{Name};
2235 }
2236
2237 =head2 bind_attribute_by_data_type
2238
2239 Given a datatype from column info, returns a database specific bind
2240 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2241 let the database planner just handle it.
2242
2243 Generally only needed for special case column types, like bytea in postgres.
2244
2245 =cut
2246
2247 sub bind_attribute_by_data_type {
2248     return;
2249 }
2250
2251 =head2 is_datatype_numeric
2252
2253 Given a datatype from column_info, returns a boolean value indicating if
2254 the current RDBMS considers it a numeric value. This controls how
2255 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2256 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2257 be performed instead of the usual C<eq>.
2258
2259 =cut
2260
2261 sub is_datatype_numeric {
2262   my ($self, $dt) = @_;
2263
2264   return 0 unless $dt;
2265
2266   return $dt =~ /^ (?:
2267     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2268   ) $/ix;
2269 }
2270
2271
2272 =head2 create_ddl_dir
2273
2274 =over 4
2275
2276 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2277
2278 =back
2279
2280 Creates a SQL file based on the Schema, for each of the specified
2281 database engines in C<\@databases> in the given directory.
2282 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2283
2284 Given a previous version number, this will also create a file containing
2285 the ALTER TABLE statements to transform the previous schema into the
2286 current one. Note that these statements may contain C<DROP TABLE> or
2287 C<DROP COLUMN> statements that can potentially destroy data.
2288
2289 The file names are created using the C<ddl_filename> method below, please
2290 override this method in your schema if you would like a different file
2291 name format. For the ALTER file, the same format is used, replacing
2292 $version in the name with "$preversion-$version".
2293
2294 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2295 The most common value for this would be C<< { add_drop_table => 1 } >>
2296 to have the SQL produced include a C<DROP TABLE> statement for each table
2297 created. For quoting purposes supply C<quote_table_names> and
2298 C<quote_field_names>.
2299
2300 If no arguments are passed, then the following default values are assumed:
2301
2302 =over 4
2303
2304 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2305
2306 =item version    - $schema->schema_version
2307
2308 =item directory  - './'
2309
2310 =item preversion - <none>
2311
2312 =back
2313
2314 By default, C<\%sqlt_args> will have
2315
2316  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2317
2318 merged with the hash passed in. To disable any of those features, pass in a
2319 hashref like the following
2320
2321  { ignore_constraint_names => 0, # ... other options }
2322
2323
2324 WARNING: You are strongly advised to check all SQL files created, before applying
2325 them.
2326
2327 =cut
2328
2329 sub create_ddl_dir {
2330   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2331
2332   unless ($dir) {
2333     carp "No directory given, using ./\n";
2334     $dir = './';
2335   } else {
2336       -d $dir or File::Path::mkpath($dir)
2337           or $self->throw_exception("create_ddl_dir: $! creating dir '$dir'");
2338   }
2339
2340   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2341
2342   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2343   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2344
2345   my $schema_version = $schema->schema_version || '1.x';
2346   $version ||= $schema_version;
2347
2348   $sqltargs = {
2349     add_drop_table => 1,
2350     ignore_constraint_names => 1,
2351     ignore_index_names => 1,
2352     %{$sqltargs || {}}
2353   };
2354
2355   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2356     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2357   }
2358
2359   my $sqlt = SQL::Translator->new( $sqltargs );
2360
2361   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2362   my $sqlt_schema = $sqlt->translate({ data => $schema })
2363     or $self->throw_exception ($sqlt->error);
2364
2365   foreach my $db (@$databases) {
2366     $sqlt->reset();
2367     $sqlt->{schema} = $sqlt_schema;
2368     $sqlt->producer($db);
2369
2370     my $file;
2371     my $filename = $schema->ddl_filename($db, $version, $dir);
2372     if (-e $filename && ($version eq $schema_version )) {
2373       # if we are dumping the current version, overwrite the DDL
2374       carp "Overwriting existing DDL file - $filename";
2375       unlink($filename);
2376     }
2377
2378     my $output = $sqlt->translate;
2379     if(!$output) {
2380       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2381       next;
2382     }
2383     if(!open($file, ">$filename")) {
2384       $self->throw_exception("Can't open $filename for writing ($!)");
2385       next;
2386     }
2387     print $file $output;
2388     close($file);
2389
2390     next unless ($preversion);
2391
2392     require SQL::Translator::Diff;
2393
2394     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2395     if(!-e $prefilename) {
2396       carp("No previous schema file found ($prefilename)");
2397       next;
2398     }
2399
2400     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2401     if(-e $difffile) {
2402       carp("Overwriting existing diff file - $difffile");
2403       unlink($difffile);
2404     }
2405
2406     my $source_schema;
2407     {
2408       my $t = SQL::Translator->new($sqltargs);
2409       $t->debug( 0 );
2410       $t->trace( 0 );
2411
2412       $t->parser( $db )
2413         or $self->throw_exception ($t->error);
2414
2415       my $out = $t->translate( $prefilename )
2416         or $self->throw_exception ($t->error);
2417
2418       $source_schema = $t->schema;
2419
2420       $source_schema->name( $prefilename )
2421         unless ( $source_schema->name );
2422     }
2423
2424     # The "new" style of producers have sane normalization and can support
2425     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2426     # And we have to diff parsed SQL against parsed SQL.
2427     my $dest_schema = $sqlt_schema;
2428
2429     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2430       my $t = SQL::Translator->new($sqltargs);
2431       $t->debug( 0 );
2432       $t->trace( 0 );
2433
2434       $t->parser( $db )
2435         or $self->throw_exception ($t->error);
2436
2437       my $out = $t->translate( $filename )
2438         or $self->throw_exception ($t->error);
2439
2440       $dest_schema = $t->schema;
2441
2442       $dest_schema->name( $filename )
2443         unless $dest_schema->name;
2444     }
2445
2446     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2447                                                   $dest_schema,   $db,
2448                                                   $sqltargs
2449                                                  );
2450     if(!open $file, ">$difffile") {
2451       $self->throw_exception("Can't write to $difffile ($!)");
2452       next;
2453     }
2454     print $file $diff;
2455     close($file);
2456   }
2457 }
2458
2459 =head2 deployment_statements
2460
2461 =over 4
2462
2463 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2464
2465 =back
2466
2467 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2468
2469 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2470 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2471
2472 C<$directory> is used to return statements from files in a previously created
2473 L</create_ddl_dir> directory and is optional. The filenames are constructed
2474 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2475
2476 If no C<$directory> is specified then the statements are constructed on the
2477 fly using L<SQL::Translator> and C<$version> is ignored.
2478
2479 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2480
2481 =cut
2482
2483 sub deployment_statements {
2484   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2485   $type ||= $self->sqlt_type;
2486   $version ||= $schema->schema_version || '1.x';
2487   $dir ||= './';
2488   my $filename = $schema->ddl_filename($type, $version, $dir);
2489   if(-f $filename)
2490   {
2491       my $file;
2492       open($file, "<$filename")
2493         or $self->throw_exception("Can't open $filename ($!)");
2494       my @rows = <$file>;
2495       close($file);
2496       return join('', @rows);
2497   }
2498
2499   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2500     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2501   }
2502
2503   # sources needs to be a parser arg, but for simplicty allow at top level
2504   # coming in
2505   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2506       if exists $sqltargs->{sources};
2507
2508   my $tr = SQL::Translator->new(
2509     producer => "SQL::Translator::Producer::${type}",
2510     %$sqltargs,
2511     parser => 'SQL::Translator::Parser::DBIx::Class',
2512     data => $schema,
2513   );
2514
2515   my @ret;
2516   my $wa = wantarray;
2517   if ($wa) {
2518     @ret = $tr->translate;
2519   }
2520   else {
2521     $ret[0] = $tr->translate;
2522   }
2523
2524   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2525     unless (@ret && defined $ret[0]);
2526
2527   return $wa ? @ret : $ret[0];
2528 }
2529
2530 sub deploy {
2531   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2532   my $deploy = sub {
2533     my $line = shift;
2534     return if($line =~ /^--/);
2535     return if(!$line);
2536     # next if($line =~ /^DROP/m);
2537     return if($line =~ /^BEGIN TRANSACTION/m);
2538     return if($line =~ /^COMMIT/m);
2539     return if $line =~ /^\s+$/; # skip whitespace only
2540     $self->_query_start($line);
2541     try {
2542       # do a dbh_do cycle here, as we need some error checking in
2543       # place (even though we will ignore errors)
2544       $self->dbh_do (sub { $_[1]->do($line) });
2545     } catch {
2546       carp qq{$@ (running "${line}")};
2547     };
2548     $self->_query_end($line);
2549   };
2550   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2551   if (@statements > 1) {
2552     foreach my $statement (@statements) {
2553       $deploy->( $statement );
2554     }
2555   }
2556   elsif (@statements == 1) {
2557     foreach my $line ( split(";\n", $statements[0])) {
2558       $deploy->( $line );
2559     }
2560   }
2561 }
2562
2563 =head2 datetime_parser
2564
2565 Returns the datetime parser class
2566
2567 =cut
2568
2569 sub datetime_parser {
2570   my $self = shift;
2571   return $self->{datetime_parser} ||= do {
2572     $self->build_datetime_parser(@_);
2573   };
2574 }
2575
2576 =head2 datetime_parser_type
2577
2578 Defines (returns) the datetime parser class - currently hardwired to
2579 L<DateTime::Format::MySQL>
2580
2581 =cut
2582
2583 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2584
2585 =head2 build_datetime_parser
2586
2587 See L</datetime_parser>
2588
2589 =cut
2590
2591 sub build_datetime_parser {
2592   my $self = shift;
2593   my $type = $self->datetime_parser_type(@_);
2594   $self->ensure_class_loaded ($type);
2595   return $type;
2596 }
2597
2598
2599 =head2 is_replicating
2600
2601 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2602 replicate from a master database.  Default is undef, which is the result
2603 returned by databases that don't support replication.
2604
2605 =cut
2606
2607 sub is_replicating {
2608     return;
2609
2610 }
2611
2612 =head2 lag_behind_master
2613
2614 Returns a number that represents a certain amount of lag behind a master db
2615 when a given storage is replicating.  The number is database dependent, but
2616 starts at zero and increases with the amount of lag. Default in undef
2617
2618 =cut
2619
2620 sub lag_behind_master {
2621     return;
2622 }
2623
2624 =head2 relname_to_table_alias
2625
2626 =over 4
2627
2628 =item Arguments: $relname, $join_count
2629
2630 =back
2631
2632 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2633 queries.
2634
2635 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2636 way these aliases are named.
2637
2638 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2639 otherwise C<"$relname">.
2640
2641 =cut
2642
2643 sub relname_to_table_alias {
2644   my ($self, $relname, $join_count) = @_;
2645
2646   my $alias = ($join_count && $join_count > 1 ?
2647     join('_', $relname, $join_count) : $relname);
2648
2649   return $alias;
2650 }
2651
2652 1;
2653
2654 =head1 USAGE NOTES
2655
2656 =head2 DBIx::Class and AutoCommit
2657
2658 DBIx::Class can do some wonderful magic with handling exceptions,
2659 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2660 (the default) combined with C<txn_do> for transaction support.
2661
2662 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2663 in an assumed transaction between commits, and you're telling us you'd
2664 like to manage that manually.  A lot of the magic protections offered by
2665 this module will go away.  We can't protect you from exceptions due to database
2666 disconnects because we don't know anything about how to restart your
2667 transactions.  You're on your own for handling all sorts of exceptional
2668 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2669 be with raw DBI.
2670
2671
2672 =head1 AUTHORS
2673
2674 Matt S. Trout <mst@shadowcatsystems.co.uk>
2675
2676 Andy Grundman <andy@hybridized.org>
2677
2678 =head1 LICENSE
2679
2680 You may distribute this code under the same terms as Perl itself.
2681
2682 =cut