lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util qw/refaddr weaken reftype blessed/;
  15 use Data::Dumper::Concise 'Dumper';
  16 use Sub::Name 'subname';
  17 use Try::Tiny;
  18 use File::Path 'make_path';
  19 use namespace::clean;
  20
  21 __PACKAGE__->mk_group_accessors('simple' => qw/
  22   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  23   _dbh _server_info_hash _conn_pid _conn_tid _sql_maker _sql_maker_opts
  24   transaction_depth _dbh_autocommit  savepoints
  25 /);
  26
  27 # the values for these accessors are picked out (and deleted) from
  28 # the attribute hashref passed to connect_info
  29 my @storage_options = qw/
  30   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  31   disable_sth_caching unsafe auto_savepoint
  32 /;
  33 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  34
  35
  36 # default cursor class, overridable in connect_info attributes
  37 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  38
  39 __PACKAGE__->mk_group_accessors('inherited' => qw/
  40   sql_maker_class
  41   _supports_insert_returning
  42 /);
  43 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  44
  45 # Each of these methods need _determine_driver called before itself
  46 # in order to function reliably. This is a purely DRY optimization
  47 my @rdbms_specific_methods = qw/
  48   deployment_statements
  49   sqlt_type
  50   sql_maker
  51   build_datetime_parser
  52   datetime_parser_type
  53
  54   insert
  55   insert_bulk
  56   update
  57   delete
  58   select
  59   select_single
  60 /;
  61
  62 for my $meth (@rdbms_specific_methods) {
  63
  64   my $orig = __PACKAGE__->can ($meth)
  65     or next;
  66
  67   no strict qw/refs/;
  68   no warnings qw/redefine/;
  69   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
  70     if (not $_[0]->_driver_determined) {
  71       $_[0]->_determine_driver;
  72       goto $_[0]->can($meth);
  73     }
  74     $orig->(@_);
  75   };
  76 }
  77
  78
  79 =head1 NAME
  80
  81 DBIx::Class::Storage::DBI - DBI storage handler
  82
  83 =head1 SYNOPSIS
  84
  85   my $schema = MySchema->connect('dbi:SQLite:my.db');
  86
  87   $schema->storage->debug(1);
  88
  89   my @stuff = $schema->storage->dbh_do(
  90     sub {
  91       my ($storage, $dbh, @args) = @_;
  92       $dbh->do("DROP TABLE authors");
  93     },
  94     @column_list
  95   );
  96
  97   $schema->resultset('Book')->search({
  98      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
  99   });
 100
 101 =head1 DESCRIPTION
 102
 103 This class represents the connection to an RDBMS via L<DBI>.  See
 104 L<DBIx::Class::Storage> for general information.  This pod only
 105 documents DBI-specific methods and behaviors.
 106
 107 =head1 METHODS
 108
 109 =cut
 110
 111 sub new {
 112   my $new = shift->next::method(@_);
 113
 114   $new->transaction_depth(0);
 115   $new->_sql_maker_opts({});
 116   $new->{savepoints} = [];
 117   $new->{_in_dbh_do} = 0;
 118   $new->{_dbh_gen} = 0;
 119
 120   # read below to see what this does
 121   $new->_arm_global_destructor;
 122
 123   $new;
 124 }
 125
 126 # This is hack to work around perl shooting stuff in random
 127 # order on exit(). If we do not walk the remaining storage
 128 # objects in an END block, there is a *small but real* chance
 129 # of a fork()ed child to kill the parent's shared DBI handle,
 130 # *before perl reaches the DESTROY in this package*
 131 # Yes, it is ugly and effective.
 132 {
 133   my %seek_and_destroy;
 134
 135   sub _arm_global_destructor {
 136     my $self = shift;
 137     my $key = Scalar::Util::refaddr ($self);
 138     $seek_and_destroy{$key} = $self;
 139     Scalar::Util::weaken ($seek_and_destroy{$key});
 140   }
 141
 142   END {
 143     local $?; # just in case the DBI destructor changes it somehow
 144
 145     # destroy just the object if not native to this process/thread
 146     $_->_preserve_foreign_dbh for (grep
 147       { defined $_ }
 148       values %seek_and_destroy
 149     );
 150   }
 151 }
 152
 153 sub DESTROY {
 154   my $self = shift;
 155
 156   # destroy just the object if not native to this process/thread
 157   $self->_preserve_foreign_dbh;
 158
 159   # some databases need this to stop spewing warnings
 160   if (my $dbh = $self->_dbh) {
 161     try {
 162       %{ $dbh->{CachedKids} } = ();
 163       $dbh->disconnect;
 164     };
 165   }
 166
 167   $self->_dbh(undef);
 168 }
 169
 170 sub _preserve_foreign_dbh {
 171   my $self = shift;
 172
 173   return unless $self->_dbh;
 174
 175   $self->_verify_tid;
 176
 177   return unless $self->_dbh;
 178
 179   $self->_verify_pid;
 180
 181 }
 182
 183 # handle pid changes correctly - do not destroy parent's connection
 184 sub _verify_pid {
 185   my $self = shift;
 186
 187   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 188
 189   $self->_dbh->{InactiveDestroy} = 1;
 190   $self->_dbh(undef);
 191   $self->{_dbh_gen}++;
 192
 193   return;
 194 }
 195
 196 # very similar to above, but seems to FAIL if I set InactiveDestroy
 197 sub _verify_tid {
 198   my $self = shift;
 199
 200   if ( ! defined $self->_conn_tid ) {
 201     return; # no threads
 202   }
 203   elsif ( $self->_conn_tid == threads->tid ) {
 204     return; # same thread
 205   }
 206
 207   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 208   $self->_dbh(undef);
 209   $self->{_dbh_gen}++;
 210
 211   return;
 212 }
 213
 214
 215 =head2 connect_info
 216
 217 This method is normally called by L<DBIx::Class::Schema/connection>, which
 218 encapsulates its argument list in an arrayref before passing them here.
 219
 220 The argument list may contain:
 221
 222 =over
 223
 224 =item *
 225
 226 The same 4-element argument set one would normally pass to
 227 L<DBI/connect>, optionally followed by
 228 L<extra attributes|/DBIx::Class specific connection attributes>
 229 recognized by DBIx::Class:
 230
 231   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 232
 233 =item *
 234
 235 A single code reference which returns a connected
 236 L<DBI database handle|DBI/connect> optionally followed by
 237 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 238 by DBIx::Class:
 239
 240   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 241
 242 =item *
 243
 244 A single hashref with all the attributes and the dsn/user/password
 245 mixed together:
 246
 247   $connect_info_args = [{
 248     dsn => $dsn,
 249     user => $user,
 250     password => $pass,
 251     %dbi_attributes,
 252     %extra_attributes,
 253   }];
 254
 255   $connect_info_args = [{
 256     dbh_maker => sub { DBI->connect (...) },
 257     %dbi_attributes,
 258     %extra_attributes,
 259   }];
 260
 261 This is particularly useful for L<Catalyst> based applications, allowing the
 262 following config (L<Config::General> style):
 263
 264   <Model::DB>
 265     schema_class   App::DB
 266     <connect_info>
 267       dsn          dbi:mysql:database=test
 268       user         testuser
 269       password     TestPass
 270       AutoCommit   1
 271     </connect_info>
 272   </Model::DB>
 273
 274 The C<dsn>/C<user>/C<password> combination can be substituted by the
 275 C<dbh_maker> key whose value is a coderef that returns a connected
 276 L<DBI database handle|DBI/connect>
 277
 278 =back
 279
 280 Please note that the L<DBI> docs recommend that you always explicitly
 281 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 282 recommends that it be set to I<1>, and that you perform transactions
 283 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 284 to I<1> if you do not do explicitly set it to zero.  This is the default
 285 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 286
 287 =head3 DBIx::Class specific connection attributes
 288
 289 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 290 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 291 the following connection options. These options can be mixed in with your other
 292 L<DBI> connection attributes, or placed in a separate hashref
 293 (C<\%extra_attributes>) as shown above.
 294
 295 Every time C<connect_info> is invoked, any previous settings for
 296 these options will be cleared before setting the new ones, regardless of
 297 whether any options are specified in the new C<connect_info>.
 298
 299
 300 =over
 301
 302 =item on_connect_do
 303
 304 Specifies things to do immediately after connecting or re-connecting to
 305 the database.  Its value may contain:
 306
 307 =over
 308
 309 =item a scalar
 310
 311 This contains one SQL statement to execute.
 312
 313 =item an array reference
 314
 315 This contains SQL statements to execute in order.  Each element contains
 316 a string or a code reference that returns a string.
 317
 318 =item a code reference
 319
 320 This contains some code to execute.  Unlike code references within an
 321 array reference, its return value is ignored.
 322
 323 =back
 324
 325 =item on_disconnect_do
 326
 327 Takes arguments in the same form as L</on_connect_do> and executes them
 328 immediately before disconnecting from the database.
 329
 330 Note, this only runs if you explicitly call L</disconnect> on the
 331 storage object.
 332
 333 =item on_connect_call
 334
 335 A more generalized form of L</on_connect_do> that calls the specified
 336 C<connect_call_METHOD> methods in your storage driver.
 337
 338   on_connect_do => 'select 1'
 339
 340 is equivalent to:
 341
 342   on_connect_call => [ [ do_sql => 'select 1' ] ]
 343
 344 Its values may contain:
 345
 346 =over
 347
 348 =item a scalar
 349
 350 Will call the C<connect_call_METHOD> method.
 351
 352 =item a code reference
 353
 354 Will execute C<< $code->($storage) >>
 355
 356 =item an array reference
 357
 358 Each value can be a method name or code reference.
 359
 360 =item an array of arrays
 361
 362 For each array, the first item is taken to be the C<connect_call_> method name
 363 or code reference, and the rest are parameters to it.
 364
 365 =back
 366
 367 Some predefined storage methods you may use:
 368
 369 =over
 370
 371 =item do_sql
 372
 373 Executes a SQL string or a code reference that returns a SQL string. This is
 374 what L</on_connect_do> and L</on_disconnect_do> use.
 375
 376 It can take:
 377
 378 =over
 379
 380 =item a scalar
 381
 382 Will execute the scalar as SQL.
 383
 384 =item an arrayref
 385
 386 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 387 attributes hashref and bind values.
 388
 389 =item a code reference
 390
 391 Will execute C<< $code->($storage) >> and execute the return array refs as
 392 above.
 393
 394 =back
 395
 396 =item datetime_setup
 397
 398 Execute any statements necessary to initialize the database session to return
 399 and accept datetime/timestamp values used with
 400 L<DBIx::Class::InflateColumn::DateTime>.
 401
 402 Only necessary for some databases, see your specific storage driver for
 403 implementation details.
 404
 405 =back
 406
 407 =item on_disconnect_call
 408
 409 Takes arguments in the same form as L</on_connect_call> and executes them
 410 immediately before disconnecting from the database.
 411
 412 Calls the C<disconnect_call_METHOD> methods as opposed to the
 413 C<connect_call_METHOD> methods called by L</on_connect_call>.
 414
 415 Note, this only runs if you explicitly call L</disconnect> on the
 416 storage object.
 417
 418 =item disable_sth_caching
 419
 420 If set to a true value, this option will disable the caching of
 421 statement handles via L<DBI/prepare_cached>.
 422
 423 =item limit_dialect
 424
 425 Sets the limit dialect. This is useful for JDBC-bridge among others
 426 where the remote SQL-dialect cannot be determined by the name of the
 427 driver alone. See also L<SQL::Abstract::Limit>.
 428
 429 =item quote_char
 430
 431 Specifies what characters to use to quote table and column names. If
 432 you use this you will want to specify L</name_sep> as well.
 433
 434 C<quote_char> expects either a single character, in which case is it
 435 is placed on either side of the table/column name, or an arrayref of length
 436 2 in which case the table/column name is placed between the elements.
 437
 438 For example under MySQL you should use C<< quote_char => '`' >>, and for
 439 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 440
 441 =item name_sep
 442
 443 This only needs to be used in conjunction with C<quote_char>, and is used to
 444 specify the character that separates elements (schemas, tables, columns) from
 445 each other. In most cases this is simply a C<.>.
 446
 447 The consequences of not supplying this value is that L<SQL::Abstract>
 448 will assume DBIx::Class' uses of aliases to be complete column
 449 names. The output will look like I<"me.name"> when it should actually
 450 be I<"me"."name">.
 451
 452 =item unsafe
 453
 454 This Storage driver normally installs its own C<HandleError>, sets
 455 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 456 all database handles, including those supplied by a coderef.  It does this
 457 so that it can have consistent and useful error behavior.
 458
 459 If you set this option to a true value, Storage will not do its usual
 460 modifications to the database handle's attributes, and instead relies on
 461 the settings in your connect_info DBI options (or the values you set in
 462 your connection coderef, in the case that you are connecting via coderef).
 463
 464 Note that your custom settings can cause Storage to malfunction,
 465 especially if you set a C<HandleError> handler that suppresses exceptions
 466 and/or disable C<RaiseError>.
 467
 468 =item auto_savepoint
 469
 470 If this option is true, L<DBIx::Class> will use savepoints when nesting
 471 transactions, making it possible to recover from failure in the inner
 472 transaction without having to abort all outer transactions.
 473
 474 =item cursor_class
 475
 476 Use this argument to supply a cursor class other than the default
 477 L<DBIx::Class::Storage::DBI::Cursor>.
 478
 479 =back
 480
 481 Some real-life examples of arguments to L</connect_info> and
 482 L<DBIx::Class::Schema/connect>
 483
 484   # Simple SQLite connection
 485   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 486
 487   # Connect via subref
 488   ->connect_info([ sub { DBI->connect(...) } ]);
 489
 490   # Connect via subref in hashref
 491   ->connect_info([{
 492     dbh_maker => sub { DBI->connect(...) },
 493     on_connect_do => 'alter session ...',
 494   }]);
 495
 496   # A bit more complicated
 497   ->connect_info(
 498     [
 499       'dbi:Pg:dbname=foo',
 500       'postgres',
 501       'my_pg_password',
 502       { AutoCommit => 1 },
 503       { quote_char => q{"}, name_sep => q{.} },
 504     ]
 505   );
 506
 507   # Equivalent to the previous example
 508   ->connect_info(
 509     [
 510       'dbi:Pg:dbname=foo',
 511       'postgres',
 512       'my_pg_password',
 513       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 514     ]
 515   );
 516
 517   # Same, but with hashref as argument
 518   # See parse_connect_info for explanation
 519   ->connect_info(
 520     [{
 521       dsn         => 'dbi:Pg:dbname=foo',
 522       user        => 'postgres',
 523       password    => 'my_pg_password',
 524       AutoCommit  => 1,
 525       quote_char  => q{"},
 526       name_sep    => q{.},
 527     }]
 528   );
 529
 530   # Subref + DBIx::Class-specific connection options
 531   ->connect_info(
 532     [
 533       sub { DBI->connect(...) },
 534       {
 535           quote_char => q{`},
 536           name_sep => q{@},
 537           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 538           disable_sth_caching => 1,
 539       },
 540     ]
 541   );
 542
 543
 544
 545 =cut
 546
 547 sub connect_info {
 548   my ($self, $info) = @_;
 549
 550   return $self->_connect_info if !$info;
 551
 552   $self->_connect_info($info); # copy for _connect_info
 553
 554   $info = $self->_normalize_connect_info($info)
 555     if ref $info eq 'ARRAY';
 556
 557   for my $storage_opt (keys %{ $info->{storage_options} }) {
 558     my $value = $info->{storage_options}{$storage_opt};
 559
 560     $self->$storage_opt($value);
 561   }
 562
 563   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 564   #  the new set of options
 565   $self->_sql_maker(undef);
 566   $self->_sql_maker_opts({});
 567
 568   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 569     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 570
 571     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 572   }
 573
 574   my %attrs = (
 575     %{ $self->_default_dbi_connect_attributes || {} },
 576     %{ $info->{attributes} || {} },
 577   );
 578
 579   my @args = @{ $info->{arguments} };
 580
 581   $self->_dbi_connect_info([@args,
 582     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 583
 584   # FIXME - dirty:
 585   # save attributes them in a separate accessor so they are always
 586   # introspectable, even in case of a CODE $dbhmaker
 587   $self->_dbic_connect_attributes (\%attrs);
 588
 589   return $self->_connect_info;
 590 }
 591
 592 sub _normalize_connect_info {
 593   my ($self, $info_arg) = @_;
 594   my %info;
 595
 596   my @args = @$info_arg;  # take a shallow copy for further mutilation
 597
 598   # combine/pre-parse arguments depending on invocation style
 599
 600   my %attrs;
 601   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 602     %attrs = %{ $args[1] || {} };
 603     @args = $args[0];
 604   }
 605   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 606     %attrs = %{$args[0]};
 607     @args = ();
 608     if (my $code = delete $attrs{dbh_maker}) {
 609       @args = $code;
 610
 611       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 612       if (@ignored) {
 613         carp sprintf (
 614             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 615           . "to the result of 'dbh_maker'",
 616
 617           join (', ', map { "'$_'" } (@ignored) ),
 618         );
 619       }
 620     }
 621     else {
 622       @args = delete @attrs{qw/dsn user password/};
 623     }
 624   }
 625   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 626     %attrs = (
 627       % { $args[3] || {} },
 628       % { $args[4] || {} },
 629     );
 630     @args = @args[0,1,2];
 631   }
 632
 633   $info{arguments} = \@args;
 634
 635   my @storage_opts = grep exists $attrs{$_},
 636     @storage_options, 'cursor_class';
 637
 638   @{ $info{storage_options} }{@storage_opts} =
 639     delete @attrs{@storage_opts} if @storage_opts;
 640
 641   my @sql_maker_opts = grep exists $attrs{$_},
 642     qw/limit_dialect quote_char name_sep/;
 643
 644   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 645     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 646
 647   $info{attributes} = \%attrs if %attrs;
 648
 649   return \%info;
 650 }
 651
 652 sub _default_dbi_connect_attributes {
 653   return {
 654     AutoCommit => 1,
 655     RaiseError => 1,
 656     PrintError => 0,
 657   };
 658 }
 659
 660 =head2 on_connect_do
 661
 662 This method is deprecated in favour of setting via L</connect_info>.
 663
 664 =cut
 665
 666 =head2 on_disconnect_do
 667
 668 This method is deprecated in favour of setting via L</connect_info>.
 669
 670 =cut
 671
 672 sub _parse_connect_do {
 673   my ($self, $type) = @_;
 674
 675   my $val = $self->$type;
 676   return () if not defined $val;
 677
 678   my @res;
 679
 680   if (not ref($val)) {
 681     push @res, [ 'do_sql', $val ];
 682   } elsif (ref($val) eq 'CODE') {
 683     push @res, $val;
 684   } elsif (ref($val) eq 'ARRAY') {
 685     push @res, map { [ 'do_sql', $_ ] } @$val;
 686   } else {
 687     $self->throw_exception("Invalid type for $type: ".ref($val));
 688   }
 689
 690   return \@res;
 691 }
 692
 693 =head2 dbh_do
 694
 695 Arguments: ($subref | $method_name), @extra_coderef_args?
 696
 697 Execute the given $subref or $method_name using the new exception-based
 698 connection management.
 699
 700 The first two arguments will be the storage object that C<dbh_do> was called
 701 on and a database handle to use.  Any additional arguments will be passed
 702 verbatim to the called subref as arguments 2 and onwards.
 703
 704 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 705 exception handling and reconnection (or failover in future subclasses).
 706
 707 Your subref should have no side-effects outside of the database, as
 708 there is the potential for your subref to be partially double-executed
 709 if the database connection was stale/dysfunctional.
 710
 711 Example:
 712
 713   my @stuff = $schema->storage->dbh_do(
 714     sub {
 715       my ($storage, $dbh, @cols) = @_;
 716       my $cols = join(q{, }, @cols);
 717       $dbh->selectrow_array("SELECT $cols FROM foo");
 718     },
 719     @column_list
 720   );
 721
 722 =cut
 723
 724 sub dbh_do {
 725   my $self = shift;
 726   my $code = shift;
 727
 728   my $dbh = $self->_get_dbh;
 729
 730   return $self->$code($dbh, @_)
 731     if ( $self->{_in_dbh_do} || $self->{transaction_depth} );
 732
 733   local $self->{_in_dbh_do} = 1;
 734
 735   # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 736   my $args = \@_;
 737   return try {
 738     $self->$code ($dbh, @$args);
 739   } catch {
 740     $self->throw_exception($_) if $self->connected;
 741
 742     # We were not connected - reconnect and retry, but let any
 743     #  exception fall right through this time
 744     carp "Retrying $code after catching disconnected exception: $_"
 745       if $ENV{DBIC_DBIRETRY_DEBUG};
 746
 747     $self->_populate_dbh;
 748     $self->$code($self->_dbh, @$args);
 749   };
 750 }
 751
 752 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 753 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 754 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 755 sub txn_do {
 756   my $self = shift;
 757   my $coderef = shift;
 758
 759   ref $coderef eq 'CODE' or $self->throw_exception
 760     ('$coderef must be a CODE reference');
 761
 762   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 763
 764   local $self->{_in_dbh_do} = 1;
 765
 766   my @result;
 767   my $want_array = wantarray;
 768
 769   my $tried = 0;
 770   while(1) {
 771     my $exception;
 772
 773     # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 774     my $args = \@_;
 775
 776     try {
 777       $self->_get_dbh;
 778
 779       $self->txn_begin;
 780       if($want_array) {
 781           @result = $coderef->(@$args);
 782       }
 783       elsif(defined $want_array) {
 784           $result[0] = $coderef->(@$args);
 785       }
 786       else {
 787           $coderef->(@$args);
 788       }
 789       $self->txn_commit;
 790     } catch {
 791       $exception = $_;
 792     };
 793
 794     if(! defined $exception) { return $want_array ? @result : $result[0] }
 795
 796     if($tried++ || $self->connected) {
 797       my $rollback_exception;
 798       try { $self->txn_rollback } catch { $rollback_exception = shift };
 799       if(defined $rollback_exception) {
 800         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 801         $self->throw_exception($exception)  # propagate nested rollback
 802           if $rollback_exception =~ /$exception_class/;
 803
 804         $self->throw_exception(
 805           "Transaction aborted: ${exception}. "
 806           . "Rollback failed: ${rollback_exception}"
 807         );
 808       }
 809       $self->throw_exception($exception)
 810     }
 811
 812     # We were not connected, and was first try - reconnect and retry
 813     # via the while loop
 814     carp "Retrying $coderef after catching disconnected exception: $exception"
 815       if $ENV{DBIC_DBIRETRY_DEBUG};
 816     $self->_populate_dbh;
 817   }
 818 }
 819
 820 =head2 disconnect
 821
 822 Our C<disconnect> method also performs a rollback first if the
 823 database is not in C<AutoCommit> mode.
 824
 825 =cut
 826
 827 sub disconnect {
 828   my ($self) = @_;
 829
 830   if( $self->_dbh ) {
 831     my @actions;
 832
 833     push @actions, ( $self->on_disconnect_call || () );
 834     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 835
 836     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 837
 838     $self->_dbh_rollback unless $self->_dbh_autocommit;
 839
 840     %{ $self->_dbh->{CachedKids} } = ();
 841     $self->_dbh->disconnect;
 842     $self->_dbh(undef);
 843     $self->{_dbh_gen}++;
 844   }
 845 }
 846
 847 =head2 with_deferred_fk_checks
 848
 849 =over 4
 850
 851 =item Arguments: C<$coderef>
 852
 853 =item Return Value: The return value of $coderef
 854
 855 =back
 856
 857 Storage specific method to run the code ref with FK checks deferred or
 858 in MySQL's case disabled entirely.
 859
 860 =cut
 861
 862 # Storage subclasses should override this
 863 sub with_deferred_fk_checks {
 864   my ($self, $sub) = @_;
 865   $sub->();
 866 }
 867
 868 =head2 connected
 869
 870 =over
 871
 872 =item Arguments: none
 873
 874 =item Return Value: 1|0
 875
 876 =back
 877
 878 Verifies that the current database handle is active and ready to execute
 879 an SQL statement (e.g. the connection did not get stale, server is still
 880 answering, etc.) This method is used internally by L</dbh>.
 881
 882 =cut
 883
 884 sub connected {
 885   my $self = shift;
 886   return 0 unless $self->_seems_connected;
 887
 888   #be on the safe side
 889   local $self->_dbh->{RaiseError} = 1;
 890
 891   return $self->_ping;
 892 }
 893
 894 sub _seems_connected {
 895   my $self = shift;
 896
 897   $self->_preserve_foreign_dbh;
 898
 899   my $dbh = $self->_dbh
 900     or return 0;
 901
 902   return $dbh->FETCH('Active');
 903 }
 904
 905 sub _ping {
 906   my $self = shift;
 907
 908   my $dbh = $self->_dbh or return 0;
 909
 910   return $dbh->ping;
 911 }
 912
 913 sub ensure_connected {
 914   my ($self) = @_;
 915
 916   unless ($self->connected) {
 917     $self->_populate_dbh;
 918   }
 919 }
 920
 921 =head2 dbh
 922
 923 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 924 is guaranteed to be healthy by implicitly calling L</connected>, and if
 925 necessary performing a reconnection before returning. Keep in mind that this
 926 is very B<expensive> on some database engines. Consider using L</dbh_do>
 927 instead.
 928
 929 =cut
 930
 931 sub dbh {
 932   my ($self) = @_;
 933
 934   if (not $self->_dbh) {
 935     $self->_populate_dbh;
 936   } else {
 937     $self->ensure_connected;
 938   }
 939   return $self->_dbh;
 940 }
 941
 942 # this is the internal "get dbh or connect (don't check)" method
 943 sub _get_dbh {
 944   my $self = shift;
 945   $self->_preserve_foreign_dbh;
 946   $self->_populate_dbh unless $self->_dbh;
 947   return $self->_dbh;
 948 }
 949
 950 sub _sql_maker_args {
 951     my ($self) = @_;
 952
 953     return (
 954       bindtype=>'columns',
 955       array_datatypes => 1,
 956       limit_dialect => $self->_get_dbh,
 957       %{$self->_sql_maker_opts}
 958     );
 959 }
 960
 961 sub sql_maker {
 962   my ($self) = @_;
 963   unless ($self->_sql_maker) {
 964     my $sql_maker_class = $self->sql_maker_class;
 965     $self->ensure_class_loaded ($sql_maker_class);
 966     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 967   }
 968   return $self->_sql_maker;
 969 }
 970
 971 # nothing to do by default
 972 sub _rebless {}
 973 sub _init {}
 974
 975 sub _populate_dbh {
 976   my ($self) = @_;
 977
 978   my @info = @{$self->_dbi_connect_info || []};
 979   $self->_dbh(undef); # in case ->connected failed we might get sent here
 980   $self->_server_info_hash (undef);
 981   $self->_dbh($self->_connect(@info));
 982
 983   $self->_conn_pid($$);
 984   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 985
 986   $self->_determine_driver;
 987
 988   # Always set the transaction depth on connect, since
 989   #  there is no transaction in progress by definition
 990   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 991
 992   $self->_run_connection_actions unless $self->{_in_determine_driver};
 993 }
 994
 995 sub _run_connection_actions {
 996   my $self = shift;
 997   my @actions;
 998
 999   push @actions, ( $self->on_connect_call || () );
1000   push @actions, $self->_parse_connect_do ('on_connect_do');
1001
1002   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1003 }
1004
1005 sub _server_info {
1006   my $self = shift;
1007
1008   unless ($self->_server_info_hash) {
1009
1010     my %info;
1011
1012     my $server_version = try { $self->_get_server_version };
1013
1014     if (defined $server_version) {
1015       $info{dbms_version} = $server_version;
1016
1017       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1018       my @verparts = split (/\./, $numeric_version);
1019       if (
1020         @verparts
1021           &&
1022         $verparts[0] <= 999
1023       ) {
1024         # consider only up to 3 version parts, iff not more than 3 digits
1025         my @use_parts;
1026         while (@verparts && @use_parts < 3) {
1027           my $p = shift @verparts;
1028           last if $p > 999;
1029           push @use_parts, $p;
1030         }
1031         push @use_parts, 0 while @use_parts < 3;
1032
1033         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1034       }
1035     }
1036
1037     $self->_server_info_hash(\%info);
1038   }
1039
1040   return $self->_server_info_hash
1041 }
1042
1043 sub _get_server_version {
1044   shift->_get_dbh->get_info(18);
1045 }
1046
1047 sub _determine_driver {
1048   my ($self) = @_;
1049
1050   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1051     my $started_connected = 0;
1052     local $self->{_in_determine_driver} = 1;
1053
1054     if (ref($self) eq __PACKAGE__) {
1055       my $driver;
1056       if ($self->_dbh) { # we are connected
1057         $driver = $self->_dbh->{Driver}{Name};
1058         $started_connected = 1;
1059       } else {
1060         # if connect_info is a CODEREF, we have no choice but to connect
1061         if (ref $self->_dbi_connect_info->[0] &&
1062             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1063           $self->_populate_dbh;
1064           $driver = $self->_dbh->{Driver}{Name};
1065         }
1066         else {
1067           # try to use dsn to not require being connected, the driver may still
1068           # force a connection in _rebless to determine version
1069           # (dsn may not be supplied at all if all we do is make a mock-schema)
1070           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1071           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1072           $driver ||= $ENV{DBI_DRIVER};
1073         }
1074       }
1075
1076       if ($driver) {
1077         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1078         if ($self->load_optional_class($storage_class)) {
1079           mro::set_mro($storage_class, 'c3');
1080           bless $self, $storage_class;
1081           $self->_rebless();
1082         }
1083       }
1084     }
1085
1086     $self->_driver_determined(1);
1087
1088     $self->_init; # run driver-specific initializations
1089
1090     $self->_run_connection_actions
1091         if !$started_connected && defined $self->_dbh;
1092   }
1093 }
1094
1095 sub _do_connection_actions {
1096   my $self          = shift;
1097   my $method_prefix = shift;
1098   my $call          = shift;
1099
1100   if (not ref($call)) {
1101     my $method = $method_prefix . $call;
1102     $self->$method(@_);
1103   } elsif (ref($call) eq 'CODE') {
1104     $self->$call(@_);
1105   } elsif (ref($call) eq 'ARRAY') {
1106     if (ref($call->[0]) ne 'ARRAY') {
1107       $self->_do_connection_actions($method_prefix, $_) for @$call;
1108     } else {
1109       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1110     }
1111   } else {
1112     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1113   }
1114
1115   return $self;
1116 }
1117
1118 sub connect_call_do_sql {
1119   my $self = shift;
1120   $self->_do_query(@_);
1121 }
1122
1123 sub disconnect_call_do_sql {
1124   my $self = shift;
1125   $self->_do_query(@_);
1126 }
1127
1128 # override in db-specific backend when necessary
1129 sub connect_call_datetime_setup { 1 }
1130
1131 sub _do_query {
1132   my ($self, $action) = @_;
1133
1134   if (ref $action eq 'CODE') {
1135     $action = $action->($self);
1136     $self->_do_query($_) foreach @$action;
1137   }
1138   else {
1139     # Most debuggers expect ($sql, @bind), so we need to exclude
1140     # the attribute hash which is the second argument to $dbh->do
1141     # furthermore the bind values are usually to be presented
1142     # as named arrayref pairs, so wrap those here too
1143     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1144     my $sql = shift @do_args;
1145     my $attrs = shift @do_args;
1146     my @bind = map { [ undef, $_ ] } @do_args;
1147
1148     $self->_query_start($sql, @bind);
1149     $self->_get_dbh->do($sql, $attrs, @do_args);
1150     $self->_query_end($sql, @bind);
1151   }
1152
1153   return $self;
1154 }
1155
1156 sub _connect {
1157   my ($self, @info) = @_;
1158
1159   $self->throw_exception("You failed to provide any connection info")
1160     if !@info;
1161
1162   my ($old_connect_via, $dbh);
1163
1164   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1165     $old_connect_via = $DBI::connect_via;
1166     $DBI::connect_via = 'connect';
1167   }
1168
1169   # FIXME - this should have been Try::Tiny, but triggers a leak-bug in perl(!)
1170   # related to coderef refcounting. A failing test has been submitted to T::T
1171   my $connect_ok = eval {
1172     if(ref $info[0] eq 'CODE') {
1173        $dbh = $info[0]->();
1174     }
1175     else {
1176        $dbh = DBI->connect(@info);
1177     }
1178
1179     if (!$dbh) {
1180       die $DBI::errstr;
1181     }
1182
1183     unless ($self->unsafe) {
1184       my $weak_self = $self;
1185       weaken $weak_self;
1186       $dbh->{HandleError} = sub {
1187           if ($weak_self) {
1188             $weak_self->throw_exception("DBI Exception: $_[0]");
1189           }
1190           else {
1191             # the handler may be invoked by something totally out of
1192             # the scope of DBIC
1193             croak ("DBI Exception: $_[0]");
1194           }
1195       };
1196       $dbh->{ShowErrorStatement} = 1;
1197       $dbh->{RaiseError} = 1;
1198       $dbh->{PrintError} = 0;
1199     }
1200
1201     1;
1202   };
1203
1204   my $possible_err = $@;
1205   $DBI::connect_via = $old_connect_via if $old_connect_via;
1206
1207   unless ($connect_ok) {
1208     $self->throw_exception("DBI Connection failed: $possible_err")
1209   }
1210
1211   $self->_dbh_autocommit($dbh->{AutoCommit});
1212   $dbh;
1213 }
1214
1215 sub svp_begin {
1216   my ($self, $name) = @_;
1217
1218   $name = $self->_svp_generate_name
1219     unless defined $name;
1220
1221   $self->throw_exception ("You can't use savepoints outside a transaction")
1222     if $self->{transaction_depth} == 0;
1223
1224   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1225     unless $self->can('_svp_begin');
1226
1227   push @{ $self->{savepoints} }, $name;
1228
1229   $self->debugobj->svp_begin($name) if $self->debug;
1230
1231   return $self->_svp_begin($name);
1232 }
1233
1234 sub svp_release {
1235   my ($self, $name) = @_;
1236
1237   $self->throw_exception ("You can't use savepoints outside a transaction")
1238     if $self->{transaction_depth} == 0;
1239
1240   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1241     unless $self->can('_svp_release');
1242
1243   if (defined $name) {
1244     $self->throw_exception ("Savepoint '$name' does not exist")
1245       unless grep { $_ eq $name } @{ $self->{savepoints} };
1246
1247     # Dig through the stack until we find the one we are releasing.  This keeps
1248     # the stack up to date.
1249     my $svp;
1250
1251     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1252   } else {
1253     $name = pop @{ $self->{savepoints} };
1254   }
1255
1256   $self->debugobj->svp_release($name) if $self->debug;
1257
1258   return $self->_svp_release($name);
1259 }
1260
1261 sub svp_rollback {
1262   my ($self, $name) = @_;
1263
1264   $self->throw_exception ("You can't use savepoints outside a transaction")
1265     if $self->{transaction_depth} == 0;
1266
1267   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1268     unless $self->can('_svp_rollback');
1269
1270   if (defined $name) {
1271       # If they passed us a name, verify that it exists in the stack
1272       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1273           $self->throw_exception("Savepoint '$name' does not exist!");
1274       }
1275
1276       # Dig through the stack until we find the one we are releasing.  This keeps
1277       # the stack up to date.
1278       while(my $s = pop(@{ $self->{savepoints} })) {
1279           last if($s eq $name);
1280       }
1281       # Add the savepoint back to the stack, as a rollback doesn't remove the
1282       # named savepoint, only everything after it.
1283       push(@{ $self->{savepoints} }, $name);
1284   } else {
1285       # We'll assume they want to rollback to the last savepoint
1286       $name = $self->{savepoints}->[-1];
1287   }
1288
1289   $self->debugobj->svp_rollback($name) if $self->debug;
1290
1291   return $self->_svp_rollback($name);
1292 }
1293
1294 sub _svp_generate_name {
1295     my ($self) = @_;
1296
1297     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1298 }
1299
1300 sub txn_begin {
1301   my $self = shift;
1302
1303   # this means we have not yet connected and do not know the AC status
1304   # (e.g. coderef $dbh)
1305   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1306
1307   if($self->{transaction_depth} == 0) {
1308     $self->debugobj->txn_begin()
1309       if $self->debug;
1310     $self->_dbh_begin_work;
1311   }
1312   elsif ($self->auto_savepoint) {
1313     $self->svp_begin;
1314   }
1315   $self->{transaction_depth}++;
1316 }
1317
1318 sub _dbh_begin_work {
1319   my $self = shift;
1320
1321   # if the user is utilizing txn_do - good for him, otherwise we need to
1322   # ensure that the $dbh is healthy on BEGIN.
1323   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1324   # will be replaced by a failure of begin_work itself (which will be
1325   # then retried on reconnect)
1326   if ($self->{_in_dbh_do}) {
1327     $self->_dbh->begin_work;
1328   } else {
1329     $self->dbh_do(sub { $_[1]->begin_work });
1330   }
1331 }
1332
1333 sub txn_commit {
1334   my $self = shift;
1335   if ($self->{transaction_depth} == 1) {
1336     $self->debugobj->txn_commit()
1337       if ($self->debug);
1338     $self->_dbh_commit;
1339     $self->{transaction_depth} = 0
1340       if $self->_dbh_autocommit;
1341   }
1342   elsif($self->{transaction_depth} > 1) {
1343     $self->{transaction_depth}--;
1344     $self->svp_release
1345       if $self->auto_savepoint;
1346   }
1347 }
1348
1349 sub _dbh_commit {
1350   my $self = shift;
1351   my $dbh  = $self->_dbh
1352     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1353   $dbh->commit;
1354 }
1355
1356 sub txn_rollback {
1357   my $self = shift;
1358   my $dbh = $self->_dbh;
1359   try {
1360     if ($self->{transaction_depth} == 1) {
1361       $self->debugobj->txn_rollback()
1362         if ($self->debug);
1363       $self->{transaction_depth} = 0
1364         if $self->_dbh_autocommit;
1365       $self->_dbh_rollback;
1366     }
1367     elsif($self->{transaction_depth} > 1) {
1368       $self->{transaction_depth}--;
1369       if ($self->auto_savepoint) {
1370         $self->svp_rollback;
1371         $self->svp_release;
1372       }
1373     }
1374     else {
1375       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1376     }
1377   }
1378   catch {
1379     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1380
1381     if ($_ !~ /$exception_class/) {
1382       # ensure that a failed rollback resets the transaction depth
1383       $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1384     }
1385
1386     $self->throw_exception($_)
1387   };
1388 }
1389
1390 sub _dbh_rollback {
1391   my $self = shift;
1392   my $dbh  = $self->_dbh
1393     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1394   $dbh->rollback;
1395 }
1396
1397 # This used to be the top-half of _execute.  It was split out to make it
1398 #  easier to override in NoBindVars without duping the rest.  It takes up
1399 #  all of _execute's args, and emits $sql, @bind.
1400 sub _prep_for_execute {
1401   my ($self, $op, $extra_bind, $ident, $args) = @_;
1402
1403   if( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
1404     $ident = $ident->from();
1405   }
1406
1407   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1408
1409   unshift(@bind,
1410     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1411       if $extra_bind;
1412   return ($sql, \@bind);
1413 }
1414
1415
1416 sub _fix_bind_params {
1417     my ($self, @bind) = @_;
1418
1419     ### Turn @bind from something like this:
1420     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1421     ### to this:
1422     ###   ( "'1'", "'1'", "'3'" )
1423     return
1424         map {
1425             if ( defined( $_ && $_->[1] ) ) {
1426                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1427             }
1428             else { q{'NULL'}; }
1429         } @bind;
1430 }
1431
1432 sub _query_start {
1433     my ( $self, $sql, @bind ) = @_;
1434
1435     if ( $self->debug ) {
1436         @bind = $self->_fix_bind_params(@bind);
1437
1438         $self->debugobj->query_start( $sql, @bind );
1439     }
1440 }
1441
1442 sub _query_end {
1443     my ( $self, $sql, @bind ) = @_;
1444
1445     if ( $self->debug ) {
1446         @bind = $self->_fix_bind_params(@bind);
1447         $self->debugobj->query_end( $sql, @bind );
1448     }
1449 }
1450
1451 sub _dbh_execute {
1452   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1453
1454   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1455
1456   $self->_query_start( $sql, @$bind );
1457
1458   my $sth = $self->sth($sql,$op);
1459
1460   my $placeholder_index = 1;
1461
1462   foreach my $bound (@$bind) {
1463     my $attributes = {};
1464     my($column_name, @data) = @$bound;
1465
1466     if ($bind_attributes) {
1467       $attributes = $bind_attributes->{$column_name}
1468       if defined $bind_attributes->{$column_name};
1469     }
1470
1471     foreach my $data (@data) {
1472       my $ref = ref $data;
1473       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1474
1475       $sth->bind_param($placeholder_index, $data, $attributes);
1476       $placeholder_index++;
1477     }
1478   }
1479
1480   # Can this fail without throwing an exception anyways???
1481   my $rv = $sth->execute();
1482   $self->throw_exception(
1483     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1484   ) if !$rv;
1485
1486   $self->_query_end( $sql, @$bind );
1487
1488   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1489 }
1490
1491 sub _execute {
1492     my $self = shift;
1493     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1494 }
1495
1496 sub _prefetch_insert_auto_nextvals {
1497   my ($self, $source, $to_insert) = @_;
1498
1499   my $upd = {};
1500
1501   foreach my $col ( $source->columns ) {
1502     if ( !defined $to_insert->{$col} ) {
1503       my $col_info = $source->column_info($col);
1504
1505       if ( $col_info->{auto_nextval} ) {
1506         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1507           'nextval',
1508           $col_info->{sequence} ||=
1509             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1510         );
1511       }
1512     }
1513   }
1514
1515   return $upd;
1516 }
1517
1518 sub insert {
1519   my $self = shift;
1520   my ($source, $to_insert, $opts) = @_;
1521
1522   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1523
1524   my $bind_attributes = $self->source_bind_attributes($source);
1525
1526   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1527
1528   if ($opts->{returning}) {
1529     my @ret_cols = @{$opts->{returning}};
1530
1531     my @ret_vals = try {
1532       local $SIG{__WARN__} = sub {};
1533       my @r = $sth->fetchrow_array;
1534       $sth->finish;
1535       @r;
1536     };
1537
1538     my %ret;
1539     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1540
1541     $updated_cols = {
1542       %$updated_cols,
1543       %ret,
1544     };
1545   }
1546
1547   return $updated_cols;
1548 }
1549
1550 ## Currently it is assumed that all values passed will be "normal", i.e. not
1551 ## scalar refs, or at least, all the same type as the first set, the statement is
1552 ## only prepped once.
1553 sub insert_bulk {
1554   my ($self, $source, $cols, $data) = @_;
1555
1556   my %colvalues;
1557   @colvalues{@$cols} = (0..$#$cols);
1558
1559   for my $i (0..$#$cols) {
1560     my $first_val = $data->[0][$i];
1561     next unless ref $first_val eq 'SCALAR';
1562
1563     $colvalues{ $cols->[$i] } = $first_val;
1564   }
1565
1566   # check for bad data and stringify stringifiable objects
1567   my $bad_slice = sub {
1568     my ($msg, $col_idx, $slice_idx) = @_;
1569     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1570       $msg,
1571       $cols->[$col_idx],
1572       do {
1573         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1574         Dumper {
1575           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1576         },
1577       }
1578     );
1579   };
1580
1581   for my $datum_idx (0..$#$data) {
1582     my $datum = $data->[$datum_idx];
1583
1584     for my $col_idx (0..$#$cols) {
1585       my $val            = $datum->[$col_idx];
1586       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1587       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1588
1589       if ($is_literal_sql) {
1590         if (not ref $val) {
1591           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1592         }
1593         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1594           $bad_slice->("$reftype reference found where literal SQL expected",
1595             $col_idx, $datum_idx);
1596         }
1597         elsif ($$val ne $$sqla_bind){
1598           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1599             $col_idx, $datum_idx);
1600         }
1601       }
1602       elsif (my $reftype = ref $val) {
1603         require overload;
1604         if (overload::Method($val, '""')) {
1605           $datum->[$col_idx] = "".$val;
1606         }
1607         else {
1608           $bad_slice->("$reftype reference found where bind expected",
1609             $col_idx, $datum_idx);
1610         }
1611       }
1612     }
1613   }
1614
1615   my ($sql, $bind) = $self->_prep_for_execute (
1616     'insert', undef, $source, [\%colvalues]
1617   );
1618   my @bind = @$bind;
1619
1620   my $empty_bind = 1 if (not @bind) &&
1621     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1622
1623   if ((not @bind) && (not $empty_bind)) {
1624     $self->throw_exception(
1625       'Cannot insert_bulk without support for placeholders'
1626     );
1627   }
1628
1629   # neither _execute_array, nor _execute_inserts_with_no_binds are
1630   # atomic (even if _execute _array is a single call). Thus a safety
1631   # scope guard
1632   my $guard = $self->txn_scope_guard;
1633
1634   $self->_query_start( $sql, [ dummy => '__BULK_INSERT__' ] );
1635   my $sth = $self->sth($sql);
1636   my $rv = do {
1637     if ($empty_bind) {
1638       # bind_param_array doesn't work if there are no binds
1639       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1640     }
1641     else {
1642 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1643       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1644     }
1645   };
1646
1647   $self->_query_end( $sql, [ dummy => '__BULK_INSERT__' ] );
1648
1649   $guard->commit;
1650
1651   return (wantarray ? ($rv, $sth, @bind) : $rv);
1652 }
1653
1654 sub _execute_array {
1655   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1656
1657   ## This must be an arrayref, else nothing works!
1658   my $tuple_status = [];
1659
1660   ## Get the bind_attributes, if any exist
1661   my $bind_attributes = $self->source_bind_attributes($source);
1662
1663   ## Bind the values and execute
1664   my $placeholder_index = 1;
1665
1666   foreach my $bound (@$bind) {
1667
1668     my $attributes = {};
1669     my ($column_name, $data_index) = @$bound;
1670
1671     if( $bind_attributes ) {
1672       $attributes = $bind_attributes->{$column_name}
1673       if defined $bind_attributes->{$column_name};
1674     }
1675
1676     my @data = map { $_->[$data_index] } @$data;
1677
1678     $sth->bind_param_array(
1679       $placeholder_index,
1680       [@data],
1681       (%$attributes ?  $attributes : ()),
1682     );
1683     $placeholder_index++;
1684   }
1685
1686   my ($rv, $err);
1687   try {
1688     $rv = $self->_dbh_execute_array($sth, $tuple_status, @extra);
1689   }
1690   catch {
1691     $err = shift;
1692   }
1693   finally {
1694     # Statement must finish even if there was an exception.
1695     try {
1696       $sth->finish
1697     }
1698     catch {
1699       $err = shift unless defined $err
1700     };
1701   };
1702
1703   $err = $sth->errstr
1704     if (! defined $err and $sth->err);
1705
1706   if (defined $err) {
1707     my $i = 0;
1708     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1709
1710     $self->throw_exception("Unexpected populate error: $err")
1711       if ($i > $#$tuple_status);
1712
1713     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1714       ($tuple_status->[$i][1] || $err),
1715       Dumper { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
1716     );
1717   }
1718
1719   return $rv;
1720 }
1721
1722 sub _dbh_execute_array {
1723     my ($self, $sth, $tuple_status, @extra) = @_;
1724
1725     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1726 }
1727
1728 sub _dbh_execute_inserts_with_no_binds {
1729   my ($self, $sth, $count) = @_;
1730
1731   my $err;
1732   try {
1733     my $dbh = $self->_get_dbh;
1734     local $dbh->{RaiseError} = 1;
1735     local $dbh->{PrintError} = 0;
1736
1737     $sth->execute foreach 1..$count;
1738   }
1739   catch {
1740     $err = shift;
1741   }
1742   finally {
1743     # Make sure statement is finished even if there was an exception.
1744     try {
1745       $sth->finish
1746     }
1747     catch {
1748       $err = shift unless defined $err;
1749     };
1750   };
1751
1752   $self->throw_exception($err) if defined $err;
1753
1754   return $count;
1755 }
1756
1757 sub update {
1758   my ($self, $source, @args) = @_;
1759
1760   my $bind_attrs = $self->source_bind_attributes($source);
1761
1762   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1763 }
1764
1765
1766 sub delete {
1767   my ($self, $source, @args) = @_;
1768
1769   my $bind_attrs = $self->source_bind_attributes($source);
1770
1771   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1772 }
1773
1774 # We were sent here because the $rs contains a complex search
1775 # which will require a subquery to select the correct rows
1776 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1777 #
1778 # Generating a single PK column subquery is trivial and supported
1779 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1780 # Look at _multipk_update_delete()
1781 sub _subq_update_delete {
1782   my $self = shift;
1783   my ($rs, $op, $values) = @_;
1784
1785   my $rsrc = $rs->result_source;
1786
1787   # quick check if we got a sane rs on our hands
1788   my @pcols = $rsrc->_pri_cols;
1789
1790   my $sel = $rs->_resolved_attrs->{select};
1791   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1792
1793   if (
1794       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1795         ne
1796       join ("\x00", sort @$sel )
1797   ) {
1798     $self->throw_exception (
1799       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1800     );
1801   }
1802
1803   if (@pcols == 1) {
1804     return $self->$op (
1805       $rsrc,
1806       $op eq 'update' ? $values : (),
1807       { $pcols[0] => { -in => $rs->as_query } },
1808     );
1809   }
1810
1811   else {
1812     return $self->_multipk_update_delete (@_);
1813   }
1814 }
1815
1816 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1817 # resultset update/delete involving subqueries. So by default resort
1818 # to simple (and inefficient) delete_all style per-row opearations,
1819 # while allowing specific storages to override this with a faster
1820 # implementation.
1821 #
1822 sub _multipk_update_delete {
1823   return shift->_per_row_update_delete (@_);
1824 }
1825
1826 # This is the default loop used to delete/update rows for multi PK
1827 # resultsets, and used by mysql exclusively (because it can't do anything
1828 # else).
1829 #
1830 # We do not use $row->$op style queries, because resultset update/delete
1831 # is not expected to cascade (this is what delete_all/update_all is for).
1832 #
1833 # There should be no race conditions as the entire operation is rolled
1834 # in a transaction.
1835 #
1836 sub _per_row_update_delete {
1837   my $self = shift;
1838   my ($rs, $op, $values) = @_;
1839
1840   my $rsrc = $rs->result_source;
1841   my @pcols = $rsrc->_pri_cols;
1842
1843   my $guard = $self->txn_scope_guard;
1844
1845   # emulate the return value of $sth->execute for non-selects
1846   my $row_cnt = '0E0';
1847
1848   my $subrs_cur = $rs->cursor;
1849   my @all_pk = $subrs_cur->all;
1850   for my $pks ( @all_pk) {
1851
1852     my $cond;
1853     for my $i (0.. $#pcols) {
1854       $cond->{$pcols[$i]} = $pks->[$i];
1855     }
1856
1857     $self->$op (
1858       $rsrc,
1859       $op eq 'update' ? $values : (),
1860       $cond,
1861     );
1862
1863     $row_cnt++;
1864   }
1865
1866   $guard->commit;
1867
1868   return $row_cnt;
1869 }
1870
1871 sub _select {
1872   my $self = shift;
1873   $self->_execute($self->_select_args(@_));
1874 }
1875
1876 sub _select_args_to_query {
1877   my $self = shift;
1878
1879   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1880   #  = $self->_select_args($ident, $select, $cond, $attrs);
1881   my ($op, $bind, $ident, $bind_attrs, @args) =
1882     $self->_select_args(@_);
1883
1884   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1885   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1886   $prepared_bind ||= [];
1887
1888   return wantarray
1889     ? ($sql, $prepared_bind, $bind_attrs)
1890     : \[ "($sql)", @$prepared_bind ]
1891   ;
1892 }
1893
1894 sub _select_args {
1895   my ($self, $ident, $select, $where, $attrs) = @_;
1896
1897   my $sql_maker = $self->sql_maker;
1898   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1899
1900   $attrs = {
1901     %$attrs,
1902     select => $select,
1903     from => $ident,
1904     where => $where,
1905     $rs_alias && $alias2source->{$rs_alias}
1906       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1907       : ()
1908     ,
1909   };
1910
1911   # calculate bind_attrs before possible $ident mangling
1912   my $bind_attrs = {};
1913   for my $alias (keys %$alias2source) {
1914     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1915     for my $col (keys %$bindtypes) {
1916
1917       my $fqcn = join ('.', $alias, $col);
1918       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1919
1920       # Unqialified column names are nice, but at the same time can be
1921       # rather ambiguous. What we do here is basically go along with
1922       # the loop, adding an unqualified column slot to $bind_attrs,
1923       # alongside the fully qualified name. As soon as we encounter
1924       # another column by that name (which would imply another table)
1925       # we unset the unqualified slot and never add any info to it
1926       # to avoid erroneous type binding. If this happens the users
1927       # only choice will be to fully qualify his column name
1928
1929       if (exists $bind_attrs->{$col}) {
1930         $bind_attrs->{$col} = {};
1931       }
1932       else {
1933         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1934       }
1935     }
1936   }
1937
1938   # adjust limits
1939   if (defined $attrs->{rows}) {
1940     $self->throw_exception("rows attribute must be positive if present")
1941       unless $attrs->{rows} > 0;
1942   }
1943   elsif (defined $attrs->{offset}) {
1944     # MySQL actually recommends this approach.  I cringe.
1945     $attrs->{rows} = $sql_maker->__max_int;
1946   }
1947
1948   my @limit;
1949
1950   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1951   # storage, unless software limit was requested
1952   if (
1953     #limited has_many
1954     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1955        ||
1956     # grouped prefetch (to satisfy group_by == select)
1957     ( $attrs->{group_by}
1958         &&
1959       @{$attrs->{group_by}}
1960         &&
1961       $attrs->{_prefetch_select}
1962         &&
1963       @{$attrs->{_prefetch_select}}
1964     )
1965   ) {
1966     ($ident, $select, $where, $attrs)
1967       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1968   }
1969   elsif (! $attrs->{software_limit} ) {
1970     push @limit, $attrs->{rows}, $attrs->{offset};
1971   }
1972
1973   # try to simplify the joinmap further (prune unreferenced type-single joins)
1974   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1975
1976 ###
1977   # This would be the point to deflate anything found in $where
1978   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1979   # expect a row object. And all we have is a resultsource (it is trivial
1980   # to extract deflator coderefs via $alias2source above).
1981   #
1982   # I don't see a way forward other than changing the way deflators are
1983   # invoked, and that's just bad...
1984 ###
1985
1986   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
1987 }
1988
1989 # Returns a counting SELECT for a simple count
1990 # query. Abstracted so that a storage could override
1991 # this to { count => 'firstcol' } or whatever makes
1992 # sense as a performance optimization
1993 sub _count_select {
1994   #my ($self, $source, $rs_attrs) = @_;
1995   return { count => '*' };
1996 }
1997
1998
1999 sub source_bind_attributes {
2000   my ($self, $source) = @_;
2001
2002   my $bind_attributes;
2003   foreach my $column ($source->columns) {
2004
2005     my $data_type = $source->column_info($column)->{data_type} || '';
2006     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
2007      if $data_type;
2008   }
2009
2010   return $bind_attributes;
2011 }
2012
2013 =head2 select
2014
2015 =over 4
2016
2017 =item Arguments: $ident, $select, $condition, $attrs
2018
2019 =back
2020
2021 Handle a SQL select statement.
2022
2023 =cut
2024
2025 sub select {
2026   my $self = shift;
2027   my ($ident, $select, $condition, $attrs) = @_;
2028   return $self->cursor_class->new($self, \@_, $attrs);
2029 }
2030
2031 sub select_single {
2032   my $self = shift;
2033   my ($rv, $sth, @bind) = $self->_select(@_);
2034   my @row = $sth->fetchrow_array;
2035   my @nextrow = $sth->fetchrow_array if @row;
2036   if(@row && @nextrow) {
2037     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2038   }
2039   # Need to call finish() to work round broken DBDs
2040   $sth->finish();
2041   return @row;
2042 }
2043
2044 =head2 sth
2045
2046 =over 4
2047
2048 =item Arguments: $sql
2049
2050 =back
2051
2052 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2053
2054 =cut
2055
2056 sub _dbh_sth {
2057   my ($self, $dbh, $sql) = @_;
2058
2059   # 3 is the if_active parameter which avoids active sth re-use
2060   my $sth = $self->disable_sth_caching
2061     ? $dbh->prepare($sql)
2062     : $dbh->prepare_cached($sql, {}, 3);
2063
2064   # XXX You would think RaiseError would make this impossible,
2065   #  but apparently that's not true :(
2066   $self->throw_exception($dbh->errstr) if !$sth;
2067
2068   $sth;
2069 }
2070
2071 sub sth {
2072   my ($self, $sql) = @_;
2073   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2074 }
2075
2076 sub _dbh_columns_info_for {
2077   my ($self, $dbh, $table) = @_;
2078
2079   if ($dbh->can('column_info')) {
2080     my %result;
2081     my $caught;
2082     try {
2083       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2084       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2085       $sth->execute();
2086       while ( my $info = $sth->fetchrow_hashref() ){
2087         my %column_info;
2088         $column_info{data_type}   = $info->{TYPE_NAME};
2089         $column_info{size}      = $info->{COLUMN_SIZE};
2090         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2091         $column_info{default_value} = $info->{COLUMN_DEF};
2092         my $col_name = $info->{COLUMN_NAME};
2093         $col_name =~ s/^\"(.*)\"$/$1/;
2094
2095         $result{$col_name} = \%column_info;
2096       }
2097     } catch {
2098       $caught = 1;
2099     };
2100     return \%result if !$caught && scalar keys %result;
2101   }
2102
2103   my %result;
2104   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2105   $sth->execute;
2106   my @columns = @{$sth->{NAME_lc}};
2107   for my $i ( 0 .. $#columns ){
2108     my %column_info;
2109     $column_info{data_type} = $sth->{TYPE}->[$i];
2110     $column_info{size} = $sth->{PRECISION}->[$i];
2111     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2112
2113     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2114       $column_info{data_type} = $1;
2115       $column_info{size}    = $2;
2116     }
2117
2118     $result{$columns[$i]} = \%column_info;
2119   }
2120   $sth->finish;
2121
2122   foreach my $col (keys %result) {
2123     my $colinfo = $result{$col};
2124     my $type_num = $colinfo->{data_type};
2125     my $type_name;
2126     if(defined $type_num && $dbh->can('type_info')) {
2127       my $type_info = $dbh->type_info($type_num);
2128       $type_name = $type_info->{TYPE_NAME} if $type_info;
2129       $colinfo->{data_type} = $type_name if $type_name;
2130     }
2131   }
2132
2133   return \%result;
2134 }
2135
2136 sub columns_info_for {
2137   my ($self, $table) = @_;
2138   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2139 }
2140
2141 =head2 last_insert_id
2142
2143 Return the row id of the last insert.
2144
2145 =cut
2146
2147 sub _dbh_last_insert_id {
2148     my ($self, $dbh, $source, $col) = @_;
2149
2150     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2151
2152     return $id if defined $id;
2153
2154     my $class = ref $self;
2155     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2156 }
2157
2158 sub last_insert_id {
2159   my $self = shift;
2160   $self->_dbh_last_insert_id ($self->_dbh, @_);
2161 }
2162
2163 =head2 _native_data_type
2164
2165 =over 4
2166
2167 =item Arguments: $type_name
2168
2169 =back
2170
2171 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2172 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2173 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2174
2175 The default implementation returns C<undef>, implement in your Storage driver if
2176 you need this functionality.
2177
2178 Should map types from other databases to the native RDBMS type, for example
2179 C<VARCHAR2> to C<VARCHAR>.
2180
2181 Types with modifiers should map to the underlying data type. For example,
2182 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2183
2184 Composite types should map to the container type, for example
2185 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2186
2187 =cut
2188
2189 sub _native_data_type {
2190   #my ($self, $data_type) = @_;
2191   return undef
2192 }
2193
2194 # Check if placeholders are supported at all
2195 sub _placeholders_supported {
2196   my $self = shift;
2197   my $dbh  = $self->_get_dbh;
2198
2199   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2200   # but it is inaccurate more often than not
2201   return try {
2202     local $dbh->{PrintError} = 0;
2203     local $dbh->{RaiseError} = 1;
2204     $dbh->do('select ?', {}, 1);
2205     1;
2206   }
2207   catch {
2208     0;
2209   };
2210 }
2211
2212 # Check if placeholders bound to non-string types throw exceptions
2213 #
2214 sub _typeless_placeholders_supported {
2215   my $self = shift;
2216   my $dbh  = $self->_get_dbh;
2217
2218   return try {
2219     local $dbh->{PrintError} = 0;
2220     local $dbh->{RaiseError} = 1;
2221     # this specifically tests a bind that is NOT a string
2222     $dbh->do('select 1 where 1 = ?', {}, 1);
2223     1;
2224   }
2225   catch {
2226     0;
2227   };
2228 }
2229
2230 =head2 sqlt_type
2231
2232 Returns the database driver name.
2233
2234 =cut
2235
2236 sub sqlt_type {
2237   shift->_get_dbh->{Driver}->{Name};
2238 }
2239
2240 =head2 bind_attribute_by_data_type
2241
2242 Given a datatype from column info, returns a database specific bind
2243 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2244 let the database planner just handle it.
2245
2246 Generally only needed for special case column types, like bytea in postgres.
2247
2248 =cut
2249
2250 sub bind_attribute_by_data_type {
2251     return;
2252 }
2253
2254 =head2 is_datatype_numeric
2255
2256 Given a datatype from column_info, returns a boolean value indicating if
2257 the current RDBMS considers it a numeric value. This controls how
2258 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2259 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2260 be performed instead of the usual C<eq>.
2261
2262 =cut
2263
2264 sub is_datatype_numeric {
2265   my ($self, $dt) = @_;
2266
2267   return 0 unless $dt;
2268
2269   return $dt =~ /^ (?:
2270     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2271   ) $/ix;
2272 }
2273
2274
2275 =head2 create_ddl_dir
2276
2277 =over 4
2278
2279 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2280
2281 =back
2282
2283 Creates a SQL file based on the Schema, for each of the specified
2284 database engines in C<\@databases> in the given directory.
2285 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2286
2287 Given a previous version number, this will also create a file containing
2288 the ALTER TABLE statements to transform the previous schema into the
2289 current one. Note that these statements may contain C<DROP TABLE> or
2290 C<DROP COLUMN> statements that can potentially destroy data.
2291
2292 The file names are created using the C<ddl_filename> method below, please
2293 override this method in your schema if you would like a different file
2294 name format. For the ALTER file, the same format is used, replacing
2295 $version in the name with "$preversion-$version".
2296
2297 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2298 The most common value for this would be C<< { add_drop_table => 1 } >>
2299 to have the SQL produced include a C<DROP TABLE> statement for each table
2300 created. For quoting purposes supply C<quote_table_names> and
2301 C<quote_field_names>.
2302
2303 If no arguments are passed, then the following default values are assumed:
2304
2305 =over 4
2306
2307 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2308
2309 =item version    - $schema->schema_version
2310
2311 =item directory  - './'
2312
2313 =item preversion - <none>
2314
2315 =back
2316
2317 By default, C<\%sqlt_args> will have
2318
2319  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2320
2321 merged with the hash passed in. To disable any of those features, pass in a
2322 hashref like the following
2323
2324  { ignore_constraint_names => 0, # ... other options }
2325
2326
2327 WARNING: You are strongly advised to check all SQL files created, before applying
2328 them.
2329
2330 =cut
2331
2332 sub create_ddl_dir {
2333   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2334
2335   unless ($dir) {
2336     carp "No directory given, using ./\n";
2337     $dir = './';
2338   } else {
2339       -d $dir
2340         or
2341       make_path ("$dir")  # make_path does not like objects (i.e. Path::Class::Dir)
2342         or
2343       $self->throw_exception(
2344         "Failed to create '$dir': " . ($! || $@ || 'error unknow')
2345       );
2346   }
2347
2348   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2349
2350   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2351   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2352
2353   my $schema_version = $schema->schema_version || '1.x';
2354   $version ||= $schema_version;
2355
2356   $sqltargs = {
2357     add_drop_table => 1,
2358     ignore_constraint_names => 1,
2359     ignore_index_names => 1,
2360     %{$sqltargs || {}}
2361   };
2362
2363   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2364     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2365   }
2366
2367   my $sqlt = SQL::Translator->new( $sqltargs );
2368
2369   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2370   my $sqlt_schema = $sqlt->translate({ data => $schema })
2371     or $self->throw_exception ($sqlt->error);
2372
2373   foreach my $db (@$databases) {
2374     $sqlt->reset();
2375     $sqlt->{schema} = $sqlt_schema;
2376     $sqlt->producer($db);
2377
2378     my $file;
2379     my $filename = $schema->ddl_filename($db, $version, $dir);
2380     if (-e $filename && ($version eq $schema_version )) {
2381       # if we are dumping the current version, overwrite the DDL
2382       carp "Overwriting existing DDL file - $filename";
2383       unlink($filename);
2384     }
2385
2386     my $output = $sqlt->translate;
2387     if(!$output) {
2388       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2389       next;
2390     }
2391     if(!open($file, ">$filename")) {
2392       $self->throw_exception("Can't open $filename for writing ($!)");
2393       next;
2394     }
2395     print $file $output;
2396     close($file);
2397
2398     next unless ($preversion);
2399
2400     require SQL::Translator::Diff;
2401
2402     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2403     if(!-e $prefilename) {
2404       carp("No previous schema file found ($prefilename)");
2405       next;
2406     }
2407
2408     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2409     if(-e $difffile) {
2410       carp("Overwriting existing diff file - $difffile");
2411       unlink($difffile);
2412     }
2413
2414     my $source_schema;
2415     {
2416       my $t = SQL::Translator->new($sqltargs);
2417       $t->debug( 0 );
2418       $t->trace( 0 );
2419
2420       $t->parser( $db )
2421         or $self->throw_exception ($t->error);
2422
2423       my $out = $t->translate( $prefilename )
2424         or $self->throw_exception ($t->error);
2425
2426       $source_schema = $t->schema;
2427
2428       $source_schema->name( $prefilename )
2429         unless ( $source_schema->name );
2430     }
2431
2432     # The "new" style of producers have sane normalization and can support
2433     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2434     # And we have to diff parsed SQL against parsed SQL.
2435     my $dest_schema = $sqlt_schema;
2436
2437     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2438       my $t = SQL::Translator->new($sqltargs);
2439       $t->debug( 0 );
2440       $t->trace( 0 );
2441
2442       $t->parser( $db )
2443         or $self->throw_exception ($t->error);
2444
2445       my $out = $t->translate( $filename )
2446         or $self->throw_exception ($t->error);
2447
2448       $dest_schema = $t->schema;
2449
2450       $dest_schema->name( $filename )
2451         unless $dest_schema->name;
2452     }
2453
2454     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2455                                                   $dest_schema,   $db,
2456                                                   $sqltargs
2457                                                  );
2458     if(!open $file, ">$difffile") {
2459       $self->throw_exception("Can't write to $difffile ($!)");
2460       next;
2461     }
2462     print $file $diff;
2463     close($file);
2464   }
2465 }
2466
2467 =head2 deployment_statements
2468
2469 =over 4
2470
2471 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2472
2473 =back
2474
2475 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2476
2477 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2478 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2479
2480 C<$directory> is used to return statements from files in a previously created
2481 L</create_ddl_dir> directory and is optional. The filenames are constructed
2482 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2483
2484 If no C<$directory> is specified then the statements are constructed on the
2485 fly using L<SQL::Translator> and C<$version> is ignored.
2486
2487 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2488
2489 =cut
2490
2491 sub deployment_statements {
2492   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2493   $type ||= $self->sqlt_type;
2494   $version ||= $schema->schema_version || '1.x';
2495   $dir ||= './';
2496   my $filename = $schema->ddl_filename($type, $version, $dir);
2497   if(-f $filename)
2498   {
2499       my $file;
2500       open($file, "<$filename")
2501         or $self->throw_exception("Can't open $filename ($!)");
2502       my @rows = <$file>;
2503       close($file);
2504       return join('', @rows);
2505   }
2506
2507   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2508     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2509   }
2510
2511   # sources needs to be a parser arg, but for simplicty allow at top level
2512   # coming in
2513   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2514       if exists $sqltargs->{sources};
2515
2516   my $tr = SQL::Translator->new(
2517     producer => "SQL::Translator::Producer::${type}",
2518     %$sqltargs,
2519     parser => 'SQL::Translator::Parser::DBIx::Class',
2520     data => $schema,
2521   );
2522
2523   my @ret;
2524   my $wa = wantarray;
2525   if ($wa) {
2526     @ret = $tr->translate;
2527   }
2528   else {
2529     $ret[0] = $tr->translate;
2530   }
2531
2532   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2533     unless (@ret && defined $ret[0]);
2534
2535   return $wa ? @ret : $ret[0];
2536 }
2537
2538 sub deploy {
2539   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2540   my $deploy = sub {
2541     my $line = shift;
2542     return if($line =~ /^--/);
2543     return if(!$line);
2544     # next if($line =~ /^DROP/m);
2545     return if($line =~ /^BEGIN TRANSACTION/m);
2546     return if($line =~ /^COMMIT/m);
2547     return if $line =~ /^\s+$/; # skip whitespace only
2548     $self->_query_start($line);
2549     try {
2550       # do a dbh_do cycle here, as we need some error checking in
2551       # place (even though we will ignore errors)
2552       $self->dbh_do (sub { $_[1]->do($line) });
2553     } catch {
2554       carp qq{$_ (running "${line}")};
2555     };
2556     $self->_query_end($line);
2557   };
2558   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2559   if (@statements > 1) {
2560     foreach my $statement (@statements) {
2561       $deploy->( $statement );
2562     }
2563   }
2564   elsif (@statements == 1) {
2565     foreach my $line ( split(";\n", $statements[0])) {
2566       $deploy->( $line );
2567     }
2568   }
2569 }
2570
2571 =head2 datetime_parser
2572
2573 Returns the datetime parser class
2574
2575 =cut
2576
2577 sub datetime_parser {
2578   my $self = shift;
2579   return $self->{datetime_parser} ||= do {
2580     $self->build_datetime_parser(@_);
2581   };
2582 }
2583
2584 =head2 datetime_parser_type
2585
2586 Defines (returns) the datetime parser class - currently hardwired to
2587 L<DateTime::Format::MySQL>
2588
2589 =cut
2590
2591 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2592
2593 =head2 build_datetime_parser
2594
2595 See L</datetime_parser>
2596
2597 =cut
2598
2599 sub build_datetime_parser {
2600   my $self = shift;
2601   my $type = $self->datetime_parser_type(@_);
2602   $self->ensure_class_loaded ($type);
2603   return $type;
2604 }
2605
2606
2607 =head2 is_replicating
2608
2609 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2610 replicate from a master database.  Default is undef, which is the result
2611 returned by databases that don't support replication.
2612
2613 =cut
2614
2615 sub is_replicating {
2616     return;
2617
2618 }
2619
2620 =head2 lag_behind_master
2621
2622 Returns a number that represents a certain amount of lag behind a master db
2623 when a given storage is replicating.  The number is database dependent, but
2624 starts at zero and increases with the amount of lag. Default in undef
2625
2626 =cut
2627
2628 sub lag_behind_master {
2629     return;
2630 }
2631
2632 =head2 relname_to_table_alias
2633
2634 =over 4
2635
2636 =item Arguments: $relname, $join_count
2637
2638 =back
2639
2640 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2641 queries.
2642
2643 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2644 way these aliases are named.
2645
2646 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2647 otherwise C<"$relname">.
2648
2649 =cut
2650
2651 sub relname_to_table_alias {
2652   my ($self, $relname, $join_count) = @_;
2653
2654   my $alias = ($join_count && $join_count > 1 ?
2655     join('_', $relname, $join_count) : $relname);
2656
2657   return $alias;
2658 }
2659
2660 1;
2661
2662 =head1 USAGE NOTES
2663
2664 =head2 DBIx::Class and AutoCommit
2665
2666 DBIx::Class can do some wonderful magic with handling exceptions,
2667 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2668 (the default) combined with C<txn_do> for transaction support.
2669
2670 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2671 in an assumed transaction between commits, and you're telling us you'd
2672 like to manage that manually.  A lot of the magic protections offered by
2673 this module will go away.  We can't protect you from exceptions due to database
2674 disconnects because we don't know anything about how to restart your
2675 transactions.  You're on your own for handling all sorts of exceptional
2676 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2677 be with raw DBI.
2678
2679
2680 =head1 AUTHORS
2681
2682 Matt S. Trout <mst@shadowcatsystems.co.uk>
2683
2684 Andy Grundman <andy@hybridized.org>
2685
2686 =head1 LICENSE
2687
2688 You may distribute this code under the same terms as Perl itself.
2689
2690 =cut