lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   local $self->{having_bind} = [];
  21   my ($sql, @ret) = $self->SUPER::select($table,
  22                       $self->_recurse_fields($fields), $where, $order, @rest);
  23   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  24 }
  25
  26 sub _emulate_limit {
  27   my $self = shift;
  28   if ($_[3] == -1) {
  29     return $_[1].$self->_order_by($_[2]);
  30   } else {
  31     return $self->SUPER::_emulate_limit(@_);
  32   }
  33 }
  34
  35 sub _recurse_fields {
  36   my ($self, $fields) = @_;
  37   my $ref = ref $fields;
  38   return $self->_quote($fields) unless $ref;
  39   return $$fields if $ref eq 'SCALAR';
  40
  41   if ($ref eq 'ARRAY') {
  42     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  43   } elsif ($ref eq 'HASH') {
  44     foreach my $func (keys %$fields) {
  45       return $self->_sqlcase($func)
  46         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  47     }
  48   }
  49 }
  50
  51 sub _order_by {
  52   my $self = shift;
  53   my $ret = '';
  54   my @extra;
  55   if (ref $_[0] eq 'HASH') {
  56     if (defined $_[0]->{group_by}) {
  57       $ret = $self->_sqlcase(' group by ')
  58                .$self->_recurse_fields($_[0]->{group_by});
  59     }
  60     if (defined $_[0]->{having}) {
  61       my $frag;
  62       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  63       push(@{$self->{having_bind}}, @extra);
  64       $ret .= $self->_sqlcase(' having ').$frag;
  65     }
  66     if (defined $_[0]->{order_by}) {
  67       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  68     }
  69   } else {
  70     $ret = $self->SUPER::_order_by(@_);
  71   }
  72   return $ret;
  73 }
  74
  75 sub _order_directions {
  76   my ($self, $order) = @_;
  77   $order = $order->{order_by} if ref $order eq 'HASH';
  78   return $self->SUPER::_order_directions($order);
  79 }
  80
  81 sub _table {
  82   my ($self, $from) = @_;
  83   if (ref $from eq 'ARRAY') {
  84     return $self->_recurse_from(@$from);
  85   } elsif (ref $from eq 'HASH') {
  86     return $self->_make_as($from);
  87   } else {
  88     return $from;
  89   }
  90 }
  91
  92 sub _recurse_from {
  93   my ($self, $from, @join) = @_;
  94   my @sqlf;
  95   push(@sqlf, $self->_make_as($from));
  96   foreach my $j (@join) {
  97     my ($to, $on) = @$j;
  98
  99     # check whether a join type exists
 100     my $join_clause = '';
 101     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 102       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 103     } else {
 104       $join_clause = ' JOIN ';
 105     }
 106     push(@sqlf, $join_clause);
 107
 108     if (ref $to eq 'ARRAY') {
 109       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 110     } else {
 111       push(@sqlf, $self->_make_as($to));
 112     }
 113     push(@sqlf, ' ON ', $self->_join_condition($on));
 114   }
 115   return join('', @sqlf);
 116 }
 117
 118 sub _make_as {
 119   my ($self, $from) = @_;
 120   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 121                            reverse each %{$self->_skip_options($from)});
 122 }
 123
 124 sub _skip_options {
 125   my ($self, $hash) = @_;
 126   my $clean_hash = {};
 127   $clean_hash->{$_} = $hash->{$_}
 128     for grep {!/^-/} keys %$hash;
 129   return $clean_hash;
 130 }
 131
 132 sub _join_condition {
 133   my ($self, $cond) = @_;
 134   if (ref $cond eq 'HASH') {
 135     my %j;
 136     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 137     return $self->_recurse_where(\%j);
 138   } elsif (ref $cond eq 'ARRAY') {
 139     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 140   } else {
 141     die "Can't handle this yet!";
 142   }
 143 }
 144
 145 sub _quote {
 146   my ($self, $label) = @_;
 147   return '' unless defined $label;
 148   return $label unless $self->{quote_char};
 149   return $self->SUPER::_quote($label);
 150 }
 151
 152 sub _RowNum {
 153    my $self = shift;
 154    my $c;
 155    $_[0] =~ s/SELECT (.*?) FROM/
 156      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 157    $self->SUPER::_RowNum(@_);
 158 }
 159
 160 # Accessor for setting limit dialect. This is useful
 161 # for JDBC-bridge among others where the remote SQL-dialect cannot
 162 # be determined by the name of the driver alone.
 163 #
 164 sub limit_dialect {
 165     my $self = shift;
 166     $self->{limit_dialect} = shift if @_;
 167     return $self->{limit_dialect};
 168 }
 169
 170 package DBIx::Class::Storage::DBI::DebugCallback;
 171
 172 sub print {
 173   my ($self, $string) = @_;
 174   $string =~ m/^(\w+)/;
 175   ${$self}->($1, $string);
 176 }
 177
 178 } # End of BEGIN block
 179
 180 use base qw/DBIx::Class/;
 181
 182 __PACKAGE__->load_components(qw/AccessorGroup/);
 183
 184 __PACKAGE__->mk_group_accessors('simple' =>
 185   qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
 186      on_connect_do transaction_depth/);
 187
 188 sub new {
 189   my $new = bless({}, ref $_[0] || $_[0]);
 190   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 191   $new->transaction_depth(0);
 192   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 193      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 194     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 195   } else {
 196     $new->debugfh(IO::File->new('>&STDERR'));
 197   }
 198   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 199   return $new;
 200 }
 201
 202 =head1 NAME
 203
 204 DBIx::Class::Storage::DBI - DBI storage handler
 205
 206 =head1 SYNOPSIS
 207
 208 =head1 DESCRIPTION
 209
 210 This class represents the connection to the database
 211
 212 =head1 METHODS
 213
 214 =cut
 215
 216 =head2 on_connect_do
 217
 218 Executes the sql statements given as a listref on every db connect.
 219
 220 =head2 debug
 221
 222 Causes SQL trace information to be emitted on C<debugfh> filehandle
 223 (or C<STDERR> if C<debugfh> has not specifically been set).
 224
 225 =head2 debugfh
 226
 227 Sets or retrieves the filehandle used for trace/debug output.  This
 228 should be an IO::Handle compatible object (only the C<print> method is
 229 used).  Initially set to be STDERR - although see information on the
 230 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 231
 232 =head2 debugcb
 233
 234 Sets a callback to be executed each time a statement is run; takes a sub
 235 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 236 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 237 be printed.
 238
 239 =cut
 240
 241 sub debugcb {
 242   my ($self, $cb) = @_;
 243   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 244   $self->debugfh($cb_obj);
 245 }
 246
 247 sub disconnect {
 248   my ($self) = @_;
 249
 250   if( $self->connected ) {
 251     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 252     $self->_dbh->disconnect;
 253     $self->_dbh(undef);
 254   }
 255 }
 256
 257 sub connected {
 258   my ($self) = @_;
 259
 260   my $dbh;
 261   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 262 }
 263
 264 sub ensure_connected {
 265   my ($self) = @_;
 266
 267   unless ($self->connected) {
 268     $self->_populate_dbh;
 269   }
 270 }
 271
 272 sub dbh {
 273   my ($self) = @_;
 274
 275   $self->_dbh(undef)
 276     if $self->_connection_pid && $self->_connection_pid != $$;
 277   $self->ensure_connected;
 278   return $self->_dbh;
 279 }
 280
 281 sub sql_maker {
 282   my ($self) = @_;
 283   unless ($self->_sql_maker) {
 284     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 285   }
 286   return $self->_sql_maker;
 287 }
 288
 289 sub _populate_dbh {
 290   my ($self) = @_;
 291   my @info = @{$self->connect_info || []};
 292   $self->_dbh($self->_connect(@info));
 293   my $driver = $self->_dbh->{Driver}->{Name};
 294   eval "require DBIx::Class::Storage::DBI::${driver}";
 295   unless ($@) {
 296     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 297   }
 298   # if on-connect sql statements are given execute them
 299   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 300     $self->_dbh->do($sql_statement);
 301   }
 302
 303   $self->_connection_pid($$);
 304 }
 305
 306 sub _connect {
 307   my ($self, @info) = @_;
 308
 309   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 310       my $old_connect_via = $DBI::connect_via;
 311       $DBI::connect_via = 'connect';
 312       my $dbh = DBI->connect(@info);
 313       $DBI::connect_via = $old_connect_via;
 314       return $dbh;
 315   }
 316
 317   my $dbh = DBI->connect(@info);
 318   croak "DBI Connection failed: $DBI::errstr"
 319       unless $dbh;
 320   $dbh;
 321 }
 322
 323 =head2 txn_begin
 324
 325 Calls begin_work on the current dbh.
 326
 327 =cut
 328
 329 sub txn_begin {
 330   my $self = shift;
 331   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 332 }
 333
 334 =head2 txn_commit
 335
 336 Issues a commit against the current dbh.
 337
 338 =cut
 339
 340 sub txn_commit {
 341   my $self = shift;
 342   if ($self->{transaction_depth} == 0) {
 343     $self->dbh->commit unless $self->dbh->{AutoCommit};
 344   }
 345   else {
 346     $self->dbh->commit if --$self->{transaction_depth} == 0;
 347   }
 348 }
 349
 350 =head2 txn_rollback
 351
 352 Issues a rollback against the current dbh.
 353
 354 =cut
 355
 356 sub txn_rollback {
 357   my $self = shift;
 358   if ($self->{transaction_depth} == 0) {
 359     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 360   }
 361   else {
 362     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 363   }
 364 }
 365
 366 sub _execute {
 367   my ($self, $op, $extra_bind, $ident, @args) = @_;
 368   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 369   unshift(@bind, @$extra_bind) if $extra_bind;
 370   if ($self->debug) {
 371       my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
 372       $self->debugfh->print("$sql: @debug_bind\n");
 373   }
 374   my $sth = $self->sth($sql,$op);
 375   croak "no sth generated via sql: $sql" unless $sth;
 376   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 377   my $rv;
 378   if ($sth) {
 379     $rv = $sth->execute(@bind);
 380   } else {
 381     croak "'$sql' did not generate a statement.";
 382   }
 383   return (wantarray ? ($rv, $sth, @bind) : $rv);
 384 }
 385
 386 sub insert {
 387   my ($self, $ident, $to_insert) = @_;
 388   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 389     unless ($self->_execute('insert' => [], $ident, $to_insert));
 390   return $to_insert;
 391 }
 392
 393 sub update {
 394   return shift->_execute('update' => [], @_);
 395 }
 396
 397 sub delete {
 398   return shift->_execute('delete' => [], @_);
 399 }
 400
 401 sub _select {
 402   my ($self, $ident, $select, $condition, $attrs) = @_;
 403   my $order = $attrs->{order_by};
 404   if (ref $condition eq 'SCALAR') {
 405     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 406   }
 407   if (exists $attrs->{group_by} || $attrs->{having}) {
 408     $order = { group_by => $attrs->{group_by},
 409                having => $attrs->{having},
 410                ($order ? (order_by => $order) : ()) };
 411   }
 412   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 413   if ($attrs->{software_limit} ||
 414       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 415         $attrs->{software_limit} = 1;
 416   } else {
 417     push @args, $attrs->{rows}, $attrs->{offset};
 418   }
 419   return $self->_execute(@args);
 420 }
 421
 422 sub select {
 423   my $self = shift;
 424   my ($ident, $select, $condition, $attrs) = @_;
 425   return $self->cursor->new($self, \@_, $attrs);
 426 }
 427
 428 # Need to call finish() to work round broken DBDs
 429
 430 sub select_single {
 431   my $self = shift;
 432   my ($rv, $sth, @bind) = $self->_select(@_);
 433   my @row = $sth->fetchrow_array;
 434   $sth->finish();
 435   return @row;
 436 }
 437
 438 sub sth {
 439   my ($self, $sql) = @_;
 440   # 3 is the if_active parameter which avoids active sth re-use
 441   return $self->dbh->prepare_cached($sql, {}, 3);
 442 }
 443
 444 =head2 columns_info_for
 445
 446 Returns database type info for a given table columns.
 447
 448 =cut
 449
 450 sub columns_info_for {
 451     my ($self, $table) = @_;
 452     my %result;
 453     if ( $self->dbh->can( 'column_info' ) ){
 454         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 455         $sth->execute();
 456         while ( my $info = $sth->fetchrow_hashref() ){
 457             my %column_info;
 458             $column_info{data_type} = $info->{TYPE_NAME};
 459             $column_info{size} = $info->{COLUMN_SIZE};
 460             $column_info{is_nullable} = $info->{NULLABLE};
 461             $result{$info->{COLUMN_NAME}} = \%column_info;
 462         }
 463     }else{
 464         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 465         $sth->execute;
 466         my @columns = @{$sth->{NAME}};
 467         for my $i ( 0 .. $#columns ){
 468             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 469         }
 470     }
 471     return \%result;
 472 }
 473
 474 sub last_insert_id {
 475   my ($self, $row) = @_;
 476
 477   return $self->dbh->func('last_insert_rowid');
 478
 479 }
 480
 481
 482
 483 sub DESTROY { shift->disconnect }
 484
 485 1;
 486
 487 =head1 ENVIRONMENT VARIABLES
 488
 489 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 490
 491 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 492 is produced (as when the L<debug> method is set).
 493
 494 If the value is of the form C<1=/path/name> then the trace output is
 495 written to the file C</path/name>.
 496
 497 =head1 AUTHORS
 498
 499 Matt S. Trout <mst@shadowcatsystems.co.uk>
 500
 501 Andy Grundman <andy@hybridized.org>
 502
 503 =head1 LICENSE
 504
 505 You may distribute this code under the same terms as Perl itself.
 506
 507 =cut
 508