lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   @rest = (-1) unless defined $rest[0];
  22   local $self->{having_bind} = [];
  23   my ($sql, @ret) = $self->SUPER::select($table,
  24                       $self->_recurse_fields($fields), $where, $order, @rest);
  25   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  26 }
  27
  28 sub _emulate_limit {
  29   my $self = shift;
  30   if ($_[3] == -1) {
  31     return $_[1].$self->_order_by($_[2]);
  32   } else {
  33     return $self->SUPER::_emulate_limit(@_);
  34   }
  35 }
  36
  37 sub _recurse_fields {
  38   my ($self, $fields) = @_;
  39   my $ref = ref $fields;
  40   return $self->_quote($fields) unless $ref;
  41   return $$fields if $ref eq 'SCALAR';
  42
  43   if ($ref eq 'ARRAY') {
  44     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  45   } elsif ($ref eq 'HASH') {
  46     foreach my $func (keys %$fields) {
  47       return $self->_sqlcase($func)
  48         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  49     }
  50   }
  51 }
  52
  53 sub _order_by {
  54   my $self = shift;
  55   my $ret = '';
  56   my @extra;
  57   if (ref $_[0] eq 'HASH') {
  58     if (defined $_[0]->{group_by}) {
  59       $ret = $self->_sqlcase(' group by ')
  60                .$self->_recurse_fields($_[0]->{group_by});
  61     }
  62     if (defined $_[0]->{having}) {
  63       my $frag;
  64       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  65       push(@{$self->{having_bind}}, @extra);
  66       $ret .= $self->_sqlcase(' having ').$frag;
  67     }
  68     if (defined $_[0]->{order_by}) {
  69       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  70     }
  71   } else {
  72     $ret = $self->SUPER::_order_by(@_);
  73   }
  74   return $ret;
  75 }
  76
  77 sub _order_directions {
  78   my ($self, $order) = @_;
  79   $order = $order->{order_by} if ref $order eq 'HASH';
  80   return $self->SUPER::_order_directions($order);
  81 }
  82
  83 sub _table {
  84   my ($self, $from) = @_;
  85   if (ref $from eq 'ARRAY') {
  86     return $self->_recurse_from(@$from);
  87   } elsif (ref $from eq 'HASH') {
  88     return $self->_make_as($from);
  89   } else {
  90     return $from;
  91   }
  92 }
  93
  94 sub _recurse_from {
  95   my ($self, $from, @join) = @_;
  96   my @sqlf;
  97   push(@sqlf, $self->_make_as($from));
  98   foreach my $j (@join) {
  99     my ($to, $on) = @$j;
 100
 101     # check whether a join type exists
 102     my $join_clause = '';
 103     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 104       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 105     } else {
 106       $join_clause = ' JOIN ';
 107     }
 108     push(@sqlf, $join_clause);
 109
 110     if (ref $to eq 'ARRAY') {
 111       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 112     } else {
 113       push(@sqlf, $self->_make_as($to));
 114     }
 115     push(@sqlf, ' ON ', $self->_join_condition($on));
 116   }
 117   return join('', @sqlf);
 118 }
 119
 120 sub _make_as {
 121   my ($self, $from) = @_;
 122   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 123                            reverse each %{$self->_skip_options($from)});
 124 }
 125
 126 sub _skip_options {
 127   my ($self, $hash) = @_;
 128   my $clean_hash = {};
 129   $clean_hash->{$_} = $hash->{$_}
 130     for grep {!/^-/} keys %$hash;
 131   return $clean_hash;
 132 }
 133
 134 sub _join_condition {
 135   my ($self, $cond) = @_;
 136   if (ref $cond eq 'HASH') {
 137     my %j;
 138     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 139     return $self->_recurse_where(\%j);
 140   } elsif (ref $cond eq 'ARRAY') {
 141     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 142   } else {
 143     die "Can't handle this yet!";
 144   }
 145 }
 146
 147 sub _quote {
 148   my ($self, $label) = @_;
 149   return '' unless defined $label;
 150   return "*" if $label eq '*';
 151   return $label unless $self->{quote_char};
 152   if(ref $self->{quote_char} eq "ARRAY"){
 153     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 154       if !defined $self->{name_sep};
 155     my $sep = $self->{name_sep};
 156     return join($self->{name_sep},
 157         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 158        split(/\Q$sep\E/,$label));
 159   }
 160   return $self->SUPER::_quote($label);
 161 }
 162
 163 sub _RowNum {
 164    my $self = shift;
 165    my $c;
 166    $_[0] =~ s/SELECT (.*?) FROM/
 167      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 168    $self->SUPER::_RowNum(@_);
 169 }
 170
 171 # Accessor for setting limit dialect. This is useful
 172 # for JDBC-bridge among others where the remote SQL-dialect cannot
 173 # be determined by the name of the driver alone.
 174 #
 175 sub limit_dialect {
 176     my $self = shift;
 177     $self->{limit_dialect} = shift if @_;
 178     return $self->{limit_dialect};
 179 }
 180
 181 sub quote_char {
 182     my $self = shift;
 183     $self->{quote_char} = shift if @_;
 184     return $self->{quote_char};
 185 }
 186
 187 sub name_sep {
 188     my $self = shift;
 189     $self->{name_sep} = shift if @_;
 190     return $self->{name_sep};
 191 }
 192
 193
 194
 195
 196 package DBIx::Class::Storage::DBI::DebugCallback;
 197
 198 sub print {
 199   my ($self, $string) = @_;
 200   $string =~ m/^(\w+)/;
 201   ${$self}->($1, $string);
 202 }
 203
 204 } # End of BEGIN block
 205
 206 use base qw/DBIx::Class/;
 207
 208 __PACKAGE__->load_components(qw/AccessorGroup/);
 209
 210 __PACKAGE__->mk_group_accessors('simple' =>
 211   qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
 212      on_connect_do transaction_depth/);
 213
 214 sub new {
 215   my $new = bless({}, ref $_[0] || $_[0]);
 216   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 217   $new->transaction_depth(0);
 218   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 219      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 220     $new->debugfh(IO::File->new($1, 'w')) || $new->throw_exception("Cannot open trace file $1");
 221   } else {
 222     $new->debugfh(IO::File->new('>&STDERR'));
 223   }
 224   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 225   return $new;
 226 }
 227
 228 sub throw_exception {
 229   my ($self, $msg) = @_;
 230   croak($msg);
 231 }
 232
 233 =head1 NAME
 234
 235 DBIx::Class::Storage::DBI - DBI storage handler
 236
 237 =head1 SYNOPSIS
 238
 239 =head1 DESCRIPTION
 240
 241 This class represents the connection to the database
 242
 243 =head1 METHODS
 244
 245 =cut
 246
 247 =head2 on_connect_do
 248
 249 Executes the sql statements given as a listref on every db connect.
 250
 251 =head2 debug
 252
 253 Causes SQL trace information to be emitted on C<debugfh> filehandle
 254 (or C<STDERR> if C<debugfh> has not specifically been set).
 255
 256 =head2 debugfh
 257
 258 Sets or retrieves the filehandle used for trace/debug output.  This
 259 should be an IO::Handle compatible object (only the C<print> method is
 260 used).  Initially set to be STDERR - although see information on the
 261 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 262
 263 =head2 debugcb
 264
 265 Sets a callback to be executed each time a statement is run; takes a sub
 266 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 267 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 268 be printed.
 269
 270 =cut
 271
 272 sub debugcb {
 273   my ($self, $cb) = @_;
 274   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 275   $self->debugfh($cb_obj);
 276 }
 277
 278 sub disconnect {
 279   my ($self) = @_;
 280
 281   if( $self->connected ) {
 282     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 283     $self->_dbh->disconnect;
 284     $self->_dbh(undef);
 285   }
 286 }
 287
 288 sub connected {
 289   my ($self) = @_;
 290
 291   my $dbh;
 292   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 293 }
 294
 295 sub ensure_connected {
 296   my ($self) = @_;
 297
 298   unless ($self->connected) {
 299     $self->_populate_dbh;
 300   }
 301 }
 302
 303 sub dbh {
 304   my ($self) = @_;
 305
 306   if($self->_connection_pid && $self->_connection_pid != $$) {
 307       $self->_dbh->{InactiveDestroy} = 1;
 308       $self->_dbh(undef)
 309   }
 310   $self->ensure_connected;
 311   return $self->_dbh;
 312 }
 313
 314 sub sql_maker {
 315   my ($self) = @_;
 316   unless ($self->_sql_maker) {
 317     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 318   }
 319   return $self->_sql_maker;
 320 }
 321
 322 sub _populate_dbh {
 323   my ($self) = @_;
 324   my @info = @{$self->connect_info || []};
 325   $self->_dbh($self->_connect(@info));
 326   my $driver = $self->_dbh->{Driver}->{Name};
 327   eval "require DBIx::Class::Storage::DBI::${driver}";
 328   unless ($@) {
 329     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 330   }
 331   # if on-connect sql statements are given execute them
 332   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 333     $self->_dbh->do($sql_statement);
 334   }
 335
 336   $self->_connection_pid($$);
 337 }
 338
 339 sub _connect {
 340   my ($self, @info) = @_;
 341
 342   my ($old_connect_via, $dbh);
 343
 344   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 345       $old_connect_via = $DBI::connect_via;
 346       $DBI::connect_via = 'connect';
 347   }
 348
 349   if(ref $info[0] eq 'CODE') {
 350       $dbh = &{$info[0]};
 351   }
 352   else {
 353       $dbh = DBI->connect(@info);
 354   }
 355
 356   $DBI::connect_via = $old_connect_via if $old_connect_via;
 357
 358   $self->throw_exception("DBI Connection failed: $DBI::errstr")
 359       unless $dbh;
 360
 361   $dbh;
 362 }
 363
 364 =head2 txn_begin
 365
 366 Calls begin_work on the current dbh.
 367
 368 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 369 an entire code block to be executed transactionally.
 370
 371 =cut
 372
 373 sub txn_begin {
 374   my $self = shift;
 375   $self->dbh->begin_work
 376     if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 377 }
 378
 379 =head2 txn_commit
 380
 381 Issues a commit against the current dbh.
 382
 383 =cut
 384
 385 sub txn_commit {
 386   my $self = shift;
 387   if ($self->{transaction_depth} == 0) {
 388     $self->dbh->commit unless $self->dbh->{AutoCommit};
 389   }
 390   else {
 391     $self->dbh->commit if --$self->{transaction_depth} == 0;
 392   }
 393 }
 394
 395 =head2 txn_rollback
 396
 397 Issues a rollback against the current dbh. A nested rollback will
 398 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 399 which allows the rollback to propagate to the outermost transaction.
 400
 401 =cut
 402
 403 sub txn_rollback {
 404   my $self = shift;
 405
 406   eval {
 407     if ($self->{transaction_depth} == 0) {
 408       $self->dbh->rollback unless $self->dbh->{AutoCommit};
 409     }
 410     else {
 411       --$self->{transaction_depth} == 0 ?
 412         $self->dbh->rollback :
 413         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 414     }
 415   };
 416
 417   if ($@) {
 418     my $error = $@;
 419     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 420     $error =~ /$exception_class/ and $self->throw_exception($error);
 421     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 422     $self->throw_exception($error);          # resets the transaction depth
 423   }
 424 }
 425
 426 sub _execute {
 427   my ($self, $op, $extra_bind, $ident, @args) = @_;
 428   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 429   unshift(@bind, @$extra_bind) if $extra_bind;
 430   if ($self->debug) {
 431       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 432       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 433   }
 434   my $sth = $self->sth($sql,$op);
 435   $self->throw_exception("no sth generated via sql: $sql") unless $sth;
 436   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 437   my $rv;
 438   if ($sth) {
 439     $rv = $sth->execute(@bind);
 440   } else {
 441     $self->throw_exception("'$sql' did not generate a statement.");
 442   }
 443   return (wantarray ? ($rv, $sth, @bind) : $rv);
 444 }
 445
 446 sub insert {
 447   my ($self, $ident, $to_insert) = @_;
 448   $self->throw_exception( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 449     unless ($self->_execute('insert' => [], $ident, $to_insert));
 450   return $to_insert;
 451 }
 452
 453 sub update {
 454   return shift->_execute('update' => [], @_);
 455 }
 456
 457 sub delete {
 458   return shift->_execute('delete' => [], @_);
 459 }
 460
 461 sub _select {
 462   my ($self, $ident, $select, $condition, $attrs) = @_;
 463   my $order = $attrs->{order_by};
 464   if (ref $condition eq 'SCALAR') {
 465     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 466   }
 467   if (exists $attrs->{group_by} || $attrs->{having}) {
 468     $order = { group_by => $attrs->{group_by},
 469                having => $attrs->{having},
 470                ($order ? (order_by => $order) : ()) };
 471   }
 472   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 473   if ($attrs->{software_limit} ||
 474       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 475         $attrs->{software_limit} = 1;
 476   } else {
 477     push @args, $attrs->{rows}, $attrs->{offset};
 478   }
 479   return $self->_execute(@args);
 480 }
 481
 482 sub select {
 483   my $self = shift;
 484   my ($ident, $select, $condition, $attrs) = @_;
 485   return $self->cursor->new($self, \@_, $attrs);
 486 }
 487
 488 # Need to call finish() to work round broken DBDs
 489
 490 sub select_single {
 491   my $self = shift;
 492   my ($rv, $sth, @bind) = $self->_select(@_);
 493   my @row = $sth->fetchrow_array;
 494   $sth->finish();
 495   return @row;
 496 }
 497
 498 sub sth {
 499   my ($self, $sql) = @_;
 500   # 3 is the if_active parameter which avoids active sth re-use
 501   return $self->dbh->prepare_cached($sql, {}, 3);
 502 }
 503
 504 =head2 columns_info_for
 505
 506 Returns database type info for a given table columns.
 507
 508 =cut
 509
 510 sub columns_info_for {
 511     my ($self, $table) = @_;
 512     my %result;
 513     if ( $self->dbh->can( 'column_info' ) ){
 514         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 515         $sth->execute();
 516         while ( my $info = $sth->fetchrow_hashref() ){
 517             my %column_info;
 518             $column_info{data_type} = $info->{TYPE_NAME};
 519             $column_info{size} = $info->{COLUMN_SIZE};
 520             $column_info{is_nullable} = $info->{NULLABLE};
 521             $result{$info->{COLUMN_NAME}} = \%column_info;
 522         }
 523     } else {
 524         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 525         $sth->execute;
 526         my @columns = @{$sth->{NAME}};
 527         for my $i ( 0 .. $#columns ){
 528             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 529         }
 530     }
 531     return \%result;
 532 }
 533
 534 sub last_insert_id {
 535   my ($self, $row) = @_;
 536
 537   return $self->dbh->func('last_insert_rowid');
 538
 539 }
 540
 541 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 542
 543 sub deployment_statements {
 544   my ($self, $schema, $type) = @_;
 545   $type ||= $self->sqlt_type;
 546   eval "use SQL::Translator";
 547   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 548   eval "use SQL::Translator::Parser::DBIx::Class;";
 549   $self->throw_exception($@) if $@;
 550   eval "use SQL::Translator::Producer::${type};";
 551   $self->throw_exception($@) if $@;
 552   my $tr = SQL::Translator->new();
 553   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 554   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 555 }
 556
 557 sub deploy {
 558   my ($self, $schema, $type) = @_;
 559   foreach(split(";\n", $self->deployment_statements($schema, $type))) {
 560           $self->dbh->do($_) or warn "SQL was:\n $_";
 561   }
 562 }
 563
 564 sub DESTROY { shift->disconnect }
 565
 566 1;
 567
 568 =head1 ENVIRONMENT VARIABLES
 569
 570 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 571
 572 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 573 is produced (as when the L<debug> method is set).
 574
 575 If the value is of the form C<1=/path/name> then the trace output is
 576 written to the file C</path/name>.
 577
 578 =head1 AUTHORS
 579
 580 Matt S. Trout <mst@shadowcatsystems.co.uk>
 581
 582 Andy Grundman <andy@hybridized.org>
 583
 584 =head1 LICENSE
 585
 586 You may distribute this code under the same terms as Perl itself.
 587
 588 =cut
 589