lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use IO::File;
  12 use Carp::Clan qw/DBIx::Class/;
  13
  14 BEGIN {
  15
  16 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  17
  18 use base qw/SQL::Abstract::Limit/;
  19
  20 sub select {
  21   my ($self, $table, $fields, $where, $order, @rest) = @_;
  22   $table = $self->_quote($table) unless ref($table);
  23   @rest = (-1) unless defined $rest[0];
  24   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  25     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  26   local $self->{having_bind} = [];
  27   my ($sql, @ret) = $self->SUPER::select(
  28     $table, $self->_recurse_fields($fields), $where, $order, @rest
  29   );
  30   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  31 }
  32
  33 sub insert {
  34   my $self = shift;
  35   my $table = shift;
  36   $table = $self->_quote($table) unless ref($table);
  37   $self->SUPER::insert($table, @_);
  38 }
  39
  40 sub update {
  41   my $self = shift;
  42   my $table = shift;
  43   $table = $self->_quote($table) unless ref($table);
  44   $self->SUPER::update($table, @_);
  45 }
  46
  47 sub delete {
  48   my $self = shift;
  49   my $table = shift;
  50   $table = $self->_quote($table) unless ref($table);
  51   $self->SUPER::delete($table, @_);
  52 }
  53
  54 sub _emulate_limit {
  55   my $self = shift;
  56   if ($_[3] == -1) {
  57     return $_[1].$self->_order_by($_[2]);
  58   } else {
  59     return $self->SUPER::_emulate_limit(@_);
  60   }
  61 }
  62
  63 sub _recurse_fields {
  64   my ($self, $fields) = @_;
  65   my $ref = ref $fields;
  66   return $self->_quote($fields) unless $ref;
  67   return $$fields if $ref eq 'SCALAR';
  68
  69   if ($ref eq 'ARRAY') {
  70     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  71   } elsif ($ref eq 'HASH') {
  72     foreach my $func (keys %$fields) {
  73       return $self->_sqlcase($func)
  74         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  75     }
  76   }
  77 }
  78
  79 sub _order_by {
  80   my $self = shift;
  81   my $ret = '';
  82   my @extra;
  83   if (ref $_[0] eq 'HASH') {
  84     if (defined $_[0]->{group_by}) {
  85       $ret = $self->_sqlcase(' group by ')
  86                .$self->_recurse_fields($_[0]->{group_by});
  87     }
  88     if (defined $_[0]->{having}) {
  89       my $frag;
  90       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  91       push(@{$self->{having_bind}}, @extra);
  92       $ret .= $self->_sqlcase(' having ').$frag;
  93     }
  94     if (defined $_[0]->{order_by}) {
  95       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  96     }
  97   } elsif(ref $_[0] eq 'SCALAR') {
  98     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  99   } else {
 100     $ret = $self->SUPER::_order_by(@_);
 101   }
 102   return $ret;
 103 }
 104
 105 sub _order_directions {
 106   my ($self, $order) = @_;
 107   $order = $order->{order_by} if ref $order eq 'HASH';
 108   return $self->SUPER::_order_directions($order);
 109 }
 110
 111 sub _table {
 112   my ($self, $from) = @_;
 113   if (ref $from eq 'ARRAY') {
 114     return $self->_recurse_from(@$from);
 115   } elsif (ref $from eq 'HASH') {
 116     return $self->_make_as($from);
 117   } else {
 118     return $from; # would love to quote here but _table ends up getting called
 119                   # twice during an ->select without a limit clause due to
 120                   # the way S::A::Limit->select works. should maybe consider
 121                   # bypassing this and doing S::A::select($self, ...) in
 122                   # our select method above. meantime, quoting shims have
 123                   # been added to select/insert/update/delete here
 124   }
 125 }
 126
 127 sub _recurse_from {
 128   my ($self, $from, @join) = @_;
 129   my @sqlf;
 130   push(@sqlf, $self->_make_as($from));
 131   foreach my $j (@join) {
 132     my ($to, $on) = @$j;
 133
 134     # check whether a join type exists
 135     my $join_clause = '';
 136     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 137       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 138     } else {
 139       $join_clause = ' JOIN ';
 140     }
 141     push(@sqlf, $join_clause);
 142
 143     if (ref $to eq 'ARRAY') {
 144       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 145     } else {
 146       push(@sqlf, $self->_make_as($to));
 147     }
 148     push(@sqlf, ' ON ', $self->_join_condition($on));
 149   }
 150   return join('', @sqlf);
 151 }
 152
 153 sub _make_as {
 154   my ($self, $from) = @_;
 155   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 156                      reverse each %{$self->_skip_options($from)});
 157 }
 158
 159 sub _skip_options {
 160   my ($self, $hash) = @_;
 161   my $clean_hash = {};
 162   $clean_hash->{$_} = $hash->{$_}
 163     for grep {!/^-/} keys %$hash;
 164   return $clean_hash;
 165 }
 166
 167 sub _join_condition {
 168   my ($self, $cond) = @_;
 169   if (ref $cond eq 'HASH') {
 170     my %j;
 171     for (keys %$cond) {
 172       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 173     };
 174     return $self->_recurse_where(\%j);
 175   } elsif (ref $cond eq 'ARRAY') {
 176     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 177   } else {
 178     die "Can't handle this yet!";
 179   }
 180 }
 181
 182 sub _quote {
 183   my ($self, $label) = @_;
 184   return '' unless defined $label;
 185   return "*" if $label eq '*';
 186   return $label unless $self->{quote_char};
 187   if(ref $self->{quote_char} eq "ARRAY"){
 188     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 189       if !defined $self->{name_sep};
 190     my $sep = $self->{name_sep};
 191     return join($self->{name_sep},
 192         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 193        split(/\Q$sep\E/,$label));
 194   }
 195   return $self->SUPER::_quote($label);
 196 }
 197
 198 sub _RowNum {
 199    my $self = shift;
 200    my $c;
 201    $_[0] =~ s/SELECT (.*?) FROM/
 202      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 203    $self->SUPER::_RowNum(@_);
 204 }
 205
 206 # Accessor for setting limit dialect. This is useful
 207 # for JDBC-bridge among others where the remote SQL-dialect cannot
 208 # be determined by the name of the driver alone.
 209 #
 210 sub limit_dialect {
 211     my $self = shift;
 212     $self->{limit_dialect} = shift if @_;
 213     return $self->{limit_dialect};
 214 }
 215
 216 sub quote_char {
 217     my $self = shift;
 218     $self->{quote_char} = shift if @_;
 219     return $self->{quote_char};
 220 }
 221
 222 sub name_sep {
 223     my $self = shift;
 224     $self->{name_sep} = shift if @_;
 225     return $self->{name_sep};
 226 }
 227
 228
 229
 230
 231 package DBIx::Class::Storage::DBI::DebugCallback;
 232
 233 sub print {
 234   my ($self, $string) = @_;
 235   $string =~ m/^(\w+)/;
 236   ${$self}->($1, $string);
 237 }
 238
 239 } # End of BEGIN block
 240
 241 use base qw/DBIx::Class/;
 242
 243 __PACKAGE__->load_components(qw/AccessorGroup/);
 244
 245 __PACKAGE__->mk_group_accessors('simple' =>
 246   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
 247      cursor on_connect_do transaction_depth/);
 248
 249 sub new {
 250   my $new = bless({}, ref $_[0] || $_[0]);
 251   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 252   $new->transaction_depth(0);
 253   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 254      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 255     $new->debugfh(IO::File->new($1, 'w'))
 256       or $new->throw_exception("Cannot open trace file $1");
 257   } else {
 258     $new->debugfh(IO::File->new('>&STDERR'));
 259   }
 260   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 261   return $new;
 262 }
 263
 264 sub throw_exception {
 265   my ($self, $msg) = @_;
 266   croak($msg);
 267 }
 268
 269 =head1 NAME
 270
 271 DBIx::Class::Storage::DBI - DBI storage handler
 272
 273 =head1 SYNOPSIS
 274
 275 =head1 DESCRIPTION
 276
 277 This class represents the connection to the database
 278
 279 =head1 METHODS
 280
 281 =cut
 282
 283 =head2 connect_info
 284
 285 Connection information arrayref.  Can either be the same arguments
 286 one would pass to DBI->connect, or a code-reference which returns
 287 a connected database handle.  In either case, there is an optional
 288 final element in the arrayref, which can hold a hashref of
 289 connection-specific Storage::DBI options.  These include
 290 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 291 C<quote_char>, and C<name_sep>.  Examples:
 292
 293   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 294   ->connect_info(sub { DBI->connect(...) });
 295   ->connect_info([ 'dbi:Pg:dbname=foo',
 296                    'postgres',
 297                    '',
 298                    { AutoCommit => 0 },
 299                    { quote_char => q{`}, name_sep => q{@} },
 300                  ]);
 301
 302 =head2 on_connect_do
 303
 304 Executes the sql statements given as a listref on every db connect.
 305
 306 =head2 debug
 307
 308 Causes SQL trace information to be emitted on C<debugfh> filehandle
 309 (or C<STDERR> if C<debugfh> has not specifically been set).
 310
 311 =head2 debugfh
 312
 313 Sets or retrieves the filehandle used for trace/debug output.  This
 314 should be an IO::Handle compatible object (only the C<print> method is
 315 used).  Initially set to be STDERR - although see information on the
 316 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 317
 318 =head2 debugcb
 319
 320 Sets a callback to be executed each time a statement is run; takes a sub
 321 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 322 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 323 be printed.
 324
 325 =cut
 326
 327 sub debugcb {
 328   my ($self, $cb) = @_;
 329   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 330   $self->debugfh($cb_obj);
 331 }
 332
 333 sub disconnect {
 334   my ($self) = @_;
 335
 336   if( $self->connected ) {
 337     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 338     $self->_dbh->disconnect;
 339     $self->_dbh(undef);
 340   }
 341 }
 342
 343 sub connected {
 344   my ($self) = @_;
 345
 346   if(my $dbh = $self->_dbh) {
 347       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 348           $self->_sql_maker(undef);
 349           return $self->_dbh(undef);
 350       }
 351       elsif($self->_conn_pid != $$) {
 352           $self->_dbh->{InactiveDestroy} = 1;
 353           $self->_sql_maker(undef);
 354           return $self->_dbh(undef)
 355       }
 356       return ($dbh->FETCH('Active') && $dbh->ping);
 357   }
 358
 359   return 0;
 360 }
 361
 362 sub ensure_connected {
 363   my ($self) = @_;
 364
 365   unless ($self->connected) {
 366     $self->_populate_dbh;
 367   }
 368 }
 369
 370 =head2 dbh
 371
 372 Returns the dbh - a data base handle of class L<DBI>.
 373
 374 =cut
 375
 376 sub dbh {
 377   my ($self) = @_;
 378
 379   $self->ensure_connected;
 380   return $self->_dbh;
 381 }
 382
 383 sub _sql_maker_args {
 384     my ($self) = @_;
 385
 386     return ( limit_dialect => $self->dbh );
 387 }
 388
 389 sub sql_maker {
 390   my ($self) = @_;
 391   unless ($self->_sql_maker) {
 392     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 393   }
 394   return $self->_sql_maker;
 395 }
 396
 397 sub connect_info {
 398     my ($self, $info_arg) = @_;
 399
 400     if($info_arg) {
 401         my $info = [ @$info_arg ]; # copy because we can alter it
 402         my $last_info = $info->[-1];
 403         if(ref $last_info eq 'HASH') {
 404             my $used;
 405             if(my $on_connect_do = $last_info->{on_connect_do}) {
 406                $used = 1;
 407                $self->on_connect_do($on_connect_do);
 408             }
 409             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 410                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 411                     $used = 1;
 412                     $self->sql_maker->$sql_maker_opt($opt_val);
 413                 }
 414             }
 415
 416             # remove our options hashref if it was there, to avoid confusing
 417             #   DBI in the case the user didn't use all 4 DBI options, as in:
 418             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 419             pop(@$info) if $used;
 420         }
 421
 422         $self->_connect_info($info);
 423     }
 424
 425     $self->_connect_info;
 426 }
 427
 428 sub _populate_dbh {
 429   my ($self) = @_;
 430   my @info = @{$self->_connect_info || []};
 431   $self->_dbh($self->_connect(@info));
 432   my $driver = $self->_dbh->{Driver}->{Name};
 433   eval "require DBIx::Class::Storage::DBI::${driver}";
 434   unless ($@) {
 435     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 436     $self->_rebless() if $self->can('_rebless');
 437   }
 438   # if on-connect sql statements are given execute them
 439   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 440     $self->_dbh->do($sql_statement);
 441   }
 442
 443   $self->_conn_pid($$);
 444   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 445 }
 446
 447 sub _connect {
 448   my ($self, @info) = @_;
 449
 450   $self->throw_exception("You failed to provide any connection info")
 451       if !@info;
 452
 453   my ($old_connect_via, $dbh);
 454
 455   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 456       $old_connect_via = $DBI::connect_via;
 457       $DBI::connect_via = 'connect';
 458   }
 459
 460   eval {
 461     if(ref $info[0] eq 'CODE') {
 462         $dbh = &{$info[0]};
 463     }
 464     else {
 465         $dbh = DBI->connect(@info);
 466     }
 467   };
 468
 469   $DBI::connect_via = $old_connect_via if $old_connect_via;
 470
 471   if (!$dbh || $@) {
 472     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 473   }
 474
 475   $dbh;
 476 }
 477
 478 =head2 txn_begin
 479
 480 Calls begin_work on the current dbh.
 481
 482 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 483 an entire code block to be executed transactionally.
 484
 485 =cut
 486
 487 sub txn_begin {
 488   my $self = shift;
 489   if ($self->{transaction_depth}++ == 0) {
 490     my $dbh = $self->dbh;
 491     if ($dbh->{AutoCommit}) {
 492       $self->debugfh->print("BEGIN WORK\n")
 493         if ($self->debug);
 494       $dbh->begin_work;
 495     }
 496   }
 497 }
 498
 499 =head2 txn_commit
 500
 501 Issues a commit against the current dbh.
 502
 503 =cut
 504
 505 sub txn_commit {
 506   my $self = shift;
 507   if ($self->{transaction_depth} == 0) {
 508     my $dbh = $self->dbh;
 509     unless ($dbh->{AutoCommit}) {
 510       $self->debugfh->print("COMMIT\n")
 511         if ($self->debug);
 512       $dbh->commit;
 513     }
 514   }
 515   else {
 516     if (--$self->{transaction_depth} == 0) {
 517       $self->debugfh->print("COMMIT\n")
 518         if ($self->debug);
 519       $self->dbh->commit;
 520     }
 521   }
 522 }
 523
 524 =head2 txn_rollback
 525
 526 Issues a rollback against the current dbh. A nested rollback will
 527 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 528 which allows the rollback to propagate to the outermost transaction.
 529
 530 =cut
 531
 532 sub txn_rollback {
 533   my $self = shift;
 534
 535   eval {
 536     if ($self->{transaction_depth} == 0) {
 537       my $dbh = $self->dbh;
 538       unless ($dbh->{AutoCommit}) {
 539         $self->debugfh->print("ROLLBACK\n")
 540           if ($self->debug);
 541         $dbh->rollback;
 542       }
 543     }
 544     else {
 545       if (--$self->{transaction_depth} == 0) {
 546         $self->debugfh->print("ROLLBACK\n")
 547           if ($self->debug);
 548         $self->dbh->rollback;
 549       }
 550       else {
 551         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 552       }
 553     }
 554   };
 555
 556   if ($@) {
 557     my $error = $@;
 558     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 559     $error =~ /$exception_class/ and $self->throw_exception($error);
 560     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 561     $self->throw_exception($error);          # resets the transaction depth
 562   }
 563 }
 564
 565 sub _execute {
 566   my ($self, $op, $extra_bind, $ident, @args) = @_;
 567   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 568   unshift(@bind, @$extra_bind) if $extra_bind;
 569   if ($self->debug) {
 570       my @debug_bind = map { defined $_ ? qq{'$_'} : q{'NULL'} } @bind;
 571       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 572   }
 573   my $sth = eval { $self->sth($sql,$op) };
 574
 575   if (!$sth || $@) {
 576     $self->throw_exception('no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql");
 577   }
 578
 579   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 580   my $rv;
 581   if ($sth) {
 582     $rv = eval { $sth->execute(@bind) };
 583
 584     if ($@ || !$rv) {
 585       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 586     }
 587   } else {
 588     $self->throw_exception("'$sql' did not generate a statement.");
 589   }
 590   return (wantarray ? ($rv, $sth, @bind) : $rv);
 591 }
 592
 593 sub insert {
 594   my ($self, $ident, $to_insert) = @_;
 595   $self->throw_exception(
 596     "Couldn't insert ".join(', ',
 597       map "$_ => $to_insert->{$_}", keys %$to_insert
 598     )." into ${ident}"
 599   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 600   return $to_insert;
 601 }
 602
 603 sub update {
 604   return shift->_execute('update' => [], @_);
 605 }
 606
 607 sub delete {
 608   return shift->_execute('delete' => [], @_);
 609 }
 610
 611 sub _select {
 612   my ($self, $ident, $select, $condition, $attrs) = @_;
 613   my $order = $attrs->{order_by};
 614   if (ref $condition eq 'SCALAR') {
 615     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 616   }
 617   if (exists $attrs->{group_by} || $attrs->{having}) {
 618     $order = {
 619       group_by => $attrs->{group_by},
 620       having => $attrs->{having},
 621       ($order ? (order_by => $order) : ())
 622     };
 623   }
 624   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 625   if ($attrs->{software_limit} ||
 626       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 627         $attrs->{software_limit} = 1;
 628   } else {
 629     $self->throw_exception("rows attribute must be positive if present")
 630       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
 631     push @args, $attrs->{rows}, $attrs->{offset};
 632   }
 633   return $self->_execute(@args);
 634 }
 635
 636 sub select {
 637   my $self = shift;
 638   my ($ident, $select, $condition, $attrs) = @_;
 639   return $self->cursor->new($self, \@_, $attrs);
 640 }
 641
 642 # Need to call finish() to work round broken DBDs
 643
 644 sub select_single {
 645   my $self = shift;
 646   my ($rv, $sth, @bind) = $self->_select(@_);
 647   my @row = $sth->fetchrow_array;
 648   $sth->finish();
 649   return @row;
 650 }
 651
 652 sub sth {
 653   my ($self, $sql) = @_;
 654   # 3 is the if_active parameter which avoids active sth re-use
 655   return $self->dbh->prepare_cached($sql, {}, 3);
 656 }
 657
 658 =head2 columns_info_for
 659
 660 Returns database type info for a given table columns.
 661
 662 =cut
 663
 664 sub columns_info_for {
 665   my ($self, $table) = @_;
 666
 667   my $dbh = $self->dbh;
 668
 669   if ($dbh->can('column_info')) {
 670     my %result;
 671     my $old_raise_err = $dbh->{RaiseError};
 672     my $old_print_err = $dbh->{PrintError};
 673     $dbh->{RaiseError} = 1;
 674     $dbh->{PrintError} = 0;
 675     eval {
 676       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
 677       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
 678       $sth->execute();
 679       while ( my $info = $sth->fetchrow_hashref() ){
 680         my %column_info;
 681         $column_info{data_type}   = $info->{TYPE_NAME};
 682         $column_info{size}      = $info->{COLUMN_SIZE};
 683         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 684         $column_info{default_value} = $info->{COLUMN_DEF};
 685
 686         $result{$info->{COLUMN_NAME}} = \%column_info;
 687       }
 688     };
 689     $dbh->{RaiseError} = $old_raise_err;
 690     $dbh->{PrintError} = $old_print_err;
 691     return \%result if !$@;
 692   }
 693
 694   my %result;
 695   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 696   $sth->execute;
 697   my @columns = @{$sth->{NAME_lc}};
 698   for my $i ( 0 .. $#columns ){
 699     my %column_info;
 700     my $type_num = $sth->{TYPE}->[$i];
 701     my $type_name;
 702     if(defined $type_num && $dbh->can('type_info')) {
 703       my $type_info = $dbh->type_info($type_num);
 704       $type_name = $type_info->{TYPE_NAME} if $type_info;
 705     }
 706     $column_info{data_type} = $type_name ? $type_name : $type_num;
 707     $column_info{size} = $sth->{PRECISION}->[$i];
 708     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 709
 710     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 711       $column_info{data_type} = $1;
 712       $column_info{size}    = $2;
 713     }
 714
 715     $result{$columns[$i]} = \%column_info;
 716   }
 717
 718   return \%result;
 719 }
 720
 721 sub last_insert_id {
 722   my ($self, $row) = @_;
 723
 724   return $self->dbh->func('last_insert_rowid');
 725
 726 }
 727
 728 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 729
 730 sub create_ddl_dir
 731 {
 732   my ($self, $schema, $databases, $version, $dir, $sqltargs) = @_;
 733
 734   if(!$dir || !-d $dir)
 735   {
 736     warn "No directory given, using ./\n";
 737     $dir = "./";
 738   }
 739   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
 740   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
 741   $version ||= $schema->VERSION || '1.x';
 742
 743   eval "use SQL::Translator";
 744   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 745
 746   my $sqlt = SQL::Translator->new({
 747 #      debug => 1,
 748       add_drop_table => 1,
 749   });
 750   foreach my $db (@$databases)
 751   {
 752     $sqlt->reset();
 753     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 754 #    $sqlt->parser_args({'DBIx::Class' => $schema);
 755     $sqlt->data($schema);
 756     $sqlt->producer($db);
 757
 758     my $file;
 759     my $filename = $schema->ddl_filename($db, $dir, $version);
 760     if(-e $filename)
 761     {
 762       $self->throw_exception("$filename already exists, skipping $db");
 763       next;
 764     }
 765     open($file, ">$filename")
 766       or $self->throw_exception("Can't open $filename for writing ($!)");
 767     my $output = $sqlt->translate;
 768 #use Data::Dumper;
 769 #    print join(":", keys %{$schema->source_registrations});
 770 #    print Dumper($sqlt->schema);
 771     if(!$output)
 772     {
 773       $self->throw_exception("Failed to translate to $db. (" . $sqlt->error . ")");
 774       next;
 775     }
 776     print $file $output;
 777     close($file);
 778   }
 779
 780 }
 781
 782 sub deployment_statements {
 783   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
 784   $type ||= $self->sqlt_type;
 785   $version ||= $schema->VERSION || '1.x';
 786   $dir ||= './';
 787   eval "use SQL::Translator";
 788   if(!$@)
 789   {
 790     eval "use SQL::Translator::Parser::DBIx::Class;";
 791     $self->throw_exception($@) if $@;
 792     eval "use SQL::Translator::Producer::${type};";
 793     $self->throw_exception($@) if $@;
 794     my $tr = SQL::Translator->new(%$sqltargs);
 795     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 796     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 797   }
 798
 799   my $filename = $schema->ddl_filename($type, $dir, $version);
 800   if(!-f $filename)
 801   {
 802 #      $schema->create_ddl_dir([ $type ], $version, $dir, $sqltargs);
 803       $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
 804       return;
 805   }
 806   my $file;
 807   open($file, "<$filename")
 808       or $self->throw_exception("Can't open $filename ($!)");
 809   my @rows = <$file>;
 810   close($file);
 811
 812   return join('', @rows);
 813
 814 }
 815
 816 sub deploy {
 817   my ($self, $schema, $type, $sqltargs) = @_;
 818   foreach my $statement ( $self->deployment_statements($schema, $type, undef, undef, $sqltargs) ) {
 819     for ( split(";\n", $statement)) {
 820       next if($_ =~ /^--/);
 821       next if(!$_);
 822 #      next if($_ =~ /^DROP/m);
 823       next if($_ =~ /^BEGIN TRANSACTION/m);
 824       next if($_ =~ /^COMMIT/m);
 825       $self->debugfh->print("$_\n") if $self->debug;
 826       $self->dbh->do($_) or warn "SQL was:\n $_";
 827     }
 828   }
 829 }
 830
 831 sub DESTROY { shift->disconnect }
 832
 833 1;
 834
 835 =head1 ENVIRONMENT VARIABLES
 836
 837 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 838
 839 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 840 is produced (as when the L<debug> method is set).
 841
 842 If the value is of the form C<1=/path/name> then the trace output is
 843 written to the file C</path/name>.
 844
 845 This environment variable is checked when the storage object is first
 846 created (when you call connect on your schema).  So, run-time changes
 847 to this environment variable will not take effect unless you also
 848 re-connect on your schema.
 849
 850 =head1 AUTHORS
 851
 852 Matt S. Trout <mst@shadowcatsystems.co.uk>
 853
 854 Andy Grundman <andy@hybridized.org>
 855
 856 =head1 LICENSE
 857
 858 You may distribute this code under the same terms as Perl itself.
 859
 860 =cut
 861