lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util();
  15 use List::Util();
  16 use Data::Dumper::Concise();
  17 use Sub::Name ();
  18
  19 __PACKAGE__->mk_group_accessors('simple' =>
  20   qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid
  21      _conn_tid transaction_depth _dbh_autocommit _driver_determined savepoints
  22      __server_info/
  23 );
  24
  25 # the values for these accessors are picked out (and deleted) from
  26 # the attribute hashref passed to connect_info
  27 my @storage_options = qw/
  28   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  29   disable_sth_caching unsafe auto_savepoint
  30 /;
  31 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  32
  33
  34 # default cursor class, overridable in connect_info attributes
  35 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  36
  37 __PACKAGE__->mk_group_accessors('inherited' => qw/
  38   sql_maker_class
  39   can_insert_returning
  40 /);
  41 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  42
  43
  44 # Each of these methods need _determine_driver called before itself
  45 # in order to function reliably. This is a purely DRY optimization
  46 my @rdbms_specific_methods = qw/
  47   deployment_statements
  48   sqlt_type
  49   build_datetime_parser
  50   datetime_parser_type
  51
  52   insert
  53   insert_bulk
  54   update
  55   delete
  56   select
  57   select_single
  58 /;
  59
  60 for my $meth (@rdbms_specific_methods) {
  61
  62   my $orig = __PACKAGE__->can ($meth)
  63     or next;
  64
  65   no strict qw/refs/;
  66   no warnings qw/redefine/;
  67   *{__PACKAGE__ ."::$meth"} = Sub::Name::subname $meth => sub {
  68     if (not $_[0]->_driver_determined) {
  69       $_[0]->_determine_driver;
  70       goto $_[0]->can($meth);
  71     }
  72     $orig->(@_);
  73   };
  74 }
  75
  76
  77 =head1 NAME
  78
  79 DBIx::Class::Storage::DBI - DBI storage handler
  80
  81 =head1 SYNOPSIS
  82
  83   my $schema = MySchema->connect('dbi:SQLite:my.db');
  84
  85   $schema->storage->debug(1);
  86
  87   my @stuff = $schema->storage->dbh_do(
  88     sub {
  89       my ($storage, $dbh, @args) = @_;
  90       $dbh->do("DROP TABLE authors");
  91     },
  92     @column_list
  93   );
  94
  95   $schema->resultset('Book')->search({
  96      written_on => $schema->storage->datetime_parser(DateTime->now)
  97   });
  98
  99 =head1 DESCRIPTION
 100
 101 This class represents the connection to an RDBMS via L<DBI>.  See
 102 L<DBIx::Class::Storage> for general information.  This pod only
 103 documents DBI-specific methods and behaviors.
 104
 105 =head1 METHODS
 106
 107 =cut
 108
 109 sub new {
 110   my $new = shift->next::method(@_);
 111
 112   $new->transaction_depth(0);
 113   $new->_sql_maker_opts({});
 114   $new->{savepoints} = [];
 115   $new->{_in_dbh_do} = 0;
 116   $new->{_dbh_gen} = 0;
 117
 118   $new;
 119 }
 120
 121 =head2 connect_info
 122
 123 This method is normally called by L<DBIx::Class::Schema/connection>, which
 124 encapsulates its argument list in an arrayref before passing them here.
 125
 126 The argument list may contain:
 127
 128 =over
 129
 130 =item *
 131
 132 The same 4-element argument set one would normally pass to
 133 L<DBI/connect>, optionally followed by
 134 L<extra attributes|/DBIx::Class specific connection attributes>
 135 recognized by DBIx::Class:
 136
 137   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 138
 139 =item *
 140
 141 A single code reference which returns a connected
 142 L<DBI database handle|DBI/connect> optionally followed by
 143 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 144 by DBIx::Class:
 145
 146   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 147
 148 =item *
 149
 150 A single hashref with all the attributes and the dsn/user/password
 151 mixed together:
 152
 153   $connect_info_args = [{
 154     dsn => $dsn,
 155     user => $user,
 156     password => $pass,
 157     %dbi_attributes,
 158     %extra_attributes,
 159   }];
 160
 161   $connect_info_args = [{
 162     dbh_maker => sub { DBI->connect (...) },
 163     %dbi_attributes,
 164     %extra_attributes,
 165   }];
 166
 167 This is particularly useful for L<Catalyst> based applications, allowing the
 168 following config (L<Config::General> style):
 169
 170   <Model::DB>
 171     schema_class   App::DB
 172     <connect_info>
 173       dsn          dbi:mysql:database=test
 174       user         testuser
 175       password     TestPass
 176       AutoCommit   1
 177     </connect_info>
 178   </Model::DB>
 179
 180 The C<dsn>/C<user>/C<password> combination can be substituted by the
 181 C<dbh_maker> key whose value is a coderef that returns a connected
 182 L<DBI database handle|DBI/connect>
 183
 184 =back
 185
 186 Please note that the L<DBI> docs recommend that you always explicitly
 187 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 188 recommends that it be set to I<1>, and that you perform transactions
 189 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 190 to I<1> if you do not do explicitly set it to zero.  This is the default
 191 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 192
 193 =head3 DBIx::Class specific connection attributes
 194
 195 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 196 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 197 the following connection options. These options can be mixed in with your other
 198 L<DBI> connection attributes, or placed in a separate hashref
 199 (C<\%extra_attributes>) as shown above.
 200
 201 Every time C<connect_info> is invoked, any previous settings for
 202 these options will be cleared before setting the new ones, regardless of
 203 whether any options are specified in the new C<connect_info>.
 204
 205
 206 =over
 207
 208 =item on_connect_do
 209
 210 Specifies things to do immediately after connecting or re-connecting to
 211 the database.  Its value may contain:
 212
 213 =over
 214
 215 =item a scalar
 216
 217 This contains one SQL statement to execute.
 218
 219 =item an array reference
 220
 221 This contains SQL statements to execute in order.  Each element contains
 222 a string or a code reference that returns a string.
 223
 224 =item a code reference
 225
 226 This contains some code to execute.  Unlike code references within an
 227 array reference, its return value is ignored.
 228
 229 =back
 230
 231 =item on_disconnect_do
 232
 233 Takes arguments in the same form as L</on_connect_do> and executes them
 234 immediately before disconnecting from the database.
 235
 236 Note, this only runs if you explicitly call L</disconnect> on the
 237 storage object.
 238
 239 =item on_connect_call
 240
 241 A more generalized form of L</on_connect_do> that calls the specified
 242 C<connect_call_METHOD> methods in your storage driver.
 243
 244   on_connect_do => 'select 1'
 245
 246 is equivalent to:
 247
 248   on_connect_call => [ [ do_sql => 'select 1' ] ]
 249
 250 Its values may contain:
 251
 252 =over
 253
 254 =item a scalar
 255
 256 Will call the C<connect_call_METHOD> method.
 257
 258 =item a code reference
 259
 260 Will execute C<< $code->($storage) >>
 261
 262 =item an array reference
 263
 264 Each value can be a method name or code reference.
 265
 266 =item an array of arrays
 267
 268 For each array, the first item is taken to be the C<connect_call_> method name
 269 or code reference, and the rest are parameters to it.
 270
 271 =back
 272
 273 Some predefined storage methods you may use:
 274
 275 =over
 276
 277 =item do_sql
 278
 279 Executes a SQL string or a code reference that returns a SQL string. This is
 280 what L</on_connect_do> and L</on_disconnect_do> use.
 281
 282 It can take:
 283
 284 =over
 285
 286 =item a scalar
 287
 288 Will execute the scalar as SQL.
 289
 290 =item an arrayref
 291
 292 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 293 attributes hashref and bind values.
 294
 295 =item a code reference
 296
 297 Will execute C<< $code->($storage) >> and execute the return array refs as
 298 above.
 299
 300 =back
 301
 302 =item datetime_setup
 303
 304 Execute any statements necessary to initialize the database session to return
 305 and accept datetime/timestamp values used with
 306 L<DBIx::Class::InflateColumn::DateTime>.
 307
 308 Only necessary for some databases, see your specific storage driver for
 309 implementation details.
 310
 311 =back
 312
 313 =item on_disconnect_call
 314
 315 Takes arguments in the same form as L</on_connect_call> and executes them
 316 immediately before disconnecting from the database.
 317
 318 Calls the C<disconnect_call_METHOD> methods as opposed to the
 319 C<connect_call_METHOD> methods called by L</on_connect_call>.
 320
 321 Note, this only runs if you explicitly call L</disconnect> on the
 322 storage object.
 323
 324 =item disable_sth_caching
 325
 326 If set to a true value, this option will disable the caching of
 327 statement handles via L<DBI/prepare_cached>.
 328
 329 =item limit_dialect
 330
 331 Sets the limit dialect. This is useful for JDBC-bridge among others
 332 where the remote SQL-dialect cannot be determined by the name of the
 333 driver alone. See also L<SQL::Abstract::Limit>.
 334
 335 =item quote_char
 336
 337 Specifies what characters to use to quote table and column names. If
 338 you use this you will want to specify L</name_sep> as well.
 339
 340 C<quote_char> expects either a single character, in which case is it
 341 is placed on either side of the table/column name, or an arrayref of length
 342 2 in which case the table/column name is placed between the elements.
 343
 344 For example under MySQL you should use C<< quote_char => '`' >>, and for
 345 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 346
 347 =item name_sep
 348
 349 This only needs to be used in conjunction with C<quote_char>, and is used to
 350 specify the character that separates elements (schemas, tables, columns) from
 351 each other. In most cases this is simply a C<.>.
 352
 353 The consequences of not supplying this value is that L<SQL::Abstract>
 354 will assume DBIx::Class' uses of aliases to be complete column
 355 names. The output will look like I<"me.name"> when it should actually
 356 be I<"me"."name">.
 357
 358 =item unsafe
 359
 360 This Storage driver normally installs its own C<HandleError>, sets
 361 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 362 all database handles, including those supplied by a coderef.  It does this
 363 so that it can have consistent and useful error behavior.
 364
 365 If you set this option to a true value, Storage will not do its usual
 366 modifications to the database handle's attributes, and instead relies on
 367 the settings in your connect_info DBI options (or the values you set in
 368 your connection coderef, in the case that you are connecting via coderef).
 369
 370 Note that your custom settings can cause Storage to malfunction,
 371 especially if you set a C<HandleError> handler that suppresses exceptions
 372 and/or disable C<RaiseError>.
 373
 374 =item auto_savepoint
 375
 376 If this option is true, L<DBIx::Class> will use savepoints when nesting
 377 transactions, making it possible to recover from failure in the inner
 378 transaction without having to abort all outer transactions.
 379
 380 =item cursor_class
 381
 382 Use this argument to supply a cursor class other than the default
 383 L<DBIx::Class::Storage::DBI::Cursor>.
 384
 385 =back
 386
 387 Some real-life examples of arguments to L</connect_info> and
 388 L<DBIx::Class::Schema/connect>
 389
 390   # Simple SQLite connection
 391   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 392
 393   # Connect via subref
 394   ->connect_info([ sub { DBI->connect(...) } ]);
 395
 396   # Connect via subref in hashref
 397   ->connect_info([{
 398     dbh_maker => sub { DBI->connect(...) },
 399     on_connect_do => 'alter session ...',
 400   }]);
 401
 402   # A bit more complicated
 403   ->connect_info(
 404     [
 405       'dbi:Pg:dbname=foo',
 406       'postgres',
 407       'my_pg_password',
 408       { AutoCommit => 1 },
 409       { quote_char => q{"}, name_sep => q{.} },
 410     ]
 411   );
 412
 413   # Equivalent to the previous example
 414   ->connect_info(
 415     [
 416       'dbi:Pg:dbname=foo',
 417       'postgres',
 418       'my_pg_password',
 419       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 420     ]
 421   );
 422
 423   # Same, but with hashref as argument
 424   # See parse_connect_info for explanation
 425   ->connect_info(
 426     [{
 427       dsn         => 'dbi:Pg:dbname=foo',
 428       user        => 'postgres',
 429       password    => 'my_pg_password',
 430       AutoCommit  => 1,
 431       quote_char  => q{"},
 432       name_sep    => q{.},
 433     }]
 434   );
 435
 436   # Subref + DBIx::Class-specific connection options
 437   ->connect_info(
 438     [
 439       sub { DBI->connect(...) },
 440       {
 441           quote_char => q{`},
 442           name_sep => q{@},
 443           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 444           disable_sth_caching => 1,
 445       },
 446     ]
 447   );
 448
 449
 450
 451 =cut
 452
 453 sub connect_info {
 454   my ($self, $info) = @_;
 455
 456   return $self->_connect_info if !$info;
 457
 458   $self->_connect_info($info); # copy for _connect_info
 459
 460   $info = $self->_normalize_connect_info($info)
 461     if ref $info eq 'ARRAY';
 462
 463   for my $storage_opt (keys %{ $info->{storage_options} }) {
 464     my $value = $info->{storage_options}{$storage_opt};
 465
 466     $self->$storage_opt($value);
 467   }
 468
 469   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 470   #  the new set of options
 471   $self->_sql_maker(undef);
 472   $self->_sql_maker_opts({});
 473
 474   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 475     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 476
 477     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 478   }
 479
 480   my %attrs = (
 481     %{ $self->_default_dbi_connect_attributes || {} },
 482     %{ $info->{attributes} || {} },
 483   );
 484
 485   my @args = @{ $info->{arguments} };
 486
 487   $self->_dbi_connect_info([@args,
 488     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 489
 490   return $self->_connect_info;
 491 }
 492
 493 sub _normalize_connect_info {
 494   my ($self, $info_arg) = @_;
 495   my %info;
 496
 497   my @args = @$info_arg;  # take a shallow copy for further mutilation
 498
 499   # combine/pre-parse arguments depending on invocation style
 500
 501   my %attrs;
 502   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 503     %attrs = %{ $args[1] || {} };
 504     @args = $args[0];
 505   }
 506   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 507     %attrs = %{$args[0]};
 508     @args = ();
 509     if (my $code = delete $attrs{dbh_maker}) {
 510       @args = $code;
 511
 512       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 513       if (@ignored) {
 514         carp sprintf (
 515             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 516           . "to the result of 'dbh_maker'",
 517
 518           join (', ', map { "'$_'" } (@ignored) ),
 519         );
 520       }
 521     }
 522     else {
 523       @args = delete @attrs{qw/dsn user password/};
 524     }
 525   }
 526   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 527     %attrs = (
 528       % { $args[3] || {} },
 529       % { $args[4] || {} },
 530     );
 531     @args = @args[0,1,2];
 532   }
 533
 534   $info{arguments} = \@args;
 535
 536   my @storage_opts = grep exists $attrs{$_},
 537     @storage_options, 'cursor_class';
 538
 539   @{ $info{storage_options} }{@storage_opts} =
 540     delete @attrs{@storage_opts} if @storage_opts;
 541
 542   my @sql_maker_opts = grep exists $attrs{$_},
 543     qw/limit_dialect quote_char name_sep/;
 544
 545   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 546     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 547
 548   $info{attributes} = \%attrs if %attrs;
 549
 550   return \%info;
 551 }
 552
 553 sub _default_dbi_connect_attributes {
 554   return {
 555     AutoCommit => 1,
 556     RaiseError => 1,
 557     PrintError => 0,
 558   };
 559 }
 560
 561 =head2 on_connect_do
 562
 563 This method is deprecated in favour of setting via L</connect_info>.
 564
 565 =cut
 566
 567 =head2 on_disconnect_do
 568
 569 This method is deprecated in favour of setting via L</connect_info>.
 570
 571 =cut
 572
 573 sub _parse_connect_do {
 574   my ($self, $type) = @_;
 575
 576   my $val = $self->$type;
 577   return () if not defined $val;
 578
 579   my @res;
 580
 581   if (not ref($val)) {
 582     push @res, [ 'do_sql', $val ];
 583   } elsif (ref($val) eq 'CODE') {
 584     push @res, $val;
 585   } elsif (ref($val) eq 'ARRAY') {
 586     push @res, map { [ 'do_sql', $_ ] } @$val;
 587   } else {
 588     $self->throw_exception("Invalid type for $type: ".ref($val));
 589   }
 590
 591   return \@res;
 592 }
 593
 594 =head2 dbh_do
 595
 596 Arguments: ($subref | $method_name), @extra_coderef_args?
 597
 598 Execute the given $subref or $method_name using the new exception-based
 599 connection management.
 600
 601 The first two arguments will be the storage object that C<dbh_do> was called
 602 on and a database handle to use.  Any additional arguments will be passed
 603 verbatim to the called subref as arguments 2 and onwards.
 604
 605 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 606 exception handling and reconnection (or failover in future subclasses).
 607
 608 Your subref should have no side-effects outside of the database, as
 609 there is the potential for your subref to be partially double-executed
 610 if the database connection was stale/dysfunctional.
 611
 612 Example:
 613
 614   my @stuff = $schema->storage->dbh_do(
 615     sub {
 616       my ($storage, $dbh, @cols) = @_;
 617       my $cols = join(q{, }, @cols);
 618       $dbh->selectrow_array("SELECT $cols FROM foo");
 619     },
 620     @column_list
 621   );
 622
 623 =cut
 624
 625 sub dbh_do {
 626   my $self = shift;
 627   my $code = shift;
 628
 629   my $dbh = $self->_get_dbh;
 630
 631   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 632       || $self->{transaction_depth};
 633
 634   local $self->{_in_dbh_do} = 1;
 635
 636   my @result;
 637   my $want_array = wantarray;
 638
 639   eval {
 640
 641     if($want_array) {
 642         @result = $self->$code($dbh, @_);
 643     }
 644     elsif(defined $want_array) {
 645         $result[0] = $self->$code($dbh, @_);
 646     }
 647     else {
 648         $self->$code($dbh, @_);
 649     }
 650   };
 651
 652   # ->connected might unset $@ - copy
 653   my $exception = $@;
 654   if(!$exception) { return $want_array ? @result : $result[0] }
 655
 656   $self->throw_exception($exception) if $self->connected;
 657
 658   # We were not connected - reconnect and retry, but let any
 659   #  exception fall right through this time
 660   carp "Retrying $code after catching disconnected exception: $exception"
 661     if $ENV{DBIC_DBIRETRY_DEBUG};
 662   $self->_populate_dbh;
 663   $self->$code($self->_dbh, @_);
 664 }
 665
 666 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 667 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 668 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 669 sub txn_do {
 670   my $self = shift;
 671   my $coderef = shift;
 672
 673   ref $coderef eq 'CODE' or $self->throw_exception
 674     ('$coderef must be a CODE reference');
 675
 676   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 677
 678   local $self->{_in_dbh_do} = 1;
 679
 680   my @result;
 681   my $want_array = wantarray;
 682
 683   my $tried = 0;
 684   while(1) {
 685     eval {
 686       $self->_get_dbh;
 687
 688       $self->txn_begin;
 689       if($want_array) {
 690           @result = $coderef->(@_);
 691       }
 692       elsif(defined $want_array) {
 693           $result[0] = $coderef->(@_);
 694       }
 695       else {
 696           $coderef->(@_);
 697       }
 698       $self->txn_commit;
 699     };
 700
 701     # ->connected might unset $@ - copy
 702     my $exception = $@;
 703     if(!$exception) { return $want_array ? @result : $result[0] }
 704
 705     if($tried++ || $self->connected) {
 706       eval { $self->txn_rollback };
 707       my $rollback_exception = $@;
 708       if($rollback_exception) {
 709         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 710         $self->throw_exception($exception)  # propagate nested rollback
 711           if $rollback_exception =~ /$exception_class/;
 712
 713         $self->throw_exception(
 714           "Transaction aborted: ${exception}. "
 715           . "Rollback failed: ${rollback_exception}"
 716         );
 717       }
 718       $self->throw_exception($exception)
 719     }
 720
 721     # We were not connected, and was first try - reconnect and retry
 722     # via the while loop
 723     carp "Retrying $coderef after catching disconnected exception: $exception"
 724       if $ENV{DBIC_DBIRETRY_DEBUG};
 725     $self->_populate_dbh;
 726   }
 727 }
 728
 729 =head2 disconnect
 730
 731 Our C<disconnect> method also performs a rollback first if the
 732 database is not in C<AutoCommit> mode.
 733
 734 =cut
 735
 736 sub disconnect {
 737   my ($self) = @_;
 738
 739   if( $self->_dbh ) {
 740     my @actions;
 741
 742     push @actions, ( $self->on_disconnect_call || () );
 743     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 744
 745     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 746
 747     $self->_dbh_rollback unless $self->_dbh_autocommit;
 748
 749     %{ $self->_dbh->{CachedKids} } = ();
 750     $self->_dbh->disconnect;
 751     $self->_dbh(undef);
 752     $self->{_dbh_gen}++;
 753   }
 754 }
 755
 756 =head2 with_deferred_fk_checks
 757
 758 =over 4
 759
 760 =item Arguments: C<$coderef>
 761
 762 =item Return Value: The return value of $coderef
 763
 764 =back
 765
 766 Storage specific method to run the code ref with FK checks deferred or
 767 in MySQL's case disabled entirely.
 768
 769 =cut
 770
 771 # Storage subclasses should override this
 772 sub with_deferred_fk_checks {
 773   my ($self, $sub) = @_;
 774   $sub->();
 775 }
 776
 777 =head2 connected
 778
 779 =over
 780
 781 =item Arguments: none
 782
 783 =item Return Value: 1|0
 784
 785 =back
 786
 787 Verifies that the current database handle is active and ready to execute
 788 an SQL statement (e.g. the connection did not get stale, server is still
 789 answering, etc.) This method is used internally by L</dbh>.
 790
 791 =cut
 792
 793 sub connected {
 794   my $self = shift;
 795   return 0 unless $self->_seems_connected;
 796
 797   #be on the safe side
 798   local $self->_dbh->{RaiseError} = 1;
 799
 800   return $self->_ping;
 801 }
 802
 803 sub _seems_connected {
 804   my $self = shift;
 805
 806   my $dbh = $self->_dbh
 807     or return 0;
 808
 809   if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 810     $self->_dbh(undef);
 811     $self->{_dbh_gen}++;
 812     return 0;
 813   }
 814   else {
 815     $self->_verify_pid;
 816     return 0 if !$self->_dbh;
 817   }
 818
 819   return $dbh->FETCH('Active');
 820 }
 821
 822 sub _ping {
 823   my $self = shift;
 824
 825   my $dbh = $self->_dbh or return 0;
 826
 827   return $dbh->ping;
 828 }
 829
 830 # handle pid changes correctly
 831 #  NOTE: assumes $self->_dbh is a valid $dbh
 832 sub _verify_pid {
 833   my ($self) = @_;
 834
 835   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 836
 837   $self->_dbh->{InactiveDestroy} = 1;
 838   $self->_dbh(undef);
 839   $self->{_dbh_gen}++;
 840
 841   return;
 842 }
 843
 844 sub ensure_connected {
 845   my ($self) = @_;
 846
 847   unless ($self->connected) {
 848     $self->_populate_dbh;
 849   }
 850 }
 851
 852 =head2 dbh
 853
 854 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 855 is guaranteed to be healthy by implicitly calling L</connected>, and if
 856 necessary performing a reconnection before returning. Keep in mind that this
 857 is very B<expensive> on some database engines. Consider using L</dbh_do>
 858 instead.
 859
 860 =cut
 861
 862 sub dbh {
 863   my ($self) = @_;
 864
 865   if (not $self->_dbh) {
 866     $self->_populate_dbh;
 867   } else {
 868     $self->ensure_connected;
 869   }
 870   return $self->_dbh;
 871 }
 872
 873 # this is the internal "get dbh or connect (don't check)" method
 874 sub _get_dbh {
 875   my $self = shift;
 876   $self->_verify_pid if $self->_dbh;
 877   $self->_populate_dbh unless $self->_dbh;
 878   return $self->_dbh;
 879 }
 880
 881 sub _sql_maker_args {
 882     my ($self) = @_;
 883
 884     return (
 885       bindtype=>'columns',
 886       array_datatypes => 1,
 887       limit_dialect => $self->_get_dbh,
 888       %{$self->_sql_maker_opts}
 889     );
 890 }
 891
 892 sub sql_maker {
 893   my ($self) = @_;
 894   unless ($self->_sql_maker) {
 895     my $sql_maker_class = $self->sql_maker_class;
 896     $self->ensure_class_loaded ($sql_maker_class);
 897     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 898   }
 899   return $self->_sql_maker;
 900 }
 901
 902 # nothing to do by default
 903 sub _rebless {}
 904 sub _init {}
 905
 906 sub _populate_dbh {
 907   my ($self) = @_;
 908
 909   my @info = @{$self->_dbi_connect_info || []};
 910   $self->_dbh(undef); # in case ->connected failed we might get sent here
 911   $self->_dbh($self->_connect(@info));
 912
 913   $self->_conn_pid($$);
 914   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 915
 916   $self->_determine_driver;
 917
 918   # Always set the transaction depth on connect, since
 919   #  there is no transaction in progress by definition
 920   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 921
 922   $self->_run_connection_actions unless $self->{_in_determine_driver};
 923
 924   $self->_populate_server_info;
 925 }
 926
 927 sub _run_connection_actions {
 928   my $self = shift;
 929   my @actions;
 930
 931   push @actions, ( $self->on_connect_call || () );
 932   push @actions, $self->_parse_connect_do ('on_connect_do');
 933
 934   $self->_do_connection_actions(connect_call_ => $_) for @actions;
 935 }
 936
 937 sub _populate_server_info {
 938   my $self = shift;
 939   my %info;
 940
 941   my $dbms_ver = eval { local $@; $self->_get_dbh->get_info(18) };
 942
 943   if (defined $dbms_ver) {
 944     $info{dbms_ver} = $dbms_ver;
 945
 946     ($dbms_ver) = $dbms_ver =~ /^(\S+)/;
 947
 948     my @verparts = split /\./, $dbms_ver;
 949     $info{dbms_ver_normalized} = sprintf "%d.%03d%03d", @verparts;
 950   }
 951
 952   $self->__server_info(\%info);
 953
 954   return \%info;
 955 }
 956
 957 sub _server_info {
 958   my $self = shift;
 959
 960   $self->_get_dbh;
 961
 962   return $self->__server_info(@_);
 963 }
 964
 965 sub _determine_driver {
 966   my ($self) = @_;
 967
 968   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
 969     my $started_connected = 0;
 970     local $self->{_in_determine_driver} = 1;
 971
 972     if (ref($self) eq __PACKAGE__) {
 973       my $driver;
 974       if ($self->_dbh) { # we are connected
 975         $driver = $self->_dbh->{Driver}{Name};
 976         $started_connected = 1;
 977       } else {
 978         # if connect_info is a CODEREF, we have no choice but to connect
 979         if (ref $self->_dbi_connect_info->[0] &&
 980             Scalar::Util::reftype($self->_dbi_connect_info->[0]) eq 'CODE') {
 981           $self->_populate_dbh;
 982           $driver = $self->_dbh->{Driver}{Name};
 983         }
 984         else {
 985           # try to use dsn to not require being connected, the driver may still
 986           # force a connection in _rebless to determine version
 987           # (dsn may not be supplied at all if all we do is make a mock-schema)
 988           my $dsn = $self->_dbi_connect_info->[0] || '';
 989           ($driver) = $dsn =~ /dbi:([^:]+):/i;
 990         }
 991       }
 992
 993       if ($driver) {
 994         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
 995         if ($self->load_optional_class($storage_class)) {
 996           mro::set_mro($storage_class, 'c3');
 997           bless $self, $storage_class;
 998           $self->_rebless();
 999         }
1000       }
1001     }
1002
1003     $self->_driver_determined(1);
1004
1005     $self->_init; # run driver-specific initializations
1006
1007     $self->_run_connection_actions
1008         if !$started_connected && defined $self->_dbh;
1009   }
1010 }
1011
1012 sub _do_connection_actions {
1013   my $self          = shift;
1014   my $method_prefix = shift;
1015   my $call          = shift;
1016
1017   if (not ref($call)) {
1018     my $method = $method_prefix . $call;
1019     $self->$method(@_);
1020   } elsif (ref($call) eq 'CODE') {
1021     $self->$call(@_);
1022   } elsif (ref($call) eq 'ARRAY') {
1023     if (ref($call->[0]) ne 'ARRAY') {
1024       $self->_do_connection_actions($method_prefix, $_) for @$call;
1025     } else {
1026       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1027     }
1028   } else {
1029     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1030   }
1031
1032   return $self;
1033 }
1034
1035 sub connect_call_do_sql {
1036   my $self = shift;
1037   $self->_do_query(@_);
1038 }
1039
1040 sub disconnect_call_do_sql {
1041   my $self = shift;
1042   $self->_do_query(@_);
1043 }
1044
1045 # override in db-specific backend when necessary
1046 sub connect_call_datetime_setup { 1 }
1047
1048 sub _do_query {
1049   my ($self, $action) = @_;
1050
1051   if (ref $action eq 'CODE') {
1052     $action = $action->($self);
1053     $self->_do_query($_) foreach @$action;
1054   }
1055   else {
1056     # Most debuggers expect ($sql, @bind), so we need to exclude
1057     # the attribute hash which is the second argument to $dbh->do
1058     # furthermore the bind values are usually to be presented
1059     # as named arrayref pairs, so wrap those here too
1060     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1061     my $sql = shift @do_args;
1062     my $attrs = shift @do_args;
1063     my @bind = map { [ undef, $_ ] } @do_args;
1064
1065     $self->_query_start($sql, @bind);
1066     $self->_get_dbh->do($sql, $attrs, @do_args);
1067     $self->_query_end($sql, @bind);
1068   }
1069
1070   return $self;
1071 }
1072
1073 sub _connect {
1074   my ($self, @info) = @_;
1075
1076   $self->throw_exception("You failed to provide any connection info")
1077     if !@info;
1078
1079   my ($old_connect_via, $dbh);
1080
1081   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1082     $old_connect_via = $DBI::connect_via;
1083     $DBI::connect_via = 'connect';
1084   }
1085
1086   eval {
1087     if(ref $info[0] eq 'CODE') {
1088        $dbh = $info[0]->();
1089     }
1090     else {
1091        $dbh = DBI->connect(@info);
1092     }
1093
1094     if($dbh && !$self->unsafe) {
1095       my $weak_self = $self;
1096       Scalar::Util::weaken($weak_self);
1097       $dbh->{HandleError} = sub {
1098           if ($weak_self) {
1099             $weak_self->throw_exception("DBI Exception: $_[0]");
1100           }
1101           else {
1102             # the handler may be invoked by something totally out of
1103             # the scope of DBIC
1104             croak ("DBI Exception: $_[0]");
1105           }
1106       };
1107       $dbh->{ShowErrorStatement} = 1;
1108       $dbh->{RaiseError} = 1;
1109       $dbh->{PrintError} = 0;
1110     }
1111   };
1112
1113   $DBI::connect_via = $old_connect_via if $old_connect_via;
1114
1115   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1116     if !$dbh || $@;
1117
1118   $self->_dbh_autocommit($dbh->{AutoCommit});
1119
1120   $dbh;
1121 }
1122
1123 sub svp_begin {
1124   my ($self, $name) = @_;
1125
1126   $name = $self->_svp_generate_name
1127     unless defined $name;
1128
1129   $self->throw_exception ("You can't use savepoints outside a transaction")
1130     if $self->{transaction_depth} == 0;
1131
1132   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1133     unless $self->can('_svp_begin');
1134
1135   push @{ $self->{savepoints} }, $name;
1136
1137   $self->debugobj->svp_begin($name) if $self->debug;
1138
1139   return $self->_svp_begin($name);
1140 }
1141
1142 sub svp_release {
1143   my ($self, $name) = @_;
1144
1145   $self->throw_exception ("You can't use savepoints outside a transaction")
1146     if $self->{transaction_depth} == 0;
1147
1148   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1149     unless $self->can('_svp_release');
1150
1151   if (defined $name) {
1152     $self->throw_exception ("Savepoint '$name' does not exist")
1153       unless grep { $_ eq $name } @{ $self->{savepoints} };
1154
1155     # Dig through the stack until we find the one we are releasing.  This keeps
1156     # the stack up to date.
1157     my $svp;
1158
1159     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1160   } else {
1161     $name = pop @{ $self->{savepoints} };
1162   }
1163
1164   $self->debugobj->svp_release($name) if $self->debug;
1165
1166   return $self->_svp_release($name);
1167 }
1168
1169 sub svp_rollback {
1170   my ($self, $name) = @_;
1171
1172   $self->throw_exception ("You can't use savepoints outside a transaction")
1173     if $self->{transaction_depth} == 0;
1174
1175   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1176     unless $self->can('_svp_rollback');
1177
1178   if (defined $name) {
1179       # If they passed us a name, verify that it exists in the stack
1180       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1181           $self->throw_exception("Savepoint '$name' does not exist!");
1182       }
1183
1184       # Dig through the stack until we find the one we are releasing.  This keeps
1185       # the stack up to date.
1186       while(my $s = pop(@{ $self->{savepoints} })) {
1187           last if($s eq $name);
1188       }
1189       # Add the savepoint back to the stack, as a rollback doesn't remove the
1190       # named savepoint, only everything after it.
1191       push(@{ $self->{savepoints} }, $name);
1192   } else {
1193       # We'll assume they want to rollback to the last savepoint
1194       $name = $self->{savepoints}->[-1];
1195   }
1196
1197   $self->debugobj->svp_rollback($name) if $self->debug;
1198
1199   return $self->_svp_rollback($name);
1200 }
1201
1202 sub _svp_generate_name {
1203     my ($self) = @_;
1204
1205     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1206 }
1207
1208 sub txn_begin {
1209   my $self = shift;
1210
1211   # this means we have not yet connected and do not know the AC status
1212   # (e.g. coderef $dbh)
1213   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1214
1215   if($self->{transaction_depth} == 0) {
1216     $self->debugobj->txn_begin()
1217       if $self->debug;
1218     $self->_dbh_begin_work;
1219   }
1220   elsif ($self->auto_savepoint) {
1221     $self->svp_begin;
1222   }
1223   $self->{transaction_depth}++;
1224 }
1225
1226 sub _dbh_begin_work {
1227   my $self = shift;
1228
1229   # if the user is utilizing txn_do - good for him, otherwise we need to
1230   # ensure that the $dbh is healthy on BEGIN.
1231   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1232   # will be replaced by a failure of begin_work itself (which will be
1233   # then retried on reconnect)
1234   if ($self->{_in_dbh_do}) {
1235     $self->_dbh->begin_work;
1236   } else {
1237     $self->dbh_do(sub { $_[1]->begin_work });
1238   }
1239 }
1240
1241 sub txn_commit {
1242   my $self = shift;
1243   if ($self->{transaction_depth} == 1) {
1244     $self->debugobj->txn_commit()
1245       if ($self->debug);
1246     $self->_dbh_commit;
1247     $self->{transaction_depth} = 0
1248       if $self->_dbh_autocommit;
1249   }
1250   elsif($self->{transaction_depth} > 1) {
1251     $self->{transaction_depth}--;
1252     $self->svp_release
1253       if $self->auto_savepoint;
1254   }
1255 }
1256
1257 sub _dbh_commit {
1258   my $self = shift;
1259   my $dbh  = $self->_dbh
1260     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1261   $dbh->commit;
1262 }
1263
1264 sub txn_rollback {
1265   my $self = shift;
1266   my $dbh = $self->_dbh;
1267   eval {
1268     if ($self->{transaction_depth} == 1) {
1269       $self->debugobj->txn_rollback()
1270         if ($self->debug);
1271       $self->{transaction_depth} = 0
1272         if $self->_dbh_autocommit;
1273       $self->_dbh_rollback;
1274     }
1275     elsif($self->{transaction_depth} > 1) {
1276       $self->{transaction_depth}--;
1277       if ($self->auto_savepoint) {
1278         $self->svp_rollback;
1279         $self->svp_release;
1280       }
1281     }
1282     else {
1283       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1284     }
1285   };
1286   if ($@) {
1287     my $error = $@;
1288     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1289     $error =~ /$exception_class/ and $self->throw_exception($error);
1290     # ensure that a failed rollback resets the transaction depth
1291     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1292     $self->throw_exception($error);
1293   }
1294 }
1295
1296 sub _dbh_rollback {
1297   my $self = shift;
1298   my $dbh  = $self->_dbh
1299     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1300   $dbh->rollback;
1301 }
1302
1303 # This used to be the top-half of _execute.  It was split out to make it
1304 #  easier to override in NoBindVars without duping the rest.  It takes up
1305 #  all of _execute's args, and emits $sql, @bind.
1306 sub _prep_for_execute {
1307   my ($self, $op, $extra_bind, $ident, $args) = @_;
1308
1309   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1310     $ident = $ident->from();
1311   }
1312
1313   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1314
1315   unshift(@bind,
1316     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1317       if $extra_bind;
1318   return ($sql, \@bind);
1319 }
1320
1321
1322 sub _fix_bind_params {
1323     my ($self, @bind) = @_;
1324
1325     ### Turn @bind from something like this:
1326     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1327     ### to this:
1328     ###   ( "'1'", "'1'", "'3'" )
1329     return
1330         map {
1331             if ( defined( $_ && $_->[1] ) ) {
1332                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1333             }
1334             else { q{'NULL'}; }
1335         } @bind;
1336 }
1337
1338 sub _query_start {
1339     my ( $self, $sql, @bind ) = @_;
1340
1341     if ( $self->debug ) {
1342         @bind = $self->_fix_bind_params(@bind);
1343
1344         $self->debugobj->query_start( $sql, @bind );
1345     }
1346 }
1347
1348 sub _query_end {
1349     my ( $self, $sql, @bind ) = @_;
1350
1351     if ( $self->debug ) {
1352         @bind = $self->_fix_bind_params(@bind);
1353         $self->debugobj->query_end( $sql, @bind );
1354     }
1355 }
1356
1357 sub _dbh_execute {
1358   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1359
1360   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1361
1362   $self->_query_start( $sql, @$bind );
1363
1364   my $sth = $self->sth($sql,$op);
1365
1366   my $placeholder_index = 1;
1367
1368   foreach my $bound (@$bind) {
1369     my $attributes = {};
1370     my($column_name, @data) = @$bound;
1371
1372     if ($bind_attributes) {
1373       $attributes = $bind_attributes->{$column_name}
1374       if defined $bind_attributes->{$column_name};
1375     }
1376
1377     foreach my $data (@data) {
1378       my $ref = ref $data;
1379       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1380
1381       $sth->bind_param($placeholder_index, $data, $attributes);
1382       $placeholder_index++;
1383     }
1384   }
1385
1386   # Can this fail without throwing an exception anyways???
1387   my $rv = $sth->execute();
1388   $self->throw_exception($sth->errstr) if !$rv;
1389
1390   $self->_query_end( $sql, @$bind );
1391
1392   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1393 }
1394
1395 sub _execute {
1396     my $self = shift;
1397     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1398 }
1399
1400 sub _prefetch_insert_auto_nextvals {
1401   my ($self, $source, $to_insert) = @_;
1402
1403   my $upd = {};
1404
1405   foreach my $col ( $source->columns ) {
1406     if ( !defined $to_insert->{$col} ) {
1407       my $col_info = $source->column_info($col);
1408
1409       if ( $col_info->{auto_nextval} ) {
1410         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1411           'nextval',
1412           $col_info->{sequence} ||=
1413             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1414         );
1415       }
1416     }
1417   }
1418
1419   return $upd;
1420 }
1421
1422 sub insert {
1423   my $self = shift;
1424   my ($source, $to_insert, $opts) = @_;
1425
1426   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1427
1428   my $bind_attributes = $self->source_bind_attributes($source);
1429
1430   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1431
1432   if ($opts->{returning}) {
1433     my @ret_cols = @{$opts->{returning}};
1434
1435     my @ret_vals = eval {
1436       local $SIG{__WARN__} = sub {};
1437       my @r = $sth->fetchrow_array;
1438       $sth->finish;
1439       @r;
1440     };
1441
1442     my %ret;
1443     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1444
1445     $updated_cols = {
1446       %$updated_cols,
1447       %ret,
1448     };
1449   }
1450
1451   return $updated_cols;
1452 }
1453
1454 ## Currently it is assumed that all values passed will be "normal", i.e. not
1455 ## scalar refs, or at least, all the same type as the first set, the statement is
1456 ## only prepped once.
1457 sub insert_bulk {
1458   my ($self, $source, $cols, $data) = @_;
1459
1460   my %colvalues;
1461   @colvalues{@$cols} = (0..$#$cols);
1462
1463   for my $i (0..$#$cols) {
1464     my $first_val = $data->[0][$i];
1465     next unless ref $first_val eq 'SCALAR';
1466
1467     $colvalues{ $cols->[$i] } = $first_val;
1468   }
1469
1470   # check for bad data and stringify stringifiable objects
1471   my $bad_slice = sub {
1472     my ($msg, $col_idx, $slice_idx) = @_;
1473     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1474       $msg,
1475       $cols->[$col_idx],
1476       do {
1477         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1478         Data::Dumper::Concise::Dumper({
1479           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1480         }),
1481       }
1482     );
1483   };
1484
1485   for my $datum_idx (0..$#$data) {
1486     my $datum = $data->[$datum_idx];
1487
1488     for my $col_idx (0..$#$cols) {
1489       my $val            = $datum->[$col_idx];
1490       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1491       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1492
1493       if ($is_literal_sql) {
1494         if (not ref $val) {
1495           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1496         }
1497         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1498           $bad_slice->("$reftype reference found where literal SQL expected",
1499             $col_idx, $datum_idx);
1500         }
1501         elsif ($$val ne $$sqla_bind){
1502           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1503             $col_idx, $datum_idx);
1504         }
1505       }
1506       elsif (my $reftype = ref $val) {
1507         require overload;
1508         if (overload::Method($val, '""')) {
1509           $datum->[$col_idx] = "".$val;
1510         }
1511         else {
1512           $bad_slice->("$reftype reference found where bind expected",
1513             $col_idx, $datum_idx);
1514         }
1515       }
1516     }
1517   }
1518
1519   my ($sql, $bind) = $self->_prep_for_execute (
1520     'insert', undef, $source, [\%colvalues]
1521   );
1522   my @bind = @$bind;
1523
1524   my $empty_bind = 1 if (not @bind) &&
1525     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1526
1527   if ((not @bind) && (not $empty_bind)) {
1528     $self->throw_exception(
1529       'Cannot insert_bulk without support for placeholders'
1530     );
1531   }
1532
1533   # neither _execute_array, nor _execute_inserts_with_no_binds are
1534   # atomic (even if _execute _array is a single call). Thus a safety
1535   # scope guard
1536   my $guard = $self->txn_scope_guard;
1537
1538   $self->_query_start( $sql, ['__BULK__'] );
1539   my $sth = $self->sth($sql);
1540   my $rv = do {
1541     if ($empty_bind) {
1542       # bind_param_array doesn't work if there are no binds
1543       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1544     }
1545     else {
1546 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1547       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1548     }
1549   };
1550
1551   $self->_query_end( $sql, ['__BULK__'] );
1552
1553   $guard->commit;
1554
1555   return (wantarray ? ($rv, $sth, @bind) : $rv);
1556 }
1557
1558 sub _execute_array {
1559   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1560
1561   ## This must be an arrayref, else nothing works!
1562   my $tuple_status = [];
1563
1564   ## Get the bind_attributes, if any exist
1565   my $bind_attributes = $self->source_bind_attributes($source);
1566
1567   ## Bind the values and execute
1568   my $placeholder_index = 1;
1569
1570   foreach my $bound (@$bind) {
1571
1572     my $attributes = {};
1573     my ($column_name, $data_index) = @$bound;
1574
1575     if( $bind_attributes ) {
1576       $attributes = $bind_attributes->{$column_name}
1577       if defined $bind_attributes->{$column_name};
1578     }
1579
1580     my @data = map { $_->[$data_index] } @$data;
1581
1582     $sth->bind_param_array(
1583       $placeholder_index,
1584       [@data],
1585       (%$attributes ?  $attributes : ()),
1586     );
1587     $placeholder_index++;
1588   }
1589
1590   my $rv = eval {
1591     $self->_dbh_execute_array($sth, $tuple_status, @extra);
1592   };
1593   my $err = $@ || $sth->errstr;
1594
1595 # Statement must finish even if there was an exception.
1596   eval { $sth->finish };
1597   $err = $@ unless $err;
1598
1599   if ($err) {
1600     my $i = 0;
1601     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1602
1603     $self->throw_exception("Unexpected populate error: $err")
1604       if ($i > $#$tuple_status);
1605
1606     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1607       ($tuple_status->[$i][1] || $err),
1608       Data::Dumper::Concise::Dumper({
1609         map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols)
1610       }),
1611     );
1612   }
1613   return $rv;
1614 }
1615
1616 sub _dbh_execute_array {
1617     my ($self, $sth, $tuple_status, @extra) = @_;
1618
1619     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1620 }
1621
1622 sub _dbh_execute_inserts_with_no_binds {
1623   my ($self, $sth, $count) = @_;
1624
1625   eval {
1626     my $dbh = $self->_get_dbh;
1627     local $dbh->{RaiseError} = 1;
1628     local $dbh->{PrintError} = 0;
1629
1630     $sth->execute foreach 1..$count;
1631   };
1632   my $exception = $@;
1633
1634 # Make sure statement is finished even if there was an exception.
1635   eval { $sth->finish };
1636   $exception = $@ unless $exception;
1637
1638   $self->throw_exception($exception) if $exception;
1639
1640   return $count;
1641 }
1642
1643 sub update {
1644   my ($self, $source, @args) = @_;
1645
1646   my $bind_attrs = $self->source_bind_attributes($source);
1647
1648   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1649 }
1650
1651
1652 sub delete {
1653   my ($self, $source, @args) = @_;
1654
1655   my $bind_attrs = $self->source_bind_attributes($source);
1656
1657   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1658 }
1659
1660 # We were sent here because the $rs contains a complex search
1661 # which will require a subquery to select the correct rows
1662 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1663 #
1664 # Generating a single PK column subquery is trivial and supported
1665 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1666 # Look at _multipk_update_delete()
1667 sub _subq_update_delete {
1668   my $self = shift;
1669   my ($rs, $op, $values) = @_;
1670
1671   my $rsrc = $rs->result_source;
1672
1673   # quick check if we got a sane rs on our hands
1674   my @pcols = $rsrc->_pri_cols;
1675
1676   my $sel = $rs->_resolved_attrs->{select};
1677   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1678
1679   if (
1680       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1681         ne
1682       join ("\x00", sort @$sel )
1683   ) {
1684     $self->throw_exception (
1685       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1686     );
1687   }
1688
1689   if (@pcols == 1) {
1690     return $self->$op (
1691       $rsrc,
1692       $op eq 'update' ? $values : (),
1693       { $pcols[0] => { -in => $rs->as_query } },
1694     );
1695   }
1696
1697   else {
1698     return $self->_multipk_update_delete (@_);
1699   }
1700 }
1701
1702 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1703 # resultset update/delete involving subqueries. So by default resort
1704 # to simple (and inefficient) delete_all style per-row opearations,
1705 # while allowing specific storages to override this with a faster
1706 # implementation.
1707 #
1708 sub _multipk_update_delete {
1709   return shift->_per_row_update_delete (@_);
1710 }
1711
1712 # This is the default loop used to delete/update rows for multi PK
1713 # resultsets, and used by mysql exclusively (because it can't do anything
1714 # else).
1715 #
1716 # We do not use $row->$op style queries, because resultset update/delete
1717 # is not expected to cascade (this is what delete_all/update_all is for).
1718 #
1719 # There should be no race conditions as the entire operation is rolled
1720 # in a transaction.
1721 #
1722 sub _per_row_update_delete {
1723   my $self = shift;
1724   my ($rs, $op, $values) = @_;
1725
1726   my $rsrc = $rs->result_source;
1727   my @pcols = $rsrc->_pri_cols;
1728
1729   my $guard = $self->txn_scope_guard;
1730
1731   # emulate the return value of $sth->execute for non-selects
1732   my $row_cnt = '0E0';
1733
1734   my $subrs_cur = $rs->cursor;
1735   my @all_pk = $subrs_cur->all;
1736   for my $pks ( @all_pk) {
1737
1738     my $cond;
1739     for my $i (0.. $#pcols) {
1740       $cond->{$pcols[$i]} = $pks->[$i];
1741     }
1742
1743     $self->$op (
1744       $rsrc,
1745       $op eq 'update' ? $values : (),
1746       $cond,
1747     );
1748
1749     $row_cnt++;
1750   }
1751
1752   $guard->commit;
1753
1754   return $row_cnt;
1755 }
1756
1757 sub _select {
1758   my $self = shift;
1759
1760   # localization is neccessary as
1761   # 1) there is no infrastructure to pass this around before SQLA2
1762   # 2) _select_args sets it and _prep_for_execute consumes it
1763   my $sql_maker = $self->sql_maker;
1764   local $sql_maker->{_dbic_rs_attrs};
1765
1766   return $self->_execute($self->_select_args(@_));
1767 }
1768
1769 sub _select_args_to_query {
1770   my $self = shift;
1771
1772   # localization is neccessary as
1773   # 1) there is no infrastructure to pass this around before SQLA2
1774   # 2) _select_args sets it and _prep_for_execute consumes it
1775   my $sql_maker = $self->sql_maker;
1776   local $sql_maker->{_dbic_rs_attrs};
1777
1778   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $order, $rows, $offset)
1779   #  = $self->_select_args($ident, $select, $cond, $attrs);
1780   my ($op, $bind, $ident, $bind_attrs, @args) =
1781     $self->_select_args(@_);
1782
1783   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $order, $rows, $offset ]);
1784   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1785   $prepared_bind ||= [];
1786
1787   return wantarray
1788     ? ($sql, $prepared_bind, $bind_attrs)
1789     : \[ "($sql)", @$prepared_bind ]
1790   ;
1791 }
1792
1793 sub _select_args {
1794   my ($self, $ident, $select, $where, $attrs) = @_;
1795
1796   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1797
1798   my $sql_maker = $self->sql_maker;
1799   $sql_maker->{_dbic_rs_attrs} = {
1800     %$attrs,
1801     select => $select,
1802     from => $ident,
1803     where => $where,
1804     $rs_alias && $alias2source->{$rs_alias}
1805       ? ( _source_handle => $alias2source->{$rs_alias}->handle )
1806       : ()
1807     ,
1808   };
1809
1810   # calculate bind_attrs before possible $ident mangling
1811   my $bind_attrs = {};
1812   for my $alias (keys %$alias2source) {
1813     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1814     for my $col (keys %$bindtypes) {
1815
1816       my $fqcn = join ('.', $alias, $col);
1817       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1818
1819       # Unqialified column names are nice, but at the same time can be
1820       # rather ambiguous. What we do here is basically go along with
1821       # the loop, adding an unqualified column slot to $bind_attrs,
1822       # alongside the fully qualified name. As soon as we encounter
1823       # another column by that name (which would imply another table)
1824       # we unset the unqualified slot and never add any info to it
1825       # to avoid erroneous type binding. If this happens the users
1826       # only choice will be to fully qualify his column name
1827
1828       if (exists $bind_attrs->{$col}) {
1829         $bind_attrs->{$col} = {};
1830       }
1831       else {
1832         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1833       }
1834     }
1835   }
1836
1837   # adjust limits
1838   if (
1839     $attrs->{software_limit}
1840       ||
1841     $sql_maker->_default_limit_syntax eq "GenericSubQ"
1842   ) {
1843     $attrs->{software_limit} = 1;
1844   }
1845   else {
1846     $self->throw_exception("rows attribute must be positive if present")
1847       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1848
1849     # MySQL actually recommends this approach.  I cringe.
1850     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1851   }
1852
1853   my @limit;
1854
1855   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1856   # storage, unless software limit was requested
1857   if (
1858     #limited has_many
1859     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1860        ||
1861     # limited prefetch with RNO subqueries
1862     (
1863       $attrs->{rows}
1864         &&
1865       $sql_maker->limit_dialect eq 'RowNumberOver'
1866         &&
1867       $attrs->{_prefetch_select}
1868         &&
1869       @{$attrs->{_prefetch_select}}
1870     )
1871       ||
1872     # grouped prefetch
1873     ( $attrs->{group_by}
1874         &&
1875       @{$attrs->{group_by}}
1876         &&
1877       $attrs->{_prefetch_select}
1878         &&
1879       @{$attrs->{_prefetch_select}}
1880     )
1881   ) {
1882     ($ident, $select, $where, $attrs)
1883       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1884   }
1885
1886   elsif (
1887     ($attrs->{rows} || $attrs->{offset})
1888       &&
1889     $sql_maker->limit_dialect eq 'RowNumberOver'
1890       &&
1891     (ref $ident eq 'ARRAY' && @$ident > 1)  # indicates a join
1892       &&
1893     scalar $self->_parse_order_by ($attrs->{order_by})
1894   ) {
1895     # the RNO limit dialect above mangles the SQL such that the join gets lost
1896     # wrap a subquery here
1897
1898     push @limit, delete @{$attrs}{qw/rows offset/};
1899
1900     my $subq = $self->_select_args_to_query (
1901       $ident,
1902       $select,
1903       $where,
1904       $attrs,
1905     );
1906
1907     $ident = {
1908       -alias => $attrs->{alias},
1909       -source_handle => $ident->[0]{-source_handle},
1910       $attrs->{alias} => $subq,
1911     };
1912
1913     # all part of the subquery now
1914     delete @{$attrs}{qw/order_by group_by having/};
1915     $where = undef;
1916   }
1917
1918   elsif (! $attrs->{software_limit} ) {
1919     push @limit, $attrs->{rows}, $attrs->{offset};
1920   }
1921
1922   # try to simplify the joinmap further (prune unreferenced type-single joins)
1923   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1924
1925 ###
1926   # This would be the point to deflate anything found in $where
1927   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1928   # expect a row object. And all we have is a resultsource (it is trivial
1929   # to extract deflator coderefs via $alias2source above).
1930   #
1931   # I don't see a way forward other than changing the way deflators are
1932   # invoked, and that's just bad...
1933 ###
1934
1935   my $order = { map
1936     { $attrs->{$_} ? ( $_ => $attrs->{$_} ) : ()  }
1937     (qw/order_by group_by having/ )
1938   };
1939
1940   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $order, @limit);
1941 }
1942
1943 # Returns a counting SELECT for a simple count
1944 # query. Abstracted so that a storage could override
1945 # this to { count => 'firstcol' } or whatever makes
1946 # sense as a performance optimization
1947 sub _count_select {
1948   #my ($self, $source, $rs_attrs) = @_;
1949   return { count => '*' };
1950 }
1951
1952 # Returns a SELECT which will end up in the subselect
1953 # There may or may not be a group_by, as the subquery
1954 # might have been called to accomodate a limit
1955 #
1956 # Most databases would be happy with whatever ends up
1957 # here, but some choke in various ways.
1958 #
1959 sub _subq_count_select {
1960   my ($self, $source, $rs_attrs) = @_;
1961
1962   if (my $groupby = $rs_attrs->{group_by}) {
1963
1964     my $avail_columns = $self->_resolve_column_info ($rs_attrs->{from});
1965
1966     my $sel_index;
1967     for my $sel (@{$rs_attrs->{select}}) {
1968       if (ref $sel eq 'HASH' and $sel->{-as}) {
1969         $sel_index->{$sel->{-as}} = $sel;
1970       }
1971     }
1972
1973     my @selection;
1974     for my $g_part (@$groupby) {
1975       if (ref $g_part or $avail_columns->{$g_part}) {
1976         push @selection, $g_part;
1977       }
1978       elsif ($sel_index->{$g_part}) {
1979         push @selection, $sel_index->{$g_part};
1980       }
1981       else {
1982         $self->throw_exception ("group_by criteria '$g_part' not contained within current resultset source(s)");
1983       }
1984     }
1985
1986     return \@selection;
1987   }
1988
1989   my @pcols = map { join '.', $rs_attrs->{alias}, $_ } ($source->primary_columns);
1990   return @pcols ? \@pcols : [ 1 ];
1991 }
1992
1993 sub source_bind_attributes {
1994   my ($self, $source) = @_;
1995
1996   my $bind_attributes;
1997   foreach my $column ($source->columns) {
1998
1999     my $data_type = $source->column_info($column)->{data_type} || '';
2000     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
2001      if $data_type;
2002   }
2003
2004   return $bind_attributes;
2005 }
2006
2007 =head2 select
2008
2009 =over 4
2010
2011 =item Arguments: $ident, $select, $condition, $attrs
2012
2013 =back
2014
2015 Handle a SQL select statement.
2016
2017 =cut
2018
2019 sub select {
2020   my $self = shift;
2021   my ($ident, $select, $condition, $attrs) = @_;
2022   return $self->cursor_class->new($self, \@_, $attrs);
2023 }
2024
2025 sub select_single {
2026   my $self = shift;
2027   my ($rv, $sth, @bind) = $self->_select(@_);
2028   my @row = $sth->fetchrow_array;
2029   my @nextrow = $sth->fetchrow_array if @row;
2030   if(@row && @nextrow) {
2031     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2032   }
2033   # Need to call finish() to work round broken DBDs
2034   $sth->finish();
2035   return @row;
2036 }
2037
2038 =head2 sth
2039
2040 =over 4
2041
2042 =item Arguments: $sql
2043
2044 =back
2045
2046 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2047
2048 =cut
2049
2050 sub _dbh_sth {
2051   my ($self, $dbh, $sql) = @_;
2052
2053   # 3 is the if_active parameter which avoids active sth re-use
2054   my $sth = $self->disable_sth_caching
2055     ? $dbh->prepare($sql)
2056     : $dbh->prepare_cached($sql, {}, 3);
2057
2058   # XXX You would think RaiseError would make this impossible,
2059   #  but apparently that's not true :(
2060   $self->throw_exception($dbh->errstr) if !$sth;
2061
2062   $sth;
2063 }
2064
2065 sub sth {
2066   my ($self, $sql) = @_;
2067   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2068 }
2069
2070 sub _dbh_columns_info_for {
2071   my ($self, $dbh, $table) = @_;
2072
2073   if ($dbh->can('column_info')) {
2074     my %result;
2075     eval {
2076       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2077       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2078       $sth->execute();
2079       while ( my $info = $sth->fetchrow_hashref() ){
2080         my %column_info;
2081         $column_info{data_type}   = $info->{TYPE_NAME};
2082         $column_info{size}      = $info->{COLUMN_SIZE};
2083         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2084         $column_info{default_value} = $info->{COLUMN_DEF};
2085         my $col_name = $info->{COLUMN_NAME};
2086         $col_name =~ s/^\"(.*)\"$/$1/;
2087
2088         $result{$col_name} = \%column_info;
2089       }
2090     };
2091     return \%result if !$@ && scalar keys %result;
2092   }
2093
2094   my %result;
2095   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2096   $sth->execute;
2097   my @columns = @{$sth->{NAME_lc}};
2098   for my $i ( 0 .. $#columns ){
2099     my %column_info;
2100     $column_info{data_type} = $sth->{TYPE}->[$i];
2101     $column_info{size} = $sth->{PRECISION}->[$i];
2102     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2103
2104     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2105       $column_info{data_type} = $1;
2106       $column_info{size}    = $2;
2107     }
2108
2109     $result{$columns[$i]} = \%column_info;
2110   }
2111   $sth->finish;
2112
2113   foreach my $col (keys %result) {
2114     my $colinfo = $result{$col};
2115     my $type_num = $colinfo->{data_type};
2116     my $type_name;
2117     if(defined $type_num && $dbh->can('type_info')) {
2118       my $type_info = $dbh->type_info($type_num);
2119       $type_name = $type_info->{TYPE_NAME} if $type_info;
2120       $colinfo->{data_type} = $type_name if $type_name;
2121     }
2122   }
2123
2124   return \%result;
2125 }
2126
2127 sub columns_info_for {
2128   my ($self, $table) = @_;
2129   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2130 }
2131
2132 =head2 last_insert_id
2133
2134 Return the row id of the last insert.
2135
2136 =cut
2137
2138 sub _dbh_last_insert_id {
2139     my ($self, $dbh, $source, $col) = @_;
2140
2141     my $id = eval { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2142
2143     return $id if defined $id;
2144
2145     my $class = ref $self;
2146     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2147 }
2148
2149 sub last_insert_id {
2150   my $self = shift;
2151   $self->_dbh_last_insert_id ($self->_dbh, @_);
2152 }
2153
2154 =head2 _native_data_type
2155
2156 =over 4
2157
2158 =item Arguments: $type_name
2159
2160 =back
2161
2162 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2163 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2164 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2165
2166 The default implementation returns C<undef>, implement in your Storage driver if
2167 you need this functionality.
2168
2169 Should map types from other databases to the native RDBMS type, for example
2170 C<VARCHAR2> to C<VARCHAR>.
2171
2172 Types with modifiers should map to the underlying data type. For example,
2173 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2174
2175 Composite types should map to the container type, for example
2176 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2177
2178 =cut
2179
2180 sub _native_data_type {
2181   #my ($self, $data_type) = @_;
2182   return undef
2183 }
2184
2185 # Check if placeholders are supported at all
2186 sub _placeholders_supported {
2187   my $self = shift;
2188   my $dbh  = $self->_get_dbh;
2189
2190   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2191   # but it is inaccurate more often than not
2192   eval {
2193     local $dbh->{PrintError} = 0;
2194     local $dbh->{RaiseError} = 1;
2195     $dbh->do('select ?', {}, 1);
2196   };
2197   return $@ ? 0 : 1;
2198 }
2199
2200 # Check if placeholders bound to non-string types throw exceptions
2201 #
2202 sub _typeless_placeholders_supported {
2203   my $self = shift;
2204   my $dbh  = $self->_get_dbh;
2205
2206   eval {
2207     local $dbh->{PrintError} = 0;
2208     local $dbh->{RaiseError} = 1;
2209     # this specifically tests a bind that is NOT a string
2210     $dbh->do('select 1 where 1 = ?', {}, 1);
2211   };
2212   return $@ ? 0 : 1;
2213 }
2214
2215 =head2 sqlt_type
2216
2217 Returns the database driver name.
2218
2219 =cut
2220
2221 sub sqlt_type {
2222   shift->_get_dbh->{Driver}->{Name};
2223 }
2224
2225 =head2 bind_attribute_by_data_type
2226
2227 Given a datatype from column info, returns a database specific bind
2228 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2229 let the database planner just handle it.
2230
2231 Generally only needed for special case column types, like bytea in postgres.
2232
2233 =cut
2234
2235 sub bind_attribute_by_data_type {
2236     return;
2237 }
2238
2239 =head2 is_datatype_numeric
2240
2241 Given a datatype from column_info, returns a boolean value indicating if
2242 the current RDBMS considers it a numeric value. This controls how
2243 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2244 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2245 be performed instead of the usual C<eq>.
2246
2247 =cut
2248
2249 sub is_datatype_numeric {
2250   my ($self, $dt) = @_;
2251
2252   return 0 unless $dt;
2253
2254   return $dt =~ /^ (?:
2255     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2256   ) $/ix;
2257 }
2258
2259
2260 =head2 create_ddl_dir
2261
2262 =over 4
2263
2264 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2265
2266 =back
2267
2268 Creates a SQL file based on the Schema, for each of the specified
2269 database engines in C<\@databases> in the given directory.
2270 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2271
2272 Given a previous version number, this will also create a file containing
2273 the ALTER TABLE statements to transform the previous schema into the
2274 current one. Note that these statements may contain C<DROP TABLE> or
2275 C<DROP COLUMN> statements that can potentially destroy data.
2276
2277 The file names are created using the C<ddl_filename> method below, please
2278 override this method in your schema if you would like a different file
2279 name format. For the ALTER file, the same format is used, replacing
2280 $version in the name with "$preversion-$version".
2281
2282 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2283 The most common value for this would be C<< { add_drop_table => 1 } >>
2284 to have the SQL produced include a C<DROP TABLE> statement for each table
2285 created. For quoting purposes supply C<quote_table_names> and
2286 C<quote_field_names>.
2287
2288 If no arguments are passed, then the following default values are assumed:
2289
2290 =over 4
2291
2292 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2293
2294 =item version    - $schema->schema_version
2295
2296 =item directory  - './'
2297
2298 =item preversion - <none>
2299
2300 =back
2301
2302 By default, C<\%sqlt_args> will have
2303
2304  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2305
2306 merged with the hash passed in. To disable any of those features, pass in a
2307 hashref like the following
2308
2309  { ignore_constraint_names => 0, # ... other options }
2310
2311
2312 WARNING: You are strongly advised to check all SQL files created, before applying
2313 them.
2314
2315 =cut
2316
2317 sub create_ddl_dir {
2318   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2319
2320   unless ($dir) {
2321     carp "No directory given, using ./\n";
2322     $dir = './';
2323   }
2324
2325   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2326
2327   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2328   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2329
2330   my $schema_version = $schema->schema_version || '1.x';
2331   $version ||= $schema_version;
2332
2333   $sqltargs = {
2334     add_drop_table => 1,
2335     ignore_constraint_names => 1,
2336     ignore_index_names => 1,
2337     %{$sqltargs || {}}
2338   };
2339
2340   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2341     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2342   }
2343
2344   my $sqlt = SQL::Translator->new( $sqltargs );
2345
2346   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2347   my $sqlt_schema = $sqlt->translate({ data => $schema })
2348     or $self->throw_exception ($sqlt->error);
2349
2350   foreach my $db (@$databases) {
2351     $sqlt->reset();
2352     $sqlt->{schema} = $sqlt_schema;
2353     $sqlt->producer($db);
2354
2355     my $file;
2356     my $filename = $schema->ddl_filename($db, $version, $dir);
2357     if (-e $filename && ($version eq $schema_version )) {
2358       # if we are dumping the current version, overwrite the DDL
2359       carp "Overwriting existing DDL file - $filename";
2360       unlink($filename);
2361     }
2362
2363     my $output = $sqlt->translate;
2364     if(!$output) {
2365       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2366       next;
2367     }
2368     if(!open($file, ">$filename")) {
2369       $self->throw_exception("Can't open $filename for writing ($!)");
2370       next;
2371     }
2372     print $file $output;
2373     close($file);
2374
2375     next unless ($preversion);
2376
2377     require SQL::Translator::Diff;
2378
2379     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2380     if(!-e $prefilename) {
2381       carp("No previous schema file found ($prefilename)");
2382       next;
2383     }
2384
2385     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2386     if(-e $difffile) {
2387       carp("Overwriting existing diff file - $difffile");
2388       unlink($difffile);
2389     }
2390
2391     my $source_schema;
2392     {
2393       my $t = SQL::Translator->new($sqltargs);
2394       $t->debug( 0 );
2395       $t->trace( 0 );
2396
2397       $t->parser( $db )
2398         or $self->throw_exception ($t->error);
2399
2400       my $out = $t->translate( $prefilename )
2401         or $self->throw_exception ($t->error);
2402
2403       $source_schema = $t->schema;
2404
2405       $source_schema->name( $prefilename )
2406         unless ( $source_schema->name );
2407     }
2408
2409     # The "new" style of producers have sane normalization and can support
2410     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2411     # And we have to diff parsed SQL against parsed SQL.
2412     my $dest_schema = $sqlt_schema;
2413
2414     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2415       my $t = SQL::Translator->new($sqltargs);
2416       $t->debug( 0 );
2417       $t->trace( 0 );
2418
2419       $t->parser( $db )
2420         or $self->throw_exception ($t->error);
2421
2422       my $out = $t->translate( $filename )
2423         or $self->throw_exception ($t->error);
2424
2425       $dest_schema = $t->schema;
2426
2427       $dest_schema->name( $filename )
2428         unless $dest_schema->name;
2429     }
2430
2431     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2432                                                   $dest_schema,   $db,
2433                                                   $sqltargs
2434                                                  );
2435     if(!open $file, ">$difffile") {
2436       $self->throw_exception("Can't write to $difffile ($!)");
2437       next;
2438     }
2439     print $file $diff;
2440     close($file);
2441   }
2442 }
2443
2444 =head2 deployment_statements
2445
2446 =over 4
2447
2448 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2449
2450 =back
2451
2452 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2453
2454 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2455 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2456
2457 C<$directory> is used to return statements from files in a previously created
2458 L</create_ddl_dir> directory and is optional. The filenames are constructed
2459 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2460
2461 If no C<$directory> is specified then the statements are constructed on the
2462 fly using L<SQL::Translator> and C<$version> is ignored.
2463
2464 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2465
2466 =cut
2467
2468 sub deployment_statements {
2469   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2470   $type ||= $self->sqlt_type;
2471   $version ||= $schema->schema_version || '1.x';
2472   $dir ||= './';
2473   my $filename = $schema->ddl_filename($type, $version, $dir);
2474   if(-f $filename)
2475   {
2476       my $file;
2477       open($file, "<$filename")
2478         or $self->throw_exception("Can't open $filename ($!)");
2479       my @rows = <$file>;
2480       close($file);
2481       return join('', @rows);
2482   }
2483
2484   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2485     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2486   }
2487
2488   # sources needs to be a parser arg, but for simplicty allow at top level
2489   # coming in
2490   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2491       if exists $sqltargs->{sources};
2492
2493   my $tr = SQL::Translator->new(
2494     producer => "SQL::Translator::Producer::${type}",
2495     %$sqltargs,
2496     parser => 'SQL::Translator::Parser::DBIx::Class',
2497     data => $schema,
2498   );
2499
2500   my @ret;
2501   my $wa = wantarray;
2502   if ($wa) {
2503     @ret = $tr->translate;
2504   }
2505   else {
2506     $ret[0] = $tr->translate;
2507   }
2508
2509   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2510     unless (@ret && defined $ret[0]);
2511
2512   return $wa ? @ret : $ret[0];
2513 }
2514
2515 sub deploy {
2516   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2517   my $deploy = sub {
2518     my $line = shift;
2519     return if($line =~ /^--/);
2520     return if(!$line);
2521     # next if($line =~ /^DROP/m);
2522     return if($line =~ /^BEGIN TRANSACTION/m);
2523     return if($line =~ /^COMMIT/m);
2524     return if $line =~ /^\s+$/; # skip whitespace only
2525     $self->_query_start($line);
2526     eval {
2527       # do a dbh_do cycle here, as we need some error checking in
2528       # place (even though we will ignore errors)
2529       $self->dbh_do (sub { $_[1]->do($line) });
2530     };
2531     if ($@) {
2532       carp qq{$@ (running "${line}")};
2533     }
2534     $self->_query_end($line);
2535   };
2536   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2537   if (@statements > 1) {
2538     foreach my $statement (@statements) {
2539       $deploy->( $statement );
2540     }
2541   }
2542   elsif (@statements == 1) {
2543     foreach my $line ( split(";\n", $statements[0])) {
2544       $deploy->( $line );
2545     }
2546   }
2547 }
2548
2549 =head2 datetime_parser
2550
2551 Returns the datetime parser class
2552
2553 =cut
2554
2555 sub datetime_parser {
2556   my $self = shift;
2557   return $self->{datetime_parser} ||= do {
2558     $self->build_datetime_parser(@_);
2559   };
2560 }
2561
2562 =head2 datetime_parser_type
2563
2564 Defines (returns) the datetime parser class - currently hardwired to
2565 L<DateTime::Format::MySQL>
2566
2567 =cut
2568
2569 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2570
2571 =head2 build_datetime_parser
2572
2573 See L</datetime_parser>
2574
2575 =cut
2576
2577 sub build_datetime_parser {
2578   my $self = shift;
2579   my $type = $self->datetime_parser_type(@_);
2580   $self->ensure_class_loaded ($type);
2581   return $type;
2582 }
2583
2584
2585 =head2 is_replicating
2586
2587 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2588 replicate from a master database.  Default is undef, which is the result
2589 returned by databases that don't support replication.
2590
2591 =cut
2592
2593 sub is_replicating {
2594     return;
2595
2596 }
2597
2598 =head2 lag_behind_master
2599
2600 Returns a number that represents a certain amount of lag behind a master db
2601 when a given storage is replicating.  The number is database dependent, but
2602 starts at zero and increases with the amount of lag. Default in undef
2603
2604 =cut
2605
2606 sub lag_behind_master {
2607     return;
2608 }
2609
2610 =head2 relname_to_table_alias
2611
2612 =over 4
2613
2614 =item Arguments: $relname, $join_count
2615
2616 =back
2617
2618 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2619 queries.
2620
2621 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2622 way these aliases are named.
2623
2624 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2625 otherwise C<"$relname">.
2626
2627 =cut
2628
2629 sub relname_to_table_alias {
2630   my ($self, $relname, $join_count) = @_;
2631
2632   my $alias = ($join_count && $join_count > 1 ?
2633     join('_', $relname, $join_count) : $relname);
2634
2635   return $alias;
2636 }
2637
2638 sub DESTROY {
2639   my $self = shift;
2640
2641   $self->_verify_pid if $self->_dbh;
2642
2643   # some databases need this to stop spewing warnings
2644   if (my $dbh = $self->_dbh) {
2645     local $@;
2646     eval {
2647       %{ $dbh->{CachedKids} } = ();
2648       $dbh->disconnect;
2649     };
2650   }
2651
2652   $self->_dbh(undef);
2653 }
2654
2655 1;
2656
2657 =head1 USAGE NOTES
2658
2659 =head2 DBIx::Class and AutoCommit
2660
2661 DBIx::Class can do some wonderful magic with handling exceptions,
2662 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2663 (the default) combined with C<txn_do> for transaction support.
2664
2665 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2666 in an assumed transaction between commits, and you're telling us you'd
2667 like to manage that manually.  A lot of the magic protections offered by
2668 this module will go away.  We can't protect you from exceptions due to database
2669 disconnects because we don't know anything about how to restart your
2670 transactions.  You're on your own for handling all sorts of exceptional
2671 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2672 be with raw DBI.
2673
2674
2675 =head1 AUTHORS
2676
2677 Matt S. Trout <mst@shadowcatsystems.co.uk>
2678
2679 Andy Grundman <andy@hybridized.org>
2680
2681 =head1 LICENSE
2682
2683 You may distribute this code under the same terms as Perl itself.
2684
2685 =cut