lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   $self->SUPER::select($table, $self->_recurse_fields($fields),
  21                          $where, $order, @rest);
  22 }
  23
  24 sub _emulate_limit {
  25   my $self = shift;
  26   if ($_[3] == -1) {
  27     return $_[1].$self->_order_by($_[2]);
  28   } else {
  29     return $self->SUPER::_emulate_limit(@_);
  30   }
  31 }
  32
  33 sub _recurse_fields {
  34   my ($self, $fields) = @_;
  35   my $ref = ref $fields;
  36   return $self->_quote($fields) unless $ref;
  37   return $$fields if $ref eq 'SCALAR';
  38
  39   if ($ref eq 'ARRAY') {
  40     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  41   } elsif ($ref eq 'HASH') {
  42     foreach my $func (keys %$fields) {
  43       return $self->_sqlcase($func)
  44         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  45     }
  46   }
  47 }
  48
  49 sub _order_by {
  50   my $self = shift;
  51   my $ret = '';
  52   if (ref $_[0] eq 'HASH') {
  53     if (defined $_[0]->{group_by}) {
  54       $ret = $self->_sqlcase(' group by ')
  55                .$self->_recurse_fields($_[0]->{group_by});
  56     }
  57     if (defined $_[0]->{order_by}) {
  58       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  59     }
  60   } else {
  61     $ret = $self->SUPER::_order_by(@_);
  62   }
  63   return $ret;
  64 }
  65
  66 sub _table {
  67   my ($self, $from) = @_;
  68   if (ref $from eq 'ARRAY') {
  69     return $self->_recurse_from(@$from);
  70   } elsif (ref $from eq 'HASH') {
  71     return $self->_make_as($from);
  72   } else {
  73     return $from;
  74   }
  75 }
  76
  77 sub _recurse_from {
  78   my ($self, $from, @join) = @_;
  79   my @sqlf;
  80   push(@sqlf, $self->_make_as($from));
  81   foreach my $j (@join) {
  82     my ($to, $on) = @$j;
  83
  84     # check whether a join type exists
  85     my $join_clause = '';
  86     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  87       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  88     } else {
  89       $join_clause = ' JOIN ';
  90     }
  91     push(@sqlf, $join_clause);
  92
  93     if (ref $to eq 'ARRAY') {
  94       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  95     } else {
  96       push(@sqlf, $self->_make_as($to));
  97     }
  98     push(@sqlf, ' ON ', $self->_join_condition($on));
  99   }
 100   return join('', @sqlf);
 101 }
 102
 103 sub _make_as {
 104   my ($self, $from) = @_;
 105   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 106                            reverse each %{$self->_skip_options($from)});
 107 }
 108
 109 sub _skip_options {
 110   my ($self, $hash) = @_;
 111   my $clean_hash = {};
 112   $clean_hash->{$_} = $hash->{$_}
 113     for grep {!/^-/} keys %$hash;
 114   return $clean_hash;
 115 }
 116
 117 sub _join_condition {
 118   my ($self, $cond) = @_;
 119   if (ref $cond eq 'HASH') {
 120     my %j;
 121     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 122     return $self->_recurse_where(\%j);
 123   } elsif (ref $cond eq 'ARRAY') {
 124     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 125   } else {
 126     die "Can't handle this yet!";
 127   }
 128 }
 129
 130 sub _quote {
 131   my ($self, $label) = @_;
 132   return '' unless defined $label;
 133   return $label unless $self->{quote_char};
 134   return $self->SUPER::_quote($label);
 135 }
 136
 137 sub _RowNum {
 138    my $self = shift;
 139    my $c;
 140    $_[0] =~ s/SELECT (.*?) FROM/
 141      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 142    $self->SUPER::_RowNum(@_);
 143 }
 144
 145 # Accessor for setting limit dialect. This is useful
 146 # for JDBC-bridge among others where the remote SQL-dialect cannot
 147 # be determined by the name of the driver alone.
 148 #
 149 sub limit_dialect {
 150     my $self = shift;
 151     $self->{limit_dialect} = shift if @_;
 152     return $self->{limit_dialect};
 153 }
 154
 155 package DBIx::Class::Storage::DBI::DebugCallback;
 156
 157 sub print {
 158   my ($self, $string) = @_;
 159   $string =~ m/^(\w+)/;
 160   ${$self}->($1, $string);
 161 }
 162
 163 } # End of BEGIN block
 164
 165 use base qw/DBIx::Class/;
 166
 167 __PACKAGE__->load_components(qw/AccessorGroup/);
 168
 169 __PACKAGE__->mk_group_accessors('simple' =>
 170   qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
 171      on_connect_do transaction_depth/);
 172
 173 sub new {
 174   my $new = bless({}, ref $_[0] || $_[0]);
 175   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 176   $new->transaction_depth(0);
 177   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 178      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 179     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 180   } else {
 181     $new->debugfh(IO::File->new('>&STDERR'));
 182   }
 183   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 184   return $new;
 185 }
 186
 187 =head1 NAME
 188
 189 DBIx::Class::Storage::DBI - DBI storage handler
 190
 191 =head1 SYNOPSIS
 192
 193 =head1 DESCRIPTION
 194
 195 This class represents the connection to the database
 196
 197 =head1 METHODS
 198
 199 =cut
 200
 201 =head2 on_connect_do
 202
 203 Executes the sql statements given as a listref on every db connect.
 204
 205 =head2 debug
 206
 207 Causes SQL trace information to be emitted on C<debugfh> filehandle
 208 (or C<STDERR> if C<debugfh> has not specifically been set).
 209
 210 =head2 debugfh
 211
 212 Sets or retrieves the filehandle used for trace/debug output.  This
 213 should be an IO::Handle compatible object (only the C<print> method is
 214 used).  Initially set to be STDERR - although see information on the
 215 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 216
 217 =head2 debugcb
 218
 219 Sets a callback to be executed each time a statement is run; takes a sub
 220 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 221 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 222 be printed.
 223
 224 =cut
 225
 226 sub debugcb {
 227   my ($self, $cb) = @_;
 228   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 229   $self->debugfh($cb_obj);
 230 }
 231
 232 sub disconnect {
 233   my ($self) = @_;
 234
 235   if( $self->connected ) {
 236     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 237     $self->_dbh->disconnect;
 238     $self->_dbh(undef);
 239   }
 240 }
 241
 242 sub connected {
 243   my ($self) = @_;
 244
 245   my $dbh;
 246   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 247 }
 248
 249 sub ensure_connected {
 250   my ($self) = @_;
 251
 252   unless ($self->connected) {
 253     $self->_populate_dbh;
 254   }
 255 }
 256
 257 sub dbh {
 258   my ($self) = @_;
 259
 260   $self->_dbh(undef)
 261     if $self->_connection_pid && $self->_connection_pid != $$;
 262   $self->ensure_connected;
 263   return $self->_dbh;
 264 }
 265
 266 sub sql_maker {
 267   my ($self) = @_;
 268   unless ($self->_sql_maker) {
 269     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 270   }
 271   return $self->_sql_maker;
 272 }
 273
 274 sub _populate_dbh {
 275   my ($self) = @_;
 276   my @info = @{$self->connect_info || []};
 277   $self->_dbh($self->_connect(@info));
 278   my $driver = $self->_dbh->{Driver}->{Name};
 279   eval "require DBIx::Class::Storage::DBI::${driver}";
 280   unless ($@) {
 281     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 282   }
 283   # if on-connect sql statements are given execute them
 284   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 285     $self->_dbh->do($sql_statement);
 286   }
 287
 288   $self->_connection_pid($$);
 289 }
 290
 291 sub _connect {
 292   my ($self, @info) = @_;
 293
 294   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 295       my $old_connect_via = $DBI::connect_via;
 296       $DBI::connect_via = 'connect';
 297       my $dbh = DBI->connect(@info);
 298       $DBI::connect_via = $old_connect_via;
 299       return $dbh;
 300   }
 301
 302   DBI->connect(@info);
 303 }
 304
 305 =head2 txn_begin
 306
 307 Calls begin_work on the current dbh.
 308
 309 =cut
 310
 311 sub txn_begin {
 312   my $self = shift;
 313   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 314 }
 315
 316 =head2 txn_commit
 317
 318 Issues a commit against the current dbh.
 319
 320 =cut
 321
 322 sub txn_commit {
 323   my $self = shift;
 324   if ($self->{transaction_depth} == 0) {
 325     $self->dbh->commit unless $self->dbh->{AutoCommit};
 326   }
 327   else {
 328     $self->dbh->commit if --$self->{transaction_depth} == 0;
 329   }
 330 }
 331
 332 =head2 txn_rollback
 333
 334 Issues a rollback against the current dbh.
 335
 336 =cut
 337
 338 sub txn_rollback {
 339   my $self = shift;
 340   if ($self->{transaction_depth} == 0) {
 341     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 342   }
 343   else {
 344     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 345   }
 346 }
 347
 348 sub _execute {
 349   my ($self, $op, $extra_bind, $ident, @args) = @_;
 350   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 351   unshift(@bind, @$extra_bind) if $extra_bind;
 352   if ($self->debug) {
 353       my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
 354       $self->debugfh->print("$sql: @debug_bind\n");
 355   }
 356   my $sth = $self->sth($sql,$op);
 357   croak "no sth generated via sql: $sql" unless $sth;
 358   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 359   my $rv;
 360   if ($sth) {
 361     $rv = $sth->execute(@bind);
 362   } else {
 363     croak "'$sql' did not generate a statement.";
 364   }
 365   return (wantarray ? ($rv, $sth, @bind) : $rv);
 366 }
 367
 368 sub insert {
 369   my ($self, $ident, $to_insert) = @_;
 370   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 371     unless ($self->_execute('insert' => [], $ident, $to_insert));
 372   return $to_insert;
 373 }
 374
 375 sub update {
 376   return shift->_execute('update' => [], @_);
 377 }
 378
 379 sub delete {
 380   return shift->_execute('delete' => [], @_);
 381 }
 382
 383 sub _select {
 384   my ($self, $ident, $select, $condition, $attrs) = @_;
 385   my $order = $attrs->{order_by};
 386   if (ref $condition eq 'SCALAR') {
 387     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 388   }
 389   if (exists $attrs->{group_by}) {
 390     $order = { group_by => $attrs->{group_by},
 391                ($order ? (order_by => $order) : ()) };
 392   }
 393   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 394   if ($attrs->{software_limit} ||
 395       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 396         $attrs->{software_limit} = 1;
 397   } else {
 398     push @args, $attrs->{rows}, $attrs->{offset};
 399   }
 400   return $self->_execute(@args);
 401 }
 402
 403 sub select {
 404   my $self = shift;
 405   my ($ident, $select, $condition, $attrs) = @_;
 406   return $self->cursor->new($self, \@_, $attrs);
 407 }
 408
 409 # Need to call finish() to work round broken DBDs
 410
 411 sub select_single {
 412   my $self = shift;
 413   my ($rv, $sth, @bind) = $self->_select(@_);
 414   my @row = $sth->fetchrow_array;
 415   $sth->finish();
 416   return @row;
 417 }
 418
 419 sub sth {
 420   my ($self, $sql) = @_;
 421   # 3 is the if_active parameter which avoids active sth re-use
 422   return $self->dbh->prepare_cached($sql, {}, 3);
 423 }
 424
 425 =head2 columns_info_for
 426
 427 Returns database type info for a given table columns.
 428
 429 =cut
 430
 431 sub columns_info_for {
 432     my ($self, $table) = @_;
 433     my %result;
 434     if ( $self->dbh->can( 'column_info' ) ){
 435         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 436         $sth->execute();
 437         while ( my $info = $sth->fetchrow_hashref() ){
 438             my %column_info;
 439             $column_info{data_type} = $info->{TYPE_NAME};
 440             $column_info{size} = $info->{COLUMN_SIZE};
 441             $column_info{is_nullable} = $info->{NULLABLE};
 442             $result{$info->{COLUMN_NAME}} = \%column_info;
 443         }
 444     }else{
 445         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 446         $sth->execute;
 447         my @columns = @{$sth->{NAME}};
 448         for my $i ( 0 .. $#columns ){
 449             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 450         }
 451     }
 452     return \%result;
 453 }
 454
 455 sub last_insert_id {
 456   my ($self, $row) = @_;
 457
 458   return $self->dbh->func('last_insert_rowid');
 459
 460 }
 461
 462
 463
 464 sub DESTROY { shift->disconnect }
 465
 466 1;
 467
 468 =head1 ENVIRONMENT VARIABLES
 469
 470 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 471
 472 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 473 is produced (as when the L<debug> method is set).
 474
 475 If the value is of the form C<1=/path/name> then the trace output is
 476 written to the file C</path/name>.
 477
 478 =head1 AUTHORS
 479
 480 Matt S. Trout <mst@shadowcatsystems.co.uk>
 481
 482 Andy Grundman <andy@hybridized.org>
 483
 484 =head1 LICENSE
 485
 486 You may distribute this code under the same terms as Perl itself.
 487
 488 =cut
 489