lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor scope_guard);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # if this is an actual *setter* - just set it, no need to connect
 129       # and determine the driver
 130       !( %1$s and @_ > 1 )
 131         and
 132       # only fire when invoked on an instance, a valid class-based invocation
 133       # would e.g. be setting a default for an inherited accessor
 134       ref $_[0]
 135         and
 136       ! $_[0]->{_driver_determined}
 137         and
 138       ! $_[0]->{_in_determine_driver}
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227
 228     if(
 229       ! DBIx::Class::_ENV_::BROKEN_FORK
 230         and
 231       my @instances = grep { defined $_ } values %seek_and_destroy
 232     ) {
 233       local $?; # just in case the DBI destructor changes it somehow
 234
 235       # disarm the handle if not native to this process (see comment on top)
 236       $_->_verify_pid for @instances;
 237     }
 238   }
 239
 240   sub CLONE {
 241     # As per DBI's recommendation, DBIC disconnects all handles as
 242     # soon as possible (DBIC will reconnect only on demand from within
 243     # the thread)
 244     my @instances = grep { defined $_ } values %seek_and_destroy;
 245     %seek_and_destroy = ();
 246
 247     for (@instances) {
 248       $_->_dbh(undef);
 249       $_->disconnect;
 250
 251       # properly renumber existing refs
 252       $_->_arm_global_destructor
 253     }
 254   }
 255 }
 256
 257 sub DESTROY {
 258   return if &detected_reinvoked_destructor;
 259
 260   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 261
 262   # some databases spew warnings on implicit disconnect
 263   return unless defined $_[0]->_dbh;
 264
 265   local $SIG{__WARN__} = sub {};
 266   $_[0]->_dbh(undef);
 267   # not calling ->disconnect here - we are being destroyed - nothing to reset
 268
 269   # this op is necessary, since the very last perl runtime statement
 270   # triggers a global destruction shootout, and the $SIG localization
 271   # may very well be destroyed before perl actually gets to do the
 272   # $dbh undef
 273   1;
 274 }
 275
 276 # handle pid changes correctly - do not destroy parent's connection
 277 sub _verify_pid {
 278
 279   my $pid = $_[0]->_conn_pid;
 280
 281   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 282     $dbh->{InactiveDestroy} = 1;
 283     $_[0]->_dbh(undef);
 284     $_[0]->disconnect;
 285   }
 286
 287   return;
 288 }
 289
 290 =head2 connect_info
 291
 292 This method is normally called by L<DBIx::Class::Schema/connection>, which
 293 encapsulates its argument list in an arrayref before passing them here.
 294
 295 The argument list may contain:
 296
 297 =over
 298
 299 =item *
 300
 301 The same 4-element argument set one would normally pass to
 302 L<DBI/connect>, optionally followed by
 303 L<extra attributes|/DBIx::Class specific connection attributes>
 304 recognized by DBIx::Class:
 305
 306   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 307
 308 =item *
 309
 310 A single code reference which returns a connected
 311 L<DBI database handle|DBI/connect> optionally followed by
 312 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 313 by DBIx::Class:
 314
 315   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 316
 317 =item *
 318
 319 A single hashref with all the attributes and the dsn/user/password
 320 mixed together:
 321
 322   $connect_info_args = [{
 323     dsn => $dsn,
 324     user => $user,
 325     password => $pass,
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330   $connect_info_args = [{
 331     dbh_maker => sub { DBI->connect (...) },
 332     %dbi_attributes,
 333     %extra_attributes,
 334   }];
 335
 336 This is particularly useful for L<Catalyst> based applications, allowing the
 337 following config (L<Config::General> style):
 338
 339   <Model::DB>
 340     schema_class   App::DB
 341     <connect_info>
 342       dsn          dbi:mysql:database=test
 343       user         testuser
 344       password     TestPass
 345       AutoCommit   1
 346     </connect_info>
 347   </Model::DB>
 348
 349 The C<dsn>/C<user>/C<password> combination can be substituted by the
 350 C<dbh_maker> key whose value is a coderef that returns a connected
 351 L<DBI database handle|DBI/connect>
 352
 353 =back
 354
 355 Please note that the L<DBI> docs recommend that you always explicitly
 356 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 357 recommends that it be set to I<1>, and that you perform transactions
 358 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 359 to I<1> if you do not do explicitly set it to zero.  This is the default
 360 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 361
 362 =head3 DBIx::Class specific connection attributes
 363
 364 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 365 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 366 the following connection options. These options can be mixed in with your other
 367 L<DBI> connection attributes, or placed in a separate hashref
 368 (C<\%extra_attributes>) as shown above.
 369
 370 Every time C<connect_info> is invoked, any previous settings for
 371 these options will be cleared before setting the new ones, regardless of
 372 whether any options are specified in the new C<connect_info>.
 373
 374
 375 =over
 376
 377 =item on_connect_do
 378
 379 Specifies things to do immediately after connecting or re-connecting to
 380 the database.  Its value may contain:
 381
 382 =over
 383
 384 =item a scalar
 385
 386 This contains one SQL statement to execute.
 387
 388 =item an array reference
 389
 390 This contains SQL statements to execute in order.  Each element contains
 391 a string or a code reference that returns a string.
 392
 393 =item a code reference
 394
 395 This contains some code to execute.  Unlike code references within an
 396 array reference, its return value is ignored.
 397
 398 =back
 399
 400 =item on_disconnect_do
 401
 402 Takes arguments in the same form as L</on_connect_do> and executes them
 403 immediately before disconnecting from the database.
 404
 405 Note, this only runs if you explicitly call L</disconnect> on the
 406 storage object.
 407
 408 =item on_connect_call
 409
 410 A more generalized form of L</on_connect_do> that calls the specified
 411 C<connect_call_METHOD> methods in your storage driver.
 412
 413   on_connect_do => 'select 1'
 414
 415 is equivalent to:
 416
 417   on_connect_call => [ [ do_sql => 'select 1' ] ]
 418
 419 Its values may contain:
 420
 421 =over
 422
 423 =item a scalar
 424
 425 Will call the C<connect_call_METHOD> method.
 426
 427 =item a code reference
 428
 429 Will execute C<< $code->($storage) >>
 430
 431 =item an array reference
 432
 433 Each value can be a method name or code reference.
 434
 435 =item an array of arrays
 436
 437 For each array, the first item is taken to be the C<connect_call_> method name
 438 or code reference, and the rest are parameters to it.
 439
 440 =back
 441
 442 Some predefined storage methods you may use:
 443
 444 =over
 445
 446 =item do_sql
 447
 448 Executes a SQL string or a code reference that returns a SQL string. This is
 449 what L</on_connect_do> and L</on_disconnect_do> use.
 450
 451 It can take:
 452
 453 =over
 454
 455 =item a scalar
 456
 457 Will execute the scalar as SQL.
 458
 459 =item an arrayref
 460
 461 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 462 attributes hashref and bind values.
 463
 464 =item a code reference
 465
 466 Will execute C<< $code->($storage) >> and execute the return array refs as
 467 above.
 468
 469 =back
 470
 471 =item datetime_setup
 472
 473 Execute any statements necessary to initialize the database session to return
 474 and accept datetime/timestamp values used with
 475 L<DBIx::Class::InflateColumn::DateTime>.
 476
 477 Only necessary for some databases, see your specific storage driver for
 478 implementation details.
 479
 480 =back
 481
 482 =item on_disconnect_call
 483
 484 Takes arguments in the same form as L</on_connect_call> and executes them
 485 immediately before disconnecting from the database.
 486
 487 Calls the C<disconnect_call_METHOD> methods as opposed to the
 488 C<connect_call_METHOD> methods called by L</on_connect_call>.
 489
 490 Note, this only runs if you explicitly call L</disconnect> on the
 491 storage object.
 492
 493 =item disable_sth_caching
 494
 495 If set to a true value, this option will disable the caching of
 496 statement handles via L<DBI/prepare_cached>.
 497
 498 =item limit_dialect
 499
 500 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 501 default L</sql_limit_dialect> setting of the storage (if any). For a list
 502 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 503
 504 =item quote_names
 505
 506 When true automatically sets L</quote_char> and L</name_sep> to the characters
 507 appropriate for your particular RDBMS. This option is preferred over specifying
 508 L</quote_char> directly.
 509
 510 =item quote_char
 511
 512 Specifies what characters to use to quote table and column names.
 513
 514 C<quote_char> expects either a single character, in which case is it
 515 is placed on either side of the table/column name, or an arrayref of length
 516 2 in which case the table/column name is placed between the elements.
 517
 518 For example under MySQL you should use C<< quote_char => '`' >>, and for
 519 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 520
 521 =item name_sep
 522
 523 This parameter is only useful in conjunction with C<quote_char>, and is used to
 524 specify the character that separates elements (schemas, tables, columns) from
 525 each other. If unspecified it defaults to the most commonly used C<.>.
 526
 527 =item unsafe
 528
 529 This Storage driver normally installs its own C<HandleError>, sets
 530 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 531 all database handles, including those supplied by a coderef.  It does this
 532 so that it can have consistent and useful error behavior.
 533
 534 If you set this option to a true value, Storage will not do its usual
 535 modifications to the database handle's attributes, and instead relies on
 536 the settings in your connect_info DBI options (or the values you set in
 537 your connection coderef, in the case that you are connecting via coderef).
 538
 539 Note that your custom settings can cause Storage to malfunction,
 540 especially if you set a C<HandleError> handler that suppresses exceptions
 541 and/or disable C<RaiseError>.
 542
 543 =item auto_savepoint
 544
 545 If this option is true, L<DBIx::Class> will use savepoints when nesting
 546 transactions, making it possible to recover from failure in the inner
 547 transaction without having to abort all outer transactions.
 548
 549 =item cursor_class
 550
 551 Use this argument to supply a cursor class other than the default
 552 L<DBIx::Class::Storage::DBI::Cursor>.
 553
 554 =back
 555
 556 Some real-life examples of arguments to L</connect_info> and
 557 L<DBIx::Class::Schema/connect>
 558
 559   # Simple SQLite connection
 560   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 561
 562   # Connect via subref
 563   ->connect_info([ sub { DBI->connect(...) } ]);
 564
 565   # Connect via subref in hashref
 566   ->connect_info([{
 567     dbh_maker => sub { DBI->connect(...) },
 568     on_connect_do => 'alter session ...',
 569   }]);
 570
 571   # A bit more complicated
 572   ->connect_info(
 573     [
 574       'dbi:Pg:dbname=foo',
 575       'postgres',
 576       'my_pg_password',
 577       { AutoCommit => 1 },
 578       { quote_char => q{"} },
 579     ]
 580   );
 581
 582   # Equivalent to the previous example
 583   ->connect_info(
 584     [
 585       'dbi:Pg:dbname=foo',
 586       'postgres',
 587       'my_pg_password',
 588       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 589     ]
 590   );
 591
 592   # Same, but with hashref as argument
 593   # See parse_connect_info for explanation
 594   ->connect_info(
 595     [{
 596       dsn         => 'dbi:Pg:dbname=foo',
 597       user        => 'postgres',
 598       password    => 'my_pg_password',
 599       AutoCommit  => 1,
 600       quote_char  => q{"},
 601       name_sep    => q{.},
 602     }]
 603   );
 604
 605   # Subref + DBIx::Class-specific connection options
 606   ->connect_info(
 607     [
 608       sub { DBI->connect(...) },
 609       {
 610           quote_char => q{`},
 611           name_sep => q{@},
 612           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 613           disable_sth_caching => 1,
 614       },
 615     ]
 616   );
 617
 618
 619
 620 =cut
 621
 622 sub connect_info {
 623   my ($self, $info) = @_;
 624
 625   return $self->_connect_info if !$info;
 626
 627   $self->_connect_info($info); # copy for _connect_info
 628
 629   $info = $self->_normalize_connect_info($info)
 630     if ref $info eq 'ARRAY';
 631
 632   my %attrs = (
 633     %{ $self->_default_dbi_connect_attributes || {} },
 634     %{ $info->{attributes} || {} },
 635   );
 636
 637   my @args = @{ $info->{arguments} };
 638
 639   if (keys %attrs and ref $args[0] ne 'CODE') {
 640     carp_unique (
 641         'You provided explicit AutoCommit => 0 in your connection_info. '
 642       . 'This is almost universally a bad idea (see the footnotes of '
 643       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 644       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 645       . 'this warning.'
 646     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 647
 648     push @args, \%attrs if keys %attrs;
 649   }
 650
 651   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 652   # OR a single-element coderef-based $dbh factory
 653   $self->_dbi_connect_info(\@args);
 654
 655   # extract the individual storage options
 656   for my $storage_opt (keys %{ $info->{storage_options} }) {
 657     my $value = $info->{storage_options}{$storage_opt};
 658
 659     $self->$storage_opt($value);
 660   }
 661
 662   # Extract the individual sqlmaker options
 663   #
 664   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 665   #  the new set of options
 666   $self->_sql_maker(undef);
 667   $self->_sql_maker_opts({});
 668
 669   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 670     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 671
 672     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 673   }
 674
 675   # FIXME - dirty:
 676   # save attributes in a separate accessor so they are always
 677   # introspectable, even in case of a CODE $dbhmaker
 678   $self->_dbic_connect_attributes (\%attrs);
 679
 680   return $self->_connect_info;
 681 }
 682
 683 sub _dbi_connect_info {
 684   my $self = shift;
 685
 686   return $self->{_dbi_connect_info} = $_[0]
 687     if @_;
 688
 689   my $conninfo = $self->{_dbi_connect_info} || [];
 690
 691   # last ditch effort to grab a DSN
 692   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 693     my @new_conninfo = @$conninfo;
 694     $new_conninfo[0] = $ENV{DBI_DSN};
 695     $conninfo = \@new_conninfo;
 696   }
 697
 698   return $conninfo;
 699 }
 700
 701
 702 sub _normalize_connect_info {
 703   my ($self, $info_arg) = @_;
 704   my %info;
 705
 706   my @args = @$info_arg;  # take a shallow copy for further mutilation
 707
 708   # combine/pre-parse arguments depending on invocation style
 709
 710   my %attrs;
 711   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 712     %attrs = %{ $args[1] || {} };
 713     @args = $args[0];
 714   }
 715   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 716     %attrs = %{$args[0]};
 717     @args = ();
 718     if (my $code = delete $attrs{dbh_maker}) {
 719       @args = $code;
 720
 721       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 722       if (@ignored) {
 723         carp sprintf (
 724             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 725           . "to the result of 'dbh_maker'",
 726
 727           join (', ', map { "'$_'" } (@ignored) ),
 728         );
 729       }
 730     }
 731     else {
 732       @args = delete @attrs{qw/dsn user password/};
 733     }
 734   }
 735   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 736     %attrs = (
 737       % { $args[3] || {} },
 738       % { $args[4] || {} },
 739     );
 740     @args = @args[0,1,2];
 741   }
 742
 743   $info{arguments} = \@args;
 744
 745   my @storage_opts = grep exists $attrs{$_},
 746     @storage_options, 'cursor_class';
 747
 748   @{ $info{storage_options} }{@storage_opts} =
 749     delete @attrs{@storage_opts} if @storage_opts;
 750
 751   my @sql_maker_opts = grep exists $attrs{$_},
 752     qw/limit_dialect quote_char name_sep quote_names/;
 753
 754   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 755     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 756
 757   $info{attributes} = \%attrs if %attrs;
 758
 759   return \%info;
 760 }
 761
 762 sub _default_dbi_connect_attributes () {
 763   +{
 764     AutoCommit => 1,
 765     PrintError => 0,
 766     RaiseError => 1,
 767     ShowErrorStatement => 1,
 768   };
 769 }
 770
 771 =head2 on_connect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 =head2 on_disconnect_do
 778
 779 This method is deprecated in favour of setting via L</connect_info>.
 780
 781 =cut
 782
 783 sub _parse_connect_do {
 784   my ($self, $type) = @_;
 785
 786   my $val = $self->$type;
 787   return () if not defined $val;
 788
 789   my @res;
 790
 791   if (not ref($val)) {
 792     push @res, [ 'do_sql', $val ];
 793   } elsif (ref($val) eq 'CODE') {
 794     push @res, $val;
 795   } elsif (ref($val) eq 'ARRAY') {
 796     push @res, map { [ 'do_sql', $_ ] } @$val;
 797   } else {
 798     $self->throw_exception("Invalid type for $type: ".ref($val));
 799   }
 800
 801   return \@res;
 802 }
 803
 804 =head2 dbh_do
 805
 806 Arguments: ($subref | $method_name), @extra_coderef_args?
 807
 808 Execute the given $subref or $method_name using the new exception-based
 809 connection management.
 810
 811 The first two arguments will be the storage object that C<dbh_do> was called
 812 on and a database handle to use.  Any additional arguments will be passed
 813 verbatim to the called subref as arguments 2 and onwards.
 814
 815 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 816 exception handling and reconnection (or failover in future subclasses).
 817
 818 Your subref should have no side-effects outside of the database, as
 819 there is the potential for your subref to be partially double-executed
 820 if the database connection was stale/dysfunctional.
 821
 822 Example:
 823
 824   my @stuff = $schema->storage->dbh_do(
 825     sub {
 826       my ($storage, $dbh, @cols) = @_;
 827       my $cols = join(q{, }, @cols);
 828       $dbh->selectrow_array("SELECT $cols FROM foo");
 829     },
 830     @column_list
 831   );
 832
 833 =cut
 834
 835 sub dbh_do {
 836   my $self = shift;
 837   my $run_target = shift; # either a coderef or a method name
 838
 839   # short circuit when we know there is no need for a runner
 840   #
 841   # FIXME - assumption may be wrong
 842   # the rationale for the txn_depth check is that if this block is a part
 843   # of a larger transaction, everything up to that point is screwed anyway
 844   return $self->$run_target($self->_get_dbh, @_)
 845     if $self->{_in_do_block} or $self->transaction_depth;
 846
 847   # take a ref instead of a copy, to preserve @_ aliasing
 848   # semantics within the coderef, but only if needed
 849   # (pseudoforking doesn't like this trick much)
 850   my $args = @_ ? \@_ : [];
 851
 852   DBIx::Class::Storage::BlockRunner->new(
 853     storage => $self,
 854     wrap_txn => 0,
 855     retry_handler => sub {
 856       $_[0]->failed_attempt_count == 1
 857         and
 858       ! $_[0]->storage->connected
 859     },
 860   )->run(sub {
 861     $self->$run_target ($self->_get_dbh, @$args )
 862   });
 863 }
 864
 865 sub txn_do {
 866   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 867   shift->next::method(@_);
 868 }
 869
 870 =head2 disconnect
 871
 872 Our C<disconnect> method also performs a rollback first if the
 873 database is not in C<AutoCommit> mode.
 874
 875 =cut
 876
 877 sub disconnect {
 878   my $self = shift;
 879
 880   # this physical disconnect below might very well throw
 881   # in order to unambiguously reset the state - do the cleanup in guard
 882
 883   my $g = scope_guard {
 884     $self->_dbh(undef);
 885     $self->_dbh_details({});
 886     $self->transaction_depth(undef);
 887     $self->_dbh_autocommit(undef);
 888     $self->savepoints([]);
 889
 890     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 891     #$self->_sql_maker(undef); # this may also end up being different
 892   };
 893
 894   if( my $dbh = $self->_dbh ) {
 895
 896     $self->_do_connection_actions(disconnect_call_ => $_) for (
 897       ( $self->on_disconnect_call || () ),
 898       $self->_parse_connect_do ('on_disconnect_do')
 899     );
 900
 901     # stops the "implicit rollback on disconnect" warning
 902     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 903
 904     %{ $dbh->{CachedKids} } = ();
 905
 906     $dbh->disconnect;
 907   }
 908 }
 909
 910 =head2 with_deferred_fk_checks
 911
 912 =over 4
 913
 914 =item Arguments: C<$coderef>
 915
 916 =item Return Value: The return value of $coderef
 917
 918 =back
 919
 920 Storage specific method to run the code ref with FK checks deferred or
 921 in MySQL's case disabled entirely.
 922
 923 =cut
 924
 925 # Storage subclasses should override this
 926 sub with_deferred_fk_checks {
 927   #my ($self, $sub) = @_;
 928   $_[1]->();
 929 }
 930
 931 =head2 connected
 932
 933 =over
 934
 935 =item Arguments: none
 936
 937 =item Return Value: 1|0
 938
 939 =back
 940
 941 Verifies that the current database handle is active and ready to execute
 942 an SQL statement (e.g. the connection did not get stale, server is still
 943 answering, etc.) This method is used internally by L</dbh>.
 944
 945 =cut
 946
 947 sub connected {
 948   return 0 unless $_[0]->_seems_connected;
 949
 950   #be on the safe side
 951   local $_[0]->_dbh->{RaiseError} = 1;
 952
 953   return $_[0]->_ping;
 954 }
 955
 956 sub _seems_connected {
 957   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 958
 959   ($_[0]->_dbh || return 0)->FETCH('Active');
 960 }
 961
 962 sub _ping {
 963   ($_[0]->_dbh || return 0)->ping;
 964 }
 965
 966 sub ensure_connected {
 967   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 968 }
 969
 970 =head2 dbh
 971
 972 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 973 is guaranteed to be healthy by implicitly calling L</connected>, and if
 974 necessary performing a reconnection before returning. Keep in mind that this
 975 is very B<expensive> on some database engines. Consider using L</dbh_do>
 976 instead.
 977
 978 =cut
 979
 980 sub dbh {
 981   # maybe save a ping call
 982   $_[0]->_dbh
 983     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 984     : $_[0]->_populate_dbh
 985   ;
 986 }
 987
 988 # this is the internal "get dbh or connect (don't check)" method
 989 sub _get_dbh {
 990   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 991   $_[0]->_dbh || $_[0]->_populate_dbh;
 992 }
 993
 994 # *DELIBERATELY* not a setter (for the time being)
 995 # Too intertwined with everything else for any kind of sanity
 996 sub sql_maker {
 997   my $self = shift;
 998
 999   $self->throw_exception('sql_maker() is not a setter method') if @_;
1000
1001   unless ($self->_sql_maker) {
1002     my $sql_maker_class = $self->sql_maker_class;
1003
1004     my %opts = %{$self->_sql_maker_opts||{}};
1005     my $dialect =
1006       $opts{limit_dialect}
1007         ||
1008       $self->sql_limit_dialect
1009         ||
1010       do {
1011         my $s_class = (ref $self) || $self;
1012         carp_unique (
1013           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1014         . 'have not supplied an explicit limit_dialect in your connection_info. '
1015         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1016         . 'databases but can be (and often is) painfully slow. '
1017         . "Please file an RT ticket against '$s_class'"
1018         ) if $self->_dbi_connect_info->[0];
1019
1020         'GenericSubQ';
1021       }
1022     ;
1023
1024     my ($quote_char, $name_sep);
1025
1026     if ($opts{quote_names}) {
1027       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1028         my $s_class = (ref $self) || $self;
1029         carp_unique (
1030           "You requested 'quote_names' but your storage class ($s_class) does "
1031         . 'not explicitly define a default sql_quote_char and you have not '
1032         . 'supplied a quote_char as part of your connection_info. DBIC will '
1033         .q{default to the ANSI SQL standard quote '"', which works most of }
1034         . "the time. Please file an RT ticket against '$s_class'."
1035         );
1036
1037         '"'; # RV
1038       };
1039
1040       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1041     }
1042
1043     $self->_sql_maker($sql_maker_class->new(
1044       bindtype=>'columns',
1045       array_datatypes => 1,
1046       limit_dialect => $dialect,
1047       ($quote_char ? (quote_char => $quote_char) : ()),
1048       name_sep => ($name_sep || '.'),
1049       %opts,
1050     ));
1051   }
1052   return $self->_sql_maker;
1053 }
1054
1055 # nothing to do by default
1056 sub _rebless {}
1057 sub _init {}
1058
1059 sub _populate_dbh {
1060
1061   # reset internal states
1062   # also in case ->connected failed we might get sent here
1063   $_[0]->disconnect;
1064
1065   $_[0]->_dbh($_[0]->_connect);
1066
1067   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1068
1069   $_[0]->_determine_driver;
1070
1071   # Always set the transaction depth on connect, since
1072   #  there is no transaction in progress by definition
1073   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1074
1075   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1076
1077   $_[0]->_dbh;
1078 }
1079
1080 sub _run_connection_actions {
1081
1082   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1083     ( $_[0]->on_connect_call || () ),
1084     $_[0]->_parse_connect_do ('on_connect_do'),
1085   );
1086 }
1087
1088
1089
1090 sub set_use_dbms_capability {
1091   $_[0]->set_inherited ($_[1], $_[2]);
1092 }
1093
1094 sub get_use_dbms_capability {
1095   my ($self, $capname) = @_;
1096
1097   my $use = $self->get_inherited ($capname);
1098   return defined $use
1099     ? $use
1100     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1101   ;
1102 }
1103
1104 sub set_dbms_capability {
1105   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1106 }
1107
1108 sub get_dbms_capability {
1109   my ($self, $capname) = @_;
1110
1111   my $cap = $self->_dbh_details->{capability}{$capname};
1112
1113   unless (defined $cap) {
1114     if (my $meth = $self->can ("_determine$capname")) {
1115       $cap = $self->$meth ? 1 : 0;
1116     }
1117     else {
1118       $cap = 0;
1119     }
1120
1121     $self->set_dbms_capability ($capname, $cap);
1122   }
1123
1124   return $cap;
1125 }
1126
1127 sub _server_info {
1128   my $self = shift;
1129
1130   # FIXME - ideally this needs to be an ||= assignment, and the final
1131   # assignment at the end of this do{} should be gone entirely. However
1132   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1133   $self->_dbh_details->{info} || do {
1134
1135     # this guarantees that problematic conninfo won't be hidden
1136     # by the try{} below
1137     $self->ensure_connected;
1138
1139     my $info = {};
1140
1141     my $server_version = try {
1142       $self->_get_server_version
1143     } catch {
1144       # driver determination *may* use this codepath
1145       # in which case we must rethrow
1146       $self->throw_exception($_) if $self->{_in_determine_driver};
1147
1148       # $server_version on failure
1149       undef;
1150     };
1151
1152     if (defined $server_version) {
1153       $info->{dbms_version} = $server_version;
1154
1155       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1156       my @verparts = split (/\./, $numeric_version);
1157       if (
1158         @verparts
1159           &&
1160         $verparts[0] <= 999
1161       ) {
1162         # consider only up to 3 version parts, iff not more than 3 digits
1163         my @use_parts;
1164         while (@verparts && @use_parts < 3) {
1165           my $p = shift @verparts;
1166           last if $p > 999;
1167           push @use_parts, $p;
1168         }
1169         push @use_parts, 0 while @use_parts < 3;
1170
1171         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1172       }
1173     }
1174
1175     $self->_dbh_details->{info} = $info;
1176   };
1177 }
1178
1179 sub _get_server_version {
1180   shift->_dbh_get_info('SQL_DBMS_VER');
1181 }
1182
1183 sub _dbh_get_info {
1184   my ($self, $info) = @_;
1185
1186   if ($info =~ /[^0-9]/) {
1187     require DBI::Const::GetInfoType;
1188     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1189     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1190       unless defined $info;
1191   }
1192
1193   $self->_get_dbh->get_info($info);
1194 }
1195
1196 sub _describe_connection {
1197   require DBI::Const::GetInfoReturn;
1198
1199   my $self = shift;
1200
1201   my $drv;
1202   try {
1203     $drv = $self->_extract_driver_from_connect_info;
1204     $self->ensure_connected;
1205   };
1206
1207   $drv = "DBD::$drv" if $drv;
1208
1209   my $res = {
1210     DBIC_DSN => $self->_dbi_connect_info->[0],
1211     DBI_VER => DBI->VERSION,
1212     DBIC_VER => DBIx::Class->VERSION,
1213     DBIC_DRIVER => ref $self,
1214     $drv ? (
1215       DBD => $drv,
1216       DBD_VER => try { $drv->VERSION },
1217     ) : (),
1218   };
1219
1220   # try to grab data even if we never managed to connect
1221   # will cover us in cases of an oddly broken half-connect
1222   for my $inf (
1223     #keys %DBI::Const::GetInfoType::GetInfoType,
1224     qw/
1225       SQL_CURSOR_COMMIT_BEHAVIOR
1226       SQL_CURSOR_ROLLBACK_BEHAVIOR
1227       SQL_CURSOR_SENSITIVITY
1228       SQL_DATA_SOURCE_NAME
1229       SQL_DBMS_NAME
1230       SQL_DBMS_VER
1231       SQL_DEFAULT_TXN_ISOLATION
1232       SQL_DM_VER
1233       SQL_DRIVER_NAME
1234       SQL_DRIVER_ODBC_VER
1235       SQL_DRIVER_VER
1236       SQL_EXPRESSIONS_IN_ORDERBY
1237       SQL_GROUP_BY
1238       SQL_IDENTIFIER_CASE
1239       SQL_IDENTIFIER_QUOTE_CHAR
1240       SQL_MAX_CATALOG_NAME_LEN
1241       SQL_MAX_COLUMN_NAME_LEN
1242       SQL_MAX_IDENTIFIER_LEN
1243       SQL_MAX_TABLE_NAME_LEN
1244       SQL_MULTIPLE_ACTIVE_TXN
1245       SQL_MULT_RESULT_SETS
1246       SQL_NEED_LONG_DATA_LEN
1247       SQL_NON_NULLABLE_COLUMNS
1248       SQL_ODBC_VER
1249       SQL_QUALIFIER_NAME_SEPARATOR
1250       SQL_QUOTED_IDENTIFIER_CASE
1251       SQL_TXN_CAPABLE
1252       SQL_TXN_ISOLATION_OPTION
1253     /
1254   ) {
1255     # some drivers barf on things they do not know about instead
1256     # of returning undef
1257     my $v = try { $self->_dbh_get_info($inf) };
1258     next unless defined $v;
1259
1260     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1261     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1262     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1263   }
1264
1265   $res;
1266 }
1267
1268 sub _determine_driver {
1269   my ($self) = @_;
1270
1271   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1272     my $started_connected = 0;
1273     local $self->{_in_determine_driver} = 1;
1274
1275     if (ref($self) eq __PACKAGE__) {
1276       my $driver;
1277       if ($self->_dbh) { # we are connected
1278         $driver = $self->_dbh->{Driver}{Name};
1279         $started_connected = 1;
1280       }
1281       else {
1282         $driver = $self->_extract_driver_from_connect_info;
1283       }
1284
1285       if ($driver) {
1286         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1287         if ($self->load_optional_class($storage_class)) {
1288           mro::set_mro($storage_class, 'c3');
1289           bless $self, $storage_class;
1290           $self->_rebless();
1291         }
1292         else {
1293           $self->_warn_undetermined_driver(
1294             'This version of DBIC does not yet seem to supply a driver for '
1295           . "your particular RDBMS and/or connection method ('$driver')."
1296           );
1297         }
1298       }
1299       else {
1300         $self->_warn_undetermined_driver(
1301           'Unable to extract a driver name from connect info - this '
1302         . 'should not have happened.'
1303         );
1304       }
1305     }
1306
1307     $self->_driver_determined(1);
1308
1309     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1310
1311     if ($self->can('source_bind_attributes')) {
1312       $self->throw_exception(
1313         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1314       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1315       . 'If you are not sure how to proceed please contact the development team via '
1316       . DBIx::Class::_ENV_::HELP_URL
1317       );
1318     }
1319
1320     $self->_init; # run driver-specific initializations
1321
1322     $self->_run_connection_actions
1323         if !$started_connected && defined $self->_dbh;
1324   }
1325 }
1326
1327 sub _extract_driver_from_connect_info {
1328   my $self = shift;
1329
1330   my $drv;
1331
1332   # if connect_info is a CODEREF, we have no choice but to connect
1333   if (
1334     ref $self->_dbi_connect_info->[0]
1335       and
1336     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1337   ) {
1338     $self->_populate_dbh;
1339     $drv = $self->_dbh->{Driver}{Name};
1340   }
1341   else {
1342     # try to use dsn to not require being connected, the driver may still
1343     # force a connection later in _rebless to determine version
1344     # (dsn may not be supplied at all if all we do is make a mock-schema)
1345     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1346     $drv ||= $ENV{DBI_DRIVER};
1347   }
1348
1349   return $drv;
1350 }
1351
1352 sub _determine_connector_driver {
1353   my ($self, $conn) = @_;
1354
1355   my $dbtype = $self->_get_rdbms_name;
1356
1357   if (not $dbtype) {
1358     $self->_warn_undetermined_driver(
1359       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1360     . "$conn connector - this should not have happened."
1361     );
1362     return;
1363   }
1364
1365   $dbtype =~ s/\W/_/gi;
1366
1367   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1368   return if $self->isa($subclass);
1369
1370   if ($self->load_optional_class($subclass)) {
1371     bless $self, $subclass;
1372     $self->_rebless;
1373   }
1374   else {
1375     $self->_warn_undetermined_driver(
1376       'This version of DBIC does not yet seem to supply a driver for '
1377     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1378     );
1379   }
1380 }
1381
1382 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1383
1384 sub _warn_undetermined_driver {
1385   my ($self, $msg) = @_;
1386
1387   require Data::Dumper::Concise;
1388
1389   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1390   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1391   . "does not go away, file a bugreport including the following info:\n"
1392   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1393   );
1394 }
1395
1396 sub _do_connection_actions {
1397   my ($self, $method_prefix, $call, @args) = @_;
1398
1399   try {
1400     if (not ref($call)) {
1401       my $method = $method_prefix . $call;
1402       $self->$method(@args);
1403     }
1404     elsif (ref($call) eq 'CODE') {
1405       $self->$call(@args);
1406     }
1407     elsif (ref($call) eq 'ARRAY') {
1408       if (ref($call->[0]) ne 'ARRAY') {
1409         $self->_do_connection_actions($method_prefix, $_) for @$call;
1410       }
1411       else {
1412         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1413       }
1414     }
1415     else {
1416       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1417     }
1418   }
1419   catch {
1420     if ( $method_prefix =~ /^connect/ ) {
1421       # this is an on_connect cycle - we can't just throw while leaving
1422       # a handle in an undefined state in our storage object
1423       # kill it with fire and rethrow
1424       $self->_dbh(undef);
1425       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1426       $self->throw_exception( $_[0] );
1427     }
1428     else {
1429       carp "Disconnect action failed: $_[0]";
1430     }
1431   };
1432
1433   return $self;
1434 }
1435
1436 sub connect_call_do_sql {
1437   my $self = shift;
1438   $self->_do_query(@_);
1439 }
1440
1441 sub disconnect_call_do_sql {
1442   my $self = shift;
1443   $self->_do_query(@_);
1444 }
1445
1446 =head2 connect_call_datetime_setup
1447
1448 A no-op stub method, provided so that one can always safely supply the
1449 L<connection option|/DBIx::Class specific connection attributes>
1450
1451  on_connect_call => 'datetime_setup'
1452
1453 This way one does not need to know in advance whether the underlying
1454 storage requires any sort of hand-holding when dealing with calendar
1455 data.
1456
1457 =cut
1458
1459 sub connect_call_datetime_setup { 1 }
1460
1461 sub _do_query {
1462   my ($self, $action) = @_;
1463
1464   if (ref $action eq 'CODE') {
1465     $action = $action->($self);
1466     $self->_do_query($_) foreach @$action;
1467   }
1468   else {
1469     # Most debuggers expect ($sql, @bind), so we need to exclude
1470     # the attribute hash which is the second argument to $dbh->do
1471     # furthermore the bind values are usually to be presented
1472     # as named arrayref pairs, so wrap those here too
1473     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1474     my $sql = shift @do_args;
1475     my $attrs = shift @do_args;
1476     my @bind = map { [ undef, $_ ] } @do_args;
1477
1478     $self->dbh_do(sub {
1479       $_[0]->_query_start($sql, \@bind);
1480       $_[1]->do($sql, $attrs, @do_args);
1481       $_[0]->_query_end($sql, \@bind);
1482     });
1483   }
1484
1485   return $self;
1486 }
1487
1488 sub _connect {
1489   my $self = shift;
1490
1491   my $info = $self->_dbi_connect_info;
1492
1493   $self->throw_exception("You did not provide any connection_info")
1494     unless defined $info->[0];
1495
1496   my ($old_connect_via, $dbh);
1497
1498   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1499
1500   # this odd anonymous coderef dereference is in fact really
1501   # necessary to avoid the unwanted effect described in perl5
1502   # RT#75792
1503   #
1504   # in addition the coderef itself can't reside inside the try{} block below
1505   # as it somehow triggers a leak under perl -d
1506   my $dbh_error_handler_installer = sub {
1507     weaken (my $weak_self = $_[0]);
1508
1509     # the coderef is blessed so we can distinguish it from externally
1510     # supplied handles (which must be preserved)
1511     $_[1]->{HandleError} = bless sub {
1512       if ($weak_self) {
1513         $weak_self->throw_exception("DBI Exception: $_[0]");
1514       }
1515       else {
1516         # the handler may be invoked by something totally out of
1517         # the scope of DBIC
1518         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1519       }
1520     }, '__DBIC__DBH__ERROR__HANDLER__';
1521   };
1522
1523   try {
1524     if(ref $info->[0] eq 'CODE') {
1525       $dbh = $info->[0]->();
1526     }
1527     else {
1528       require DBI;
1529       $dbh = DBI->connect(@$info);
1530     }
1531
1532     die $DBI::errstr unless $dbh;
1533
1534     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1535       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1536       . 'not continue',
1537       ref $info->[0] eq 'CODE'
1538         ? "Connection coderef $info->[0] returned a"
1539         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1540     ) unless $dbh->FETCH('Active');
1541
1542     # sanity checks unless asked otherwise
1543     unless ($self->unsafe) {
1544
1545       $self->throw_exception(
1546         'Refusing clobbering of {HandleError} installed on externally supplied '
1547        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1548       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1549
1550       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1551       # request, or an external handle. Complain and set anyway
1552       unless ($dbh->{RaiseError}) {
1553         carp( ref $info->[0] eq 'CODE'
1554
1555           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1556            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1557            .'attribute has been supplied'
1558
1559           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1560            .'unsafe => 1. Toggling RaiseError back to true'
1561         );
1562
1563         $dbh->{RaiseError} = 1;
1564       }
1565
1566       $dbh_error_handler_installer->($self, $dbh);
1567     }
1568   }
1569   catch {
1570     $self->throw_exception("DBI Connection failed: $_")
1571   };
1572
1573   $self->_dbh_autocommit($dbh->{AutoCommit});
1574   return $dbh;
1575 }
1576
1577 sub txn_begin {
1578   # this means we have not yet connected and do not know the AC status
1579   # (e.g. coderef $dbh), need a full-fledged connection check
1580   if (! defined $_[0]->_dbh_autocommit) {
1581     $_[0]->ensure_connected;
1582   }
1583   # Otherwise simply connect or re-connect on pid changes
1584   else {
1585     $_[0]->_get_dbh;
1586   }
1587
1588   shift->next::method(@_);
1589 }
1590
1591 sub _exec_txn_begin {
1592   my $self = shift;
1593
1594   # if the user is utilizing txn_do - good for him, otherwise we need to
1595   # ensure that the $dbh is healthy on BEGIN.
1596   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1597   # will be replaced by a failure of begin_work itself (which will be
1598   # then retried on reconnect)
1599   if ($self->{_in_do_block}) {
1600     $self->_dbh->begin_work;
1601   } else {
1602     $self->dbh_do(sub { $_[1]->begin_work });
1603   }
1604 }
1605
1606 sub txn_commit {
1607   my $self = shift;
1608
1609   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1610     unless $self->_seems_connected;
1611
1612   # esoteric case for folks using external $dbh handles
1613   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1614     carp "Storage transaction_depth 0 does not match "
1615         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1616     $self->transaction_depth(1);
1617   }
1618
1619   $self->next::method(@_);
1620
1621   # if AutoCommit is disabled txn_depth never goes to 0
1622   # as a new txn is started immediately on commit
1623   $self->transaction_depth(1) if (
1624     !$self->transaction_depth
1625       and
1626     defined $self->_dbh_autocommit
1627       and
1628     ! $self->_dbh_autocommit
1629   );
1630 }
1631
1632 sub _exec_txn_commit {
1633   shift->_dbh->commit;
1634 }
1635
1636 sub txn_rollback {
1637   my $self = shift;
1638
1639   # do a minimal connectivity check due to weird shit like
1640   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1641   $self->throw_exception("lost connection to storage")
1642     unless $self->_seems_connected;
1643
1644   # esoteric case for folks using external $dbh handles
1645   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1646     carp "Storage transaction_depth 0 does not match "
1647         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1648     $self->transaction_depth(1);
1649   }
1650
1651   $self->next::method(@_);
1652
1653   # if AutoCommit is disabled txn_depth never goes to 0
1654   # as a new txn is started immediately on commit
1655   $self->transaction_depth(1) if (
1656     !$self->transaction_depth
1657       and
1658     defined $self->_dbh_autocommit
1659       and
1660     ! $self->_dbh_autocommit
1661   );
1662 }
1663
1664 sub _exec_txn_rollback {
1665   shift->_dbh->rollback;
1666 }
1667
1668 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1669 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1670   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1671     unless $_[0]->_seems_connected;
1672   shift->next::method(@_);
1673 EOS
1674
1675 # This used to be the top-half of _execute.  It was split out to make it
1676 #  easier to override in NoBindVars without duping the rest.  It takes up
1677 #  all of _execute's args, and emits $sql, @bind.
1678 sub _prep_for_execute {
1679   #my ($self, $op, $ident, $args) = @_;
1680   return shift->_gen_sql_bind(@_)
1681 }
1682
1683 sub _gen_sql_bind {
1684   my ($self, $op, $ident, $args) = @_;
1685
1686   my ($colinfos, $from);
1687   if ( blessed($ident) ) {
1688     $from = $ident->from;
1689     $colinfos = $ident->columns_info;
1690   }
1691
1692   my ($sql, $bind);
1693   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1694
1695   $bind = $self->_resolve_bindattrs(
1696     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1697   );
1698
1699   if (
1700     ! $ENV{DBIC_DT_SEARCH_OK}
1701       and
1702     $op eq 'select'
1703       and
1704     first {
1705       length ref $_->[1]
1706         and
1707       blessed($_->[1])
1708         and
1709       $_->[1]->isa('DateTime')
1710     } @$bind
1711   ) {
1712     carp_unique 'DateTime objects passed to search() are not supported '
1713       . 'properly (InflateColumn::DateTime formats and settings are not '
1714       . 'respected.) See ".. format a DateTime object for searching?" in '
1715       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1716       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1717   }
1718
1719   return( $sql, $bind );
1720 }
1721
1722 sub _resolve_bindattrs {
1723   my ($self, $ident, $bind, $colinfos) = @_;
1724
1725   my $resolve_bindinfo = sub {
1726     #my $infohash = shift;
1727
1728     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1729
1730     my $ret;
1731     if (my $col = $_[0]->{dbic_colname}) {
1732       $ret = { %{$_[0]} };
1733
1734       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1735         if $colinfos->{$col}{data_type};
1736
1737       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1738         if $colinfos->{$col}{size};
1739     }
1740
1741     $ret || $_[0];
1742   };
1743
1744   return [ map {
1745       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1746     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1747     : (ref $_->[0] eq 'HASH')           ? [(
1748                                             ! keys %{$_->[0]}
1749                                               or
1750                                             exists $_->[0]{dbd_attrs}
1751                                               or
1752                                             $_->[0]{sqlt_datatype}
1753                                            ) ? $_->[0]
1754                                              : $resolve_bindinfo->($_->[0])
1755                                            , $_->[1]
1756                                           ]
1757     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1758     :                                     [ $resolve_bindinfo->(
1759                                               { dbic_colname => $_->[0] }
1760                                             ), $_->[1] ]
1761   } @$bind ];
1762 }
1763
1764 sub _format_for_trace {
1765   #my ($self, $bind) = @_;
1766
1767   ### Turn @bind from something like this:
1768   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1769   ### to this:
1770   ###   ( "'1'", "'3'" )
1771
1772   map {
1773     defined( $_ && $_->[1] )
1774       ? qq{'$_->[1]'}
1775       : q{NULL}
1776   } @{$_[1] || []};
1777 }
1778
1779 sub _query_start {
1780   my ( $self, $sql, $bind ) = @_;
1781
1782   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1783     if $self->debug;
1784 }
1785
1786 sub _query_end {
1787   my ( $self, $sql, $bind ) = @_;
1788
1789   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1790     if $self->debug;
1791 }
1792
1793 sub _dbi_attrs_for_bind {
1794   #my ($self, $ident, $bind) = @_;
1795
1796   return [ map {
1797
1798     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1799
1800   : ! $_->{sqlt_datatype}   ? undef
1801
1802   :                           do {
1803
1804     # cache the result in the dbh_details hash, as it (usually) can not change
1805     # unless we connect to something else
1806     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1807     # the LOB storage
1808     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1809
1810     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1811       if ! exists $cache->{$_->{sqlt_datatype}};
1812
1813     $cache->{$_->{sqlt_datatype}};
1814
1815   } } map { $_->[0] } @{$_[2]} ];
1816 }
1817
1818 sub _execute {
1819   my ($self, $op, $ident, @args) = @_;
1820
1821   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1822
1823   # not even a PID check - we do not care about the state of the _dbh.
1824   # All we need is to get the appropriate drivers loaded if they aren't
1825   # already so that the assumption in ad7c50fc26e holds
1826   $self->_populate_dbh unless $self->_dbh;
1827
1828   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1829     $sql,
1830     $bind,
1831     $self->_dbi_attrs_for_bind($ident, $bind),
1832   );
1833 }
1834
1835 sub _dbh_execute {
1836   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1837
1838   $self->_query_start( $sql, $bind );
1839
1840   my $sth = $self->_bind_sth_params(
1841     $self->_prepare_sth($dbh, $sql),
1842     $bind,
1843     $bind_attrs,
1844   );
1845
1846   # Can this fail without throwing an exception anyways???
1847   my $rv = $sth->execute();
1848   $self->throw_exception(
1849     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1850   ) if !$rv;
1851
1852   $self->_query_end( $sql, $bind );
1853
1854   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1855 }
1856
1857 sub _prepare_sth {
1858   my ($self, $dbh, $sql) = @_;
1859
1860   # 3 is the if_active parameter which avoids active sth re-use
1861   my $sth = $self->disable_sth_caching
1862     ? $dbh->prepare($sql)
1863     : $dbh->prepare_cached($sql, {}, 3);
1864
1865   # XXX You would think RaiseError would make this impossible,
1866   #  but apparently that's not true :(
1867   $self->throw_exception(
1868     $dbh->errstr
1869       ||
1870     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1871             .'an exception and/or setting $dbh->errstr',
1872       length ($sql) > 20
1873         ? substr($sql, 0, 20) . '...'
1874         : $sql
1875       ,
1876       'DBD::' . $dbh->{Driver}{Name},
1877     )
1878   ) if !$sth;
1879
1880   $sth;
1881 }
1882
1883 sub _bind_sth_params {
1884   my ($self, $sth, $bind, $bind_attrs) = @_;
1885
1886   for my $i (0 .. $#$bind) {
1887     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1888       $sth->bind_param_inout(
1889         $i + 1, # bind params counts are 1-based
1890         $bind->[$i][1],
1891         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1892         $bind_attrs->[$i],
1893       );
1894     }
1895     else {
1896       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1897       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1898         ? "$bind->[$i][1]"
1899         : $bind->[$i][1]
1900       ;
1901
1902       $sth->bind_param(
1903         $i + 1,
1904         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1905         $v,
1906         $bind_attrs->[$i],
1907       );
1908     }
1909   }
1910
1911   $sth;
1912 }
1913
1914 sub _prefetch_autovalues {
1915   my ($self, $source, $colinfo, $to_insert) = @_;
1916
1917   my %values;
1918   for my $col (keys %$colinfo) {
1919     if (
1920       $colinfo->{$col}{auto_nextval}
1921         and
1922       (
1923         ! exists $to_insert->{$col}
1924           or
1925         is_literal_value($to_insert->{$col})
1926       )
1927     ) {
1928       $values{$col} = $self->_sequence_fetch(
1929         'NEXTVAL',
1930         ( $colinfo->{$col}{sequence} ||=
1931             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1932         ),
1933       );
1934     }
1935   }
1936
1937   \%values;
1938 }
1939
1940 sub insert {
1941   my ($self, $source, $to_insert) = @_;
1942
1943   my $col_infos = $source->columns_info;
1944
1945   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1946
1947   # fuse the values, but keep a separate list of prefetched_values so that
1948   # they can be fused once again with the final return
1949   $to_insert = { %$to_insert, %$prefetched_values };
1950
1951   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1952   # Investigate what does it take to s/defined/exists/
1953   my %pcols = map { $_ => 1 } $source->primary_columns;
1954   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1955   for my $col ($source->columns) {
1956     if ($col_infos->{$col}{is_auto_increment}) {
1957       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1958       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1959     }
1960
1961     # nothing to retrieve when explicit values are supplied
1962     next if (
1963       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1964     );
1965
1966     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1967     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1968       $pcols{$col}
1969         or
1970       $col_infos->{$col}{retrieve_on_insert}
1971     );
1972   };
1973
1974   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1975   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1976
1977   my ($sqla_opts, @ir_container);
1978   if (%retrieve_cols and $self->_use_insert_returning) {
1979     $sqla_opts->{returning_container} = \@ir_container
1980       if $self->_use_insert_returning_bound;
1981
1982     $sqla_opts->{returning} = [
1983       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1984     ];
1985   }
1986
1987   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1988
1989   my %returned_cols = %$to_insert;
1990   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1991
1992     unless( @ir_container ) {
1993       try {
1994
1995         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
1996         local $SIG{__WARN__} = sub {};
1997
1998         @ir_container = $sth->fetchrow_array;
1999         $sth->finish;
2000
2001       } catch {
2002         # Evict the $sth from the cache in case we got here, since the finish()
2003         # is crucial, at least on older Firebirds, possibly on other engines too
2004         #
2005         # It would be too complex to make this a proper subclass override,
2006         # and besides we already take the try{} penalty, adding a catch that
2007         # triggers infrequently is a no-brainer
2008         #
2009         if( my $kids = $self->_dbh->{CachedKids} ) {
2010           $kids->{$_} == $sth and delete $kids->{$_}
2011             for keys %$kids
2012         }
2013       };
2014     }
2015
2016     @returned_cols{@$retlist} = @ir_container if @ir_container;
2017   }
2018   else {
2019     # pull in PK if needed and then everything else
2020     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2021
2022       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2023         unless $self->can('last_insert_id');
2024
2025       my @pri_values = $self->last_insert_id($source, @missing_pri);
2026
2027       $self->throw_exception( "Can't get last insert id" )
2028         unless (@pri_values == @missing_pri);
2029
2030       @returned_cols{@missing_pri} = @pri_values;
2031       delete @retrieve_cols{@missing_pri};
2032     }
2033
2034     # if there is more left to pull
2035     if (%retrieve_cols) {
2036       $self->throw_exception(
2037         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2038       ) unless %pcols;
2039
2040       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2041
2042       my $cur = DBIx::Class::ResultSet->new($source, {
2043         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2044         select => \@left_to_fetch,
2045       })->cursor;
2046
2047       @returned_cols{@left_to_fetch} = $cur->next;
2048
2049       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2050         if scalar $cur->next;
2051     }
2052   }
2053
2054   return { %$prefetched_values, %returned_cols };
2055 }
2056
2057 sub insert_bulk {
2058   carp_unique(
2059     'insert_bulk() should have never been exposed as a public method and '
2060   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2061   . 'use for this method please contact the development team via '
2062   . DBIx::Class::_ENV_::HELP_URL
2063   );
2064
2065   return '0E0' unless @{$_[3]||[]};
2066
2067   shift->_insert_bulk(@_);
2068 }
2069
2070 sub _insert_bulk {
2071   my ($self, $source, $cols, $data) = @_;
2072
2073   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2074     unless @{$data||[]};
2075
2076   my $colinfos = $source->columns_info($cols);
2077
2078   local $self->{_autoinc_supplied_for_op} =
2079     (grep { $_->{is_auto_increment} } values %$colinfos)
2080       ? 1
2081       : 0
2082   ;
2083
2084   # get a slice type index based on first row of data
2085   # a "column" in this context may refer to more than one bind value
2086   # e.g. \[ '?, ?', [...], [...] ]
2087   #
2088   # construct the value type index - a description of values types for every
2089   # per-column slice of $data:
2090   #
2091   # nonexistent - nonbind literal
2092   # 0 - regular value
2093   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2094   #
2095   # also construct the column hash to pass to the SQL generator. For plain
2096   # (non literal) values - convert the members of the first row into a
2097   # literal+bind combo, with extra positional info in the bind attr hashref.
2098   # This will allow us to match the order properly, and is so contrived
2099   # because a user-supplied literal/bind (or something else specific to a
2100   # resultsource and/or storage driver) can inject extra binds along the
2101   # way, so one can't rely on "shift positions" ordering at all. Also we
2102   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2103   # can be later matched up by address), because we want to supply a real
2104   # value on which perhaps e.g. datatype checks will be performed
2105   my ($proto_data, $serialized_bind_type_by_col_idx);
2106   for my $col_idx (0..$#$cols) {
2107     my $colname = $cols->[$col_idx];
2108     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2109       # no bind value at all - no type
2110
2111       $proto_data->{$colname} = $data->[0][$col_idx];
2112     }
2113     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2114       # repack, so we don't end up mangling the original \[]
2115       my ($sql, @bind) = @${$data->[0][$col_idx]};
2116
2117       # normalization of user supplied stuff
2118       my $resolved_bind = $self->_resolve_bindattrs(
2119         $source, \@bind, $colinfos,
2120       );
2121
2122       # store value-less (attrs only) bind info - we will be comparing all
2123       # supplied binds against this for sanity
2124       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2125
2126       $proto_data->{$colname} = \[ $sql, map { [
2127         # inject slice order to use for $proto_bind construction
2128           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2129             =>
2130           $resolved_bind->[$_][1]
2131         ] } (0 .. $#bind)
2132       ];
2133     }
2134     else {
2135       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2136
2137       $proto_data->{$colname} = \[ '?', [
2138         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2139           =>
2140         $data->[0][$col_idx]
2141       ] ];
2142     }
2143   }
2144
2145   my ($sql, $proto_bind) = $self->_prep_for_execute (
2146     'insert',
2147     $source,
2148     [ $proto_data ],
2149   );
2150
2151   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2152     # if the bindlist is empty and we had some dynamic binds, this means the
2153     # storage ate them away (e.g. the NoBindVars component) and interpolated
2154     # them directly into the SQL. This obviously can't be good for multi-inserts
2155     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2156   }
2157
2158   # sanity checks
2159   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2160   #
2161   # use an error reporting closure for convenience (less to pass)
2162   my $bad_slice_report_cref = sub {
2163     my ($msg, $r_idx, $c_idx) = @_;
2164     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2165       $msg,
2166       $cols->[$c_idx],
2167       do {
2168         require Data::Dumper::Concise;
2169         local $Data::Dumper::Maxdepth = 5;
2170         Data::Dumper::Concise::Dumper ({
2171           map { $cols->[$_] =>
2172             $data->[$r_idx][$_]
2173           } 0..$#$cols
2174         }),
2175       }
2176     );
2177   };
2178
2179   for my $col_idx (0..$#$cols) {
2180     my $reference_val = $data->[0][$col_idx];
2181
2182     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2183       my $val = $data->[$row_idx][$col_idx];
2184
2185       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2186         if (ref $val ne 'SCALAR') {
2187           $bad_slice_report_cref->(
2188             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2189             $row_idx,
2190             $col_idx,
2191           );
2192         }
2193         elsif ($$val ne $$reference_val) {
2194           $bad_slice_report_cref->(
2195             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2196             $row_idx,
2197             $col_idx,
2198           );
2199         }
2200       }
2201       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2202         if (is_literal_value($val)) {
2203           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2204         }
2205       }
2206       else {  # binds from a \[], compare type and attrs
2207         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2208           $bad_slice_report_cref->(
2209             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2210             $row_idx,
2211             $col_idx,
2212           );
2213         }
2214         # start drilling down and bail out early on identical refs
2215         elsif (
2216           $reference_val != $val
2217             or
2218           $$reference_val != $$val
2219         ) {
2220           if (${$val}->[0] ne ${$reference_val}->[0]) {
2221             $bad_slice_report_cref->(
2222               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2223               $row_idx,
2224               $col_idx,
2225             );
2226           }
2227           # need to check the bind attrs - a bind will happen only once for
2228           # the entire dataset, so any changes further down will be ignored.
2229           elsif (
2230             $serialized_bind_type_by_col_idx->{$col_idx}
2231               ne
2232             serialize [
2233               map
2234               { $_->[0] }
2235               @{$self->_resolve_bindattrs(
2236                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2237               )}
2238             ]
2239           ) {
2240             $bad_slice_report_cref->(
2241               'Differing bind attributes on literal/bind values not supported',
2242               $row_idx,
2243               $col_idx,
2244             );
2245           }
2246         }
2247       }
2248     }
2249   }
2250
2251   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2252   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2253   # scope guard
2254   my $guard = $self->txn_scope_guard;
2255
2256   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2257   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2258   my $rv = do {
2259     if (@$proto_bind) {
2260       # proto bind contains the information on which pieces of $data to pull
2261       # $cols is passed in only for prettier error-reporting
2262       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2263     }
2264     else {
2265       # bind_param_array doesn't work if there are no binds
2266       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2267     }
2268   };
2269
2270   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2271
2272   $guard->commit;
2273
2274   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2275 }
2276
2277 # execute_for_fetch is capable of returning data just fine (it means it
2278 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2279 # is the void-populate fast-path we will just ignore this altogether
2280 # for the time being.
2281 sub _dbh_execute_for_fetch {
2282   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2283
2284   # If we have any bind attributes to take care of, we will bind the
2285   # proto-bind data (which will never be used by execute_for_fetch)
2286   # However since column bindtypes are "sticky", this is sufficient
2287   # to get the DBD to apply the bindtype to all values later on
2288   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2289
2290   for my $i (0 .. $#$proto_bind) {
2291     $sth->bind_param (
2292       $i+1, # DBI bind indexes are 1-based
2293       $proto_bind->[$i][1],
2294       $bind_attrs->[$i],
2295     ) if defined $bind_attrs->[$i];
2296   }
2297
2298   # At this point $data slots named in the _bind_data_slice_idx of
2299   # each piece of $proto_bind are either \[]s or plain values to be
2300   # passed in. Construct the dispensing coderef. *NOTE* the order
2301   # of $data will differ from this of the ?s in the SQL (due to
2302   # alphabetical ordering by colname). We actually do want to
2303   # preserve this behavior so that prepare_cached has a better
2304   # chance of matching on unrelated calls
2305
2306   my $fetch_row_idx = -1; # saner loop this way
2307   my $fetch_tuple = sub {
2308     return undef if ++$fetch_row_idx > $#$data;
2309
2310     return [ map {
2311       my $v = ! defined $_->{_literal_bind_subindex}
2312
2313         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2314
2315         # There are no attributes to resolve here - we already did everything
2316         # when we constructed proto_bind. However we still want to sanity-check
2317         # what the user supplied, so pass stuff through to the resolver *anyway*
2318         : $self->_resolve_bindattrs (
2319             undef,  # a fake rsrc
2320             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2321             {},     # a fake column_info bag
2322           )->[0][1]
2323       ;
2324
2325       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2326       # For the time being forcibly stringify whatever is stringifiable
2327       my $vref;
2328
2329       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2330     : defined blessed( $$vref )                             ? "$$vref"
2331                                                             : $$vref
2332     ;
2333     } map { $_->[0] } @$proto_bind ];
2334   };
2335
2336   my $tuple_status = [];
2337   my ($rv, $err);
2338   try {
2339     $rv = $sth->execute_for_fetch(
2340       $fetch_tuple,
2341       $tuple_status,
2342     );
2343   }
2344   catch {
2345     $err = shift;
2346   };
2347
2348   # Not all DBDs are create equal. Some throw on error, some return
2349   # an undef $rv, and some set $sth->err - try whatever we can
2350   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2351     ! defined $err
2352       and
2353     ( !defined $rv or $sth->err )
2354   );
2355
2356   # Statement must finish even if there was an exception.
2357   try {
2358     $sth->finish
2359   }
2360   catch {
2361     $err = shift unless defined $err
2362   };
2363
2364   if (defined $err) {
2365     my $i = 0;
2366     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2367
2368     $self->throw_exception("Unexpected populate error: $err")
2369       if ($i > $#$tuple_status);
2370
2371     require Data::Dumper::Concise;
2372     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2373       ($tuple_status->[$i][1] || $err),
2374       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2375     );
2376   }
2377
2378   return $rv;
2379 }
2380
2381 sub _dbh_execute_inserts_with_no_binds {
2382   my ($self, $sth, $count) = @_;
2383
2384   my $err;
2385   try {
2386     my $dbh = $self->_get_dbh;
2387     local $dbh->{RaiseError} = 1;
2388     local $dbh->{PrintError} = 0;
2389
2390     $sth->execute foreach 1..$count;
2391   }
2392   catch {
2393     $err = shift;
2394   };
2395
2396   # Make sure statement is finished even if there was an exception.
2397   try {
2398     $sth->finish
2399   }
2400   catch {
2401     $err = shift unless defined $err;
2402   };
2403
2404   $self->throw_exception($err) if defined $err;
2405
2406   return $count;
2407 }
2408
2409 sub update {
2410   #my ($self, $source, @args) = @_;
2411   shift->_execute('update', @_);
2412 }
2413
2414
2415 sub delete {
2416   #my ($self, $source, @args) = @_;
2417   shift->_execute('delete', @_);
2418 }
2419
2420 sub _select {
2421   my $self = shift;
2422   $self->_execute($self->_select_args(@_));
2423 }
2424
2425 sub _select_args_to_query {
2426   my $self = shift;
2427
2428   $self->throw_exception(
2429     "Unable to generate limited query representation with 'software_limit' enabled"
2430   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2431
2432   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2433   #  = $self->_select_args($ident, $select, $cond, $attrs);
2434   my ($op, $ident, @args) =
2435     $self->_select_args(@_);
2436
2437   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2438   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2439
2440   # reuse the bind arrayref
2441   unshift @{$bind}, "($sql)";
2442   \$bind;
2443 }
2444
2445 sub _select_args {
2446   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2447
2448   # FIXME - that kind of caching would be nice to have
2449   # however currently we *may* pass the same $orig_attrs
2450   # with different ident/select/where
2451   # the whole interface needs to be rethought, since it
2452   # was centered around the flawed SQLA API. We can do
2453   # soooooo much better now. But that is also another
2454   # battle...
2455   #return (
2456   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2457   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2458
2459   my $sql_maker = $self->sql_maker;
2460
2461   my $attrs = {
2462     %$orig_attrs,
2463     select => $select,
2464     from => $ident,
2465     where => $where,
2466   };
2467
2468   # MySQL actually recommends this approach.  I cringe.
2469   $attrs->{rows} ||= $sql_maker->__max_int
2470     if $attrs->{offset};
2471
2472   # see if we will need to tear the prefetch apart to satisfy group_by == select
2473   # this is *extremely tricky* to get right, I am still not sure I did
2474   #
2475   my ($prefetch_needs_subquery, @limit_args);
2476
2477   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2478     # we already know there is a valid group_by (we made it) and we know it is
2479     # intended to be based *only* on non-multi stuff
2480     # short circuit the group_by parsing below
2481     $prefetch_needs_subquery = 1;
2482   }
2483   elsif (
2484     # The rationale is that even if we do *not* have collapse, we still
2485     # need to wrap the core grouped select/group_by in a subquery
2486     # so that databases that care about group_by/select equivalence
2487     # are happy (this includes MySQL in strict_mode)
2488     # If any of the other joined tables are referenced in the group_by
2489     # however - the user is on their own
2490     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2491       and
2492     $attrs->{group_by}
2493       and
2494     @{$attrs->{group_by}}
2495       and
2496     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2497       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2498     }
2499   ) {
2500     # no aliases other than our own in group_by
2501     # if there are - do not allow subquery even if limit is present
2502     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2503   }
2504   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2505     # active collapse with a limit - that one is a no-brainer unless
2506     # overruled by a group_by above
2507     $prefetch_needs_subquery = 1;
2508   }
2509
2510   if ($prefetch_needs_subquery) {
2511     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2512   }
2513   elsif (! $attrs->{software_limit} ) {
2514     push @limit_args, (
2515       $attrs->{rows} || (),
2516       $attrs->{offset} || (),
2517     );
2518   }
2519
2520   # try to simplify the joinmap further (prune unreferenced type-single joins)
2521   if (
2522     ! $prefetch_needs_subquery  # already pruned
2523       and
2524     ref $attrs->{from}
2525       and
2526     reftype $attrs->{from} eq 'ARRAY'
2527       and
2528     @{$attrs->{from}} != 1
2529   ) {
2530     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2531   }
2532
2533   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2534   # during the result inflation stage we *need* to know what was the aliastype
2535   # map as sqla saw it when the final pieces of SQL were being assembled
2536   # Originally we simply carried around the entirety of $attrs, but this
2537   # resulted in resultsets that are being reused growing continuously, as
2538   # the hash in question grew deeper and deeper.
2539   # Instead hand-pick what to take with us here (we actually don't need much
2540   # at this point just the map itself)
2541   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2542
2543 ###
2544   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2545   #
2546   # This would be the point to deflate anything found in $attrs->{where}
2547   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2548   # expect a result object. And all we have is a resultsource (it is trivial
2549   # to extract deflator coderefs via $alias2source above).
2550   #
2551   # I don't see a way forward other than changing the way deflators are
2552   # invoked, and that's just bad...
2553 ###
2554
2555   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2556 }
2557
2558 # Returns a counting SELECT for a simple count
2559 # query. Abstracted so that a storage could override
2560 # this to { count => 'firstcol' } or whatever makes
2561 # sense as a performance optimization
2562 sub _count_select {
2563   #my ($self, $source, $rs_attrs) = @_;
2564   return { count => '*' };
2565 }
2566
2567 =head2 select
2568
2569 =over 4
2570
2571 =item Arguments: $ident, $select, $condition, $attrs
2572
2573 =back
2574
2575 Handle a SQL select statement.
2576
2577 =cut
2578
2579 sub select {
2580   my $self = shift;
2581   my ($ident, $select, $condition, $attrs) = @_;
2582   return $self->cursor_class->new($self, \@_, $attrs);
2583 }
2584
2585 sub select_single {
2586   my $self = shift;
2587   my ($rv, $sth, @bind) = $self->_select(@_);
2588   my @row = $sth->fetchrow_array;
2589   my @nextrow = $sth->fetchrow_array if @row;
2590   if(@row && @nextrow) {
2591     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2592   }
2593   # Need to call finish() to work round broken DBDs
2594   $sth->finish();
2595   return @row;
2596 }
2597
2598 =head2 sql_limit_dialect
2599
2600 This is an accessor for the default SQL limit dialect used by a particular
2601 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2602 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2603 see L<DBIx::Class::SQLMaker::LimitDialects>.
2604
2605 =cut
2606
2607 sub _dbh_columns_info_for {
2608   my ($self, $dbh, $table) = @_;
2609
2610   my %result;
2611
2612   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2613     try {
2614       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2615       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2616       $sth->execute();
2617       while ( my $info = $sth->fetchrow_hashref() ){
2618         my %column_info;
2619         $column_info{data_type}   = $info->{TYPE_NAME};
2620         $column_info{size}      = $info->{COLUMN_SIZE};
2621         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2622         $column_info{default_value} = $info->{COLUMN_DEF};
2623         my $col_name = $info->{COLUMN_NAME};
2624         $col_name =~ s/^\"(.*)\"$/$1/;
2625
2626         $result{$col_name} = \%column_info;
2627       }
2628     } catch {
2629       %result = ();
2630     };
2631
2632     return \%result if keys %result;
2633   }
2634
2635   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2636   $sth->execute;
2637
2638 ### The acrobatics with lc names is necessary to support both the legacy
2639 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2640 ### with column names differing in cas eonly (thanks pg!)
2641
2642   my ($columns, $seen_lcs);
2643
2644   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2645     idx => scalar keys %$columns,
2646     name => $_,
2647     lc_name => lc($_),
2648   } for @{$sth->{NAME}};
2649
2650   $seen_lcs->{$_->{lc_name}} == 1
2651     and
2652   $_->{name} = $_->{lc_name}
2653     for values %$columns;
2654
2655   for ( values %$columns ) {
2656     my $inf = {
2657       data_type => $sth->{TYPE}->[$_->{idx}],
2658       size => $sth->{PRECISION}->[$_->{idx}],
2659       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2660     };
2661
2662     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2663       @{$inf}{qw( data_type  size)} = ($1, $2);
2664     }
2665
2666     $result{$_->{name}} = $inf;
2667   }
2668
2669   $sth->finish;
2670
2671   if ($dbh->can('type_info')) {
2672     for my $inf (values %result) {
2673       next if ! defined $inf->{data_type};
2674
2675       $inf->{data_type} = (
2676         (
2677           (
2678             $dbh->type_info( $inf->{data_type} )
2679               ||
2680             next
2681           )
2682             ||
2683           next
2684         )->{TYPE_NAME}
2685           ||
2686         next
2687       );
2688
2689       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2690       # needs more testing in the future...
2691       $inf->{size} -= 4 if (
2692         ( $inf->{size}||0 > 4 )
2693           and
2694         $inf->{data_type} =~ qr/^text$/i
2695       );
2696     }
2697
2698   }
2699
2700   return \%result;
2701 }
2702
2703 sub columns_info_for {
2704   my ($self, $table) = @_;
2705   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2706 }
2707
2708 =head2 last_insert_id
2709
2710 Return the row id of the last insert.
2711
2712 =cut
2713
2714 sub _dbh_last_insert_id {
2715     my ($self, $dbh, $source, $col) = @_;
2716
2717     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2718
2719     return $id if defined $id;
2720
2721     my $class = ref $self;
2722     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2723 }
2724
2725 sub last_insert_id {
2726   my $self = shift;
2727   $self->_dbh_last_insert_id ($self->_dbh, @_);
2728 }
2729
2730 =head2 _native_data_type
2731
2732 =over 4
2733
2734 =item Arguments: $type_name
2735
2736 =back
2737
2738 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2739 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2740 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2741
2742 The default implementation returns C<undef>, implement in your Storage driver if
2743 you need this functionality.
2744
2745 Should map types from other databases to the native RDBMS type, for example
2746 C<VARCHAR2> to C<VARCHAR>.
2747
2748 Types with modifiers should map to the underlying data type. For example,
2749 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2750
2751 Composite types should map to the container type, for example
2752 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2753
2754 =cut
2755
2756 sub _native_data_type {
2757   #my ($self, $data_type) = @_;
2758   return undef
2759 }
2760
2761 # Check if placeholders are supported at all
2762 sub _determine_supports_placeholders {
2763   my $self = shift;
2764   my $dbh  = $self->_get_dbh;
2765
2766   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2767   # but it is inaccurate more often than not
2768   return try {
2769     local $dbh->{PrintError} = 0;
2770     local $dbh->{RaiseError} = 1;
2771     $dbh->do('select ?', {}, 1);
2772     1;
2773   }
2774   catch {
2775     0;
2776   };
2777 }
2778
2779 # Check if placeholders bound to non-string types throw exceptions
2780 #
2781 sub _determine_supports_typeless_placeholders {
2782   my $self = shift;
2783   my $dbh  = $self->_get_dbh;
2784
2785   return try {
2786     local $dbh->{PrintError} = 0;
2787     local $dbh->{RaiseError} = 1;
2788     # this specifically tests a bind that is NOT a string
2789     $dbh->do('select 1 where 1 = ?', {}, 1);
2790     1;
2791   }
2792   catch {
2793     0;
2794   };
2795 }
2796
2797 =head2 sqlt_type
2798
2799 Returns the database driver name.
2800
2801 =cut
2802
2803 sub sqlt_type {
2804   shift->_get_dbh->{Driver}->{Name};
2805 }
2806
2807 =head2 bind_attribute_by_data_type
2808
2809 Given a datatype from column info, returns a database specific bind
2810 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2811 let the database planner just handle it.
2812
2813 This method is always called after the driver has been determined and a DBI
2814 connection has been established. Therefore you can refer to C<DBI::$constant>
2815 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2816 the correct modules.
2817
2818 =cut
2819
2820 sub bind_attribute_by_data_type {
2821     return;
2822 }
2823
2824 =head2 is_datatype_numeric
2825
2826 Given a datatype from column_info, returns a boolean value indicating if
2827 the current RDBMS considers it a numeric value. This controls how
2828 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2829 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2830 be performed instead of the usual C<eq>.
2831
2832 =cut
2833
2834 sub is_datatype_numeric {
2835   #my ($self, $dt) = @_;
2836
2837   return 0 unless $_[1];
2838
2839   $_[1] =~ /^ (?:
2840     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2841   ) $/ix;
2842 }
2843
2844
2845 =head2 create_ddl_dir
2846
2847 =over 4
2848
2849 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2850
2851 =back
2852
2853 Creates a SQL file based on the Schema, for each of the specified
2854 database engines in C<\@databases> in the given directory.
2855 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2856
2857 Given a previous version number, this will also create a file containing
2858 the ALTER TABLE statements to transform the previous schema into the
2859 current one. Note that these statements may contain C<DROP TABLE> or
2860 C<DROP COLUMN> statements that can potentially destroy data.
2861
2862 The file names are created using the C<ddl_filename> method below, please
2863 override this method in your schema if you would like a different file
2864 name format. For the ALTER file, the same format is used, replacing
2865 $version in the name with "$preversion-$version".
2866
2867 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2868 The most common value for this would be C<< { add_drop_table => 1 } >>
2869 to have the SQL produced include a C<DROP TABLE> statement for each table
2870 created. For quoting purposes supply C<quote_identifiers>.
2871
2872 If no arguments are passed, then the following default values are assumed:
2873
2874 =over 4
2875
2876 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2877
2878 =item version    - $schema->schema_version
2879
2880 =item directory  - './'
2881
2882 =item preversion - <none>
2883
2884 =back
2885
2886 By default, C<\%sqlt_args> will have
2887
2888  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2889
2890 merged with the hash passed in. To disable any of those features, pass in a
2891 hashref like the following
2892
2893  { ignore_constraint_names => 0, # ... other options }
2894
2895
2896 WARNING: You are strongly advised to check all SQL files created, before applying
2897 them.
2898
2899 =cut
2900
2901 sub create_ddl_dir {
2902   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2903
2904   unless ($dir) {
2905     carp "No directory given, using ./\n";
2906     $dir = './';
2907   } else {
2908       -d $dir
2909         or
2910       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2911         or
2912       $self->throw_exception(
2913         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2914       );
2915   }
2916
2917   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2918
2919   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2920   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2921
2922   my $schema_version = $schema->schema_version || '1.x';
2923   $version ||= $schema_version;
2924
2925   $sqltargs = {
2926     add_drop_table => 1,
2927     ignore_constraint_names => 1,
2928     ignore_index_names => 1,
2929     quote_identifiers => $self->sql_maker->_quoting_enabled,
2930     %{$sqltargs || {}}
2931   };
2932
2933   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2934     $self->throw_exception("Can't create a ddl file without $missing");
2935   }
2936
2937   my $sqlt = SQL::Translator->new( $sqltargs );
2938
2939   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2940   my $sqlt_schema = $sqlt->translate({ data => $schema })
2941     or $self->throw_exception ($sqlt->error);
2942
2943   foreach my $db (@$databases) {
2944     $sqlt->reset();
2945     $sqlt->{schema} = $sqlt_schema;
2946     $sqlt->producer($db);
2947
2948     my $file;
2949     my $filename = $schema->ddl_filename($db, $version, $dir);
2950     if (-e $filename && ($version eq $schema_version )) {
2951       # if we are dumping the current version, overwrite the DDL
2952       carp "Overwriting existing DDL file - $filename";
2953       unlink($filename);
2954     }
2955
2956     my $output = $sqlt->translate;
2957     if(!$output) {
2958       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2959       next;
2960     }
2961     if(!open($file, ">$filename")) {
2962       $self->throw_exception("Can't open $filename for writing ($!)");
2963       next;
2964     }
2965     print $file $output;
2966     close($file);
2967
2968     next unless ($preversion);
2969
2970     require SQL::Translator::Diff;
2971
2972     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2973     if(!-e $prefilename) {
2974       carp("No previous schema file found ($prefilename)");
2975       next;
2976     }
2977
2978     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2979     if(-e $difffile) {
2980       carp("Overwriting existing diff file - $difffile");
2981       unlink($difffile);
2982     }
2983
2984     my $source_schema;
2985     {
2986       my $t = SQL::Translator->new($sqltargs);
2987       $t->debug( 0 );
2988       $t->trace( 0 );
2989
2990       $t->parser( $db )
2991         or $self->throw_exception ($t->error);
2992
2993       my $out = $t->translate( $prefilename )
2994         or $self->throw_exception ($t->error);
2995
2996       $source_schema = $t->schema;
2997
2998       $source_schema->name( $prefilename )
2999         unless ( $source_schema->name );
3000     }
3001
3002     # The "new" style of producers have sane normalization and can support
3003     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3004     # And we have to diff parsed SQL against parsed SQL.
3005     my $dest_schema = $sqlt_schema;
3006
3007     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3008       my $t = SQL::Translator->new($sqltargs);
3009       $t->debug( 0 );
3010       $t->trace( 0 );
3011
3012       $t->parser( $db )
3013         or $self->throw_exception ($t->error);
3014
3015       my $out = $t->translate( $filename )
3016         or $self->throw_exception ($t->error);
3017
3018       $dest_schema = $t->schema;
3019
3020       $dest_schema->name( $filename )
3021         unless $dest_schema->name;
3022     }
3023
3024     my $diff = do {
3025       # FIXME - this is a terrible workaround for
3026       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3027       # Fixing it in this sloppy manner so that we don't hve to
3028       # lockstep an SQLT release as well. Needs to be removed at
3029       # some point, and SQLT dep bumped
3030       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3031         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3032
3033       SQL::Translator::Diff::schema_diff($source_schema, $db,
3034                                          $dest_schema,   $db,
3035                                          $sqltargs
3036                                        );
3037     };
3038
3039     if(!open $file, ">$difffile") {
3040       $self->throw_exception("Can't write to $difffile ($!)");
3041       next;
3042     }
3043     print $file $diff;
3044     close($file);
3045   }
3046 }
3047
3048 =head2 deployment_statements
3049
3050 =over 4
3051
3052 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3053
3054 =back
3055
3056 Returns the statements used by L<DBIx::Class::Storage/deploy>
3057 and L<DBIx::Class::Schema/deploy>.
3058
3059 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3060 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3061
3062 C<$directory> is used to return statements from files in a previously created
3063 L</create_ddl_dir> directory and is optional. The filenames are constructed
3064 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3065
3066 If no C<$directory> is specified then the statements are constructed on the
3067 fly using L<SQL::Translator> and C<$version> is ignored.
3068
3069 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3070
3071 =cut
3072
3073 sub deployment_statements {
3074   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3075   $type ||= $self->sqlt_type;
3076   $version ||= $schema->schema_version || '1.x';
3077   $dir ||= './';
3078   my $filename = $schema->ddl_filename($type, $version, $dir);
3079   if(-f $filename)
3080   {
3081       # FIXME replace this block when a proper sane sql parser is available
3082       my $file;
3083       open($file, "<$filename")
3084         or $self->throw_exception("Can't open $filename ($!)");
3085       my @rows = <$file>;
3086       close($file);
3087       return join('', @rows);
3088   }
3089
3090   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3091     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3092   }
3093
3094   # sources needs to be a parser arg, but for simplicity allow at top level
3095   # coming in
3096   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3097       if exists $sqltargs->{sources};
3098
3099   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3100     unless exists $sqltargs->{quote_identifiers};
3101
3102   my $tr = SQL::Translator->new(
3103     producer => "SQL::Translator::Producer::${type}",
3104     %$sqltargs,
3105     parser => 'SQL::Translator::Parser::DBIx::Class',
3106     data => $schema,
3107   );
3108
3109   return preserve_context {
3110     $tr->translate
3111   } after => sub {
3112     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3113       unless defined $_[0];
3114   };
3115 }
3116
3117 # FIXME deploy() currently does not accurately report sql errors
3118 # Will always return true while errors are warned
3119 sub deploy {
3120   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3121   my $deploy = sub {
3122     my $line = shift;
3123     return if(!$line);
3124     return if($line =~ /^--/);
3125     # next if($line =~ /^DROP/m);
3126     return if($line =~ /^BEGIN TRANSACTION/m);
3127     return if($line =~ /^COMMIT/m);
3128     return if $line =~ /^\s+$/; # skip whitespace only
3129     $self->_query_start($line);
3130     try {
3131       # do a dbh_do cycle here, as we need some error checking in
3132       # place (even though we will ignore errors)
3133       $self->dbh_do (sub { $_[1]->do($line) });
3134     } catch {
3135       carp qq{$_ (running "${line}")};
3136     };
3137     $self->_query_end($line);
3138   };
3139   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3140   if (@statements > 1) {
3141     foreach my $statement (@statements) {
3142       $deploy->( $statement );
3143     }
3144   }
3145   elsif (@statements == 1) {
3146     # split on single line comments and end of statements
3147     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3148       $deploy->( $line );
3149     }
3150   }
3151 }
3152
3153 =head2 datetime_parser
3154
3155 Returns the datetime parser class
3156
3157 =cut
3158
3159 sub datetime_parser {
3160   my $self = shift;
3161   return $self->{datetime_parser} ||= do {
3162     $self->build_datetime_parser(@_);
3163   };
3164 }
3165
3166 =head2 datetime_parser_type
3167
3168 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3169
3170 =head2 build_datetime_parser
3171
3172 See L</datetime_parser>
3173
3174 =cut
3175
3176 sub build_datetime_parser {
3177   my $self = shift;
3178   my $type = $self->datetime_parser_type(@_);
3179   return $type;
3180 }
3181
3182
3183 =head2 is_replicating
3184
3185 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3186 replicate from a master database.  Default is undef, which is the result
3187 returned by databases that don't support replication.
3188
3189 =cut
3190
3191 sub is_replicating {
3192     return;
3193
3194 }
3195
3196 =head2 lag_behind_master
3197
3198 Returns a number that represents a certain amount of lag behind a master db
3199 when a given storage is replicating.  The number is database dependent, but
3200 starts at zero and increases with the amount of lag. Default in undef
3201
3202 =cut
3203
3204 sub lag_behind_master {
3205     return;
3206 }
3207
3208 =head2 relname_to_table_alias
3209
3210 =over 4
3211
3212 =item Arguments: $relname, $join_count
3213
3214 =item Return Value: $alias
3215
3216 =back
3217
3218 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3219 queries.
3220
3221 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3222 way these aliases are named.
3223
3224 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3225 otherwise C<"$relname">.
3226
3227 =cut
3228
3229 sub relname_to_table_alias {
3230   my ($self, $relname, $join_count) = @_;
3231
3232   my $alias = ($join_count && $join_count > 1 ?
3233     join('_', $relname, $join_count) : $relname);
3234
3235   return $alias;
3236 }
3237
3238 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3239 # version and it may be necessary to amend or override it for a specific storage
3240 # if such binds are necessary.
3241 sub _max_column_bytesize {
3242   my ($self, $attr) = @_;
3243
3244   my $max_size;
3245
3246   if ($attr->{sqlt_datatype}) {
3247     my $data_type = lc($attr->{sqlt_datatype});
3248
3249     if ($attr->{sqlt_size}) {
3250
3251       # String/sized-binary types
3252       if ($data_type =~ /^(?:
3253           l? (?:var)? char(?:acter)? (?:\s*varying)?
3254             |
3255           (?:var)? binary (?:\s*varying)?
3256             |
3257           raw
3258         )\b/x
3259       ) {
3260         $max_size = $attr->{sqlt_size};
3261       }
3262       # Other charset/unicode types, assume scale of 4
3263       elsif ($data_type =~ /^(?:
3264           national \s* character (?:\s*varying)?
3265             |
3266           nchar
3267             |
3268           univarchar
3269             |
3270           nvarchar
3271         )\b/x
3272       ) {
3273         $max_size = $attr->{sqlt_size} * 4;
3274       }
3275     }
3276
3277     if (!$max_size and !$self->_is_lob_type($data_type)) {
3278       $max_size = 100 # for all other (numeric?) datatypes
3279     }
3280   }
3281
3282   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3283 }
3284
3285 # Determine if a data_type is some type of BLOB
3286 sub _is_lob_type {
3287   my ($self, $data_type) = @_;
3288   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3289     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3290                                   |varchar|character\s*varying|nvarchar
3291                                   |national\s*character\s*varying))?\z/xi);
3292 }
3293
3294 sub _is_binary_lob_type {
3295   my ($self, $data_type) = @_;
3296   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3297     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3298 }
3299
3300 sub _is_text_lob_type {
3301   my ($self, $data_type) = @_;
3302   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3303     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3304                         |national\s*character\s*varying))\z/xi);
3305 }
3306
3307 # Determine if a data_type is some type of a binary type
3308 sub _is_binary_type {
3309   my ($self, $data_type) = @_;
3310   $data_type && ($self->_is_binary_lob_type($data_type)
3311     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3312 }
3313
3314 1;
3315
3316 =head1 USAGE NOTES
3317
3318 =head2 DBIx::Class and AutoCommit
3319
3320 DBIx::Class can do some wonderful magic with handling exceptions,
3321 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3322 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3323 transaction support.
3324
3325 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3326 in an assumed transaction between commits, and you're telling us you'd
3327 like to manage that manually.  A lot of the magic protections offered by
3328 this module will go away.  We can't protect you from exceptions due to database
3329 disconnects because we don't know anything about how to restart your
3330 transactions.  You're on your own for handling all sorts of exceptional
3331 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3332 be with raw DBI.
3333
3334 =head1 FURTHER QUESTIONS?
3335
3336 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3337
3338 =head1 COPYRIGHT AND LICENSE
3339
3340 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3341 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3342 redistribute it and/or modify it under the same terms as the
3343 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.