lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $is_getter = $storage_accessor_idx->{$meth} ? 0 : 1;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $is_getter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # only fire when invoked on an instance, a valid class-based invocation
 129       # would e.g. be setting a default for an inherited accessor
 130       ref $_[0]
 131         and
 132       ! $_[0]->{_driver_determined}
 133         and
 134       ! $_[0]->{_in_determine_driver}
 135         and
 136       # if this is a known *setter* - just set it, no need to connect
 137       # and determine the driver
 138       ( %1$s or @_ <= 1 )
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227     local $?; # just in case the DBI destructor changes it somehow
 228
 229     # destroy just the object if not native to this process
 230     $_->_verify_pid for (grep
 231       { defined $_ }
 232       values %seek_and_destroy
 233     );
 234   }
 235
 236   sub CLONE {
 237     # As per DBI's recommendation, DBIC disconnects all handles as
 238     # soon as possible (DBIC will reconnect only on demand from within
 239     # the thread)
 240     my @instances = grep { defined $_ } values %seek_and_destroy;
 241     %seek_and_destroy = ();
 242
 243     for (@instances) {
 244       $_->_dbh(undef);
 245
 246       $_->transaction_depth(0);
 247       $_->savepoints([]);
 248
 249       # properly renumber existing refs
 250       $_->_arm_global_destructor
 251     }
 252   }
 253 }
 254
 255 sub DESTROY {
 256   return if &detected_reinvoked_destructor;
 257
 258   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   # some databases spew warnings on implicit disconnect
 260   local $SIG{__WARN__} = sub {};
 261   $_[0]->_dbh(undef);
 262
 263   # this op is necessary, since the very last perl runtime statement
 264   # triggers a global destruction shootout, and the $SIG localization
 265   # may very well be destroyed before perl actually gets to do the
 266   # $dbh undef
 267   1;
 268 }
 269
 270 # handle pid changes correctly - do not destroy parent's connection
 271 sub _verify_pid {
 272
 273   my $pid = $_[0]->_conn_pid;
 274
 275   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 276     $dbh->{InactiveDestroy} = 1;
 277     $_[0]->_dbh(undef);
 278     $_[0]->transaction_depth(0);
 279     $_[0]->savepoints([]);
 280   }
 281
 282   return;
 283 }
 284
 285 =head2 connect_info
 286
 287 This method is normally called by L<DBIx::Class::Schema/connection>, which
 288 encapsulates its argument list in an arrayref before passing them here.
 289
 290 The argument list may contain:
 291
 292 =over
 293
 294 =item *
 295
 296 The same 4-element argument set one would normally pass to
 297 L<DBI/connect>, optionally followed by
 298 L<extra attributes|/DBIx::Class specific connection attributes>
 299 recognized by DBIx::Class:
 300
 301   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 302
 303 =item *
 304
 305 A single code reference which returns a connected
 306 L<DBI database handle|DBI/connect> optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 308 by DBIx::Class:
 309
 310   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single hashref with all the attributes and the dsn/user/password
 315 mixed together:
 316
 317   $connect_info_args = [{
 318     dsn => $dsn,
 319     user => $user,
 320     password => $pass,
 321     %dbi_attributes,
 322     %extra_attributes,
 323   }];
 324
 325   $connect_info_args = [{
 326     dbh_maker => sub { DBI->connect (...) },
 327     %dbi_attributes,
 328     %extra_attributes,
 329   }];
 330
 331 This is particularly useful for L<Catalyst> based applications, allowing the
 332 following config (L<Config::General> style):
 333
 334   <Model::DB>
 335     schema_class   App::DB
 336     <connect_info>
 337       dsn          dbi:mysql:database=test
 338       user         testuser
 339       password     TestPass
 340       AutoCommit   1
 341     </connect_info>
 342   </Model::DB>
 343
 344 The C<dsn>/C<user>/C<password> combination can be substituted by the
 345 C<dbh_maker> key whose value is a coderef that returns a connected
 346 L<DBI database handle|DBI/connect>
 347
 348 =back
 349
 350 Please note that the L<DBI> docs recommend that you always explicitly
 351 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 352 recommends that it be set to I<1>, and that you perform transactions
 353 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 354 to I<1> if you do not do explicitly set it to zero.  This is the default
 355 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 356
 357 =head3 DBIx::Class specific connection attributes
 358
 359 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 360 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 361 the following connection options. These options can be mixed in with your other
 362 L<DBI> connection attributes, or placed in a separate hashref
 363 (C<\%extra_attributes>) as shown above.
 364
 365 Every time C<connect_info> is invoked, any previous settings for
 366 these options will be cleared before setting the new ones, regardless of
 367 whether any options are specified in the new C<connect_info>.
 368
 369
 370 =over
 371
 372 =item on_connect_do
 373
 374 Specifies things to do immediately after connecting or re-connecting to
 375 the database.  Its value may contain:
 376
 377 =over
 378
 379 =item a scalar
 380
 381 This contains one SQL statement to execute.
 382
 383 =item an array reference
 384
 385 This contains SQL statements to execute in order.  Each element contains
 386 a string or a code reference that returns a string.
 387
 388 =item a code reference
 389
 390 This contains some code to execute.  Unlike code references within an
 391 array reference, its return value is ignored.
 392
 393 =back
 394
 395 =item on_disconnect_do
 396
 397 Takes arguments in the same form as L</on_connect_do> and executes them
 398 immediately before disconnecting from the database.
 399
 400 Note, this only runs if you explicitly call L</disconnect> on the
 401 storage object.
 402
 403 =item on_connect_call
 404
 405 A more generalized form of L</on_connect_do> that calls the specified
 406 C<connect_call_METHOD> methods in your storage driver.
 407
 408   on_connect_do => 'select 1'
 409
 410 is equivalent to:
 411
 412   on_connect_call => [ [ do_sql => 'select 1' ] ]
 413
 414 Its values may contain:
 415
 416 =over
 417
 418 =item a scalar
 419
 420 Will call the C<connect_call_METHOD> method.
 421
 422 =item a code reference
 423
 424 Will execute C<< $code->($storage) >>
 425
 426 =item an array reference
 427
 428 Each value can be a method name or code reference.
 429
 430 =item an array of arrays
 431
 432 For each array, the first item is taken to be the C<connect_call_> method name
 433 or code reference, and the rest are parameters to it.
 434
 435 =back
 436
 437 Some predefined storage methods you may use:
 438
 439 =over
 440
 441 =item do_sql
 442
 443 Executes a SQL string or a code reference that returns a SQL string. This is
 444 what L</on_connect_do> and L</on_disconnect_do> use.
 445
 446 It can take:
 447
 448 =over
 449
 450 =item a scalar
 451
 452 Will execute the scalar as SQL.
 453
 454 =item an arrayref
 455
 456 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 457 attributes hashref and bind values.
 458
 459 =item a code reference
 460
 461 Will execute C<< $code->($storage) >> and execute the return array refs as
 462 above.
 463
 464 =back
 465
 466 =item datetime_setup
 467
 468 Execute any statements necessary to initialize the database session to return
 469 and accept datetime/timestamp values used with
 470 L<DBIx::Class::InflateColumn::DateTime>.
 471
 472 Only necessary for some databases, see your specific storage driver for
 473 implementation details.
 474
 475 =back
 476
 477 =item on_disconnect_call
 478
 479 Takes arguments in the same form as L</on_connect_call> and executes them
 480 immediately before disconnecting from the database.
 481
 482 Calls the C<disconnect_call_METHOD> methods as opposed to the
 483 C<connect_call_METHOD> methods called by L</on_connect_call>.
 484
 485 Note, this only runs if you explicitly call L</disconnect> on the
 486 storage object.
 487
 488 =item disable_sth_caching
 489
 490 If set to a true value, this option will disable the caching of
 491 statement handles via L<DBI/prepare_cached>.
 492
 493 =item limit_dialect
 494
 495 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 496 default L</sql_limit_dialect> setting of the storage (if any). For a list
 497 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 498
 499 =item quote_names
 500
 501 When true automatically sets L</quote_char> and L</name_sep> to the characters
 502 appropriate for your particular RDBMS. This option is preferred over specifying
 503 L</quote_char> directly.
 504
 505 =item quote_char
 506
 507 Specifies what characters to use to quote table and column names.
 508
 509 C<quote_char> expects either a single character, in which case is it
 510 is placed on either side of the table/column name, or an arrayref of length
 511 2 in which case the table/column name is placed between the elements.
 512
 513 For example under MySQL you should use C<< quote_char => '`' >>, and for
 514 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 515
 516 =item name_sep
 517
 518 This parameter is only useful in conjunction with C<quote_char>, and is used to
 519 specify the character that separates elements (schemas, tables, columns) from
 520 each other. If unspecified it defaults to the most commonly used C<.>.
 521
 522 =item unsafe
 523
 524 This Storage driver normally installs its own C<HandleError>, sets
 525 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 526 all database handles, including those supplied by a coderef.  It does this
 527 so that it can have consistent and useful error behavior.
 528
 529 If you set this option to a true value, Storage will not do its usual
 530 modifications to the database handle's attributes, and instead relies on
 531 the settings in your connect_info DBI options (or the values you set in
 532 your connection coderef, in the case that you are connecting via coderef).
 533
 534 Note that your custom settings can cause Storage to malfunction,
 535 especially if you set a C<HandleError> handler that suppresses exceptions
 536 and/or disable C<RaiseError>.
 537
 538 =item auto_savepoint
 539
 540 If this option is true, L<DBIx::Class> will use savepoints when nesting
 541 transactions, making it possible to recover from failure in the inner
 542 transaction without having to abort all outer transactions.
 543
 544 =item cursor_class
 545
 546 Use this argument to supply a cursor class other than the default
 547 L<DBIx::Class::Storage::DBI::Cursor>.
 548
 549 =back
 550
 551 Some real-life examples of arguments to L</connect_info> and
 552 L<DBIx::Class::Schema/connect>
 553
 554   # Simple SQLite connection
 555   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 556
 557   # Connect via subref
 558   ->connect_info([ sub { DBI->connect(...) } ]);
 559
 560   # Connect via subref in hashref
 561   ->connect_info([{
 562     dbh_maker => sub { DBI->connect(...) },
 563     on_connect_do => 'alter session ...',
 564   }]);
 565
 566   # A bit more complicated
 567   ->connect_info(
 568     [
 569       'dbi:Pg:dbname=foo',
 570       'postgres',
 571       'my_pg_password',
 572       { AutoCommit => 1 },
 573       { quote_char => q{"} },
 574     ]
 575   );
 576
 577   # Equivalent to the previous example
 578   ->connect_info(
 579     [
 580       'dbi:Pg:dbname=foo',
 581       'postgres',
 582       'my_pg_password',
 583       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 584     ]
 585   );
 586
 587   # Same, but with hashref as argument
 588   # See parse_connect_info for explanation
 589   ->connect_info(
 590     [{
 591       dsn         => 'dbi:Pg:dbname=foo',
 592       user        => 'postgres',
 593       password    => 'my_pg_password',
 594       AutoCommit  => 1,
 595       quote_char  => q{"},
 596       name_sep    => q{.},
 597     }]
 598   );
 599
 600   # Subref + DBIx::Class-specific connection options
 601   ->connect_info(
 602     [
 603       sub { DBI->connect(...) },
 604       {
 605           quote_char => q{`},
 606           name_sep => q{@},
 607           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 608           disable_sth_caching => 1,
 609       },
 610     ]
 611   );
 612
 613
 614
 615 =cut
 616
 617 sub connect_info {
 618   my ($self, $info) = @_;
 619
 620   return $self->_connect_info if !$info;
 621
 622   $self->_connect_info($info); # copy for _connect_info
 623
 624   $info = $self->_normalize_connect_info($info)
 625     if ref $info eq 'ARRAY';
 626
 627   my %attrs = (
 628     %{ $self->_default_dbi_connect_attributes || {} },
 629     %{ $info->{attributes} || {} },
 630   );
 631
 632   my @args = @{ $info->{arguments} };
 633
 634   if (keys %attrs and ref $args[0] ne 'CODE') {
 635     carp_unique (
 636         'You provided explicit AutoCommit => 0 in your connection_info. '
 637       . 'This is almost universally a bad idea (see the footnotes of '
 638       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 639       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 640       . 'this warning.'
 641     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 642
 643     push @args, \%attrs if keys %attrs;
 644   }
 645
 646   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 647   # OR a single-element coderef-based $dbh factory
 648   $self->_dbi_connect_info(\@args);
 649
 650   # extract the individual storage options
 651   for my $storage_opt (keys %{ $info->{storage_options} }) {
 652     my $value = $info->{storage_options}{$storage_opt};
 653
 654     $self->$storage_opt($value);
 655   }
 656
 657   # Extract the individual sqlmaker options
 658   #
 659   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 660   #  the new set of options
 661   $self->_sql_maker(undef);
 662   $self->_sql_maker_opts({});
 663
 664   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 665     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 666
 667     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 668   }
 669
 670   # FIXME - dirty:
 671   # save attributes in a separate accessor so they are always
 672   # introspectable, even in case of a CODE $dbhmaker
 673   $self->_dbic_connect_attributes (\%attrs);
 674
 675   return $self->_connect_info;
 676 }
 677
 678 sub _dbi_connect_info {
 679   my $self = shift;
 680
 681   return $self->{_dbi_connect_info} = $_[0]
 682     if @_;
 683
 684   my $conninfo = $self->{_dbi_connect_info} || [];
 685
 686   # last ditch effort to grab a DSN
 687   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 688     my @new_conninfo = @$conninfo;
 689     $new_conninfo[0] = $ENV{DBI_DSN};
 690     $conninfo = \@new_conninfo;
 691   }
 692
 693   return $conninfo;
 694 }
 695
 696
 697 sub _normalize_connect_info {
 698   my ($self, $info_arg) = @_;
 699   my %info;
 700
 701   my @args = @$info_arg;  # take a shallow copy for further mutilation
 702
 703   # combine/pre-parse arguments depending on invocation style
 704
 705   my %attrs;
 706   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 707     %attrs = %{ $args[1] || {} };
 708     @args = $args[0];
 709   }
 710   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 711     %attrs = %{$args[0]};
 712     @args = ();
 713     if (my $code = delete $attrs{dbh_maker}) {
 714       @args = $code;
 715
 716       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 717       if (@ignored) {
 718         carp sprintf (
 719             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 720           . "to the result of 'dbh_maker'",
 721
 722           join (', ', map { "'$_'" } (@ignored) ),
 723         );
 724       }
 725     }
 726     else {
 727       @args = delete @attrs{qw/dsn user password/};
 728     }
 729   }
 730   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 731     %attrs = (
 732       % { $args[3] || {} },
 733       % { $args[4] || {} },
 734     );
 735     @args = @args[0,1,2];
 736   }
 737
 738   $info{arguments} = \@args;
 739
 740   my @storage_opts = grep exists $attrs{$_},
 741     @storage_options, 'cursor_class';
 742
 743   @{ $info{storage_options} }{@storage_opts} =
 744     delete @attrs{@storage_opts} if @storage_opts;
 745
 746   my @sql_maker_opts = grep exists $attrs{$_},
 747     qw/limit_dialect quote_char name_sep quote_names/;
 748
 749   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 750     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 751
 752   $info{attributes} = \%attrs if %attrs;
 753
 754   return \%info;
 755 }
 756
 757 sub _default_dbi_connect_attributes () {
 758   +{
 759     AutoCommit => 1,
 760     PrintError => 0,
 761     RaiseError => 1,
 762     ShowErrorStatement => 1,
 763   };
 764 }
 765
 766 =head2 on_connect_do
 767
 768 This method is deprecated in favour of setting via L</connect_info>.
 769
 770 =cut
 771
 772 =head2 on_disconnect_do
 773
 774 This method is deprecated in favour of setting via L</connect_info>.
 775
 776 =cut
 777
 778 sub _parse_connect_do {
 779   my ($self, $type) = @_;
 780
 781   my $val = $self->$type;
 782   return () if not defined $val;
 783
 784   my @res;
 785
 786   if (not ref($val)) {
 787     push @res, [ 'do_sql', $val ];
 788   } elsif (ref($val) eq 'CODE') {
 789     push @res, $val;
 790   } elsif (ref($val) eq 'ARRAY') {
 791     push @res, map { [ 'do_sql', $_ ] } @$val;
 792   } else {
 793     $self->throw_exception("Invalid type for $type: ".ref($val));
 794   }
 795
 796   return \@res;
 797 }
 798
 799 =head2 dbh_do
 800
 801 Arguments: ($subref | $method_name), @extra_coderef_args?
 802
 803 Execute the given $subref or $method_name using the new exception-based
 804 connection management.
 805
 806 The first two arguments will be the storage object that C<dbh_do> was called
 807 on and a database handle to use.  Any additional arguments will be passed
 808 verbatim to the called subref as arguments 2 and onwards.
 809
 810 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 811 exception handling and reconnection (or failover in future subclasses).
 812
 813 Your subref should have no side-effects outside of the database, as
 814 there is the potential for your subref to be partially double-executed
 815 if the database connection was stale/dysfunctional.
 816
 817 Example:
 818
 819   my @stuff = $schema->storage->dbh_do(
 820     sub {
 821       my ($storage, $dbh, @cols) = @_;
 822       my $cols = join(q{, }, @cols);
 823       $dbh->selectrow_array("SELECT $cols FROM foo");
 824     },
 825     @column_list
 826   );
 827
 828 =cut
 829
 830 sub dbh_do {
 831   my $self = shift;
 832   my $run_target = shift; # either a coderef or a method name
 833
 834   # short circuit when we know there is no need for a runner
 835   #
 836   # FIXME - assumption may be wrong
 837   # the rationale for the txn_depth check is that if this block is a part
 838   # of a larger transaction, everything up to that point is screwed anyway
 839   return $self->$run_target($self->_get_dbh, @_)
 840     if $self->{_in_do_block} or $self->transaction_depth;
 841
 842   # take a ref instead of a copy, to preserve @_ aliasing
 843   # semantics within the coderef, but only if needed
 844   # (pseudoforking doesn't like this trick much)
 845   my $args = @_ ? \@_ : [];
 846
 847   DBIx::Class::Storage::BlockRunner->new(
 848     storage => $self,
 849     wrap_txn => 0,
 850     retry_handler => sub {
 851       $_[0]->failed_attempt_count == 1
 852         and
 853       ! $_[0]->storage->connected
 854     },
 855   )->run(sub {
 856     $self->$run_target ($self->_get_dbh, @$args )
 857   });
 858 }
 859
 860 sub txn_do {
 861   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 862   shift->next::method(@_);
 863 }
 864
 865 =head2 disconnect
 866
 867 Our C<disconnect> method also performs a rollback first if the
 868 database is not in C<AutoCommit> mode.
 869
 870 =cut
 871
 872 sub disconnect {
 873
 874   if( my $dbh = $_[0]->_dbh ) {
 875
 876     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 877       ( $_[0]->on_disconnect_call || () ),
 878       $_[0]->_parse_connect_do ('on_disconnect_do')
 879     );
 880
 881     # stops the "implicit rollback on disconnect" warning
 882     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 883
 884     %{ $dbh->{CachedKids} } = ();
 885     $dbh->disconnect;
 886     $_[0]->_dbh(undef);
 887   }
 888 }
 889
 890 =head2 with_deferred_fk_checks
 891
 892 =over 4
 893
 894 =item Arguments: C<$coderef>
 895
 896 =item Return Value: The return value of $coderef
 897
 898 =back
 899
 900 Storage specific method to run the code ref with FK checks deferred or
 901 in MySQL's case disabled entirely.
 902
 903 =cut
 904
 905 # Storage subclasses should override this
 906 sub with_deferred_fk_checks {
 907   #my ($self, $sub) = @_;
 908   $_[1]->();
 909 }
 910
 911 =head2 connected
 912
 913 =over
 914
 915 =item Arguments: none
 916
 917 =item Return Value: 1|0
 918
 919 =back
 920
 921 Verifies that the current database handle is active and ready to execute
 922 an SQL statement (e.g. the connection did not get stale, server is still
 923 answering, etc.) This method is used internally by L</dbh>.
 924
 925 =cut
 926
 927 sub connected {
 928   return 0 unless $_[0]->_seems_connected;
 929
 930   #be on the safe side
 931   local $_[0]->_dbh->{RaiseError} = 1;
 932
 933   return $_[0]->_ping;
 934 }
 935
 936 sub _seems_connected {
 937   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938
 939   ($_[0]->_dbh || return 0)->FETCH('Active');
 940 }
 941
 942 sub _ping {
 943   ($_[0]->_dbh || return 0)->ping;
 944 }
 945
 946 sub ensure_connected {
 947   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 948 }
 949
 950 =head2 dbh
 951
 952 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 953 is guaranteed to be healthy by implicitly calling L</connected>, and if
 954 necessary performing a reconnection before returning. Keep in mind that this
 955 is very B<expensive> on some database engines. Consider using L</dbh_do>
 956 instead.
 957
 958 =cut
 959
 960 sub dbh {
 961   # maybe save a ping call
 962   $_[0]->_dbh
 963     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 964     : $_[0]->_populate_dbh
 965   ;
 966 }
 967
 968 # this is the internal "get dbh or connect (don't check)" method
 969 sub _get_dbh {
 970   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 971   $_[0]->_dbh || $_[0]->_populate_dbh;
 972 }
 973
 974 # *DELIBERATELY* not a setter (for the time being)
 975 # Too intertwined with everything else for any kind of sanity
 976 sub sql_maker {
 977   my $self = shift;
 978
 979   $self->throw_exception('sql_maker() is not a setter method') if @_;
 980
 981   unless ($self->_sql_maker) {
 982     my $sql_maker_class = $self->sql_maker_class;
 983
 984     my %opts = %{$self->_sql_maker_opts||{}};
 985     my $dialect =
 986       $opts{limit_dialect}
 987         ||
 988       $self->sql_limit_dialect
 989         ||
 990       do {
 991         my $s_class = (ref $self) || $self;
 992         carp_unique (
 993           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 994         . 'have not supplied an explicit limit_dialect in your connection_info. '
 995         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 996         . 'databases but can be (and often is) painfully slow. '
 997         . "Please file an RT ticket against '$s_class'"
 998         ) if $self->_dbi_connect_info->[0];
 999
1000         'GenericSubQ';
1001       }
1002     ;
1003
1004     my ($quote_char, $name_sep);
1005
1006     if ($opts{quote_names}) {
1007       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1008         my $s_class = (ref $self) || $self;
1009         carp_unique (
1010           "You requested 'quote_names' but your storage class ($s_class) does "
1011         . 'not explicitly define a default sql_quote_char and you have not '
1012         . 'supplied a quote_char as part of your connection_info. DBIC will '
1013         .q{default to the ANSI SQL standard quote '"', which works most of }
1014         . "the time. Please file an RT ticket against '$s_class'."
1015         );
1016
1017         '"'; # RV
1018       };
1019
1020       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1021     }
1022
1023     $self->_sql_maker($sql_maker_class->new(
1024       bindtype=>'columns',
1025       array_datatypes => 1,
1026       limit_dialect => $dialect,
1027       ($quote_char ? (quote_char => $quote_char) : ()),
1028       name_sep => ($name_sep || '.'),
1029       %opts,
1030     ));
1031   }
1032   return $self->_sql_maker;
1033 }
1034
1035 # nothing to do by default
1036 sub _rebless {}
1037 sub _init {}
1038
1039 sub _populate_dbh {
1040
1041   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1042
1043   $_[0]->_dbh_details({}); # reset everything we know
1044
1045   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1046   #$_[0]->_sql_maker(undef); # this may also end up being different
1047
1048   $_[0]->_dbh($_[0]->_connect);
1049
1050   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1051
1052   $_[0]->_determine_driver;
1053
1054   # Always set the transaction depth on connect, since
1055   #  there is no transaction in progress by definition
1056   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1057
1058   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1059
1060   $_[0]->_dbh;
1061 }
1062
1063 sub _run_connection_actions {
1064
1065   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1066     ( $_[0]->on_connect_call || () ),
1067     $_[0]->_parse_connect_do ('on_connect_do'),
1068   );
1069 }
1070
1071
1072
1073 sub set_use_dbms_capability {
1074   $_[0]->set_inherited ($_[1], $_[2]);
1075 }
1076
1077 sub get_use_dbms_capability {
1078   my ($self, $capname) = @_;
1079
1080   my $use = $self->get_inherited ($capname);
1081   return defined $use
1082     ? $use
1083     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1084   ;
1085 }
1086
1087 sub set_dbms_capability {
1088   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1089 }
1090
1091 sub get_dbms_capability {
1092   my ($self, $capname) = @_;
1093
1094   my $cap = $self->_dbh_details->{capability}{$capname};
1095
1096   unless (defined $cap) {
1097     if (my $meth = $self->can ("_determine$capname")) {
1098       $cap = $self->$meth ? 1 : 0;
1099     }
1100     else {
1101       $cap = 0;
1102     }
1103
1104     $self->set_dbms_capability ($capname, $cap);
1105   }
1106
1107   return $cap;
1108 }
1109
1110 sub _server_info {
1111   my $self = shift;
1112
1113   # FIXME - ideally this needs to be an ||= assignment, and the final
1114   # assignment at the end of this do{} should be gone entirely. However
1115   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1116   $self->_dbh_details->{info} || do {
1117
1118     my $info = {};
1119
1120     my $server_version = try {
1121       $self->_get_server_version
1122     } catch {
1123       # driver determination *may* use this codepath
1124       # in which case we must rethrow
1125       $self->throw_exception($_) if $self->{_in_determine_driver};
1126
1127       # $server_version on failure
1128       undef;
1129     };
1130
1131     if (defined $server_version) {
1132       $info->{dbms_version} = $server_version;
1133
1134       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1135       my @verparts = split (/\./, $numeric_version);
1136       if (
1137         @verparts
1138           &&
1139         $verparts[0] <= 999
1140       ) {
1141         # consider only up to 3 version parts, iff not more than 3 digits
1142         my @use_parts;
1143         while (@verparts && @use_parts < 3) {
1144           my $p = shift @verparts;
1145           last if $p > 999;
1146           push @use_parts, $p;
1147         }
1148         push @use_parts, 0 while @use_parts < 3;
1149
1150         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1151       }
1152     }
1153
1154     $self->_dbh_details->{info} = $info;
1155   };
1156 }
1157
1158 sub _get_server_version {
1159   shift->_dbh_get_info('SQL_DBMS_VER');
1160 }
1161
1162 sub _dbh_get_info {
1163   my ($self, $info) = @_;
1164
1165   if ($info =~ /[^0-9]/) {
1166     require DBI::Const::GetInfoType;
1167     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1168     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1169       unless defined $info;
1170   }
1171
1172   $self->_get_dbh->get_info($info);
1173 }
1174
1175 sub _describe_connection {
1176   require DBI::Const::GetInfoReturn;
1177
1178   my $self = shift;
1179
1180   my $drv;
1181   try {
1182     $drv = $self->_extract_driver_from_connect_info;
1183     $self->ensure_connected;
1184   };
1185
1186   $drv = "DBD::$drv" if $drv;
1187
1188   my $res = {
1189     DBIC_DSN => $self->_dbi_connect_info->[0],
1190     DBI_VER => DBI->VERSION,
1191     DBIC_VER => DBIx::Class->VERSION,
1192     DBIC_DRIVER => ref $self,
1193     $drv ? (
1194       DBD => $drv,
1195       DBD_VER => try { $drv->VERSION },
1196     ) : (),
1197   };
1198
1199   # try to grab data even if we never managed to connect
1200   # will cover us in cases of an oddly broken half-connect
1201   for my $inf (
1202     #keys %DBI::Const::GetInfoType::GetInfoType,
1203     qw/
1204       SQL_CURSOR_COMMIT_BEHAVIOR
1205       SQL_CURSOR_ROLLBACK_BEHAVIOR
1206       SQL_CURSOR_SENSITIVITY
1207       SQL_DATA_SOURCE_NAME
1208       SQL_DBMS_NAME
1209       SQL_DBMS_VER
1210       SQL_DEFAULT_TXN_ISOLATION
1211       SQL_DM_VER
1212       SQL_DRIVER_NAME
1213       SQL_DRIVER_ODBC_VER
1214       SQL_DRIVER_VER
1215       SQL_EXPRESSIONS_IN_ORDERBY
1216       SQL_GROUP_BY
1217       SQL_IDENTIFIER_CASE
1218       SQL_IDENTIFIER_QUOTE_CHAR
1219       SQL_MAX_CATALOG_NAME_LEN
1220       SQL_MAX_COLUMN_NAME_LEN
1221       SQL_MAX_IDENTIFIER_LEN
1222       SQL_MAX_TABLE_NAME_LEN
1223       SQL_MULTIPLE_ACTIVE_TXN
1224       SQL_MULT_RESULT_SETS
1225       SQL_NEED_LONG_DATA_LEN
1226       SQL_NON_NULLABLE_COLUMNS
1227       SQL_ODBC_VER
1228       SQL_QUALIFIER_NAME_SEPARATOR
1229       SQL_QUOTED_IDENTIFIER_CASE
1230       SQL_TXN_CAPABLE
1231       SQL_TXN_ISOLATION_OPTION
1232     /
1233   ) {
1234     # some drivers barf on things they do not know about instead
1235     # of returning undef
1236     my $v = try { $self->_dbh_get_info($inf) };
1237     next unless defined $v;
1238
1239     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1240     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1241     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1242   }
1243
1244   $res;
1245 }
1246
1247 sub _determine_driver {
1248   my ($self) = @_;
1249
1250   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1251     my $started_connected = 0;
1252     local $self->{_in_determine_driver} = 1;
1253
1254     if (ref($self) eq __PACKAGE__) {
1255       my $driver;
1256       if ($self->_dbh) { # we are connected
1257         $driver = $self->_dbh->{Driver}{Name};
1258         $started_connected = 1;
1259       }
1260       else {
1261         $driver = $self->_extract_driver_from_connect_info;
1262       }
1263
1264       if ($driver) {
1265         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1266         if ($self->load_optional_class($storage_class)) {
1267           mro::set_mro($storage_class, 'c3');
1268           bless $self, $storage_class;
1269           $self->_rebless();
1270         }
1271         else {
1272           $self->_warn_undetermined_driver(
1273             'This version of DBIC does not yet seem to supply a driver for '
1274           . "your particular RDBMS and/or connection method ('$driver')."
1275           );
1276         }
1277       }
1278       else {
1279         $self->_warn_undetermined_driver(
1280           'Unable to extract a driver name from connect info - this '
1281         . 'should not have happened.'
1282         );
1283       }
1284     }
1285
1286     $self->_driver_determined(1);
1287
1288     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1289
1290     if ($self->can('source_bind_attributes')) {
1291       $self->throw_exception(
1292         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1293       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1294       . 'If you are not sure how to proceed please contact the development team via '
1295       . DBIx::Class::_ENV_::HELP_URL
1296       );
1297     }
1298
1299     $self->_init; # run driver-specific initializations
1300
1301     $self->_run_connection_actions
1302         if !$started_connected && defined $self->_dbh;
1303   }
1304 }
1305
1306 sub _extract_driver_from_connect_info {
1307   my $self = shift;
1308
1309   my $drv;
1310
1311   # if connect_info is a CODEREF, we have no choice but to connect
1312   if (
1313     ref $self->_dbi_connect_info->[0]
1314       and
1315     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1316   ) {
1317     $self->_populate_dbh;
1318     $drv = $self->_dbh->{Driver}{Name};
1319   }
1320   else {
1321     # try to use dsn to not require being connected, the driver may still
1322     # force a connection later in _rebless to determine version
1323     # (dsn may not be supplied at all if all we do is make a mock-schema)
1324     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1325     $drv ||= $ENV{DBI_DRIVER};
1326   }
1327
1328   return $drv;
1329 }
1330
1331 sub _determine_connector_driver {
1332   my ($self, $conn) = @_;
1333
1334   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1335
1336   if (not $dbtype) {
1337     $self->_warn_undetermined_driver(
1338       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1339     . "$conn connector - this should not have happened."
1340     );
1341     return;
1342   }
1343
1344   $dbtype =~ s/\W/_/gi;
1345
1346   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1347   return if $self->isa($subclass);
1348
1349   if ($self->load_optional_class($subclass)) {
1350     bless $self, $subclass;
1351     $self->_rebless;
1352   }
1353   else {
1354     $self->_warn_undetermined_driver(
1355       'This version of DBIC does not yet seem to supply a driver for '
1356     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1357     );
1358   }
1359 }
1360
1361 sub _warn_undetermined_driver {
1362   my ($self, $msg) = @_;
1363
1364   require Data::Dumper::Concise;
1365
1366   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1367   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1368   . "does not go away, file a bugreport including the following info:\n"
1369   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1370   );
1371 }
1372
1373 sub _do_connection_actions {
1374   my ($self, $method_prefix, $call, @args) = @_;
1375
1376     if (not ref($call)) {
1377       my $method = $method_prefix . $call;
1378       $self->$method(@args);
1379     }
1380     elsif (ref($call) eq 'CODE') {
1381       $self->$call(@args);
1382     }
1383     elsif (ref($call) eq 'ARRAY') {
1384       if (ref($call->[0]) ne 'ARRAY') {
1385         $self->_do_connection_actions($method_prefix, $_) for @$call;
1386       }
1387       else {
1388         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1389       }
1390     }
1391     else {
1392       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1393     }
1394
1395   return $self;
1396 }
1397
1398 sub connect_call_do_sql {
1399   my $self = shift;
1400   $self->_do_query(@_);
1401 }
1402
1403 sub disconnect_call_do_sql {
1404   my $self = shift;
1405   $self->_do_query(@_);
1406 }
1407
1408 =head2 connect_call_datetime_setup
1409
1410 A no-op stub method, provided so that one can always safely supply the
1411 L<connection option|/DBIx::Class specific connection attributes>
1412
1413  on_connect_call => 'datetime_setup'
1414
1415 This way one does not need to know in advance whether the underlying
1416 storage requires any sort of hand-holding when dealing with calendar
1417 data.
1418
1419 =cut
1420
1421 sub connect_call_datetime_setup { 1 }
1422
1423 sub _do_query {
1424   my ($self, $action) = @_;
1425
1426   if (ref $action eq 'CODE') {
1427     $action = $action->($self);
1428     $self->_do_query($_) foreach @$action;
1429   }
1430   else {
1431     # Most debuggers expect ($sql, @bind), so we need to exclude
1432     # the attribute hash which is the second argument to $dbh->do
1433     # furthermore the bind values are usually to be presented
1434     # as named arrayref pairs, so wrap those here too
1435     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1436     my $sql = shift @do_args;
1437     my $attrs = shift @do_args;
1438     my @bind = map { [ undef, $_ ] } @do_args;
1439
1440     $self->dbh_do(sub {
1441       $_[0]->_query_start($sql, \@bind);
1442       $_[1]->do($sql, $attrs, @do_args);
1443       $_[0]->_query_end($sql, \@bind);
1444     });
1445   }
1446
1447   return $self;
1448 }
1449
1450 sub _connect {
1451   my $self = shift;
1452
1453   my $info = $self->_dbi_connect_info;
1454
1455   $self->throw_exception("You did not provide any connection_info")
1456     unless defined $info->[0];
1457
1458   my ($old_connect_via, $dbh);
1459
1460   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1461
1462   # this odd anonymous coderef dereference is in fact really
1463   # necessary to avoid the unwanted effect described in perl5
1464   # RT#75792
1465   #
1466   # in addition the coderef itself can't reside inside the try{} block below
1467   # as it somehow triggers a leak under perl -d
1468   my $dbh_error_handler_installer = sub {
1469     weaken (my $weak_self = $_[0]);
1470
1471     # the coderef is blessed so we can distinguish it from externally
1472     # supplied handles (which must be preserved)
1473     $_[1]->{HandleError} = bless sub {
1474       if ($weak_self) {
1475         $weak_self->throw_exception("DBI Exception: $_[0]");
1476       }
1477       else {
1478         # the handler may be invoked by something totally out of
1479         # the scope of DBIC
1480         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1481       }
1482     }, '__DBIC__DBH__ERROR__HANDLER__';
1483   };
1484
1485   try {
1486     if(ref $info->[0] eq 'CODE') {
1487       $dbh = $info->[0]->();
1488     }
1489     else {
1490       require DBI;
1491       $dbh = DBI->connect(@$info);
1492     }
1493
1494     die $DBI::errstr unless $dbh;
1495
1496     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1497       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1498       . 'not continue',
1499       ref $info->[0] eq 'CODE'
1500         ? "Connection coderef $info->[0] returned a"
1501         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1502     ) unless $dbh->FETCH('Active');
1503
1504     # sanity checks unless asked otherwise
1505     unless ($self->unsafe) {
1506
1507       $self->throw_exception(
1508         'Refusing clobbering of {HandleError} installed on externally supplied '
1509        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1510       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1511
1512       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1513       # request, or an external handle. Complain and set anyway
1514       unless ($dbh->{RaiseError}) {
1515         carp( ref $info->[0] eq 'CODE'
1516
1517           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1518            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1519            .'attribute has been supplied'
1520
1521           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1522            .'unsafe => 1. Toggling RaiseError back to true'
1523         );
1524
1525         $dbh->{RaiseError} = 1;
1526       }
1527
1528       $dbh_error_handler_installer->($self, $dbh);
1529     }
1530   }
1531   catch {
1532     $self->throw_exception("DBI Connection failed: $_")
1533   };
1534
1535   $self->_dbh_autocommit($dbh->{AutoCommit});
1536   return $dbh;
1537 }
1538
1539 sub txn_begin {
1540   # this means we have not yet connected and do not know the AC status
1541   # (e.g. coderef $dbh), need a full-fledged connection check
1542   if (! defined $_[0]->_dbh_autocommit) {
1543     $_[0]->ensure_connected;
1544   }
1545   # Otherwise simply connect or re-connect on pid changes
1546   else {
1547     $_[0]->_get_dbh;
1548   }
1549
1550   shift->next::method(@_);
1551 }
1552
1553 sub _exec_txn_begin {
1554   my $self = shift;
1555
1556   # if the user is utilizing txn_do - good for him, otherwise we need to
1557   # ensure that the $dbh is healthy on BEGIN.
1558   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1559   # will be replaced by a failure of begin_work itself (which will be
1560   # then retried on reconnect)
1561   if ($self->{_in_do_block}) {
1562     $self->_dbh->begin_work;
1563   } else {
1564     $self->dbh_do(sub { $_[1]->begin_work });
1565   }
1566 }
1567
1568 sub txn_commit {
1569   my $self = shift;
1570
1571   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1572     unless $self->_seems_connected;
1573
1574   # esoteric case for folks using external $dbh handles
1575   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1576     carp "Storage transaction_depth 0 does not match "
1577         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1578     $self->transaction_depth(1);
1579   }
1580
1581   $self->next::method(@_);
1582
1583   # if AutoCommit is disabled txn_depth never goes to 0
1584   # as a new txn is started immediately on commit
1585   $self->transaction_depth(1) if (
1586     !$self->transaction_depth
1587       and
1588     defined $self->_dbh_autocommit
1589       and
1590     ! $self->_dbh_autocommit
1591   );
1592 }
1593
1594 sub _exec_txn_commit {
1595   shift->_dbh->commit;
1596 }
1597
1598 sub txn_rollback {
1599   my $self = shift;
1600
1601   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1602     unless $self->_seems_connected;
1603
1604   # esoteric case for folks using external $dbh handles
1605   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1606     carp "Storage transaction_depth 0 does not match "
1607         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1608     $self->transaction_depth(1);
1609   }
1610
1611   $self->next::method(@_);
1612
1613   # if AutoCommit is disabled txn_depth never goes to 0
1614   # as a new txn is started immediately on commit
1615   $self->transaction_depth(1) if (
1616     !$self->transaction_depth
1617       and
1618     defined $self->_dbh_autocommit
1619       and
1620     ! $self->_dbh_autocommit
1621   );
1622 }
1623
1624 sub _exec_txn_rollback {
1625   shift->_dbh->rollback;
1626 }
1627
1628 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1629 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1630   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1631     unless $_[0]->_seems_connected;
1632   shift->next::method(@_);
1633 EOS
1634
1635 # This used to be the top-half of _execute.  It was split out to make it
1636 #  easier to override in NoBindVars without duping the rest.  It takes up
1637 #  all of _execute's args, and emits $sql, @bind.
1638 sub _prep_for_execute {
1639   #my ($self, $op, $ident, $args) = @_;
1640   return shift->_gen_sql_bind(@_)
1641 }
1642
1643 sub _gen_sql_bind {
1644   my ($self, $op, $ident, $args) = @_;
1645
1646   my ($colinfos, $from);
1647   if ( blessed($ident) ) {
1648     $from = $ident->from;
1649     $colinfos = $ident->columns_info;
1650   }
1651
1652   my ($sql, $bind);
1653   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1654
1655   $bind = $self->_resolve_bindattrs(
1656     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1657   );
1658
1659   if (
1660     ! $ENV{DBIC_DT_SEARCH_OK}
1661       and
1662     $op eq 'select'
1663       and
1664     first {
1665       length ref $_->[1]
1666         and
1667       blessed($_->[1])
1668         and
1669       $_->[1]->isa('DateTime')
1670     } @$bind
1671   ) {
1672     carp_unique 'DateTime objects passed to search() are not supported '
1673       . 'properly (InflateColumn::DateTime formats and settings are not '
1674       . 'respected.) See ".. format a DateTime object for searching?" in '
1675       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1676       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1677   }
1678
1679   return( $sql, $bind );
1680 }
1681
1682 sub _resolve_bindattrs {
1683   my ($self, $ident, $bind, $colinfos) = @_;
1684
1685   my $resolve_bindinfo = sub {
1686     #my $infohash = shift;
1687
1688     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1689
1690     my $ret;
1691     if (my $col = $_[0]->{dbic_colname}) {
1692       $ret = { %{$_[0]} };
1693
1694       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1695         if $colinfos->{$col}{data_type};
1696
1697       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1698         if $colinfos->{$col}{size};
1699     }
1700
1701     $ret || $_[0];
1702   };
1703
1704   return [ map {
1705     my $resolved =
1706       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1707     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1708     : (ref $_->[0] eq 'HASH')           ? [(
1709                                             ! keys %{$_->[0]}
1710                                               or
1711                                             exists $_->[0]{dbd_attrs}
1712                                               or
1713                                             $_->[0]{sqlt_datatype}
1714                                            ) ? $_->[0]
1715                                              : $resolve_bindinfo->($_->[0])
1716                                            , $_->[1]
1717                                           ]
1718     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1719     :                                     [ $resolve_bindinfo->(
1720                                               { dbic_colname => $_->[0] }
1721                                             ), $_->[1] ]
1722     ;
1723
1724     if (
1725       ! exists $resolved->[0]{dbd_attrs}
1726         and
1727       ! $resolved->[0]{sqlt_datatype}
1728         and
1729       length ref $resolved->[1]
1730         and
1731       ! is_plain_value $resolved->[1]
1732     ) {
1733       require Data::Dumper;
1734       local $Data::Dumper::Maxdepth = 1;
1735       local $Data::Dumper::Terse = 1;
1736       local $Data::Dumper::Useqq = 1;
1737       local $Data::Dumper::Indent = 0;
1738       local $Data::Dumper::Pad = ' ';
1739       $self->throw_exception(
1740         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1741       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1742       );
1743     }
1744
1745     $resolved;
1746
1747   } @$bind ];
1748 }
1749
1750 sub _format_for_trace {
1751   #my ($self, $bind) = @_;
1752
1753   ### Turn @bind from something like this:
1754   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1755   ### to this:
1756   ###   ( "'1'", "'3'" )
1757
1758   map {
1759     defined( $_ && $_->[1] )
1760       ? qq{'$_->[1]'}
1761       : q{NULL}
1762   } @{$_[1] || []};
1763 }
1764
1765 sub _query_start {
1766   my ( $self, $sql, $bind ) = @_;
1767
1768   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1769     if $self->debug;
1770 }
1771
1772 sub _query_end {
1773   my ( $self, $sql, $bind ) = @_;
1774
1775   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1776     if $self->debug;
1777 }
1778
1779 sub _dbi_attrs_for_bind {
1780   #my ($self, $ident, $bind) = @_;
1781
1782   return [ map {
1783
1784     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1785
1786   : ! $_->{sqlt_datatype}   ? undef
1787
1788   :                           do {
1789
1790     # cache the result in the dbh_details hash, as it (usually) can not change
1791     # unless we connect to something else
1792     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1793     # the LOB storage
1794     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1795
1796     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1797       if ! exists $cache->{$_->{sqlt_datatype}};
1798
1799     $cache->{$_->{sqlt_datatype}};
1800
1801   } } map { $_->[0] } @{$_[2]} ];
1802 }
1803
1804 sub _execute {
1805   my ($self, $op, $ident, @args) = @_;
1806
1807   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1808
1809   # not even a PID check - we do not care about the state of the _dbh.
1810   # All we need is to get the appropriate drivers loaded if they aren't
1811   # already so that the assumption in ad7c50fc26e holds
1812   $self->_populate_dbh unless $self->_dbh;
1813
1814   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1815     $sql,
1816     $bind,
1817     $self->_dbi_attrs_for_bind($ident, $bind),
1818   );
1819 }
1820
1821 sub _dbh_execute {
1822   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1823
1824   $self->_query_start( $sql, $bind );
1825
1826   my $sth = $self->_bind_sth_params(
1827     $self->_prepare_sth($dbh, $sql),
1828     $bind,
1829     $bind_attrs,
1830   );
1831
1832   # Can this fail without throwing an exception anyways???
1833   my $rv = $sth->execute();
1834   $self->throw_exception(
1835     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1836   ) if !$rv;
1837
1838   $self->_query_end( $sql, $bind );
1839
1840   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1841 }
1842
1843 sub _prepare_sth {
1844   my ($self, $dbh, $sql) = @_;
1845
1846   # 3 is the if_active parameter which avoids active sth re-use
1847   my $sth = $self->disable_sth_caching
1848     ? $dbh->prepare($sql)
1849     : $dbh->prepare_cached($sql, {}, 3);
1850
1851   # XXX You would think RaiseError would make this impossible,
1852   #  but apparently that's not true :(
1853   $self->throw_exception(
1854     $dbh->errstr
1855       ||
1856     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1857             .'an exception and/or setting $dbh->errstr',
1858       length ($sql) > 20
1859         ? substr($sql, 0, 20) . '...'
1860         : $sql
1861       ,
1862       'DBD::' . $dbh->{Driver}{Name},
1863     )
1864   ) if !$sth;
1865
1866   $sth;
1867 }
1868
1869 sub _bind_sth_params {
1870   my ($self, $sth, $bind, $bind_attrs) = @_;
1871
1872   for my $i (0 .. $#$bind) {
1873     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1874       $sth->bind_param_inout(
1875         $i + 1, # bind params counts are 1-based
1876         $bind->[$i][1],
1877         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1878         $bind_attrs->[$i],
1879       );
1880     }
1881     else {
1882       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1883       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1884         ? "$bind->[$i][1]"
1885         : $bind->[$i][1]
1886       ;
1887
1888       $sth->bind_param(
1889         $i + 1,
1890         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1891         $v,
1892         $bind_attrs->[$i],
1893       );
1894     }
1895   }
1896
1897   $sth;
1898 }
1899
1900 sub _prefetch_autovalues {
1901   my ($self, $source, $colinfo, $to_insert) = @_;
1902
1903   my %values;
1904   for my $col (keys %$colinfo) {
1905     if (
1906       $colinfo->{$col}{auto_nextval}
1907         and
1908       (
1909         ! exists $to_insert->{$col}
1910           or
1911         is_literal_value($to_insert->{$col})
1912       )
1913     ) {
1914       $values{$col} = $self->_sequence_fetch(
1915         'NEXTVAL',
1916         ( $colinfo->{$col}{sequence} ||=
1917             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1918         ),
1919       );
1920     }
1921   }
1922
1923   \%values;
1924 }
1925
1926 sub insert {
1927   my ($self, $source, $to_insert) = @_;
1928
1929   my $col_infos = $source->columns_info;
1930
1931   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1932
1933   # fuse the values, but keep a separate list of prefetched_values so that
1934   # they can be fused once again with the final return
1935   $to_insert = { %$to_insert, %$prefetched_values };
1936
1937   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1938   # Investigate what does it take to s/defined/exists/
1939   my %pcols = map { $_ => 1 } $source->primary_columns;
1940   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1941   for my $col ($source->columns) {
1942     if ($col_infos->{$col}{is_auto_increment}) {
1943       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1944       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1945     }
1946
1947     # nothing to retrieve when explicit values are supplied
1948     next if (
1949       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1950     );
1951
1952     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1953     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1954       $pcols{$col}
1955         or
1956       $col_infos->{$col}{retrieve_on_insert}
1957     );
1958   };
1959
1960   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1961   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1962
1963   my ($sqla_opts, @ir_container);
1964   if (%retrieve_cols and $self->_use_insert_returning) {
1965     $sqla_opts->{returning_container} = \@ir_container
1966       if $self->_use_insert_returning_bound;
1967
1968     $sqla_opts->{returning} = [
1969       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1970     ];
1971   }
1972
1973   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1974
1975   my %returned_cols = %$to_insert;
1976   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1977     @ir_container = try {
1978       local $SIG{__WARN__} = sub {};
1979       my @r = $sth->fetchrow_array;
1980       $sth->finish;
1981       @r;
1982     } unless @ir_container;
1983
1984     @returned_cols{@$retlist} = @ir_container if @ir_container;
1985   }
1986   else {
1987     # pull in PK if needed and then everything else
1988     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1989
1990       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1991         unless $self->can('last_insert_id');
1992
1993       my @pri_values = $self->last_insert_id($source, @missing_pri);
1994
1995       $self->throw_exception( "Can't get last insert id" )
1996         unless (@pri_values == @missing_pri);
1997
1998       @returned_cols{@missing_pri} = @pri_values;
1999       delete @retrieve_cols{@missing_pri};
2000     }
2001
2002     # if there is more left to pull
2003     if (%retrieve_cols) {
2004       $self->throw_exception(
2005         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2006       ) unless %pcols;
2007
2008       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2009
2010       my $cur = DBIx::Class::ResultSet->new($source, {
2011         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2012         select => \@left_to_fetch,
2013       })->cursor;
2014
2015       @returned_cols{@left_to_fetch} = $cur->next;
2016
2017       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2018         if scalar $cur->next;
2019     }
2020   }
2021
2022   return { %$prefetched_values, %returned_cols };
2023 }
2024
2025 sub insert_bulk {
2026   carp_unique(
2027     'insert_bulk() should have never been exposed as a public method and '
2028   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2029   . 'use for this method please contact the development team via '
2030   . DBIx::Class::_ENV_::HELP_URL
2031   );
2032
2033   return '0E0' unless @{$_[3]||[]};
2034
2035   shift->_insert_bulk(@_);
2036 }
2037
2038 sub _insert_bulk {
2039   my ($self, $source, $cols, $data) = @_;
2040
2041   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2042     unless @{$data||[]};
2043
2044   my $colinfos = $source->columns_info($cols);
2045
2046   local $self->{_autoinc_supplied_for_op} =
2047     (grep { $_->{is_auto_increment} } values %$colinfos)
2048       ? 1
2049       : 0
2050   ;
2051
2052   # get a slice type index based on first row of data
2053   # a "column" in this context may refer to more than one bind value
2054   # e.g. \[ '?, ?', [...], [...] ]
2055   #
2056   # construct the value type index - a description of values types for every
2057   # per-column slice of $data:
2058   #
2059   # nonexistent - nonbind literal
2060   # 0 - regular value
2061   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2062   #
2063   # also construct the column hash to pass to the SQL generator. For plain
2064   # (non literal) values - convert the members of the first row into a
2065   # literal+bind combo, with extra positional info in the bind attr hashref.
2066   # This will allow us to match the order properly, and is so contrived
2067   # because a user-supplied literal/bind (or something else specific to a
2068   # resultsource and/or storage driver) can inject extra binds along the
2069   # way, so one can't rely on "shift positions" ordering at all. Also we
2070   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2071   # can be later matched up by address), because we want to supply a real
2072   # value on which perhaps e.g. datatype checks will be performed
2073   my ($proto_data, $serialized_bind_type_by_col_idx);
2074   for my $col_idx (0..$#$cols) {
2075     my $colname = $cols->[$col_idx];
2076     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2077       # no bind value at all - no type
2078
2079       $proto_data->{$colname} = $data->[0][$col_idx];
2080     }
2081     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2082       # repack, so we don't end up mangling the original \[]
2083       my ($sql, @bind) = @${$data->[0][$col_idx]};
2084
2085       # normalization of user supplied stuff
2086       my $resolved_bind = $self->_resolve_bindattrs(
2087         $source, \@bind, $colinfos,
2088       );
2089
2090       # store value-less (attrs only) bind info - we will be comparing all
2091       # supplied binds against this for sanity
2092       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2093
2094       $proto_data->{$colname} = \[ $sql, map { [
2095         # inject slice order to use for $proto_bind construction
2096           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2097             =>
2098           $resolved_bind->[$_][1]
2099         ] } (0 .. $#bind)
2100       ];
2101     }
2102     else {
2103       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2104
2105       $proto_data->{$colname} = \[ '?', [
2106         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2107           =>
2108         $data->[0][$col_idx]
2109       ] ];
2110     }
2111   }
2112
2113   my ($sql, $proto_bind) = $self->_prep_for_execute (
2114     'insert',
2115     $source,
2116     [ $proto_data ],
2117   );
2118
2119   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2120     # if the bindlist is empty and we had some dynamic binds, this means the
2121     # storage ate them away (e.g. the NoBindVars component) and interpolated
2122     # them directly into the SQL. This obviously can't be good for multi-inserts
2123     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2124   }
2125
2126   # sanity checks
2127   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2128   #
2129   # use an error reporting closure for convenience (less to pass)
2130   my $bad_slice_report_cref = sub {
2131     my ($msg, $r_idx, $c_idx) = @_;
2132     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2133       $msg,
2134       $cols->[$c_idx],
2135       do {
2136         require Data::Dumper::Concise;
2137         local $Data::Dumper::Maxdepth = 5;
2138         Data::Dumper::Concise::Dumper ({
2139           map { $cols->[$_] =>
2140             $data->[$r_idx][$_]
2141           } 0..$#$cols
2142         }),
2143       }
2144     );
2145   };
2146
2147   for my $col_idx (0..$#$cols) {
2148     my $reference_val = $data->[0][$col_idx];
2149
2150     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2151       my $val = $data->[$row_idx][$col_idx];
2152
2153       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2154         if (ref $val ne 'SCALAR') {
2155           $bad_slice_report_cref->(
2156             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2157             $row_idx,
2158             $col_idx,
2159           );
2160         }
2161         elsif ($$val ne $$reference_val) {
2162           $bad_slice_report_cref->(
2163             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2164             $row_idx,
2165             $col_idx,
2166           );
2167         }
2168       }
2169       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2170         if (is_literal_value($val)) {
2171           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2172         }
2173       }
2174       else {  # binds from a \[], compare type and attrs
2175         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2176           $bad_slice_report_cref->(
2177             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2178             $row_idx,
2179             $col_idx,
2180           );
2181         }
2182         # start drilling down and bail out early on identical refs
2183         elsif (
2184           $reference_val != $val
2185             or
2186           $$reference_val != $$val
2187         ) {
2188           if (${$val}->[0] ne ${$reference_val}->[0]) {
2189             $bad_slice_report_cref->(
2190               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2191               $row_idx,
2192               $col_idx,
2193             );
2194           }
2195           # need to check the bind attrs - a bind will happen only once for
2196           # the entire dataset, so any changes further down will be ignored.
2197           elsif (
2198             $serialized_bind_type_by_col_idx->{$col_idx}
2199               ne
2200             serialize [
2201               map
2202               { $_->[0] }
2203               @{$self->_resolve_bindattrs(
2204                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2205               )}
2206             ]
2207           ) {
2208             $bad_slice_report_cref->(
2209               'Differing bind attributes on literal/bind values not supported',
2210               $row_idx,
2211               $col_idx,
2212             );
2213           }
2214         }
2215       }
2216     }
2217   }
2218
2219   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2220   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2221   # scope guard
2222   my $guard = $self->txn_scope_guard;
2223
2224   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2225   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2226   my $rv = do {
2227     if (@$proto_bind) {
2228       # proto bind contains the information on which pieces of $data to pull
2229       # $cols is passed in only for prettier error-reporting
2230       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2231     }
2232     else {
2233       # bind_param_array doesn't work if there are no binds
2234       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2235     }
2236   };
2237
2238   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2239
2240   $guard->commit;
2241
2242   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2243 }
2244
2245 # execute_for_fetch is capable of returning data just fine (it means it
2246 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2247 # is the void-populate fast-path we will just ignore this altogether
2248 # for the time being.
2249 sub _dbh_execute_for_fetch {
2250   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2251
2252   # If we have any bind attributes to take care of, we will bind the
2253   # proto-bind data (which will never be used by execute_for_fetch)
2254   # However since column bindtypes are "sticky", this is sufficient
2255   # to get the DBD to apply the bindtype to all values later on
2256   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2257
2258   for my $i (0 .. $#$proto_bind) {
2259     $sth->bind_param (
2260       $i+1, # DBI bind indexes are 1-based
2261       $proto_bind->[$i][1],
2262       $bind_attrs->[$i],
2263     ) if defined $bind_attrs->[$i];
2264   }
2265
2266   # At this point $data slots named in the _bind_data_slice_idx of
2267   # each piece of $proto_bind are either \[]s or plain values to be
2268   # passed in. Construct the dispensing coderef. *NOTE* the order
2269   # of $data will differ from this of the ?s in the SQL (due to
2270   # alphabetical ordering by colname). We actually do want to
2271   # preserve this behavior so that prepare_cached has a better
2272   # chance of matching on unrelated calls
2273
2274   my $fetch_row_idx = -1; # saner loop this way
2275   my $fetch_tuple = sub {
2276     return undef if ++$fetch_row_idx > $#$data;
2277
2278     return [ map {
2279       my $v = ! defined $_->{_literal_bind_subindex}
2280
2281         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2282
2283         # There are no attributes to resolve here - we already did everything
2284         # when we constructed proto_bind. However we still want to sanity-check
2285         # what the user supplied, so pass stuff through to the resolver *anyway*
2286         : $self->_resolve_bindattrs (
2287             undef,  # a fake rsrc
2288             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2289             {},     # a fake column_info bag
2290           )->[0][1]
2291       ;
2292
2293       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2294       # For the time being forcibly stringify whatever is stringifiable
2295       (length ref $v and is_plain_value $v)
2296         ? "$v"
2297         : $v
2298       ;
2299     } map { $_->[0] } @$proto_bind ];
2300   };
2301
2302   my $tuple_status = [];
2303   my ($rv, $err);
2304   try {
2305     $rv = $sth->execute_for_fetch(
2306       $fetch_tuple,
2307       $tuple_status,
2308     );
2309   }
2310   catch {
2311     $err = shift;
2312   };
2313
2314   # Not all DBDs are create equal. Some throw on error, some return
2315   # an undef $rv, and some set $sth->err - try whatever we can
2316   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2317     ! defined $err
2318       and
2319     ( !defined $rv or $sth->err )
2320   );
2321
2322   # Statement must finish even if there was an exception.
2323   try {
2324     $sth->finish
2325   }
2326   catch {
2327     $err = shift unless defined $err
2328   };
2329
2330   if (defined $err) {
2331     my $i = 0;
2332     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2333
2334     $self->throw_exception("Unexpected populate error: $err")
2335       if ($i > $#$tuple_status);
2336
2337     require Data::Dumper::Concise;
2338     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2339       ($tuple_status->[$i][1] || $err),
2340       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2341     );
2342   }
2343
2344   return $rv;
2345 }
2346
2347 sub _dbh_execute_inserts_with_no_binds {
2348   my ($self, $sth, $count) = @_;
2349
2350   my $err;
2351   try {
2352     my $dbh = $self->_get_dbh;
2353     local $dbh->{RaiseError} = 1;
2354     local $dbh->{PrintError} = 0;
2355
2356     $sth->execute foreach 1..$count;
2357   }
2358   catch {
2359     $err = shift;
2360   };
2361
2362   # Make sure statement is finished even if there was an exception.
2363   try {
2364     $sth->finish
2365   }
2366   catch {
2367     $err = shift unless defined $err;
2368   };
2369
2370   $self->throw_exception($err) if defined $err;
2371
2372   return $count;
2373 }
2374
2375 sub update {
2376   #my ($self, $source, @args) = @_;
2377   shift->_execute('update', @_);
2378 }
2379
2380
2381 sub delete {
2382   #my ($self, $source, @args) = @_;
2383   shift->_execute('delete', @_);
2384 }
2385
2386 sub _select {
2387   my $self = shift;
2388   $self->_execute($self->_select_args(@_));
2389 }
2390
2391 sub _select_args_to_query {
2392   my $self = shift;
2393
2394   $self->throw_exception(
2395     "Unable to generate limited query representation with 'software_limit' enabled"
2396   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2397
2398   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2399   #  = $self->_select_args($ident, $select, $cond, $attrs);
2400   my ($op, $ident, @args) =
2401     $self->_select_args(@_);
2402
2403   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2404   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2405
2406   # reuse the bind arrayref
2407   unshift @{$bind}, "($sql)";
2408   \$bind;
2409 }
2410
2411 sub _select_args {
2412   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2413
2414   # FIXME - that kind of caching would be nice to have
2415   # however currently we *may* pass the same $orig_attrs
2416   # with different ident/select/where
2417   # the whole interface needs to be rethought, since it
2418   # was centered around the flawed SQLA API. We can do
2419   # soooooo much better now. But that is also another
2420   # battle...
2421   #return (
2422   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2423   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2424
2425   my $sql_maker = $self->sql_maker;
2426
2427   my $attrs = {
2428     %$orig_attrs,
2429     select => $select,
2430     from => $ident,
2431     where => $where,
2432   };
2433
2434   # Sanity check the attributes (SQLMaker does it too, but
2435   # in case of a software_limit we'll never reach there)
2436   if (defined $attrs->{offset}) {
2437     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2438       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2439   }
2440
2441   if (defined $attrs->{rows}) {
2442     $self->throw_exception("The rows attribute must be a positive integer if present")
2443       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2444   }
2445   elsif ($attrs->{offset}) {
2446     # MySQL actually recommends this approach.  I cringe.
2447     $attrs->{rows} = $sql_maker->__max_int;
2448   }
2449
2450   # see if we will need to tear the prefetch apart to satisfy group_by == select
2451   # this is *extremely tricky* to get right, I am still not sure I did
2452   #
2453   my ($prefetch_needs_subquery, @limit_args);
2454
2455   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2456     # we already know there is a valid group_by (we made it) and we know it is
2457     # intended to be based *only* on non-multi stuff
2458     # short circuit the group_by parsing below
2459     $prefetch_needs_subquery = 1;
2460   }
2461   elsif (
2462     # The rationale is that even if we do *not* have collapse, we still
2463     # need to wrap the core grouped select/group_by in a subquery
2464     # so that databases that care about group_by/select equivalence
2465     # are happy (this includes MySQL in strict_mode)
2466     # If any of the other joined tables are referenced in the group_by
2467     # however - the user is on their own
2468     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2469       and
2470     $attrs->{group_by}
2471       and
2472     @{$attrs->{group_by}}
2473       and
2474     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2475       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2476     }
2477   ) {
2478     # no aliases other than our own in group_by
2479     # if there are - do not allow subquery even if limit is present
2480     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2481   }
2482   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2483     # active collapse with a limit - that one is a no-brainer unless
2484     # overruled by a group_by above
2485     $prefetch_needs_subquery = 1;
2486   }
2487
2488   if ($prefetch_needs_subquery) {
2489     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2490   }
2491   elsif (! $attrs->{software_limit} ) {
2492     push @limit_args, (
2493       $attrs->{rows} || (),
2494       $attrs->{offset} || (),
2495     );
2496   }
2497
2498   # try to simplify the joinmap further (prune unreferenced type-single joins)
2499   if (
2500     ! $prefetch_needs_subquery  # already pruned
2501       and
2502     ref $attrs->{from}
2503       and
2504     reftype $attrs->{from} eq 'ARRAY'
2505       and
2506     @{$attrs->{from}} != 1
2507   ) {
2508     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2509   }
2510
2511   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2512   # during the result inflation stage we *need* to know what was the aliastype
2513   # map as sqla saw it when the final pieces of SQL were being assembled
2514   # Originally we simply carried around the entirety of $attrs, but this
2515   # resulted in resultsets that are being reused growing continuously, as
2516   # the hash in question grew deeper and deeper.
2517   # Instead hand-pick what to take with us here (we actually don't need much
2518   # at this point just the map itself)
2519   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2520
2521 ###
2522   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2523   #
2524   # This would be the point to deflate anything found in $attrs->{where}
2525   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2526   # expect a result object. And all we have is a resultsource (it is trivial
2527   # to extract deflator coderefs via $alias2source above).
2528   #
2529   # I don't see a way forward other than changing the way deflators are
2530   # invoked, and that's just bad...
2531 ###
2532
2533   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2534 }
2535
2536 # Returns a counting SELECT for a simple count
2537 # query. Abstracted so that a storage could override
2538 # this to { count => 'firstcol' } or whatever makes
2539 # sense as a performance optimization
2540 sub _count_select {
2541   #my ($self, $source, $rs_attrs) = @_;
2542   return { count => '*' };
2543 }
2544
2545 =head2 select
2546
2547 =over 4
2548
2549 =item Arguments: $ident, $select, $condition, $attrs
2550
2551 =back
2552
2553 Handle a SQL select statement.
2554
2555 =cut
2556
2557 sub select {
2558   my $self = shift;
2559   my ($ident, $select, $condition, $attrs) = @_;
2560   return $self->cursor_class->new($self, \@_, $attrs);
2561 }
2562
2563 sub select_single {
2564   my $self = shift;
2565   my ($rv, $sth, @bind) = $self->_select(@_);
2566   my @row = $sth->fetchrow_array;
2567   my @nextrow = $sth->fetchrow_array if @row;
2568   if(@row && @nextrow) {
2569     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2570   }
2571   # Need to call finish() to work round broken DBDs
2572   $sth->finish();
2573   return @row;
2574 }
2575
2576 =head2 sql_limit_dialect
2577
2578 This is an accessor for the default SQL limit dialect used by a particular
2579 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2580 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2581 see L<DBIx::Class::SQLMaker::LimitDialects>.
2582
2583 =cut
2584
2585 sub _dbh_columns_info_for {
2586   my ($self, $dbh, $table) = @_;
2587
2588   my %result;
2589
2590   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2591     try {
2592       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2593       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2594       $sth->execute();
2595       while ( my $info = $sth->fetchrow_hashref() ){
2596         my %column_info;
2597         $column_info{data_type}   = $info->{TYPE_NAME};
2598         $column_info{size}      = $info->{COLUMN_SIZE};
2599         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2600         $column_info{default_value} = $info->{COLUMN_DEF};
2601         my $col_name = $info->{COLUMN_NAME};
2602         $col_name =~ s/^\"(.*)\"$/$1/;
2603
2604         $result{$col_name} = \%column_info;
2605       }
2606     } catch {
2607       %result = ();
2608     };
2609
2610     return \%result if keys %result;
2611   }
2612
2613   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2614   $sth->execute;
2615
2616 ### The acrobatics with lc names is necessary to support both the legacy
2617 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2618 ### with column names differing in cas eonly (thanks pg!)
2619
2620   my ($columns, $seen_lcs);
2621
2622   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2623     idx => scalar keys %$columns,
2624     name => $_,
2625     lc_name => lc($_),
2626   } for @{$sth->{NAME}};
2627
2628   $seen_lcs->{$_->{lc_name}} == 1
2629     and
2630   $_->{name} = $_->{lc_name}
2631     for values %$columns;
2632
2633   for ( values %$columns ) {
2634     my $inf = {
2635       data_type => $sth->{TYPE}->[$_->{idx}],
2636       size => $sth->{PRECISION}->[$_->{idx}],
2637       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2638     };
2639
2640     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2641       @{$inf}{qw( data_type  size)} = ($1, $2);
2642     }
2643
2644     $result{$_->{name}} = $inf;
2645   }
2646
2647   $sth->finish;
2648
2649   if ($dbh->can('type_info')) {
2650     for my $inf (values %result) {
2651       next if ! defined $inf->{data_type};
2652
2653       $inf->{data_type} = (
2654         (
2655           (
2656             $dbh->type_info( $inf->{data_type} )
2657               ||
2658             next
2659           )
2660             ||
2661           next
2662         )->{TYPE_NAME}
2663           ||
2664         next
2665       );
2666
2667       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2668       # needs more testing in the future...
2669       $inf->{size} -= 4 if (
2670         ( $inf->{size}||0 > 4 )
2671           and
2672         $inf->{data_type} =~ qr/^text$/i
2673       );
2674     }
2675
2676   }
2677
2678   return \%result;
2679 }
2680
2681 sub columns_info_for {
2682   my ($self, $table) = @_;
2683   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2684 }
2685
2686 =head2 last_insert_id
2687
2688 Return the row id of the last insert.
2689
2690 =cut
2691
2692 sub _dbh_last_insert_id {
2693     my ($self, $dbh, $source, $col) = @_;
2694
2695     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2696
2697     return $id if defined $id;
2698
2699     my $class = ref $self;
2700     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2701 }
2702
2703 sub last_insert_id {
2704   my $self = shift;
2705   $self->_dbh_last_insert_id ($self->_dbh, @_);
2706 }
2707
2708 =head2 _native_data_type
2709
2710 =over 4
2711
2712 =item Arguments: $type_name
2713
2714 =back
2715
2716 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2717 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2718 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2719
2720 The default implementation returns C<undef>, implement in your Storage driver if
2721 you need this functionality.
2722
2723 Should map types from other databases to the native RDBMS type, for example
2724 C<VARCHAR2> to C<VARCHAR>.
2725
2726 Types with modifiers should map to the underlying data type. For example,
2727 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2728
2729 Composite types should map to the container type, for example
2730 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2731
2732 =cut
2733
2734 sub _native_data_type {
2735   #my ($self, $data_type) = @_;
2736   return undef
2737 }
2738
2739 # Check if placeholders are supported at all
2740 sub _determine_supports_placeholders {
2741   my $self = shift;
2742   my $dbh  = $self->_get_dbh;
2743
2744   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2745   # but it is inaccurate more often than not
2746   return try {
2747     local $dbh->{PrintError} = 0;
2748     local $dbh->{RaiseError} = 1;
2749     $dbh->do('select ?', {}, 1);
2750     1;
2751   }
2752   catch {
2753     0;
2754   };
2755 }
2756
2757 # Check if placeholders bound to non-string types throw exceptions
2758 #
2759 sub _determine_supports_typeless_placeholders {
2760   my $self = shift;
2761   my $dbh  = $self->_get_dbh;
2762
2763   return try {
2764     local $dbh->{PrintError} = 0;
2765     local $dbh->{RaiseError} = 1;
2766     # this specifically tests a bind that is NOT a string
2767     $dbh->do('select 1 where 1 = ?', {}, 1);
2768     1;
2769   }
2770   catch {
2771     0;
2772   };
2773 }
2774
2775 =head2 sqlt_type
2776
2777 Returns the database driver name.
2778
2779 =cut
2780
2781 sub sqlt_type {
2782   shift->_get_dbh->{Driver}->{Name};
2783 }
2784
2785 =head2 bind_attribute_by_data_type
2786
2787 Given a datatype from column info, returns a database specific bind
2788 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2789 let the database planner just handle it.
2790
2791 This method is always called after the driver has been determined and a DBI
2792 connection has been established. Therefore you can refer to C<DBI::$constant>
2793 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2794 the correct modules.
2795
2796 =cut
2797
2798 sub bind_attribute_by_data_type {
2799     return;
2800 }
2801
2802 =head2 is_datatype_numeric
2803
2804 Given a datatype from column_info, returns a boolean value indicating if
2805 the current RDBMS considers it a numeric value. This controls how
2806 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2807 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2808 be performed instead of the usual C<eq>.
2809
2810 =cut
2811
2812 sub is_datatype_numeric {
2813   #my ($self, $dt) = @_;
2814
2815   return 0 unless $_[1];
2816
2817   $_[1] =~ /^ (?:
2818     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2819   ) $/ix;
2820 }
2821
2822
2823 =head2 create_ddl_dir
2824
2825 =over 4
2826
2827 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2828
2829 =back
2830
2831 Creates a SQL file based on the Schema, for each of the specified
2832 database engines in C<\@databases> in the given directory.
2833 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2834
2835 Given a previous version number, this will also create a file containing
2836 the ALTER TABLE statements to transform the previous schema into the
2837 current one. Note that these statements may contain C<DROP TABLE> or
2838 C<DROP COLUMN> statements that can potentially destroy data.
2839
2840 The file names are created using the C<ddl_filename> method below, please
2841 override this method in your schema if you would like a different file
2842 name format. For the ALTER file, the same format is used, replacing
2843 $version in the name with "$preversion-$version".
2844
2845 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2846 The most common value for this would be C<< { add_drop_table => 1 } >>
2847 to have the SQL produced include a C<DROP TABLE> statement for each table
2848 created. For quoting purposes supply C<quote_identifiers>.
2849
2850 If no arguments are passed, then the following default values are assumed:
2851
2852 =over 4
2853
2854 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2855
2856 =item version    - $schema->schema_version
2857
2858 =item directory  - './'
2859
2860 =item preversion - <none>
2861
2862 =back
2863
2864 By default, C<\%sqlt_args> will have
2865
2866  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2867
2868 merged with the hash passed in. To disable any of those features, pass in a
2869 hashref like the following
2870
2871  { ignore_constraint_names => 0, # ... other options }
2872
2873
2874 WARNING: You are strongly advised to check all SQL files created, before applying
2875 them.
2876
2877 =cut
2878
2879 sub create_ddl_dir {
2880   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2881
2882   unless ($dir) {
2883     carp "No directory given, using ./\n";
2884     $dir = './';
2885   } else {
2886       -d $dir
2887         or
2888       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2889         or
2890       $self->throw_exception(
2891         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2892       );
2893   }
2894
2895   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2896
2897   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2898   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2899
2900   my $schema_version = $schema->schema_version || '1.x';
2901   $version ||= $schema_version;
2902
2903   $sqltargs = {
2904     add_drop_table => 1,
2905     ignore_constraint_names => 1,
2906     ignore_index_names => 1,
2907     quote_identifiers => $self->sql_maker->_quoting_enabled,
2908     %{$sqltargs || {}}
2909   };
2910
2911   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2912     $self->throw_exception("Can't create a ddl file without $missing");
2913   }
2914
2915   my $sqlt = SQL::Translator->new( $sqltargs );
2916
2917   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2918   my $sqlt_schema = $sqlt->translate({ data => $schema })
2919     or $self->throw_exception ($sqlt->error);
2920
2921   foreach my $db (@$databases) {
2922     $sqlt->reset();
2923     $sqlt->{schema} = $sqlt_schema;
2924     $sqlt->producer($db);
2925
2926     my $file;
2927     my $filename = $schema->ddl_filename($db, $version, $dir);
2928     if (-e $filename && ($version eq $schema_version )) {
2929       # if we are dumping the current version, overwrite the DDL
2930       carp "Overwriting existing DDL file - $filename";
2931       unlink($filename);
2932     }
2933
2934     my $output = $sqlt->translate;
2935     if(!$output) {
2936       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2937       next;
2938     }
2939     if(!open($file, ">$filename")) {
2940       $self->throw_exception("Can't open $filename for writing ($!)");
2941       next;
2942     }
2943     print $file $output;
2944     close($file);
2945
2946     next unless ($preversion);
2947
2948     require SQL::Translator::Diff;
2949
2950     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2951     if(!-e $prefilename) {
2952       carp("No previous schema file found ($prefilename)");
2953       next;
2954     }
2955
2956     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2957     if(-e $difffile) {
2958       carp("Overwriting existing diff file - $difffile");
2959       unlink($difffile);
2960     }
2961
2962     my $source_schema;
2963     {
2964       my $t = SQL::Translator->new($sqltargs);
2965       $t->debug( 0 );
2966       $t->trace( 0 );
2967
2968       $t->parser( $db )
2969         or $self->throw_exception ($t->error);
2970
2971       my $out = $t->translate( $prefilename )
2972         or $self->throw_exception ($t->error);
2973
2974       $source_schema = $t->schema;
2975
2976       $source_schema->name( $prefilename )
2977         unless ( $source_schema->name );
2978     }
2979
2980     # The "new" style of producers have sane normalization and can support
2981     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2982     # And we have to diff parsed SQL against parsed SQL.
2983     my $dest_schema = $sqlt_schema;
2984
2985     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2986       my $t = SQL::Translator->new($sqltargs);
2987       $t->debug( 0 );
2988       $t->trace( 0 );
2989
2990       $t->parser( $db )
2991         or $self->throw_exception ($t->error);
2992
2993       my $out = $t->translate( $filename )
2994         or $self->throw_exception ($t->error);
2995
2996       $dest_schema = $t->schema;
2997
2998       $dest_schema->name( $filename )
2999         unless $dest_schema->name;
3000     }
3001
3002     my $diff = do {
3003       # FIXME - this is a terrible workaround for
3004       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3005       # Fixing it in this sloppy manner so that we don't hve to
3006       # lockstep an SQLT release as well. Needs to be removed at
3007       # some point, and SQLT dep bumped
3008       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3009         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3010
3011       SQL::Translator::Diff::schema_diff($source_schema, $db,
3012                                          $dest_schema,   $db,
3013                                          $sqltargs
3014                                        );
3015     };
3016
3017     if(!open $file, ">$difffile") {
3018       $self->throw_exception("Can't write to $difffile ($!)");
3019       next;
3020     }
3021     print $file $diff;
3022     close($file);
3023   }
3024 }
3025
3026 =head2 deployment_statements
3027
3028 =over 4
3029
3030 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3031
3032 =back
3033
3034 Returns the statements used by L<DBIx::Class::Storage/deploy>
3035 and L<DBIx::Class::Schema/deploy>.
3036
3037 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3038 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3039
3040 C<$directory> is used to return statements from files in a previously created
3041 L</create_ddl_dir> directory and is optional. The filenames are constructed
3042 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3043
3044 If no C<$directory> is specified then the statements are constructed on the
3045 fly using L<SQL::Translator> and C<$version> is ignored.
3046
3047 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3048
3049 =cut
3050
3051 sub deployment_statements {
3052   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3053   $type ||= $self->sqlt_type;
3054   $version ||= $schema->schema_version || '1.x';
3055   $dir ||= './';
3056   my $filename = $schema->ddl_filename($type, $version, $dir);
3057   if(-f $filename)
3058   {
3059       # FIXME replace this block when a proper sane sql parser is available
3060       my $file;
3061       open($file, "<$filename")
3062         or $self->throw_exception("Can't open $filename ($!)");
3063       my @rows = <$file>;
3064       close($file);
3065       return join('', @rows);
3066   }
3067
3068   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3069     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3070   }
3071
3072   # sources needs to be a parser arg, but for simplicity allow at top level
3073   # coming in
3074   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3075       if exists $sqltargs->{sources};
3076
3077   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3078     unless exists $sqltargs->{quote_identifiers};
3079
3080   my $tr = SQL::Translator->new(
3081     producer => "SQL::Translator::Producer::${type}",
3082     %$sqltargs,
3083     parser => 'SQL::Translator::Parser::DBIx::Class',
3084     data => $schema,
3085   );
3086
3087   return preserve_context {
3088     $tr->translate
3089   } after => sub {
3090     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3091       unless defined $_[0];
3092   };
3093 }
3094
3095 # FIXME deploy() currently does not accurately report sql errors
3096 # Will always return true while errors are warned
3097 sub deploy {
3098   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3099   my $deploy = sub {
3100     my $line = shift;
3101     return if(!$line);
3102     return if($line =~ /^--/);
3103     # next if($line =~ /^DROP/m);
3104     return if($line =~ /^BEGIN TRANSACTION/m);
3105     return if($line =~ /^COMMIT/m);
3106     return if $line =~ /^\s+$/; # skip whitespace only
3107     $self->_query_start($line);
3108     try {
3109       # do a dbh_do cycle here, as we need some error checking in
3110       # place (even though we will ignore errors)
3111       $self->dbh_do (sub { $_[1]->do($line) });
3112     } catch {
3113       carp qq{$_ (running "${line}")};
3114     };
3115     $self->_query_end($line);
3116   };
3117   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3118   if (@statements > 1) {
3119     foreach my $statement (@statements) {
3120       $deploy->( $statement );
3121     }
3122   }
3123   elsif (@statements == 1) {
3124     # split on single line comments and end of statements
3125     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3126       $deploy->( $line );
3127     }
3128   }
3129 }
3130
3131 =head2 datetime_parser
3132
3133 Returns the datetime parser class
3134
3135 =cut
3136
3137 sub datetime_parser {
3138   my $self = shift;
3139   return $self->{datetime_parser} ||= do {
3140     $self->build_datetime_parser(@_);
3141   };
3142 }
3143
3144 =head2 datetime_parser_type
3145
3146 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3147
3148 =head2 build_datetime_parser
3149
3150 See L</datetime_parser>
3151
3152 =cut
3153
3154 sub build_datetime_parser {
3155   my $self = shift;
3156   my $type = $self->datetime_parser_type(@_);
3157   return $type;
3158 }
3159
3160
3161 =head2 is_replicating
3162
3163 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3164 replicate from a master database.  Default is undef, which is the result
3165 returned by databases that don't support replication.
3166
3167 =cut
3168
3169 sub is_replicating {
3170     return;
3171
3172 }
3173
3174 =head2 lag_behind_master
3175
3176 Returns a number that represents a certain amount of lag behind a master db
3177 when a given storage is replicating.  The number is database dependent, but
3178 starts at zero and increases with the amount of lag. Default in undef
3179
3180 =cut
3181
3182 sub lag_behind_master {
3183     return;
3184 }
3185
3186 =head2 relname_to_table_alias
3187
3188 =over 4
3189
3190 =item Arguments: $relname, $join_count
3191
3192 =item Return Value: $alias
3193
3194 =back
3195
3196 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3197 queries.
3198
3199 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3200 way these aliases are named.
3201
3202 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3203 otherwise C<"$relname">.
3204
3205 =cut
3206
3207 sub relname_to_table_alias {
3208   my ($self, $relname, $join_count) = @_;
3209
3210   my $alias = ($join_count && $join_count > 1 ?
3211     join('_', $relname, $join_count) : $relname);
3212
3213   return $alias;
3214 }
3215
3216 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3217 # version and it may be necessary to amend or override it for a specific storage
3218 # if such binds are necessary.
3219 sub _max_column_bytesize {
3220   my ($self, $attr) = @_;
3221
3222   my $max_size;
3223
3224   if ($attr->{sqlt_datatype}) {
3225     my $data_type = lc($attr->{sqlt_datatype});
3226
3227     if ($attr->{sqlt_size}) {
3228
3229       # String/sized-binary types
3230       if ($data_type =~ /^(?:
3231           l? (?:var)? char(?:acter)? (?:\s*varying)?
3232             |
3233           (?:var)? binary (?:\s*varying)?
3234             |
3235           raw
3236         )\b/x
3237       ) {
3238         $max_size = $attr->{sqlt_size};
3239       }
3240       # Other charset/unicode types, assume scale of 4
3241       elsif ($data_type =~ /^(?:
3242           national \s* character (?:\s*varying)?
3243             |
3244           nchar
3245             |
3246           univarchar
3247             |
3248           nvarchar
3249         )\b/x
3250       ) {
3251         $max_size = $attr->{sqlt_size} * 4;
3252       }
3253     }
3254
3255     if (!$max_size and !$self->_is_lob_type($data_type)) {
3256       $max_size = 100 # for all other (numeric?) datatypes
3257     }
3258   }
3259
3260   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3261 }
3262
3263 # Determine if a data_type is some type of BLOB
3264 sub _is_lob_type {
3265   my ($self, $data_type) = @_;
3266   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3267     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3268                                   |varchar|character\s*varying|nvarchar
3269                                   |national\s*character\s*varying))?\z/xi);
3270 }
3271
3272 sub _is_binary_lob_type {
3273   my ($self, $data_type) = @_;
3274   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3275     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3276 }
3277
3278 sub _is_text_lob_type {
3279   my ($self, $data_type) = @_;
3280   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3281     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3282                         |national\s*character\s*varying))\z/xi);
3283 }
3284
3285 # Determine if a data_type is some type of a binary type
3286 sub _is_binary_type {
3287   my ($self, $data_type) = @_;
3288   $data_type && ($self->_is_binary_lob_type($data_type)
3289     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3290 }
3291
3292 1;
3293
3294 =head1 USAGE NOTES
3295
3296 =head2 DBIx::Class and AutoCommit
3297
3298 DBIx::Class can do some wonderful magic with handling exceptions,
3299 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3300 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3301 transaction support.
3302
3303 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3304 in an assumed transaction between commits, and you're telling us you'd
3305 like to manage that manually.  A lot of the magic protections offered by
3306 this module will go away.  We can't protect you from exceptions due to database
3307 disconnects because we don't know anything about how to restart your
3308 transactions.  You're on your own for handling all sorts of exceptional
3309 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3310 be with raw DBI.
3311
3312 =head1 FURTHER QUESTIONS?
3313
3314 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3315
3316 =head1 COPYRIGHT AND LICENSE
3317
3318 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3319 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3320 redistribute it and/or modify it under the same terms as the
3321 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.