lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Carp::Clan qw/DBIx::Class/;
  14 BEGIN {
  15
  16 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  17
  18 use base qw/SQL::Abstract::Limit/;
  19
  20 sub select {
  21   my ($self, $table, $fields, $where, $order, @rest) = @_;
  22   $table = $self->_quote($table) unless ref($table);
  23   @rest = (-1) unless defined $rest[0];
  24   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  25     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  26   local $self->{having_bind} = [];
  27   my ($sql, @ret) = $self->SUPER::select(
  28     $table, $self->_recurse_fields($fields), $where, $order, @rest
  29   );
  30   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  31 }
  32
  33 sub insert {
  34   my $self = shift;
  35   my $table = shift;
  36   $table = $self->_quote($table) unless ref($table);
  37   $self->SUPER::insert($table, @_);
  38 }
  39
  40 sub update {
  41   my $self = shift;
  42   my $table = shift;
  43   $table = $self->_quote($table) unless ref($table);
  44   $self->SUPER::update($table, @_);
  45 }
  46
  47 sub delete {
  48   my $self = shift;
  49   my $table = shift;
  50   $table = $self->_quote($table) unless ref($table);
  51   $self->SUPER::delete($table, @_);
  52 }
  53
  54 sub _emulate_limit {
  55   my $self = shift;
  56   if ($_[3] == -1) {
  57     return $_[1].$self->_order_by($_[2]);
  58   } else {
  59     return $self->SUPER::_emulate_limit(@_);
  60   }
  61 }
  62
  63 sub _recurse_fields {
  64   my ($self, $fields) = @_;
  65   my $ref = ref $fields;
  66   return $self->_quote($fields) unless $ref;
  67   return $$fields if $ref eq 'SCALAR';
  68
  69   if ($ref eq 'ARRAY') {
  70     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  71   } elsif ($ref eq 'HASH') {
  72     foreach my $func (keys %$fields) {
  73       return $self->_sqlcase($func)
  74         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  75     }
  76   }
  77 }
  78
  79 sub _order_by {
  80   my $self = shift;
  81   my $ret = '';
  82   my @extra;
  83   if (ref $_[0] eq 'HASH') {
  84     if (defined $_[0]->{group_by}) {
  85       $ret = $self->_sqlcase(' group by ')
  86                .$self->_recurse_fields($_[0]->{group_by});
  87     }
  88     if (defined $_[0]->{having}) {
  89       my $frag;
  90       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  91       push(@{$self->{having_bind}}, @extra);
  92       $ret .= $self->_sqlcase(' having ').$frag;
  93     }
  94     if (defined $_[0]->{order_by}) {
  95       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  96     }
  97   } elsif(ref $_[0] eq 'SCALAR') {
  98     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  99   } else {
 100     $ret = $self->SUPER::_order_by(@_);
 101   }
 102   return $ret;
 103 }
 104
 105 sub _order_directions {
 106   my ($self, $order) = @_;
 107   $order = $order->{order_by} if ref $order eq 'HASH';
 108   return $self->SUPER::_order_directions($order);
 109 }
 110
 111 sub _table {
 112   my ($self, $from) = @_;
 113   if (ref $from eq 'ARRAY') {
 114     return $self->_recurse_from(@$from);
 115   } elsif (ref $from eq 'HASH') {
 116     return $self->_make_as($from);
 117   } else {
 118     return $from; # would love to quote here but _table ends up getting called
 119                   # twice during an ->select without a limit clause due to
 120                   # the way S::A::Limit->select works. should maybe consider
 121                   # bypassing this and doing S::A::select($self, ...) in
 122                   # our select method above. meantime, quoting shims have
 123                   # been added to select/insert/update/delete here
 124   }
 125 }
 126
 127 sub _recurse_from {
 128   my ($self, $from, @join) = @_;
 129   my @sqlf;
 130   push(@sqlf, $self->_make_as($from));
 131   foreach my $j (@join) {
 132     my ($to, $on) = @$j;
 133
 134     # check whether a join type exists
 135     my $join_clause = '';
 136     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 137       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 138     } else {
 139       $join_clause = ' JOIN ';
 140     }
 141     push(@sqlf, $join_clause);
 142
 143     if (ref $to eq 'ARRAY') {
 144       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 145     } else {
 146       push(@sqlf, $self->_make_as($to));
 147     }
 148     push(@sqlf, ' ON ', $self->_join_condition($on));
 149   }
 150   return join('', @sqlf);
 151 }
 152
 153 sub _make_as {
 154   my ($self, $from) = @_;
 155   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 156                      reverse each %{$self->_skip_options($from)});
 157 }
 158
 159 sub _skip_options {
 160   my ($self, $hash) = @_;
 161   my $clean_hash = {};
 162   $clean_hash->{$_} = $hash->{$_}
 163     for grep {!/^-/} keys %$hash;
 164   return $clean_hash;
 165 }
 166
 167 sub _join_condition {
 168   my ($self, $cond) = @_;
 169   if (ref $cond eq 'HASH') {
 170     my %j;
 171     for (keys %$cond) {
 172       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 173     };
 174     return $self->_recurse_where(\%j);
 175   } elsif (ref $cond eq 'ARRAY') {
 176     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 177   } else {
 178     die "Can't handle this yet!";
 179   }
 180 }
 181
 182 sub _quote {
 183   my ($self, $label) = @_;
 184   return '' unless defined $label;
 185   return "*" if $label eq '*';
 186   return $label unless $self->{quote_char};
 187   if(ref $self->{quote_char} eq "ARRAY"){
 188     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 189       if !defined $self->{name_sep};
 190     my $sep = $self->{name_sep};
 191     return join($self->{name_sep},
 192         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 193        split(/\Q$sep\E/,$label));
 194   }
 195   return $self->SUPER::_quote($label);
 196 }
 197
 198 sub _RowNum {
 199    my $self = shift;
 200    my $c;
 201    $_[0] =~ s/SELECT (.*?) FROM/
 202      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 203    $self->SUPER::_RowNum(@_);
 204 }
 205
 206 # Accessor for setting limit dialect. This is useful
 207 # for JDBC-bridge among others where the remote SQL-dialect cannot
 208 # be determined by the name of the driver alone.
 209 #
 210 sub limit_dialect {
 211     my $self = shift;
 212     $self->{limit_dialect} = shift if @_;
 213     return $self->{limit_dialect};
 214 }
 215
 216 sub quote_char {
 217     my $self = shift;
 218     $self->{quote_char} = shift if @_;
 219     return $self->{quote_char};
 220 }
 221
 222 sub name_sep {
 223     my $self = shift;
 224     $self->{name_sep} = shift if @_;
 225     return $self->{name_sep};
 226 }
 227
 228 } # End of BEGIN block
 229
 230 use base qw/DBIx::Class/;
 231
 232 __PACKAGE__->load_components(qw/AccessorGroup/);
 233
 234 __PACKAGE__->mk_group_accessors('simple' =>
 235   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugobj
 236      cursor on_connect_do transaction_depth/);
 237
 238 sub new {
 239   my $new = bless({}, ref $_[0] || $_[0]);
 240   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 241   $new->transaction_depth(0);
 242
 243   $new->debugobj(new DBIx::Class::Storage::Statistics());
 244
 245   my $fh;
 246   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 247      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 248     $fh = IO::File->new($1, 'w')
 249       or $new->throw_exception("Cannot open trace file $1");
 250   } else {
 251     $fh = IO::File->new('>&STDERR');
 252   }
 253   $new->debugobj->debugfh($fh);
 254   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 255   return $new;
 256 }
 257
 258 sub throw_exception {
 259   my ($self, $msg) = @_;
 260   croak($msg);
 261 }
 262
 263 =head1 NAME
 264
 265 DBIx::Class::Storage::DBI - DBI storage handler
 266
 267 =head1 SYNOPSIS
 268
 269 =head1 DESCRIPTION
 270
 271 This class represents the connection to the database
 272
 273 =head1 METHODS
 274
 275 =cut
 276
 277 =head2 connect_info
 278
 279 Connection information arrayref.  Can either be the same arguments
 280 one would pass to DBI->connect, or a code-reference which returns
 281 a connected database handle.  In either case, there is an optional
 282 final element in the arrayref, which can hold a hashref of
 283 connection-specific Storage::DBI options.  These include
 284 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 285 C<quote_char>, and C<name_sep>.  Examples:
 286
 287   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 288   ->connect_info(sub { DBI->connect(...) });
 289   ->connect_info([ 'dbi:Pg:dbname=foo',
 290                    'postgres',
 291                    '',
 292                    { AutoCommit => 0 },
 293                    { quote_char => q{`}, name_sep => q{@} },
 294                  ]);
 295
 296 =head2 on_connect_do
 297
 298 Executes the sql statements given as a listref on every db connect.
 299
 300 =head2 quote_char
 301
 302 Specifies what characters to use to quote table and column names. If
 303 you use this you will want to specify L<name_sep> as well.
 304
 305 quote_char expectes either a single character, in which case is it is placed
 306 on either side of the table/column, or an array of length 2 in which case the
 307 table/column name is placed between the elements.
 308
 309 For example under MySQL you'd use C<quote_char('`')>, and user SQL Server you'd
 310 use C<quote_char(qw/[ ]/)>.
 311
 312 =head2 name_sep
 313
 314 This only needs to be used in conjunction with L<quote_char>, and is used to
 315 specify the charecter that seperates elements (schemas, tables, columns) from
 316 each other. In most cases this is simply a C<.>.
 317
 318 =head2 debug
 319
 320 Causes SQL trace information to be emitted on the C<debugobj> object.
 321 (or C<STDERR> if C<debugobj> has not specifically been set).
 322
 323 =head2 debugfh
 324
 325 Set or retrieve the filehandle used for trace/debug output.  This should be
 326 an IO::Handle compatible ojbect (only the C<print> method is used.  Initially
 327 set to be STDERR - although see information on the
 328 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 329
 330 =head2 debugobj
 331
 332 Sets or retrieves the object used for metric collection. Defaults to an instance
 333 of L<DBIx::Class::Storage::Statistics> that is campatible with the original
 334 method of using a coderef as a callback.  See the aforementioned Statistics
 335 class for more information.
 336
 337 =head2 debugcb
 338
 339 Sets a callback to be executed each time a statement is run; takes a sub
 340 reference.  Callback is executed as $sub->($op, $info) where $op is
 341 SELECT/INSERT/UPDATE/DELETE and $info is what would normally be printed.
 342
 343 See L<debugobj> for a better way.
 344
 345 =cut
 346 sub debugcb {
 347     my $self = shift();
 348
 349     if($self->debugobj()->can('callback')) {
 350         $self->debugobj()->callback(shift());
 351     }
 352 }
 353
 354 sub disconnect {
 355   my ($self) = @_;
 356
 357   if( $self->connected ) {
 358     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 359     $self->_dbh->disconnect;
 360     $self->_dbh(undef);
 361   }
 362 }
 363
 364 sub connected {
 365   my ($self) = @_;
 366
 367   if(my $dbh = $self->_dbh) {
 368       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 369           $self->_sql_maker(undef);
 370           return $self->_dbh(undef);
 371       }
 372       elsif($self->_conn_pid != $$) {
 373           $self->_dbh->{InactiveDestroy} = 1;
 374           $self->_sql_maker(undef);
 375           return $self->_dbh(undef)
 376       }
 377       return ($dbh->FETCH('Active') && $dbh->ping);
 378   }
 379
 380   return 0;
 381 }
 382
 383 sub ensure_connected {
 384   my ($self) = @_;
 385
 386   unless ($self->connected) {
 387     $self->_populate_dbh;
 388   }
 389 }
 390
 391 =head2 dbh
 392
 393 Returns the dbh - a data base handle of class L<DBI>.
 394
 395 =cut
 396
 397 sub dbh {
 398   my ($self) = @_;
 399
 400   $self->ensure_connected;
 401   return $self->_dbh;
 402 }
 403
 404 sub _sql_maker_args {
 405     my ($self) = @_;
 406
 407     return ( limit_dialect => $self->dbh );
 408 }
 409
 410 sub sql_maker {
 411   my ($self) = @_;
 412   unless ($self->_sql_maker) {
 413     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 414   }
 415   return $self->_sql_maker;
 416 }
 417
 418 sub connect_info {
 419     my ($self, $info_arg) = @_;
 420
 421     if($info_arg) {
 422         my $info = [ @$info_arg ]; # copy because we can alter it
 423         my $last_info = $info->[-1];
 424         if(ref $last_info eq 'HASH') {
 425             my $used;
 426             if(my $on_connect_do = $last_info->{on_connect_do}) {
 427                $used = 1;
 428                $self->on_connect_do($on_connect_do);
 429             }
 430             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 431                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 432                     $used = 1;
 433                     $self->sql_maker->$sql_maker_opt($opt_val);
 434                 }
 435             }
 436
 437             # remove our options hashref if it was there, to avoid confusing
 438             #   DBI in the case the user didn't use all 4 DBI options, as in:
 439             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 440             pop(@$info) if $used;
 441         }
 442
 443         $self->_connect_info($info);
 444     }
 445
 446     $self->_connect_info;
 447 }
 448
 449 sub _populate_dbh {
 450   my ($self) = @_;
 451   my @info = @{$self->_connect_info || []};
 452   $self->_dbh($self->_connect(@info));
 453   my $driver = $self->_dbh->{Driver}->{Name};
 454   eval "require DBIx::Class::Storage::DBI::${driver}";
 455   unless ($@) {
 456     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 457     $self->_rebless() if $self->can('_rebless');
 458   }
 459   # if on-connect sql statements are given execute them
 460   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 461     $self->debugobj->query_start($sql_statement) if $self->debug();
 462     $self->_dbh->do($sql_statement);
 463     $self->debugobj->query_end($sql_statement) if $self->debug();
 464   }
 465
 466   $self->_conn_pid($$);
 467   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 468 }
 469
 470 sub _connect {
 471   my ($self, @info) = @_;
 472
 473   $self->throw_exception("You failed to provide any connection info")
 474       if !@info;
 475
 476   my ($old_connect_via, $dbh);
 477
 478   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 479       $old_connect_via = $DBI::connect_via;
 480       $DBI::connect_via = 'connect';
 481   }
 482
 483   eval {
 484     if(ref $info[0] eq 'CODE') {
 485         $dbh = &{$info[0]};
 486     }
 487     else {
 488         $dbh = DBI->connect(@info);
 489     }
 490   };
 491
 492   $DBI::connect_via = $old_connect_via if $old_connect_via;
 493
 494   if (!$dbh || $@) {
 495     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 496   }
 497
 498   $dbh;
 499 }
 500
 501 =head2 txn_begin
 502
 503 Calls begin_work on the current dbh.
 504
 505 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 506 an entire code block to be executed transactionally.
 507
 508 =cut
 509
 510 sub txn_begin {
 511   my $self = shift;
 512   if ($self->{transaction_depth}++ == 0) {
 513     my $dbh = $self->dbh;
 514     if ($dbh->{AutoCommit}) {
 515       $self->debugobj->txn_begin()
 516         if ($self->debug);
 517       $dbh->begin_work;
 518     }
 519   }
 520 }
 521
 522 =head2 txn_commit
 523
 524 Issues a commit against the current dbh.
 525
 526 =cut
 527
 528 sub txn_commit {
 529   my $self = shift;
 530   my $dbh = $self->dbh;
 531   if ($self->{transaction_depth} == 0) {
 532     unless ($dbh->{AutoCommit}) {
 533       $self->debugobj->txn_commit()
 534         if ($self->debug);
 535       $dbh->commit;
 536     }
 537   }
 538   else {
 539     if (--$self->{transaction_depth} == 0) {
 540       $self->debugobj->txn_commit()
 541         if ($self->debug);
 542       $dbh->commit;
 543     }
 544   }
 545 }
 546
 547 =head2 txn_rollback
 548
 549 Issues a rollback against the current dbh. A nested rollback will
 550 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 551 which allows the rollback to propagate to the outermost transaction.
 552
 553 =cut
 554
 555 sub txn_rollback {
 556   my $self = shift;
 557
 558   eval {
 559     my $dbh = $self->dbh;
 560     if ($self->{transaction_depth} == 0) {
 561       unless ($dbh->{AutoCommit}) {
 562         $self->debugobj->txn_rollback()
 563           if ($self->debug);
 564         $dbh->rollback;
 565       }
 566     }
 567     else {
 568       if (--$self->{transaction_depth} == 0) {
 569         $self->debugobj->txn_rollback()
 570           if ($self->debug);
 571         $dbh->rollback;
 572       }
 573       else {
 574         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 575       }
 576     }
 577   };
 578
 579   if ($@) {
 580     my $error = $@;
 581     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 582     $error =~ /$exception_class/ and $self->throw_exception($error);
 583     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 584     $self->throw_exception($error);          # resets the transaction depth
 585   }
 586 }
 587
 588 sub _execute {
 589   my ($self, $op, $extra_bind, $ident, @args) = @_;
 590   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 591   unshift(@bind, @$extra_bind) if $extra_bind;
 592   if ($self->debug) {
 593       my @debug_bind = map { defined $_ ? qq{'$_'} : q{'NULL'} } @bind;
 594       $self->debugobj->query_start($sql, @debug_bind);
 595   }
 596   my $sth = eval { $self->sth($sql,$op) };
 597
 598   if (!$sth || $@) {
 599     $self->throw_exception(
 600       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 601     );
 602   }
 603   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 604   my $rv;
 605   if ($sth) {
 606     my $time = time();
 607     $rv = eval { $sth->execute(@bind) };
 608
 609     if ($@ || !$rv) {
 610       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 611     }
 612   } else {
 613     $self->throw_exception("'$sql' did not generate a statement.");
 614   }
 615   if ($self->debug) {
 616       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 617       $self->debugobj->query_end($sql, @debug_bind);
 618   }
 619   return (wantarray ? ($rv, $sth, @bind) : $rv);
 620 }
 621
 622 sub insert {
 623   my ($self, $ident, $to_insert) = @_;
 624   $self->throw_exception(
 625     "Couldn't insert ".join(', ',
 626       map "$_ => $to_insert->{$_}", keys %$to_insert
 627     )." into ${ident}"
 628   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 629   return $to_insert;
 630 }
 631
 632 sub update {
 633   return shift->_execute('update' => [], @_);
 634 }
 635
 636 sub delete {
 637   return shift->_execute('delete' => [], @_);
 638 }
 639
 640 sub _select {
 641   my ($self, $ident, $select, $condition, $attrs) = @_;
 642   my $order = $attrs->{order_by};
 643   if (ref $condition eq 'SCALAR') {
 644     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 645   }
 646   if (exists $attrs->{group_by} || $attrs->{having}) {
 647     $order = {
 648       group_by => $attrs->{group_by},
 649       having => $attrs->{having},
 650       ($order ? (order_by => $order) : ())
 651     };
 652   }
 653   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 654   if ($attrs->{software_limit} ||
 655       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 656         $attrs->{software_limit} = 1;
 657   } else {
 658     $self->throw_exception("rows attribute must be positive if present")
 659       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
 660     push @args, $attrs->{rows}, $attrs->{offset};
 661   }
 662   return $self->_execute(@args);
 663 }
 664
 665 sub select {
 666   my $self = shift;
 667   my ($ident, $select, $condition, $attrs) = @_;
 668   return $self->cursor->new($self, \@_, $attrs);
 669 }
 670
 671 # Need to call finish() to work round broken DBDs
 672
 673 sub select_single {
 674   my $self = shift;
 675   my ($rv, $sth, @bind) = $self->_select(@_);
 676   my @row = $sth->fetchrow_array;
 677   $sth->finish();
 678   return @row;
 679 }
 680
 681 sub sth {
 682   my ($self, $sql) = @_;
 683   # 3 is the if_active parameter which avoids active sth re-use
 684   return $self->dbh->prepare_cached($sql, {}, 3);
 685 }
 686
 687 =head2 columns_info_for
 688
 689 Returns database type info for a given table columns.
 690
 691 =cut
 692
 693 sub columns_info_for {
 694   my ($self, $table) = @_;
 695
 696   my $dbh = $self->dbh;
 697
 698   if ($dbh->can('column_info')) {
 699     my %result;
 700     my $old_raise_err = $dbh->{RaiseError};
 701     my $old_print_err = $dbh->{PrintError};
 702     $dbh->{RaiseError} = 1;
 703     $dbh->{PrintError} = 0;
 704     eval {
 705       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
 706       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
 707       $sth->execute();
 708       while ( my $info = $sth->fetchrow_hashref() ){
 709         my %column_info;
 710         $column_info{data_type}   = $info->{TYPE_NAME};
 711         $column_info{size}      = $info->{COLUMN_SIZE};
 712         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 713         $column_info{default_value} = $info->{COLUMN_DEF};
 714         my $col_name = $info->{COLUMN_NAME};
 715         $col_name =~ s/^\"(.*)\"$/$1/;
 716
 717         $result{$col_name} = \%column_info;
 718       }
 719     };
 720     $dbh->{RaiseError} = $old_raise_err;
 721     $dbh->{PrintError} = $old_print_err;
 722     return \%result if !$@;
 723   }
 724
 725   my %result;
 726   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 727   $sth->execute;
 728   my @columns = @{$sth->{NAME_lc}};
 729   for my $i ( 0 .. $#columns ){
 730     my %column_info;
 731     my $type_num = $sth->{TYPE}->[$i];
 732     my $type_name;
 733     if(defined $type_num && $dbh->can('type_info')) {
 734       my $type_info = $dbh->type_info($type_num);
 735       $type_name = $type_info->{TYPE_NAME} if $type_info;
 736     }
 737     $column_info{data_type} = $type_name ? $type_name : $type_num;
 738     $column_info{size} = $sth->{PRECISION}->[$i];
 739     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 740
 741     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 742       $column_info{data_type} = $1;
 743       $column_info{size}    = $2;
 744     }
 745
 746     $result{$columns[$i]} = \%column_info;
 747   }
 748
 749   return \%result;
 750 }
 751
 752 sub last_insert_id {
 753   my ($self, $row) = @_;
 754
 755   return $self->dbh->func('last_insert_rowid');
 756
 757 }
 758
 759 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 760
 761 sub create_ddl_dir
 762 {
 763   my ($self, $schema, $databases, $version, $dir, $sqltargs) = @_;
 764
 765   if(!$dir || !-d $dir)
 766   {
 767     warn "No directory given, using ./\n";
 768     $dir = "./";
 769   }
 770   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
 771   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
 772   $version ||= $schema->VERSION || '1.x';
 773
 774   eval "use SQL::Translator";
 775   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 776
 777   my $sqlt = SQL::Translator->new({
 778 #      debug => 1,
 779       add_drop_table => 1,
 780   });
 781   foreach my $db (@$databases)
 782   {
 783     $sqlt->reset();
 784     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 785 #    $sqlt->parser_args({'DBIx::Class' => $schema);
 786     $sqlt->data($schema);
 787     $sqlt->producer($db);
 788
 789     my $file;
 790     my $filename = $schema->ddl_filename($db, $dir, $version);
 791     if(-e $filename)
 792     {
 793       $self->throw_exception("$filename already exists, skipping $db");
 794       next;
 795     }
 796     open($file, ">$filename")
 797       or $self->throw_exception("Can't open $filename for writing ($!)");
 798     my $output = $sqlt->translate;
 799 #use Data::Dumper;
 800 #    print join(":", keys %{$schema->source_registrations});
 801 #    print Dumper($sqlt->schema);
 802     if(!$output)
 803     {
 804       $self->throw_exception("Failed to translate to $db. (" . $sqlt->error . ")");
 805       next;
 806     }
 807     print $file $output;
 808     close($file);
 809   }
 810
 811 }
 812
 813 sub deployment_statements {
 814   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
 815   $type ||= $self->sqlt_type;
 816   $version ||= $schema->VERSION || '1.x';
 817   $dir ||= './';
 818   eval "use SQL::Translator";
 819   if(!$@)
 820   {
 821     eval "use SQL::Translator::Parser::DBIx::Class;";
 822     $self->throw_exception($@) if $@;
 823     eval "use SQL::Translator::Producer::${type};";
 824     $self->throw_exception($@) if $@;
 825     my $tr = SQL::Translator->new(%$sqltargs);
 826     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 827     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 828   }
 829
 830   my $filename = $schema->ddl_filename($type, $dir, $version);
 831   if(!-f $filename)
 832   {
 833 #      $schema->create_ddl_dir([ $type ], $version, $dir, $sqltargs);
 834       $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
 835       return;
 836   }
 837   my $file;
 838   open($file, "<$filename")
 839       or $self->throw_exception("Can't open $filename ($!)");
 840   my @rows = <$file>;
 841   close($file);
 842
 843   return join('', @rows);
 844
 845 }
 846
 847 sub deploy {
 848   my ($self, $schema, $type, $sqltargs) = @_;
 849   foreach my $statement ( $self->deployment_statements($schema, $type, undef, undef, $sqltargs) ) {
 850     for ( split(";\n", $statement)) {
 851       next if($_ =~ /^--/);
 852       next if(!$_);
 853 #      next if($_ =~ /^DROP/m);
 854       next if($_ =~ /^BEGIN TRANSACTION/m);
 855       next if($_ =~ /^COMMIT/m);
 856       $self->debugobj->query_begin($_) if $self->debug;
 857       $self->dbh->do($_) or warn "SQL was:\n $_";
 858       $self->debugobj->query_end($_) if $self->debug;
 859     }
 860   }
 861 }
 862
 863 sub datetime_parser {
 864   my $self = shift;
 865   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
 866 }
 867
 868 sub datetime_parser_type { "DateTime::Format::MySQL"; }
 869
 870 sub build_datetime_parser {
 871   my $self = shift;
 872   my $type = $self->datetime_parser_type(@_);
 873   eval "use ${type}";
 874   $self->throw_exception("Couldn't load ${type}: $@") if $@;
 875   return $type;
 876 }
 877
 878 sub DESTROY { shift->disconnect }
 879
 880 1;
 881
 882 =head1 ENVIRONMENT VARIABLES
 883
 884 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 885
 886 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 887 is produced (as when the L<debug> method is set).
 888
 889 If the value is of the form C<1=/path/name> then the trace output is
 890 written to the file C</path/name>.
 891
 892 This environment variable is checked when the storage object is first
 893 created (when you call connect on your schema).  So, run-time changes
 894 to this environment variable will not take effect unless you also
 895 re-connect on your schema.
 896
 897 =head1 AUTHORS
 898
 899 Matt S. Trout <mst@shadowcatsystems.co.uk>
 900
 901 Andy Grundman <andy@hybridized.org>
 902
 903 =head1 LICENSE
 904
 905 You may distribute this code under the same terms as Perl itself.
 906
 907 =cut
 908