lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(
  17   quote_sub perlstring serialize
  18   dbic_internal_try
  19   detected_reinvoked_destructor scope_guard
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228   }
 229
 230   END {
 231
 232     if(
 233       ! DBIx::Class::_ENV_::BROKEN_FORK
 234         and
 235       my @instances = grep { defined $_ } values %seek_and_destroy
 236     ) {
 237       local $?; # just in case the DBI destructor changes it somehow
 238
 239       # disarm the handle if not native to this process (see comment on top)
 240       $_->_verify_pid for @instances;
 241     }
 242   }
 243
 244   sub CLONE {
 245     # As per DBI's recommendation, DBIC disconnects all handles as
 246     # soon as possible (DBIC will reconnect only on demand from within
 247     # the thread)
 248     my @instances = grep { defined $_ } values %seek_and_destroy;
 249     %seek_and_destroy = ();
 250
 251     for (@instances) {
 252       $_->_dbh(undef);
 253       $_->disconnect;
 254
 255       # properly renumber existing refs
 256       $_->_arm_global_destructor
 257     }
 258   }
 259 }
 260
 261 sub DESTROY {
 262   return if &detected_reinvoked_destructor;
 263
 264   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 265
 266   # some databases spew warnings on implicit disconnect
 267   return unless defined $_[0]->_dbh;
 268
 269   local $SIG{__WARN__} = sub {};
 270   $_[0]->_dbh(undef);
 271   # not calling ->disconnect here - we are being destroyed - nothing to reset
 272
 273   # this op is necessary, since the very last perl runtime statement
 274   # triggers a global destruction shootout, and the $SIG localization
 275   # may very well be destroyed before perl actually gets to do the
 276   # $dbh undef
 277   1;
 278 }
 279
 280 # handle pid changes correctly - do not destroy parent's connection
 281 sub _verify_pid {
 282
 283   my $pid = $_[0]->_conn_pid;
 284
 285   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 286     $dbh->{InactiveDestroy} = 1;
 287     $_[0]->_dbh(undef);
 288     $_[0]->disconnect;
 289   }
 290
 291   return;
 292 }
 293
 294 =head2 connect_info
 295
 296 This method is normally called by L<DBIx::Class::Schema/connection>, which
 297 encapsulates its argument list in an arrayref before passing them here.
 298
 299 The argument list may contain:
 300
 301 =over
 302
 303 =item *
 304
 305 The same 4-element argument set one would normally pass to
 306 L<DBI/connect>, optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes>
 308 recognized by DBIx::Class:
 309
 310   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single code reference which returns a connected
 315 L<DBI database handle|DBI/connect> optionally followed by
 316 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 317 by DBIx::Class:
 318
 319   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 320
 321 =item *
 322
 323 A single hashref with all the attributes and the dsn/user/password
 324 mixed together:
 325
 326   $connect_info_args = [{
 327     dsn => $dsn,
 328     user => $user,
 329     password => $pass,
 330     %dbi_attributes,
 331     %extra_attributes,
 332   }];
 333
 334   $connect_info_args = [{
 335     dbh_maker => sub { DBI->connect (...) },
 336     %dbi_attributes,
 337     %extra_attributes,
 338   }];
 339
 340 This is particularly useful for L<Catalyst> based applications, allowing the
 341 following config (L<Config::General> style):
 342
 343   <Model::DB>
 344     schema_class   App::DB
 345     <connect_info>
 346       dsn          dbi:mysql:database=test
 347       user         testuser
 348       password     TestPass
 349       AutoCommit   1
 350     </connect_info>
 351   </Model::DB>
 352
 353 The C<dsn>/C<user>/C<password> combination can be substituted by the
 354 C<dbh_maker> key whose value is a coderef that returns a connected
 355 L<DBI database handle|DBI/connect>
 356
 357 =back
 358
 359 Please note that the L<DBI> docs recommend that you always explicitly
 360 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 361 recommends that it be set to I<1>, and that you perform transactions
 362 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 363 to I<1> if you do not do explicitly set it to zero.  This is the default
 364 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 365
 366 =head3 DBIx::Class specific connection attributes
 367
 368 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 369 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 370 the following connection options. These options can be mixed in with your other
 371 L<DBI> connection attributes, or placed in a separate hashref
 372 (C<\%extra_attributes>) as shown above.
 373
 374 Every time C<connect_info> is invoked, any previous settings for
 375 these options will be cleared before setting the new ones, regardless of
 376 whether any options are specified in the new C<connect_info>.
 377
 378
 379 =over
 380
 381 =item on_connect_do
 382
 383 Specifies things to do immediately after connecting or re-connecting to
 384 the database.  Its value may contain:
 385
 386 =over
 387
 388 =item a scalar
 389
 390 This contains one SQL statement to execute.
 391
 392 =item an array reference
 393
 394 This contains SQL statements to execute in order.  Each element contains
 395 a string or a code reference that returns a string.
 396
 397 =item a code reference
 398
 399 This contains some code to execute.  Unlike code references within an
 400 array reference, its return value is ignored.
 401
 402 =back
 403
 404 =item on_disconnect_do
 405
 406 Takes arguments in the same form as L</on_connect_do> and executes them
 407 immediately before disconnecting from the database.
 408
 409 Note, this only runs if you explicitly call L</disconnect> on the
 410 storage object.
 411
 412 =item on_connect_call
 413
 414 A more generalized form of L</on_connect_do> that calls the specified
 415 C<connect_call_METHOD> methods in your storage driver.
 416
 417   on_connect_do => 'select 1'
 418
 419 is equivalent to:
 420
 421   on_connect_call => [ [ do_sql => 'select 1' ] ]
 422
 423 Its values may contain:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will call the C<connect_call_METHOD> method.
 430
 431 =item a code reference
 432
 433 Will execute C<< $code->($storage) >>
 434
 435 =item an array reference
 436
 437 Each value can be a method name or code reference.
 438
 439 =item an array of arrays
 440
 441 For each array, the first item is taken to be the C<connect_call_> method name
 442 or code reference, and the rest are parameters to it.
 443
 444 =back
 445
 446 Some predefined storage methods you may use:
 447
 448 =over
 449
 450 =item do_sql
 451
 452 Executes a SQL string or a code reference that returns a SQL string. This is
 453 what L</on_connect_do> and L</on_disconnect_do> use.
 454
 455 It can take:
 456
 457 =over
 458
 459 =item a scalar
 460
 461 Will execute the scalar as SQL.
 462
 463 =item an arrayref
 464
 465 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 466 attributes hashref and bind values.
 467
 468 =item a code reference
 469
 470 Will execute C<< $code->($storage) >> and execute the return array refs as
 471 above.
 472
 473 =back
 474
 475 =item datetime_setup
 476
 477 Execute any statements necessary to initialize the database session to return
 478 and accept datetime/timestamp values used with
 479 L<DBIx::Class::InflateColumn::DateTime>.
 480
 481 Only necessary for some databases, see your specific storage driver for
 482 implementation details.
 483
 484 =back
 485
 486 =item on_disconnect_call
 487
 488 Takes arguments in the same form as L</on_connect_call> and executes them
 489 immediately before disconnecting from the database.
 490
 491 Calls the C<disconnect_call_METHOD> methods as opposed to the
 492 C<connect_call_METHOD> methods called by L</on_connect_call>.
 493
 494 Note, this only runs if you explicitly call L</disconnect> on the
 495 storage object.
 496
 497 =item disable_sth_caching
 498
 499 If set to a true value, this option will disable the caching of
 500 statement handles via L<DBI/prepare_cached>.
 501
 502 =item limit_dialect
 503
 504 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 505 default L</sql_limit_dialect> setting of the storage (if any). For a list
 506 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 507
 508 =item quote_names
 509
 510 When true automatically sets L</quote_char> and L</name_sep> to the characters
 511 appropriate for your particular RDBMS. This option is preferred over specifying
 512 L</quote_char> directly.
 513
 514 =item quote_char
 515
 516 Specifies what characters to use to quote table and column names.
 517
 518 C<quote_char> expects either a single character, in which case is it
 519 is placed on either side of the table/column name, or an arrayref of length
 520 2 in which case the table/column name is placed between the elements.
 521
 522 For example under MySQL you should use C<< quote_char => '`' >>, and for
 523 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 524
 525 =item name_sep
 526
 527 This parameter is only useful in conjunction with C<quote_char>, and is used to
 528 specify the character that separates elements (schemas, tables, columns) from
 529 each other. If unspecified it defaults to the most commonly used C<.>.
 530
 531 =item unsafe
 532
 533 This Storage driver normally installs its own C<HandleError>, sets
 534 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 535 all database handles, including those supplied by a coderef.  It does this
 536 so that it can have consistent and useful error behavior.
 537
 538 If you set this option to a true value, Storage will not do its usual
 539 modifications to the database handle's attributes, and instead relies on
 540 the settings in your connect_info DBI options (or the values you set in
 541 your connection coderef, in the case that you are connecting via coderef).
 542
 543 Note that your custom settings can cause Storage to malfunction,
 544 especially if you set a C<HandleError> handler that suppresses exceptions
 545 and/or disable C<RaiseError>.
 546
 547 =item auto_savepoint
 548
 549 If this option is true, L<DBIx::Class> will use savepoints when nesting
 550 transactions, making it possible to recover from failure in the inner
 551 transaction without having to abort all outer transactions.
 552
 553 =item cursor_class
 554
 555 Use this argument to supply a cursor class other than the default
 556 L<DBIx::Class::Storage::DBI::Cursor>.
 557
 558 =back
 559
 560 Some real-life examples of arguments to L</connect_info> and
 561 L<DBIx::Class::Schema/connect>
 562
 563   # Simple SQLite connection
 564   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 565
 566   # Connect via subref
 567   ->connect_info([ sub { DBI->connect(...) } ]);
 568
 569   # Connect via subref in hashref
 570   ->connect_info([{
 571     dbh_maker => sub { DBI->connect(...) },
 572     on_connect_do => 'alter session ...',
 573   }]);
 574
 575   # A bit more complicated
 576   ->connect_info(
 577     [
 578       'dbi:Pg:dbname=foo',
 579       'postgres',
 580       'my_pg_password',
 581       { AutoCommit => 1 },
 582       { quote_char => q{"} },
 583     ]
 584   );
 585
 586   # Equivalent to the previous example
 587   ->connect_info(
 588     [
 589       'dbi:Pg:dbname=foo',
 590       'postgres',
 591       'my_pg_password',
 592       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 593     ]
 594   );
 595
 596   # Same, but with hashref as argument
 597   # See parse_connect_info for explanation
 598   ->connect_info(
 599     [{
 600       dsn         => 'dbi:Pg:dbname=foo',
 601       user        => 'postgres',
 602       password    => 'my_pg_password',
 603       AutoCommit  => 1,
 604       quote_char  => q{"},
 605       name_sep    => q{.},
 606     }]
 607   );
 608
 609   # Subref + DBIx::Class-specific connection options
 610   ->connect_info(
 611     [
 612       sub { DBI->connect(...) },
 613       {
 614           quote_char => q{`},
 615           name_sep => q{@},
 616           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 617           disable_sth_caching => 1,
 618       },
 619     ]
 620   );
 621
 622
 623
 624 =cut
 625
 626 sub connect_info {
 627   my ($self, $info) = @_;
 628
 629   return $self->_connect_info if !$info;
 630
 631   $self->_connect_info($info); # copy for _connect_info
 632
 633   $info = $self->_normalize_connect_info($info)
 634     if ref $info eq 'ARRAY';
 635
 636   my %attrs = (
 637     %{ $self->_default_dbi_connect_attributes || {} },
 638     %{ $info->{attributes} || {} },
 639   );
 640
 641   my @args = @{ $info->{arguments} };
 642
 643   if (keys %attrs and ref $args[0] ne 'CODE') {
 644     carp_unique (
 645         'You provided explicit AutoCommit => 0 in your connection_info. '
 646       . 'This is almost universally a bad idea (see the footnotes of '
 647       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 648       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 649       . 'this warning.'
 650     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 651
 652     push @args, \%attrs if keys %attrs;
 653   }
 654
 655   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 656   # OR a single-element coderef-based $dbh factory
 657   $self->_dbi_connect_info(\@args);
 658
 659   # extract the individual storage options
 660   for my $storage_opt (keys %{ $info->{storage_options} }) {
 661     my $value = $info->{storage_options}{$storage_opt};
 662
 663     $self->$storage_opt($value);
 664   }
 665
 666   # Extract the individual sqlmaker options
 667   #
 668   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 669   #  the new set of options
 670   $self->_sql_maker(undef);
 671   $self->_sql_maker_opts({});
 672
 673   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 674     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 675
 676     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 677   }
 678
 679   # FIXME - dirty:
 680   # save attributes in a separate accessor so they are always
 681   # introspectable, even in case of a CODE $dbhmaker
 682   $self->_dbic_connect_attributes (\%attrs);
 683
 684   return $self->_connect_info;
 685 }
 686
 687 sub _dbi_connect_info {
 688   my $self = shift;
 689
 690   return $self->{_dbi_connect_info} = $_[0]
 691     if @_;
 692
 693   my $conninfo = $self->{_dbi_connect_info} || [];
 694
 695   # last ditch effort to grab a DSN
 696   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 697     my @new_conninfo = @$conninfo;
 698     $new_conninfo[0] = $ENV{DBI_DSN};
 699     $conninfo = \@new_conninfo;
 700   }
 701
 702   return $conninfo;
 703 }
 704
 705
 706 sub _normalize_connect_info {
 707   my ($self, $info_arg) = @_;
 708   my %info;
 709
 710   my @args = @$info_arg;  # take a shallow copy for further mutilation
 711
 712   # combine/pre-parse arguments depending on invocation style
 713
 714   my %attrs;
 715   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 716     %attrs = %{ $args[1] || {} };
 717     @args = $args[0];
 718   }
 719   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 720     %attrs = %{$args[0]};
 721     @args = ();
 722     if (my $code = delete $attrs{dbh_maker}) {
 723       @args = $code;
 724
 725       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 726       if (@ignored) {
 727         carp sprintf (
 728             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 729           . "to the result of 'dbh_maker'",
 730
 731           join (', ', map { "'$_'" } (@ignored) ),
 732         );
 733       }
 734     }
 735     else {
 736       @args = delete @attrs{qw/dsn user password/};
 737     }
 738   }
 739   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 740     %attrs = (
 741       % { $args[3] || {} },
 742       % { $args[4] || {} },
 743     );
 744     @args = @args[0,1,2];
 745   }
 746
 747   $info{arguments} = \@args;
 748
 749   my @storage_opts = grep exists $attrs{$_},
 750     @storage_options, 'cursor_class';
 751
 752   @{ $info{storage_options} }{@storage_opts} =
 753     delete @attrs{@storage_opts} if @storage_opts;
 754
 755   my @sql_maker_opts = grep exists $attrs{$_},
 756     qw/limit_dialect quote_char name_sep quote_names/;
 757
 758   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 759     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 760
 761   $info{attributes} = \%attrs if %attrs;
 762
 763   return \%info;
 764 }
 765
 766 sub _default_dbi_connect_attributes () {
 767   +{
 768     AutoCommit => 1,
 769     PrintError => 0,
 770     RaiseError => 1,
 771     ShowErrorStatement => 1,
 772   };
 773 }
 774
 775 =head2 on_connect_do
 776
 777 This method is deprecated in favour of setting via L</connect_info>.
 778
 779 =cut
 780
 781 =head2 on_disconnect_do
 782
 783 This method is deprecated in favour of setting via L</connect_info>.
 784
 785 =cut
 786
 787 sub _parse_connect_do {
 788   my ($self, $type) = @_;
 789
 790   my $val = $self->$type;
 791   return () if not defined $val;
 792
 793   my @res;
 794
 795   if (not ref($val)) {
 796     push @res, [ 'do_sql', $val ];
 797   } elsif (ref($val) eq 'CODE') {
 798     push @res, $val;
 799   } elsif (ref($val) eq 'ARRAY') {
 800     push @res, map { [ 'do_sql', $_ ] } @$val;
 801   } else {
 802     $self->throw_exception("Invalid type for $type: ".ref($val));
 803   }
 804
 805   return \@res;
 806 }
 807
 808 =head2 dbh_do
 809
 810 Arguments: ($subref | $method_name), @extra_coderef_args?
 811
 812 Execute the given $subref or $method_name using the new exception-based
 813 connection management.
 814
 815 The first two arguments will be the storage object that C<dbh_do> was called
 816 on and a database handle to use.  Any additional arguments will be passed
 817 verbatim to the called subref as arguments 2 and onwards.
 818
 819 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 820 exception handling and reconnection (or failover in future subclasses).
 821
 822 Your subref should have no side-effects outside of the database, as
 823 there is the potential for your subref to be partially double-executed
 824 if the database connection was stale/dysfunctional.
 825
 826 Example:
 827
 828   my @stuff = $schema->storage->dbh_do(
 829     sub {
 830       my ($storage, $dbh, @cols) = @_;
 831       my $cols = join(q{, }, @cols);
 832       $dbh->selectrow_array("SELECT $cols FROM foo");
 833     },
 834     @column_list
 835   );
 836
 837 =cut
 838
 839 sub dbh_do {
 840   my $self = shift;
 841   my $run_target = shift; # either a coderef or a method name
 842
 843   # short circuit when we know there is no need for a runner
 844   #
 845   # FIXME - assumption may be wrong
 846   # the rationale for the txn_depth check is that if this block is a part
 847   # of a larger transaction, everything up to that point is screwed anyway
 848   return $self->$run_target($self->_get_dbh, @_)
 849     if $self->{_in_do_block} or $self->transaction_depth;
 850
 851   # take a ref instead of a copy, to preserve @_ aliasing
 852   # semantics within the coderef, but only if needed
 853   # (pseudoforking doesn't like this trick much)
 854   my $args = @_ ? \@_ : [];
 855
 856   DBIx::Class::Storage::BlockRunner->new(
 857     storage => $self,
 858     wrap_txn => 0,
 859     retry_handler => sub {
 860       $_[0]->failed_attempt_count == 1
 861         and
 862       ! $_[0]->storage->connected
 863     },
 864   )->run(sub {
 865     $self->$run_target ($self->_get_dbh, @$args )
 866   });
 867 }
 868
 869 sub txn_do {
 870   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 871   shift->next::method(@_);
 872 }
 873
 874 =head2 disconnect
 875
 876 Our C<disconnect> method also performs a rollback first if the
 877 database is not in C<AutoCommit> mode.
 878
 879 =cut
 880
 881 sub disconnect {
 882   my $self = shift;
 883
 884   # this physical disconnect below might very well throw
 885   # in order to unambiguously reset the state - do the cleanup in guard
 886
 887   my $g = scope_guard {
 888
 889     {
 890       local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 891       eval { $self->_dbh->disconnect };
 892     }
 893
 894     $self->_dbh(undef);
 895     $self->_dbh_details({});
 896     $self->transaction_depth(undef);
 897     $self->_dbh_autocommit(undef);
 898     $self->savepoints([]);
 899
 900     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 901     #$self->_sql_maker(undef); # this may also end up being different
 902   };
 903
 904   if( $self->_dbh ) {
 905
 906     $self->_do_connection_actions(disconnect_call_ => $_) for (
 907       ( $self->on_disconnect_call || () ),
 908       $self->_parse_connect_do ('on_disconnect_do')
 909     );
 910
 911     # stops the "implicit rollback on disconnect" warning
 912     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 913   }
 914 }
 915
 916 =head2 with_deferred_fk_checks
 917
 918 =over 4
 919
 920 =item Arguments: C<$coderef>
 921
 922 =item Return Value: The return value of $coderef
 923
 924 =back
 925
 926 Storage specific method to run the code ref with FK checks deferred or
 927 in MySQL's case disabled entirely.
 928
 929 =cut
 930
 931 # Storage subclasses should override this
 932 sub with_deferred_fk_checks {
 933   #my ($self, $sub) = @_;
 934   $_[1]->();
 935 }
 936
 937 =head2 connected
 938
 939 =over
 940
 941 =item Arguments: none
 942
 943 =item Return Value: 1|0
 944
 945 =back
 946
 947 Verifies that the current database handle is active and ready to execute
 948 an SQL statement (e.g. the connection did not get stale, server is still
 949 answering, etc.) This method is used internally by L</dbh>.
 950
 951 =cut
 952
 953 sub connected {
 954   return 0 unless $_[0]->_seems_connected;
 955
 956   #be on the safe side
 957   local $_[0]->_dbh->{RaiseError} = 1;
 958
 959   return $_[0]->_ping;
 960 }
 961
 962 sub _seems_connected {
 963   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 964
 965   $_[0]->_dbh
 966     and
 967   $_[0]->_dbh->FETCH('Active')
 968     and
 969   return 1;
 970
 971   # explicitly reset all state
 972   $_[0]->disconnect;
 973   return 0;
 974 }
 975
 976 sub _ping {
 977   ($_[0]->_dbh || return 0)->ping;
 978 }
 979
 980 sub ensure_connected {
 981   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 982 }
 983
 984 =head2 dbh
 985
 986 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 987 is guaranteed to be healthy by implicitly calling L</connected>, and if
 988 necessary performing a reconnection before returning. Keep in mind that this
 989 is very B<expensive> on some database engines. Consider using L</dbh_do>
 990 instead.
 991
 992 =cut
 993
 994 sub dbh {
 995   # maybe save a ping call
 996   $_[0]->_dbh
 997     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 998     : $_[0]->_populate_dbh
 999   ;
1000 }
1001
1002 # this is the internal "get dbh or connect (don't check)" method
1003 sub _get_dbh {
1004   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1005   $_[0]->_dbh || $_[0]->_populate_dbh;
1006 }
1007
1008 # *DELIBERATELY* not a setter (for the time being)
1009 # Too intertwined with everything else for any kind of sanity
1010 sub sql_maker {
1011   my $self = shift;
1012
1013   $self->throw_exception('sql_maker() is not a setter method') if @_;
1014
1015   unless ($self->_sql_maker) {
1016     my $sql_maker_class = $self->sql_maker_class;
1017
1018     my %opts = %{$self->_sql_maker_opts||{}};
1019     my $dialect =
1020       $opts{limit_dialect}
1021         ||
1022       $self->sql_limit_dialect
1023         ||
1024       do {
1025         my $s_class = (ref $self) || $self;
1026         carp_unique (
1027           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1028         . 'have not supplied an explicit limit_dialect in your connection_info. '
1029         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1030         . 'databases but can be (and often is) painfully slow. '
1031         . "Please file an RT ticket against '$s_class'"
1032         ) if $self->_dbi_connect_info->[0];
1033
1034         'GenericSubQ';
1035       }
1036     ;
1037
1038     my ($quote_char, $name_sep);
1039
1040     if ($opts{quote_names}) {
1041       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1042         my $s_class = (ref $self) || $self;
1043         carp_unique (
1044           "You requested 'quote_names' but your storage class ($s_class) does "
1045         . 'not explicitly define a default sql_quote_char and you have not '
1046         . 'supplied a quote_char as part of your connection_info. DBIC will '
1047         .q{default to the ANSI SQL standard quote '"', which works most of }
1048         . "the time. Please file an RT ticket against '$s_class'."
1049         );
1050
1051         '"'; # RV
1052       };
1053
1054       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1055     }
1056
1057     $self->_sql_maker($sql_maker_class->new(
1058       bindtype=>'columns',
1059       array_datatypes => 1,
1060       limit_dialect => $dialect,
1061       ($quote_char ? (quote_char => $quote_char) : ()),
1062       name_sep => ($name_sep || '.'),
1063       %opts,
1064     ));
1065   }
1066   return $self->_sql_maker;
1067 }
1068
1069 # nothing to do by default
1070 sub _rebless {}
1071 sub _init {}
1072
1073 sub _populate_dbh {
1074
1075   # reset internal states
1076   # also in case ->connected failed we might get sent here
1077   $_[0]->disconnect;
1078
1079   $_[0]->_dbh($_[0]->_connect);
1080
1081   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1082
1083   $_[0]->_determine_driver;
1084
1085   # Always set the transaction depth on connect, since
1086   #  there is no transaction in progress by definition
1087   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1088
1089   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1090
1091   $_[0]->_dbh;
1092 }
1093
1094 sub _run_connection_actions {
1095
1096   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1097     ( $_[0]->on_connect_call || () ),
1098     $_[0]->_parse_connect_do ('on_connect_do'),
1099   );
1100 }
1101
1102
1103
1104 sub set_use_dbms_capability {
1105   $_[0]->set_inherited ($_[1], $_[2]);
1106 }
1107
1108 sub get_use_dbms_capability {
1109   my ($self, $capname) = @_;
1110
1111   my $use = $self->get_inherited ($capname);
1112   return defined $use
1113     ? $use
1114     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1115   ;
1116 }
1117
1118 sub set_dbms_capability {
1119   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1120 }
1121
1122 sub get_dbms_capability {
1123   my ($self, $capname) = @_;
1124
1125   my $cap = $self->_dbh_details->{capability}{$capname};
1126
1127   unless (defined $cap) {
1128     if (my $meth = $self->can ("_determine$capname")) {
1129       $cap = $self->$meth ? 1 : 0;
1130     }
1131     else {
1132       $cap = 0;
1133     }
1134
1135     $self->set_dbms_capability ($capname, $cap);
1136   }
1137
1138   return $cap;
1139 }
1140
1141 sub _server_info {
1142   my $self = shift;
1143
1144   # FIXME - ideally this needs to be an ||= assignment, and the final
1145   # assignment at the end of this do{} should be gone entirely. However
1146   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1147   $self->_dbh_details->{info} || do {
1148
1149     # this guarantees that problematic conninfo won't be hidden
1150     # by the try{} below
1151     $self->ensure_connected;
1152
1153     my $info = {};
1154
1155     my $server_version = dbic_internal_try {
1156       $self->_get_server_version
1157     } catch {
1158       # driver determination *may* use this codepath
1159       # in which case we must rethrow
1160       $self->throw_exception($_) if $self->{_in_determine_driver};
1161
1162       # $server_version on failure
1163       undef;
1164     };
1165
1166     if (defined $server_version) {
1167       $info->{dbms_version} = $server_version;
1168
1169       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1170       my @verparts = split (/\./, $numeric_version);
1171       if (
1172         @verparts
1173           &&
1174         $verparts[0] <= 999
1175       ) {
1176         # consider only up to 3 version parts, iff not more than 3 digits
1177         my @use_parts;
1178         while (@verparts && @use_parts < 3) {
1179           my $p = shift @verparts;
1180           last if $p > 999;
1181           push @use_parts, $p;
1182         }
1183         push @use_parts, 0 while @use_parts < 3;
1184
1185         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1186       }
1187     }
1188
1189     $self->_dbh_details->{info} = $info;
1190   };
1191 }
1192
1193 sub _get_server_version {
1194   shift->_dbh_get_info('SQL_DBMS_VER');
1195 }
1196
1197 sub _dbh_get_info {
1198   my ($self, $info) = @_;
1199
1200   if ($info =~ /[^0-9]/) {
1201     require DBI::Const::GetInfoType;
1202     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1203     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1204       unless defined $info;
1205   }
1206
1207   $self->_get_dbh->get_info($info);
1208 }
1209
1210 sub _describe_connection {
1211   require DBI::Const::GetInfoReturn;
1212
1213   my $self = shift;
1214
1215   my $drv;
1216   dbic_internal_try {
1217     $drv = $self->_extract_driver_from_connect_info;
1218     $self->ensure_connected;
1219   };
1220
1221   $drv = "DBD::$drv" if $drv;
1222
1223   my $res = {
1224     DBIC_DSN => $self->_dbi_connect_info->[0],
1225     DBI_VER => DBI->VERSION,
1226     DBIC_VER => DBIx::Class->VERSION,
1227     DBIC_DRIVER => ref $self,
1228     $drv ? (
1229       DBD => $drv,
1230       DBD_VER => dbic_internal_try { $drv->VERSION },
1231     ) : (),
1232   };
1233
1234   # try to grab data even if we never managed to connect
1235   # will cover us in cases of an oddly broken half-connect
1236   for my $inf (
1237     #keys %DBI::Const::GetInfoType::GetInfoType,
1238     qw/
1239       SQL_CURSOR_COMMIT_BEHAVIOR
1240       SQL_CURSOR_ROLLBACK_BEHAVIOR
1241       SQL_CURSOR_SENSITIVITY
1242       SQL_DATA_SOURCE_NAME
1243       SQL_DBMS_NAME
1244       SQL_DBMS_VER
1245       SQL_DEFAULT_TXN_ISOLATION
1246       SQL_DM_VER
1247       SQL_DRIVER_NAME
1248       SQL_DRIVER_ODBC_VER
1249       SQL_DRIVER_VER
1250       SQL_EXPRESSIONS_IN_ORDERBY
1251       SQL_GROUP_BY
1252       SQL_IDENTIFIER_CASE
1253       SQL_IDENTIFIER_QUOTE_CHAR
1254       SQL_MAX_CATALOG_NAME_LEN
1255       SQL_MAX_COLUMN_NAME_LEN
1256       SQL_MAX_IDENTIFIER_LEN
1257       SQL_MAX_TABLE_NAME_LEN
1258       SQL_MULTIPLE_ACTIVE_TXN
1259       SQL_MULT_RESULT_SETS
1260       SQL_NEED_LONG_DATA_LEN
1261       SQL_NON_NULLABLE_COLUMNS
1262       SQL_ODBC_VER
1263       SQL_QUALIFIER_NAME_SEPARATOR
1264       SQL_QUOTED_IDENTIFIER_CASE
1265       SQL_TXN_CAPABLE
1266       SQL_TXN_ISOLATION_OPTION
1267     /
1268   ) {
1269     # some drivers barf on things they do not know about instead
1270     # of returning undef
1271     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1272     next unless defined $v;
1273
1274     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1275     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1276     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1277   }
1278
1279   $res;
1280 }
1281
1282 sub _determine_driver {
1283   my ($self) = @_;
1284
1285   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1286     my $started_connected = 0;
1287     local $self->{_in_determine_driver} = 1;
1288
1289     if (ref($self) eq __PACKAGE__) {
1290       my $driver;
1291       if ($self->_dbh) { # we are connected
1292         $driver = $self->_dbh->{Driver}{Name};
1293         $started_connected = 1;
1294       }
1295       else {
1296         $driver = $self->_extract_driver_from_connect_info;
1297       }
1298
1299       if ($driver) {
1300         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1301         if ($self->load_optional_class($storage_class)) {
1302           mro::set_mro($storage_class, 'c3');
1303           bless $self, $storage_class;
1304           $self->_rebless();
1305         }
1306         else {
1307           $self->_warn_undetermined_driver(
1308             'This version of DBIC does not yet seem to supply a driver for '
1309           . "your particular RDBMS and/or connection method ('$driver')."
1310           );
1311         }
1312       }
1313       else {
1314         $self->_warn_undetermined_driver(
1315           'Unable to extract a driver name from connect info - this '
1316         . 'should not have happened.'
1317         );
1318       }
1319     }
1320
1321     $self->_driver_determined(1);
1322
1323     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1324
1325     if ($self->can('source_bind_attributes')) {
1326       $self->throw_exception(
1327         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1328       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1329       . 'If you are not sure how to proceed please contact the development team via '
1330       . DBIx::Class::_ENV_::HELP_URL
1331       );
1332     }
1333
1334     $self->_init; # run driver-specific initializations
1335
1336     $self->_run_connection_actions
1337         if !$started_connected && defined $self->_dbh;
1338   }
1339 }
1340
1341 sub _extract_driver_from_connect_info {
1342   my $self = shift;
1343
1344   my $drv;
1345
1346   # if connect_info is a CODEREF, we have no choice but to connect
1347   if (
1348     ref $self->_dbi_connect_info->[0]
1349       and
1350     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1351   ) {
1352     $self->_populate_dbh;
1353     $drv = $self->_dbh->{Driver}{Name};
1354   }
1355   else {
1356     # try to use dsn to not require being connected, the driver may still
1357     # force a connection later in _rebless to determine version
1358     # (dsn may not be supplied at all if all we do is make a mock-schema)
1359     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1360     $drv ||= $ENV{DBI_DRIVER};
1361   }
1362
1363   return $drv;
1364 }
1365
1366 sub _determine_connector_driver {
1367   my ($self, $conn) = @_;
1368
1369   my $dbtype = $self->_get_rdbms_name;
1370
1371   if (not $dbtype) {
1372     $self->_warn_undetermined_driver(
1373       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1374     . "$conn connector - this should not have happened."
1375     );
1376     return;
1377   }
1378
1379   $dbtype =~ s/\W/_/gi;
1380
1381   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1382   return if $self->isa($subclass);
1383
1384   if ($self->load_optional_class($subclass)) {
1385     bless $self, $subclass;
1386     $self->_rebless;
1387   }
1388   else {
1389     $self->_warn_undetermined_driver(
1390       'This version of DBIC does not yet seem to supply a driver for '
1391     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1392     );
1393   }
1394 }
1395
1396 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1397
1398 sub _warn_undetermined_driver {
1399   my ($self, $msg) = @_;
1400
1401   require Data::Dumper::Concise;
1402
1403   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1404   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1405   . "does not go away, file a bugreport including the following info:\n"
1406   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1407   );
1408 }
1409
1410 sub _do_connection_actions {
1411   my ($self, $method_prefix, $call, @args) = @_;
1412
1413   dbic_internal_try {
1414     if (not ref($call)) {
1415       my $method = $method_prefix . $call;
1416       $self->$method(@args);
1417     }
1418     elsif (ref($call) eq 'CODE') {
1419       $self->$call(@args);
1420     }
1421     elsif (ref($call) eq 'ARRAY') {
1422       if (ref($call->[0]) ne 'ARRAY') {
1423         $self->_do_connection_actions($method_prefix, $_) for @$call;
1424       }
1425       else {
1426         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1427       }
1428     }
1429     else {
1430       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1431     }
1432   }
1433   catch {
1434     if ( $method_prefix =~ /^connect/ ) {
1435       # this is an on_connect cycle - we can't just throw while leaving
1436       # a handle in an undefined state in our storage object
1437       # kill it with fire and rethrow
1438       $self->_dbh(undef);
1439       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1440       $self->throw_exception( $_[0] );
1441     }
1442     else {
1443       carp "Disconnect action failed: $_[0]";
1444     }
1445   };
1446
1447   return $self;
1448 }
1449
1450 sub connect_call_do_sql {
1451   my $self = shift;
1452   $self->_do_query(@_);
1453 }
1454
1455 sub disconnect_call_do_sql {
1456   my $self = shift;
1457   $self->_do_query(@_);
1458 }
1459
1460 =head2 connect_call_datetime_setup
1461
1462 A no-op stub method, provided so that one can always safely supply the
1463 L<connection option|/DBIx::Class specific connection attributes>
1464
1465  on_connect_call => 'datetime_setup'
1466
1467 This way one does not need to know in advance whether the underlying
1468 storage requires any sort of hand-holding when dealing with calendar
1469 data.
1470
1471 =cut
1472
1473 sub connect_call_datetime_setup { 1 }
1474
1475 sub _do_query {
1476   my ($self, $action) = @_;
1477
1478   if (ref $action eq 'CODE') {
1479     $action = $action->($self);
1480     $self->_do_query($_) foreach @$action;
1481   }
1482   else {
1483     # Most debuggers expect ($sql, @bind), so we need to exclude
1484     # the attribute hash which is the second argument to $dbh->do
1485     # furthermore the bind values are usually to be presented
1486     # as named arrayref pairs, so wrap those here too
1487     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1488     my $sql = shift @do_args;
1489     my $attrs = shift @do_args;
1490     my @bind = map { [ undef, $_ ] } @do_args;
1491
1492     $self->dbh_do(sub {
1493       $_[0]->_query_start($sql, \@bind);
1494       $_[1]->do($sql, $attrs, @do_args);
1495       $_[0]->_query_end($sql, \@bind);
1496     });
1497   }
1498
1499   return $self;
1500 }
1501
1502 sub _connect {
1503   my $self = shift;
1504
1505   my $info = $self->_dbi_connect_info;
1506
1507   $self->throw_exception("You did not provide any connection_info")
1508     unless defined $info->[0];
1509
1510   my ($old_connect_via, $dbh);
1511
1512   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1513
1514   # this odd anonymous coderef dereference is in fact really
1515   # necessary to avoid the unwanted effect described in perl5
1516   # RT#75792
1517   #
1518   # in addition the coderef itself can't reside inside the try{} block below
1519   # as it somehow triggers a leak under perl -d
1520   my $dbh_error_handler_installer = sub {
1521     weaken (my $weak_self = $_[0]);
1522
1523     # the coderef is blessed so we can distinguish it from externally
1524     # supplied handles (which must be preserved)
1525     $_[1]->{HandleError} = bless sub {
1526       if ($weak_self) {
1527         $weak_self->throw_exception("DBI Exception: $_[0]");
1528       }
1529       else {
1530         # the handler may be invoked by something totally out of
1531         # the scope of DBIC
1532         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1533       }
1534     }, '__DBIC__DBH__ERROR__HANDLER__';
1535   };
1536
1537   dbic_internal_try {
1538     if(ref $info->[0] eq 'CODE') {
1539       $dbh = $info->[0]->();
1540     }
1541     else {
1542       require DBI;
1543       $dbh = DBI->connect(@$info);
1544     }
1545
1546     die $DBI::errstr unless $dbh;
1547
1548     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1549       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1550       . 'not continue',
1551       ref $info->[0] eq 'CODE'
1552         ? "Connection coderef $info->[0] returned a"
1553         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1554     ) unless $dbh->FETCH('Active');
1555
1556     # sanity checks unless asked otherwise
1557     unless ($self->unsafe) {
1558
1559       $self->throw_exception(
1560         'Refusing clobbering of {HandleError} installed on externally supplied '
1561        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1562       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1563
1564       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1565       # request, or an external handle. Complain and set anyway
1566       unless ($dbh->{RaiseError}) {
1567         carp( ref $info->[0] eq 'CODE'
1568
1569           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1570            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1571            .'attribute has been supplied'
1572
1573           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1574            .'unsafe => 1. Toggling RaiseError back to true'
1575         );
1576
1577         $dbh->{RaiseError} = 1;
1578       }
1579
1580       $dbh_error_handler_installer->($self, $dbh);
1581     }
1582   }
1583   catch {
1584     $self->throw_exception("DBI Connection failed: $_")
1585   };
1586
1587   $self->_dbh_autocommit($dbh->{AutoCommit});
1588   return $dbh;
1589 }
1590
1591 sub txn_begin {
1592   # this means we have not yet connected and do not know the AC status
1593   # (e.g. coderef $dbh), need a full-fledged connection check
1594   if (! defined $_[0]->_dbh_autocommit) {
1595     $_[0]->ensure_connected;
1596   }
1597   # Otherwise simply connect or re-connect on pid changes
1598   else {
1599     $_[0]->_get_dbh;
1600   }
1601
1602   shift->next::method(@_);
1603 }
1604
1605 sub _exec_txn_begin {
1606   my $self = shift;
1607
1608   # if the user is utilizing txn_do - good for him, otherwise we need to
1609   # ensure that the $dbh is healthy on BEGIN.
1610   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1611   # will be replaced by a failure of begin_work itself (which will be
1612   # then retried on reconnect)
1613   if ($self->{_in_do_block}) {
1614     $self->_dbh->begin_work;
1615   } else {
1616     $self->dbh_do(sub { $_[1]->begin_work });
1617   }
1618 }
1619
1620 sub txn_commit {
1621   my $self = shift;
1622
1623   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1624     unless $self->_seems_connected;
1625
1626   # esoteric case for folks using external $dbh handles
1627   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1628     carp "Storage transaction_depth 0 does not match "
1629         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1630     $self->transaction_depth(1);
1631   }
1632
1633   $self->next::method(@_);
1634
1635   # if AutoCommit is disabled txn_depth never goes to 0
1636   # as a new txn is started immediately on commit
1637   $self->transaction_depth(1) if (
1638     !$self->transaction_depth
1639       and
1640     defined $self->_dbh_autocommit
1641       and
1642     ! $self->_dbh_autocommit
1643   );
1644 }
1645
1646 sub _exec_txn_commit {
1647   shift->_dbh->commit;
1648 }
1649
1650 sub txn_rollback {
1651   my $self = shift;
1652
1653   # do a minimal connectivity check due to weird shit like
1654   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1655   $self->throw_exception("lost connection to storage")
1656     unless $self->_seems_connected;
1657
1658   # esoteric case for folks using external $dbh handles
1659   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1660     carp "Storage transaction_depth 0 does not match "
1661         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1662     $self->transaction_depth(1);
1663   }
1664
1665   $self->next::method(@_);
1666
1667   # if AutoCommit is disabled txn_depth never goes to 0
1668   # as a new txn is started immediately on commit
1669   $self->transaction_depth(1) if (
1670     !$self->transaction_depth
1671       and
1672     defined $self->_dbh_autocommit
1673       and
1674     ! $self->_dbh_autocommit
1675   );
1676 }
1677
1678 sub _exec_txn_rollback {
1679   shift->_dbh->rollback;
1680 }
1681
1682 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1683 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1684   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1685     unless $_[0]->_seems_connected;
1686   shift->next::method(@_);
1687 EOS
1688
1689 # This used to be the top-half of _execute.  It was split out to make it
1690 #  easier to override in NoBindVars without duping the rest.  It takes up
1691 #  all of _execute's args, and emits $sql, @bind.
1692 sub _prep_for_execute {
1693   #my ($self, $op, $ident, $args) = @_;
1694   return shift->_gen_sql_bind(@_)
1695 }
1696
1697 sub _gen_sql_bind {
1698   my ($self, $op, $ident, $args) = @_;
1699
1700   my ($colinfos, $from);
1701   if ( blessed($ident) ) {
1702     $from = $ident->from;
1703     $colinfos = $ident->columns_info;
1704   }
1705
1706   my ($sql, $bind);
1707   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1708
1709   $bind = $self->_resolve_bindattrs(
1710     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1711   );
1712
1713   if (
1714     ! $ENV{DBIC_DT_SEARCH_OK}
1715       and
1716     $op eq 'select'
1717       and
1718     first {
1719       length ref $_->[1]
1720         and
1721       blessed($_->[1])
1722         and
1723       $_->[1]->isa('DateTime')
1724     } @$bind
1725   ) {
1726     carp_unique 'DateTime objects passed to search() are not supported '
1727       . 'properly (InflateColumn::DateTime formats and settings are not '
1728       . 'respected.) See ".. format a DateTime object for searching?" in '
1729       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1730       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1731   }
1732
1733   return( $sql, $bind );
1734 }
1735
1736 sub _resolve_bindattrs {
1737   my ($self, $ident, $bind, $colinfos) = @_;
1738
1739   my $resolve_bindinfo = sub {
1740     #my $infohash = shift;
1741
1742     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1743
1744     my $ret;
1745     if (my $col = $_[0]->{dbic_colname}) {
1746       $ret = { %{$_[0]} };
1747
1748       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1749         if $colinfos->{$col}{data_type};
1750
1751       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1752         if $colinfos->{$col}{size};
1753     }
1754
1755     $ret || $_[0];
1756   };
1757
1758   return [ map {
1759       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1760     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1761     : (ref $_->[0] eq 'HASH')           ? [(
1762                                             ! keys %{$_->[0]}
1763                                               or
1764                                             exists $_->[0]{dbd_attrs}
1765                                               or
1766                                             $_->[0]{sqlt_datatype}
1767                                            ) ? $_->[0]
1768                                              : $resolve_bindinfo->($_->[0])
1769                                            , $_->[1]
1770                                           ]
1771     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1772     :                                     [ $resolve_bindinfo->(
1773                                               { dbic_colname => $_->[0] }
1774                                             ), $_->[1] ]
1775   } @$bind ];
1776 }
1777
1778 sub _format_for_trace {
1779   #my ($self, $bind) = @_;
1780
1781   ### Turn @bind from something like this:
1782   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1783   ### to this:
1784   ###   ( "'1'", "'3'" )
1785
1786   map {
1787     defined( $_ && $_->[1] )
1788       ? qq{'$_->[1]'}
1789       : q{NULL}
1790   } @{$_[1] || []};
1791 }
1792
1793 sub _query_start {
1794   my ( $self, $sql, $bind ) = @_;
1795
1796   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1797     if $self->debug;
1798 }
1799
1800 sub _query_end {
1801   my ( $self, $sql, $bind ) = @_;
1802
1803   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1804     if $self->debug;
1805 }
1806
1807 sub _dbi_attrs_for_bind {
1808   #my ($self, $ident, $bind) = @_;
1809
1810   return [ map {
1811
1812     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1813
1814   : ! $_->{sqlt_datatype}   ? undef
1815
1816   :                           do {
1817
1818     # cache the result in the dbh_details hash, as it (usually) can not change
1819     # unless we connect to something else
1820     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1821     # the LOB storage
1822     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1823
1824     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1825       if ! exists $cache->{$_->{sqlt_datatype}};
1826
1827     $cache->{$_->{sqlt_datatype}};
1828
1829   } } map { $_->[0] } @{$_[2]} ];
1830 }
1831
1832 sub _execute {
1833   my ($self, $op, $ident, @args) = @_;
1834
1835   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1836
1837   # not even a PID check - we do not care about the state of the _dbh.
1838   # All we need is to get the appropriate drivers loaded if they aren't
1839   # already so that the assumption in ad7c50fc26e holds
1840   $self->_populate_dbh unless $self->_dbh;
1841
1842   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1843     $sql,
1844     $bind,
1845     $self->_dbi_attrs_for_bind($ident, $bind),
1846   );
1847 }
1848
1849 sub _dbh_execute {
1850   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1851
1852   $self->_query_start( $sql, $bind );
1853
1854   my $sth = $self->_bind_sth_params(
1855     $self->_prepare_sth($dbh, $sql),
1856     $bind,
1857     $bind_attrs,
1858   );
1859
1860   # Can this fail without throwing an exception anyways???
1861   my $rv = $sth->execute();
1862   $self->throw_exception(
1863     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1864   ) if !$rv;
1865
1866   $self->_query_end( $sql, $bind );
1867
1868   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1869 }
1870
1871 sub _prepare_sth {
1872   my ($self, $dbh, $sql) = @_;
1873
1874   # 3 is the if_active parameter which avoids active sth re-use
1875   my $sth = $self->disable_sth_caching
1876     ? $dbh->prepare($sql)
1877     : $dbh->prepare_cached($sql, {}, 3);
1878
1879   # XXX You would think RaiseError would make this impossible,
1880   #  but apparently that's not true :(
1881   $self->throw_exception(
1882     $dbh->errstr
1883       ||
1884     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1885             .'an exception and/or setting $dbh->errstr',
1886       length ($sql) > 20
1887         ? substr($sql, 0, 20) . '...'
1888         : $sql
1889       ,
1890       'DBD::' . $dbh->{Driver}{Name},
1891     )
1892   ) if !$sth;
1893
1894   $sth;
1895 }
1896
1897 sub _bind_sth_params {
1898   my ($self, $sth, $bind, $bind_attrs) = @_;
1899
1900   for my $i (0 .. $#$bind) {
1901     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1902       $sth->bind_param_inout(
1903         $i + 1, # bind params counts are 1-based
1904         $bind->[$i][1],
1905         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1906         $bind_attrs->[$i],
1907       );
1908     }
1909     else {
1910       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1911       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1912         ? "$bind->[$i][1]"
1913         : $bind->[$i][1]
1914       ;
1915
1916       $sth->bind_param(
1917         $i + 1,
1918         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1919         $v,
1920         $bind_attrs->[$i],
1921       );
1922     }
1923   }
1924
1925   $sth;
1926 }
1927
1928 sub _prefetch_autovalues {
1929   my ($self, $source, $colinfo, $to_insert) = @_;
1930
1931   my %values;
1932   for my $col (keys %$colinfo) {
1933     if (
1934       $colinfo->{$col}{auto_nextval}
1935         and
1936       (
1937         ! exists $to_insert->{$col}
1938           or
1939         is_literal_value($to_insert->{$col})
1940       )
1941     ) {
1942       $values{$col} = $self->_sequence_fetch(
1943         'NEXTVAL',
1944         ( $colinfo->{$col}{sequence} ||=
1945             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1946         ),
1947       );
1948     }
1949   }
1950
1951   \%values;
1952 }
1953
1954 sub insert {
1955   my ($self, $source, $to_insert) = @_;
1956
1957   my $col_infos = $source->columns_info;
1958
1959   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1960
1961   # fuse the values, but keep a separate list of prefetched_values so that
1962   # they can be fused once again with the final return
1963   $to_insert = { %$to_insert, %$prefetched_values };
1964
1965   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1966   # Investigate what does it take to s/defined/exists/
1967   my %pcols = map { $_ => 1 } $source->primary_columns;
1968   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1969   for my $col ($source->columns) {
1970     if ($col_infos->{$col}{is_auto_increment}) {
1971       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1972       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1973     }
1974
1975     # nothing to retrieve when explicit values are supplied
1976     next if (
1977       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1978     );
1979
1980     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1981     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1982       $pcols{$col}
1983         or
1984       $col_infos->{$col}{retrieve_on_insert}
1985     );
1986   };
1987
1988   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1989   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1990
1991   my ($sqla_opts, @ir_container);
1992   if (%retrieve_cols and $self->_use_insert_returning) {
1993     $sqla_opts->{returning_container} = \@ir_container
1994       if $self->_use_insert_returning_bound;
1995
1996     $sqla_opts->{returning} = [
1997       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1998     ];
1999   }
2000
2001   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2002
2003   my %returned_cols = %$to_insert;
2004   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2005
2006     unless( @ir_container ) {
2007       dbic_internal_try {
2008
2009         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2010         local $SIG{__WARN__} = sub {};
2011
2012         @ir_container = $sth->fetchrow_array;
2013         $sth->finish;
2014
2015       } catch {
2016         # Evict the $sth from the cache in case we got here, since the finish()
2017         # is crucial, at least on older Firebirds, possibly on other engines too
2018         #
2019         # It would be too complex to make this a proper subclass override,
2020         # and besides we already take the try{} penalty, adding a catch that
2021         # triggers infrequently is a no-brainer
2022         #
2023         if( my $kids = $self->_dbh->{CachedKids} ) {
2024           $kids->{$_} == $sth and delete $kids->{$_}
2025             for keys %$kids
2026         }
2027       };
2028     }
2029
2030     @returned_cols{@$retlist} = @ir_container if @ir_container;
2031   }
2032   else {
2033     # pull in PK if needed and then everything else
2034     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2035
2036       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2037         unless $self->can('last_insert_id');
2038
2039       my @pri_values = $self->last_insert_id($source, @missing_pri);
2040
2041       $self->throw_exception( "Can't get last insert id" )
2042         unless (@pri_values == @missing_pri);
2043
2044       @returned_cols{@missing_pri} = @pri_values;
2045       delete @retrieve_cols{@missing_pri};
2046     }
2047
2048     # if there is more left to pull
2049     if (%retrieve_cols) {
2050       $self->throw_exception(
2051         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2052       ) unless %pcols;
2053
2054       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2055
2056       my $cur = DBIx::Class::ResultSet->new($source, {
2057         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2058         select => \@left_to_fetch,
2059       })->cursor;
2060
2061       @returned_cols{@left_to_fetch} = $cur->next;
2062
2063       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2064         if scalar $cur->next;
2065     }
2066   }
2067
2068   return { %$prefetched_values, %returned_cols };
2069 }
2070
2071 sub insert_bulk {
2072   carp_unique(
2073     'insert_bulk() should have never been exposed as a public method and '
2074   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2075   . 'use for this method please contact the development team via '
2076   . DBIx::Class::_ENV_::HELP_URL
2077   );
2078
2079   return '0E0' unless @{$_[3]||[]};
2080
2081   shift->_insert_bulk(@_);
2082 }
2083
2084 sub _insert_bulk {
2085   my ($self, $source, $cols, $data) = @_;
2086
2087   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2088     unless @{$data||[]};
2089
2090   my $colinfos = $source->columns_info($cols);
2091
2092   local $self->{_autoinc_supplied_for_op} =
2093     (grep { $_->{is_auto_increment} } values %$colinfos)
2094       ? 1
2095       : 0
2096   ;
2097
2098   # get a slice type index based on first row of data
2099   # a "column" in this context may refer to more than one bind value
2100   # e.g. \[ '?, ?', [...], [...] ]
2101   #
2102   # construct the value type index - a description of values types for every
2103   # per-column slice of $data:
2104   #
2105   # nonexistent - nonbind literal
2106   # 0 - regular value
2107   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2108   #
2109   # also construct the column hash to pass to the SQL generator. For plain
2110   # (non literal) values - convert the members of the first row into a
2111   # literal+bind combo, with extra positional info in the bind attr hashref.
2112   # This will allow us to match the order properly, and is so contrived
2113   # because a user-supplied literal/bind (or something else specific to a
2114   # resultsource and/or storage driver) can inject extra binds along the
2115   # way, so one can't rely on "shift positions" ordering at all. Also we
2116   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2117   # can be later matched up by address), because we want to supply a real
2118   # value on which perhaps e.g. datatype checks will be performed
2119   my ($proto_data, $serialized_bind_type_by_col_idx);
2120   for my $col_idx (0..$#$cols) {
2121     my $colname = $cols->[$col_idx];
2122     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2123       # no bind value at all - no type
2124
2125       $proto_data->{$colname} = $data->[0][$col_idx];
2126     }
2127     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2128       # repack, so we don't end up mangling the original \[]
2129       my ($sql, @bind) = @${$data->[0][$col_idx]};
2130
2131       # normalization of user supplied stuff
2132       my $resolved_bind = $self->_resolve_bindattrs(
2133         $source, \@bind, $colinfos,
2134       );
2135
2136       # store value-less (attrs only) bind info - we will be comparing all
2137       # supplied binds against this for sanity
2138       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2139
2140       $proto_data->{$colname} = \[ $sql, map { [
2141         # inject slice order to use for $proto_bind construction
2142           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2143             =>
2144           $resolved_bind->[$_][1]
2145         ] } (0 .. $#bind)
2146       ];
2147     }
2148     else {
2149       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2150
2151       $proto_data->{$colname} = \[ '?', [
2152         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2153           =>
2154         $data->[0][$col_idx]
2155       ] ];
2156     }
2157   }
2158
2159   my ($sql, $proto_bind) = $self->_prep_for_execute (
2160     'insert',
2161     $source,
2162     [ $proto_data ],
2163   );
2164
2165   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2166     # if the bindlist is empty and we had some dynamic binds, this means the
2167     # storage ate them away (e.g. the NoBindVars component) and interpolated
2168     # them directly into the SQL. This obviously can't be good for multi-inserts
2169     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2170   }
2171
2172   # sanity checks
2173   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2174   #
2175   # use an error reporting closure for convenience (less to pass)
2176   my $bad_slice_report_cref = sub {
2177     my ($msg, $r_idx, $c_idx) = @_;
2178     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2179       $msg,
2180       $cols->[$c_idx],
2181       do {
2182         require Data::Dumper::Concise;
2183         local $Data::Dumper::Maxdepth = 5;
2184         Data::Dumper::Concise::Dumper ({
2185           map { $cols->[$_] =>
2186             $data->[$r_idx][$_]
2187           } 0..$#$cols
2188         }),
2189       }
2190     );
2191   };
2192
2193   for my $col_idx (0..$#$cols) {
2194     my $reference_val = $data->[0][$col_idx];
2195
2196     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2197       my $val = $data->[$row_idx][$col_idx];
2198
2199       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2200         if (ref $val ne 'SCALAR') {
2201           $bad_slice_report_cref->(
2202             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2203             $row_idx,
2204             $col_idx,
2205           );
2206         }
2207         elsif ($$val ne $$reference_val) {
2208           $bad_slice_report_cref->(
2209             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2210             $row_idx,
2211             $col_idx,
2212           );
2213         }
2214       }
2215       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2216         if (is_literal_value($val)) {
2217           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2218         }
2219       }
2220       else {  # binds from a \[], compare type and attrs
2221         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2222           $bad_slice_report_cref->(
2223             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2224             $row_idx,
2225             $col_idx,
2226           );
2227         }
2228         # start drilling down and bail out early on identical refs
2229         elsif (
2230           $reference_val != $val
2231             or
2232           $$reference_val != $$val
2233         ) {
2234           if (${$val}->[0] ne ${$reference_val}->[0]) {
2235             $bad_slice_report_cref->(
2236               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2237               $row_idx,
2238               $col_idx,
2239             );
2240           }
2241           # need to check the bind attrs - a bind will happen only once for
2242           # the entire dataset, so any changes further down will be ignored.
2243           elsif (
2244             $serialized_bind_type_by_col_idx->{$col_idx}
2245               ne
2246             serialize [
2247               map
2248               { $_->[0] }
2249               @{$self->_resolve_bindattrs(
2250                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2251               )}
2252             ]
2253           ) {
2254             $bad_slice_report_cref->(
2255               'Differing bind attributes on literal/bind values not supported',
2256               $row_idx,
2257               $col_idx,
2258             );
2259           }
2260         }
2261       }
2262     }
2263   }
2264
2265   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2266   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2267   # scope guard
2268   my $guard = $self->txn_scope_guard;
2269
2270   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2271   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2272   my $rv = do {
2273     if (@$proto_bind) {
2274       # proto bind contains the information on which pieces of $data to pull
2275       # $cols is passed in only for prettier error-reporting
2276       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2277     }
2278     else {
2279       # bind_param_array doesn't work if there are no binds
2280       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2281     }
2282   };
2283
2284   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2285
2286   $guard->commit;
2287
2288   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2289 }
2290
2291 # execute_for_fetch is capable of returning data just fine (it means it
2292 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2293 # is the void-populate fast-path we will just ignore this altogether
2294 # for the time being.
2295 sub _dbh_execute_for_fetch {
2296   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2297
2298   # If we have any bind attributes to take care of, we will bind the
2299   # proto-bind data (which will never be used by execute_for_fetch)
2300   # However since column bindtypes are "sticky", this is sufficient
2301   # to get the DBD to apply the bindtype to all values later on
2302   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2303
2304   for my $i (0 .. $#$proto_bind) {
2305     $sth->bind_param (
2306       $i+1, # DBI bind indexes are 1-based
2307       $proto_bind->[$i][1],
2308       $bind_attrs->[$i],
2309     ) if defined $bind_attrs->[$i];
2310   }
2311
2312   # At this point $data slots named in the _bind_data_slice_idx of
2313   # each piece of $proto_bind are either \[]s or plain values to be
2314   # passed in. Construct the dispensing coderef. *NOTE* the order
2315   # of $data will differ from this of the ?s in the SQL (due to
2316   # alphabetical ordering by colname). We actually do want to
2317   # preserve this behavior so that prepare_cached has a better
2318   # chance of matching on unrelated calls
2319
2320   my $fetch_row_idx = -1; # saner loop this way
2321   my $fetch_tuple = sub {
2322     return undef if ++$fetch_row_idx > $#$data;
2323
2324     return [ map {
2325       my $v = ! defined $_->{_literal_bind_subindex}
2326
2327         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2328
2329         # There are no attributes to resolve here - we already did everything
2330         # when we constructed proto_bind. However we still want to sanity-check
2331         # what the user supplied, so pass stuff through to the resolver *anyway*
2332         : $self->_resolve_bindattrs (
2333             undef,  # a fake rsrc
2334             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2335             {},     # a fake column_info bag
2336           )->[0][1]
2337       ;
2338
2339       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2340       # For the time being forcibly stringify whatever is stringifiable
2341       my $vref;
2342
2343       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2344     : defined blessed( $$vref )                             ? "$$vref"
2345                                                             : $$vref
2346     ;
2347     } map { $_->[0] } @$proto_bind ];
2348   };
2349
2350   my $tuple_status = [];
2351   my ($rv, $err);
2352   dbic_internal_try {
2353     $rv = $sth->execute_for_fetch(
2354       $fetch_tuple,
2355       $tuple_status,
2356     );
2357   }
2358   catch {
2359     $err = shift;
2360   };
2361
2362   # Not all DBDs are create equal. Some throw on error, some return
2363   # an undef $rv, and some set $sth->err - try whatever we can
2364   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2365     ! defined $err
2366       and
2367     ( !defined $rv or $sth->err )
2368   );
2369
2370   # Statement must finish even if there was an exception.
2371   dbic_internal_try {
2372     $sth->finish
2373   }
2374   catch {
2375     $err = shift unless defined $err
2376   };
2377
2378   if (defined $err) {
2379     my $i = 0;
2380     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2381
2382     $self->throw_exception("Unexpected populate error: $err")
2383       if ($i > $#$tuple_status);
2384
2385     require Data::Dumper::Concise;
2386     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2387       ($tuple_status->[$i][1] || $err),
2388       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2389     );
2390   }
2391
2392   return $rv;
2393 }
2394
2395 sub _dbh_execute_inserts_with_no_binds {
2396   my ($self, $sth, $count) = @_;
2397
2398   my $err;
2399   dbic_internal_try {
2400     my $dbh = $self->_get_dbh;
2401     local $dbh->{RaiseError} = 1;
2402     local $dbh->{PrintError} = 0;
2403
2404     $sth->execute foreach 1..$count;
2405   }
2406   catch {
2407     $err = shift;
2408   };
2409
2410   # Make sure statement is finished even if there was an exception.
2411   dbic_internal_try {
2412     $sth->finish
2413   }
2414   catch {
2415     $err = shift unless defined $err;
2416   };
2417
2418   $self->throw_exception($err) if defined $err;
2419
2420   return $count;
2421 }
2422
2423 sub update {
2424   #my ($self, $source, @args) = @_;
2425   shift->_execute('update', @_);
2426 }
2427
2428
2429 sub delete {
2430   #my ($self, $source, @args) = @_;
2431   shift->_execute('delete', @_);
2432 }
2433
2434 sub _select {
2435   my $self = shift;
2436   $self->_execute($self->_select_args(@_));
2437 }
2438
2439 sub _select_args_to_query {
2440   my $self = shift;
2441
2442   $self->throw_exception(
2443     "Unable to generate limited query representation with 'software_limit' enabled"
2444   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2445
2446   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2447   #  = $self->_select_args($ident, $select, $cond, $attrs);
2448   my ($op, $ident, @args) =
2449     $self->_select_args(@_);
2450
2451   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2452   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2453
2454   # reuse the bind arrayref
2455   unshift @{$bind}, "($sql)";
2456   \$bind;
2457 }
2458
2459 sub _select_args {
2460   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2461
2462   # FIXME - that kind of caching would be nice to have
2463   # however currently we *may* pass the same $orig_attrs
2464   # with different ident/select/where
2465   # the whole interface needs to be rethought, since it
2466   # was centered around the flawed SQLA API. We can do
2467   # soooooo much better now. But that is also another
2468   # battle...
2469   #return (
2470   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2471   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2472
2473   my $sql_maker = $self->sql_maker;
2474
2475   my $attrs = {
2476     %$orig_attrs,
2477     select => $select,
2478     from => $ident,
2479     where => $where,
2480   };
2481
2482   # MySQL actually recommends this approach.  I cringe.
2483   $attrs->{rows} ||= $sql_maker->__max_int
2484     if $attrs->{offset};
2485
2486   # see if we will need to tear the prefetch apart to satisfy group_by == select
2487   # this is *extremely tricky* to get right, I am still not sure I did
2488   #
2489   my ($prefetch_needs_subquery, @limit_args);
2490
2491   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2492     # we already know there is a valid group_by (we made it) and we know it is
2493     # intended to be based *only* on non-multi stuff
2494     # short circuit the group_by parsing below
2495     $prefetch_needs_subquery = 1;
2496   }
2497   elsif (
2498     # The rationale is that even if we do *not* have collapse, we still
2499     # need to wrap the core grouped select/group_by in a subquery
2500     # so that databases that care about group_by/select equivalence
2501     # are happy (this includes MySQL in strict_mode)
2502     # If any of the other joined tables are referenced in the group_by
2503     # however - the user is on their own
2504     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2505       and
2506     $attrs->{group_by}
2507       and
2508     @{$attrs->{group_by}}
2509       and
2510     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2511       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2512     }
2513   ) {
2514     # no aliases other than our own in group_by
2515     # if there are - do not allow subquery even if limit is present
2516     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2517   }
2518   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2519     # active collapse with a limit - that one is a no-brainer unless
2520     # overruled by a group_by above
2521     $prefetch_needs_subquery = 1;
2522   }
2523
2524   if ($prefetch_needs_subquery) {
2525     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2526   }
2527   elsif (! $attrs->{software_limit} ) {
2528     push @limit_args, (
2529       $attrs->{rows} || (),
2530       $attrs->{offset} || (),
2531     );
2532   }
2533
2534   # try to simplify the joinmap further (prune unreferenced type-single joins)
2535   if (
2536     ! $prefetch_needs_subquery  # already pruned
2537       and
2538     ref $attrs->{from}
2539       and
2540     reftype $attrs->{from} eq 'ARRAY'
2541       and
2542     @{$attrs->{from}} != 1
2543   ) {
2544     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2545   }
2546
2547   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2548   # during the result inflation stage we *need* to know what was the aliastype
2549   # map as sqla saw it when the final pieces of SQL were being assembled
2550   # Originally we simply carried around the entirety of $attrs, but this
2551   # resulted in resultsets that are being reused growing continuously, as
2552   # the hash in question grew deeper and deeper.
2553   # Instead hand-pick what to take with us here (we actually don't need much
2554   # at this point just the map itself)
2555   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2556
2557 ###
2558   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2559   #
2560   # This would be the point to deflate anything found in $attrs->{where}
2561   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2562   # expect a result object. And all we have is a resultsource (it is trivial
2563   # to extract deflator coderefs via $alias2source above).
2564   #
2565   # I don't see a way forward other than changing the way deflators are
2566   # invoked, and that's just bad...
2567 ###
2568
2569   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2570 }
2571
2572 # Returns a counting SELECT for a simple count
2573 # query. Abstracted so that a storage could override
2574 # this to { count => 'firstcol' } or whatever makes
2575 # sense as a performance optimization
2576 sub _count_select {
2577   #my ($self, $source, $rs_attrs) = @_;
2578   return { count => '*' };
2579 }
2580
2581 =head2 select
2582
2583 =over 4
2584
2585 =item Arguments: $ident, $select, $condition, $attrs
2586
2587 =back
2588
2589 Handle a SQL select statement.
2590
2591 =cut
2592
2593 sub select {
2594   my $self = shift;
2595   my ($ident, $select, $condition, $attrs) = @_;
2596   return $self->cursor_class->new($self, \@_, $attrs);
2597 }
2598
2599 sub select_single {
2600   my $self = shift;
2601   my ($rv, $sth, @bind) = $self->_select(@_);
2602   my @row = $sth->fetchrow_array;
2603   my @nextrow = $sth->fetchrow_array if @row;
2604   if(@row && @nextrow) {
2605     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2606   }
2607   # Need to call finish() to work round broken DBDs
2608   $sth->finish();
2609   return @row;
2610 }
2611
2612 =head2 sql_limit_dialect
2613
2614 This is an accessor for the default SQL limit dialect used by a particular
2615 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2616 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2617 see L<DBIx::Class::SQLMaker::LimitDialects>.
2618
2619 =cut
2620
2621 sub _dbh_columns_info_for {
2622   my ($self, $dbh, $table) = @_;
2623
2624   my %result;
2625
2626   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2627     dbic_internal_try {
2628       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2629       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2630       $sth->execute();
2631       while ( my $info = $sth->fetchrow_hashref() ){
2632         my %column_info;
2633         $column_info{data_type}   = $info->{TYPE_NAME};
2634         $column_info{size}      = $info->{COLUMN_SIZE};
2635         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2636         $column_info{default_value} = $info->{COLUMN_DEF};
2637         my $col_name = $info->{COLUMN_NAME};
2638         $col_name =~ s/^\"(.*)\"$/$1/;
2639
2640         $result{$col_name} = \%column_info;
2641       }
2642     } catch {
2643       %result = ();
2644     };
2645
2646     return \%result if keys %result;
2647   }
2648
2649   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2650   $sth->execute;
2651
2652 ### The acrobatics with lc names is necessary to support both the legacy
2653 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2654 ### with column names differing in cas eonly (thanks pg!)
2655
2656   my ($columns, $seen_lcs);
2657
2658   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2659     idx => scalar keys %$columns,
2660     name => $_,
2661     lc_name => lc($_),
2662   } for @{$sth->{NAME}};
2663
2664   $seen_lcs->{$_->{lc_name}} == 1
2665     and
2666   $_->{name} = $_->{lc_name}
2667     for values %$columns;
2668
2669   for ( values %$columns ) {
2670     my $inf = {
2671       data_type => $sth->{TYPE}->[$_->{idx}],
2672       size => $sth->{PRECISION}->[$_->{idx}],
2673       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2674     };
2675
2676     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2677       @{$inf}{qw( data_type  size)} = ($1, $2);
2678     }
2679
2680     $result{$_->{name}} = $inf;
2681   }
2682
2683   $sth->finish;
2684
2685   if ($dbh->can('type_info')) {
2686     for my $inf (values %result) {
2687       next if ! defined $inf->{data_type};
2688
2689       $inf->{data_type} = (
2690         (
2691           (
2692             $dbh->type_info( $inf->{data_type} )
2693               ||
2694             next
2695           )
2696             ||
2697           next
2698         )->{TYPE_NAME}
2699           ||
2700         next
2701       );
2702
2703       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2704       # needs more testing in the future...
2705       $inf->{size} -= 4 if (
2706         ( $inf->{size}||0 > 4 )
2707           and
2708         $inf->{data_type} =~ qr/^text$/i
2709       );
2710     }
2711
2712   }
2713
2714   return \%result;
2715 }
2716
2717 sub columns_info_for {
2718   my ($self, $table) = @_;
2719   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2720 }
2721
2722 =head2 last_insert_id
2723
2724 Return the row id of the last insert.
2725
2726 =cut
2727
2728 sub _dbh_last_insert_id {
2729     my ($self, $dbh, $source, $col) = @_;
2730
2731     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2732
2733     return $id if defined $id;
2734
2735     my $class = ref $self;
2736     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2737 }
2738
2739 sub last_insert_id {
2740   my $self = shift;
2741   $self->_dbh_last_insert_id ($self->_dbh, @_);
2742 }
2743
2744 =head2 _native_data_type
2745
2746 =over 4
2747
2748 =item Arguments: $type_name
2749
2750 =back
2751
2752 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2753 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2754 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2755
2756 The default implementation returns C<undef>, implement in your Storage driver if
2757 you need this functionality.
2758
2759 Should map types from other databases to the native RDBMS type, for example
2760 C<VARCHAR2> to C<VARCHAR>.
2761
2762 Types with modifiers should map to the underlying data type. For example,
2763 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2764
2765 Composite types should map to the container type, for example
2766 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2767
2768 =cut
2769
2770 sub _native_data_type {
2771   #my ($self, $data_type) = @_;
2772   return undef
2773 }
2774
2775 # Check if placeholders are supported at all
2776 sub _determine_supports_placeholders {
2777   my $self = shift;
2778   my $dbh  = $self->_get_dbh;
2779
2780   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2781   # but it is inaccurate more often than not
2782   ( dbic_internal_try {
2783     local $dbh->{PrintError} = 0;
2784     local $dbh->{RaiseError} = 1;
2785     $dbh->do('select ?', {}, 1);
2786     1;
2787   } )
2788     ? 1
2789     : 0
2790   ;
2791 }
2792
2793 # Check if placeholders bound to non-string types throw exceptions
2794 #
2795 sub _determine_supports_typeless_placeholders {
2796   my $self = shift;
2797   my $dbh  = $self->_get_dbh;
2798
2799   ( dbic_internal_try {
2800     local $dbh->{PrintError} = 0;
2801     local $dbh->{RaiseError} = 1;
2802     # this specifically tests a bind that is NOT a string
2803     $dbh->do('select 1 where 1 = ?', {}, 1);
2804     1;
2805   } )
2806     ? 1
2807     : 0
2808   ;
2809 }
2810
2811 =head2 sqlt_type
2812
2813 Returns the database driver name.
2814
2815 =cut
2816
2817 sub sqlt_type {
2818   shift->_get_dbh->{Driver}->{Name};
2819 }
2820
2821 =head2 bind_attribute_by_data_type
2822
2823 Given a datatype from column info, returns a database specific bind
2824 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2825 let the database planner just handle it.
2826
2827 This method is always called after the driver has been determined and a DBI
2828 connection has been established. Therefore you can refer to C<DBI::$constant>
2829 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2830 the correct modules.
2831
2832 =cut
2833
2834 sub bind_attribute_by_data_type {
2835     return;
2836 }
2837
2838 =head2 is_datatype_numeric
2839
2840 Given a datatype from column_info, returns a boolean value indicating if
2841 the current RDBMS considers it a numeric value. This controls how
2842 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2843 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2844 be performed instead of the usual C<eq>.
2845
2846 =cut
2847
2848 sub is_datatype_numeric {
2849   #my ($self, $dt) = @_;
2850
2851   return 0 unless $_[1];
2852
2853   $_[1] =~ /^ (?:
2854     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2855   ) $/ix;
2856 }
2857
2858
2859 =head2 create_ddl_dir
2860
2861 =over 4
2862
2863 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2864
2865 =back
2866
2867 Creates a SQL file based on the Schema, for each of the specified
2868 database engines in C<\@databases> in the given directory.
2869 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2870
2871 Given a previous version number, this will also create a file containing
2872 the ALTER TABLE statements to transform the previous schema into the
2873 current one. Note that these statements may contain C<DROP TABLE> or
2874 C<DROP COLUMN> statements that can potentially destroy data.
2875
2876 The file names are created using the C<ddl_filename> method below, please
2877 override this method in your schema if you would like a different file
2878 name format. For the ALTER file, the same format is used, replacing
2879 $version in the name with "$preversion-$version".
2880
2881 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2882 The most common value for this would be C<< { add_drop_table => 1 } >>
2883 to have the SQL produced include a C<DROP TABLE> statement for each table
2884 created. For quoting purposes supply C<quote_identifiers>.
2885
2886 If no arguments are passed, then the following default values are assumed:
2887
2888 =over 4
2889
2890 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2891
2892 =item version    - $schema->schema_version
2893
2894 =item directory  - './'
2895
2896 =item preversion - <none>
2897
2898 =back
2899
2900 By default, C<\%sqlt_args> will have
2901
2902  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2903
2904 merged with the hash passed in. To disable any of those features, pass in a
2905 hashref like the following
2906
2907  { ignore_constraint_names => 0, # ... other options }
2908
2909
2910 WARNING: You are strongly advised to check all SQL files created, before applying
2911 them.
2912
2913 =cut
2914
2915 sub create_ddl_dir {
2916   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2917
2918   unless ($dir) {
2919     carp "No directory given, using ./\n";
2920     $dir = './';
2921   } else {
2922       -d $dir
2923         or
2924       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2925         or
2926       $self->throw_exception(
2927         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2928       );
2929   }
2930
2931   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2932
2933   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2934   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2935
2936   my $schema_version = $schema->schema_version || '1.x';
2937   $version ||= $schema_version;
2938
2939   $sqltargs = {
2940     add_drop_table => 1,
2941     ignore_constraint_names => 1,
2942     ignore_index_names => 1,
2943     quote_identifiers => $self->sql_maker->_quoting_enabled,
2944     %{$sqltargs || {}}
2945   };
2946
2947   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2948     $self->throw_exception("Can't create a ddl file without $missing");
2949   }
2950
2951   my $sqlt = SQL::Translator->new( $sqltargs );
2952
2953   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2954   my $sqlt_schema = $sqlt->translate({ data => $schema })
2955     or $self->throw_exception ($sqlt->error);
2956
2957   foreach my $db (@$databases) {
2958     $sqlt->reset();
2959     $sqlt->{schema} = $sqlt_schema;
2960     $sqlt->producer($db);
2961
2962     my $file;
2963     my $filename = $schema->ddl_filename($db, $version, $dir);
2964     if (-e $filename && ($version eq $schema_version )) {
2965       # if we are dumping the current version, overwrite the DDL
2966       carp "Overwriting existing DDL file - $filename";
2967       unlink($filename);
2968     }
2969
2970     my $output = $sqlt->translate;
2971     if(!$output) {
2972       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2973       next;
2974     }
2975     if(!open($file, ">$filename")) {
2976       $self->throw_exception("Can't open $filename for writing ($!)");
2977       next;
2978     }
2979     print $file $output;
2980     close($file);
2981
2982     next unless ($preversion);
2983
2984     require SQL::Translator::Diff;
2985
2986     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2987     if(!-e $prefilename) {
2988       carp("No previous schema file found ($prefilename)");
2989       next;
2990     }
2991
2992     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2993     if(-e $difffile) {
2994       carp("Overwriting existing diff file - $difffile");
2995       unlink($difffile);
2996     }
2997
2998     my $source_schema;
2999     {
3000       my $t = SQL::Translator->new($sqltargs);
3001       $t->debug( 0 );
3002       $t->trace( 0 );
3003
3004       $t->parser( $db )
3005         or $self->throw_exception ($t->error);
3006
3007       my $out = $t->translate( $prefilename )
3008         or $self->throw_exception ($t->error);
3009
3010       $source_schema = $t->schema;
3011
3012       $source_schema->name( $prefilename )
3013         unless ( $source_schema->name );
3014     }
3015
3016     # The "new" style of producers have sane normalization and can support
3017     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3018     # And we have to diff parsed SQL against parsed SQL.
3019     my $dest_schema = $sqlt_schema;
3020
3021     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3022       my $t = SQL::Translator->new($sqltargs);
3023       $t->debug( 0 );
3024       $t->trace( 0 );
3025
3026       $t->parser( $db )
3027         or $self->throw_exception ($t->error);
3028
3029       my $out = $t->translate( $filename )
3030         or $self->throw_exception ($t->error);
3031
3032       $dest_schema = $t->schema;
3033
3034       $dest_schema->name( $filename )
3035         unless $dest_schema->name;
3036     }
3037
3038     my $diff = do {
3039       # FIXME - this is a terrible workaround for
3040       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3041       # Fixing it in this sloppy manner so that we don't hve to
3042       # lockstep an SQLT release as well. Needs to be removed at
3043       # some point, and SQLT dep bumped
3044       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3045         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3046
3047       SQL::Translator::Diff::schema_diff($source_schema, $db,
3048                                          $dest_schema,   $db,
3049                                          $sqltargs
3050                                        );
3051     };
3052
3053     if(!open $file, ">$difffile") {
3054       $self->throw_exception("Can't write to $difffile ($!)");
3055       next;
3056     }
3057     print $file $diff;
3058     close($file);
3059   }
3060 }
3061
3062 =head2 deployment_statements
3063
3064 =over 4
3065
3066 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3067
3068 =back
3069
3070 Returns the statements used by L<DBIx::Class::Storage/deploy>
3071 and L<DBIx::Class::Schema/deploy>.
3072
3073 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3074 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3075
3076 C<$directory> is used to return statements from files in a previously created
3077 L</create_ddl_dir> directory and is optional. The filenames are constructed
3078 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3079
3080 If no C<$directory> is specified then the statements are constructed on the
3081 fly using L<SQL::Translator> and C<$version> is ignored.
3082
3083 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3084
3085 =cut
3086
3087 sub deployment_statements {
3088   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3089   $type ||= $self->sqlt_type;
3090   $version ||= $schema->schema_version || '1.x';
3091   $dir ||= './';
3092   my $filename = $schema->ddl_filename($type, $version, $dir);
3093   if(-f $filename)
3094   {
3095       # FIXME replace this block when a proper sane sql parser is available
3096       my $file;
3097       open($file, "<$filename")
3098         or $self->throw_exception("Can't open $filename ($!)");
3099       my @rows = <$file>;
3100       close($file);
3101       return join('', @rows);
3102   }
3103
3104   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3105     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3106   }
3107
3108   # sources needs to be a parser arg, but for simplicity allow at top level
3109   # coming in
3110   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3111       if exists $sqltargs->{sources};
3112
3113   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3114     unless exists $sqltargs->{quote_identifiers};
3115
3116   my $tr = SQL::Translator->new(
3117     producer => "SQL::Translator::Producer::${type}",
3118     %$sqltargs,
3119     parser => 'SQL::Translator::Parser::DBIx::Class',
3120     data => $schema,
3121   );
3122
3123   return preserve_context {
3124     $tr->translate
3125   } after => sub {
3126     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3127       unless defined $_[0];
3128   };
3129 }
3130
3131 # FIXME deploy() currently does not accurately report sql errors
3132 # Will always return true while errors are warned
3133 sub deploy {
3134   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3135   my $deploy = sub {
3136     my $line = shift;
3137     return if(!$line);
3138     return if($line =~ /^--/);
3139     # next if($line =~ /^DROP/m);
3140     return if($line =~ /^BEGIN TRANSACTION/m);
3141     return if($line =~ /^COMMIT/m);
3142     return if $line =~ /^\s+$/; # skip whitespace only
3143     $self->_query_start($line);
3144     dbic_internal_try {
3145       # do a dbh_do cycle here, as we need some error checking in
3146       # place (even though we will ignore errors)
3147       $self->dbh_do (sub { $_[1]->do($line) });
3148     } catch {
3149       carp qq{$_ (running "${line}")};
3150     };
3151     $self->_query_end($line);
3152   };
3153   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3154   if (@statements > 1) {
3155     foreach my $statement (@statements) {
3156       $deploy->( $statement );
3157     }
3158   }
3159   elsif (@statements == 1) {
3160     # split on single line comments and end of statements
3161     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3162       $deploy->( $line );
3163     }
3164   }
3165 }
3166
3167 =head2 datetime_parser
3168
3169 Returns the datetime parser class
3170
3171 =cut
3172
3173 sub datetime_parser {
3174   my $self = shift;
3175   return $self->{datetime_parser} ||= do {
3176     $self->build_datetime_parser(@_);
3177   };
3178 }
3179
3180 =head2 datetime_parser_type
3181
3182 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3183
3184 =head2 build_datetime_parser
3185
3186 See L</datetime_parser>
3187
3188 =cut
3189
3190 sub build_datetime_parser {
3191   my $self = shift;
3192   my $type = $self->datetime_parser_type(@_);
3193   return $type;
3194 }
3195
3196
3197 =head2 is_replicating
3198
3199 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3200 replicate from a master database.  Default is undef, which is the result
3201 returned by databases that don't support replication.
3202
3203 =cut
3204
3205 sub is_replicating {
3206     return;
3207
3208 }
3209
3210 =head2 lag_behind_master
3211
3212 Returns a number that represents a certain amount of lag behind a master db
3213 when a given storage is replicating.  The number is database dependent, but
3214 starts at zero and increases with the amount of lag. Default in undef
3215
3216 =cut
3217
3218 sub lag_behind_master {
3219     return;
3220 }
3221
3222 =head2 relname_to_table_alias
3223
3224 =over 4
3225
3226 =item Arguments: $relname, $join_count
3227
3228 =item Return Value: $alias
3229
3230 =back
3231
3232 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3233 queries.
3234
3235 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3236 way these aliases are named.
3237
3238 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3239 otherwise C<"$relname">.
3240
3241 =cut
3242
3243 sub relname_to_table_alias {
3244   my ($self, $relname, $join_count) = @_;
3245
3246   my $alias = ($join_count && $join_count > 1 ?
3247     join('_', $relname, $join_count) : $relname);
3248
3249   return $alias;
3250 }
3251
3252 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3253 # version and it may be necessary to amend or override it for a specific storage
3254 # if such binds are necessary.
3255 sub _max_column_bytesize {
3256   my ($self, $attr) = @_;
3257
3258   my $max_size;
3259
3260   if ($attr->{sqlt_datatype}) {
3261     my $data_type = lc($attr->{sqlt_datatype});
3262
3263     if ($attr->{sqlt_size}) {
3264
3265       # String/sized-binary types
3266       if ($data_type =~ /^(?:
3267           l? (?:var)? char(?:acter)? (?:\s*varying)?
3268             |
3269           (?:var)? binary (?:\s*varying)?
3270             |
3271           raw
3272         )\b/x
3273       ) {
3274         $max_size = $attr->{sqlt_size};
3275       }
3276       # Other charset/unicode types, assume scale of 4
3277       elsif ($data_type =~ /^(?:
3278           national \s* character (?:\s*varying)?
3279             |
3280           nchar
3281             |
3282           univarchar
3283             |
3284           nvarchar
3285         )\b/x
3286       ) {
3287         $max_size = $attr->{sqlt_size} * 4;
3288       }
3289     }
3290
3291     if (!$max_size and !$self->_is_lob_type($data_type)) {
3292       $max_size = 100 # for all other (numeric?) datatypes
3293     }
3294   }
3295
3296   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3297 }
3298
3299 # Determine if a data_type is some type of BLOB
3300 sub _is_lob_type {
3301   my ($self, $data_type) = @_;
3302   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3303     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3304                                   |varchar|character\s*varying|nvarchar
3305                                   |national\s*character\s*varying))?\z/xi);
3306 }
3307
3308 sub _is_binary_lob_type {
3309   my ($self, $data_type) = @_;
3310   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3311     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3312 }
3313
3314 sub _is_text_lob_type {
3315   my ($self, $data_type) = @_;
3316   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3317     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3318                         |national\s*character\s*varying))\z/xi);
3319 }
3320
3321 # Determine if a data_type is some type of a binary type
3322 sub _is_binary_type {
3323   my ($self, $data_type) = @_;
3324   $data_type && ($self->_is_binary_lob_type($data_type)
3325     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3326 }
3327
3328 1;
3329
3330 =head1 USAGE NOTES
3331
3332 =head2 DBIx::Class and AutoCommit
3333
3334 DBIx::Class can do some wonderful magic with handling exceptions,
3335 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3336 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3337 transaction support.
3338
3339 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3340 in an assumed transaction between commits, and you're telling us you'd
3341 like to manage that manually.  A lot of the magic protections offered by
3342 this module will go away.  We can't protect you from exceptions due to database
3343 disconnects because we don't know anything about how to restart your
3344 transactions.  You're on your own for handling all sorts of exceptional
3345 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3346 be with raw DBI.
3347
3348 =head1 FURTHER QUESTIONS?
3349
3350 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3351
3352 =head1 COPYRIGHT AND LICENSE
3353
3354 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3355 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3356 redistribute it and/or modify it under the same terms as the
3357 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.