lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  18        transaction_depth unsafe/
  19 );
  20
  21 BEGIN {
  22
  23 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  24
  25 use base qw/SQL::Abstract::Limit/;
  26
  27 # This prevents the caching of $dbh in S::A::L, I believe
  28 sub new {
  29   my $self = shift->SUPER::new(@_);
  30
  31   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  32   #   it with what it resolves to:
  33   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  34     if ref $self->{limit_dialect};
  35
  36   $self;
  37 }
  38
  39 sub _RowNumberOver {
  40   my ($self, $sql, $order, $rows, $offset ) = @_;
  41
  42   $offset += 1;
  43   my $last = $rows + $offset;
  44   my ( $order_by ) = $self->_order_by( $order );
  45
  46   $sql = <<"";
  47 SELECT * FROM
  48 (
  49    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  50       $sql
  51       $order_by
  52    ) Q1
  53 ) Q2
  54 WHERE ROW_NUM BETWEEN $offset AND $last
  55
  56   return $sql;
  57 }
  58
  59
  60 # While we're at it, this should make LIMIT queries more efficient,
  61 #  without digging into things too deeply
  62 use Scalar::Util 'blessed';
  63 sub _find_syntax {
  64   my ($self, $syntax) = @_;
  65   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  66   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  67     return 'RowNumberOver';
  68   }
  69
  70   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  71 }
  72
  73 sub select {
  74   my ($self, $table, $fields, $where, $order, @rest) = @_;
  75   $table = $self->_quote($table) unless ref($table);
  76   local $self->{rownum_hack_count} = 1
  77     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  78   @rest = (-1) unless defined $rest[0];
  79   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  80     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  81   local $self->{having_bind} = [];
  82   my ($sql, @ret) = $self->SUPER::select(
  83     $table, $self->_recurse_fields($fields), $where, $order, @rest
  84   );
  85   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  86 }
  87
  88 sub insert {
  89   my $self = shift;
  90   my $table = shift;
  91   $table = $self->_quote($table) unless ref($table);
  92   $self->SUPER::insert($table, @_);
  93 }
  94
  95 sub update {
  96   my $self = shift;
  97   my $table = shift;
  98   $table = $self->_quote($table) unless ref($table);
  99   $self->SUPER::update($table, @_);
 100 }
 101
 102 sub delete {
 103   my $self = shift;
 104   my $table = shift;
 105   $table = $self->_quote($table) unless ref($table);
 106   $self->SUPER::delete($table, @_);
 107 }
 108
 109 sub _emulate_limit {
 110   my $self = shift;
 111   if ($_[3] == -1) {
 112     return $_[1].$self->_order_by($_[2]);
 113   } else {
 114     return $self->SUPER::_emulate_limit(@_);
 115   }
 116 }
 117
 118 sub _recurse_fields {
 119   my ($self, $fields) = @_;
 120   my $ref = ref $fields;
 121   return $self->_quote($fields) unless $ref;
 122   return $$fields if $ref eq 'SCALAR';
 123
 124   if ($ref eq 'ARRAY') {
 125     return join(', ', map {
 126       $self->_recurse_fields($_)
 127       .(exists $self->{rownum_hack_count}
 128          ? ' AS col'.$self->{rownum_hack_count}++
 129          : '')
 130      } @$fields);
 131   } elsif ($ref eq 'HASH') {
 132     foreach my $func (keys %$fields) {
 133       return $self->_sqlcase($func)
 134         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 135     }
 136   }
 137 }
 138
 139 sub _order_by {
 140   my $self = shift;
 141   my $ret = '';
 142   my @extra;
 143   if (ref $_[0] eq 'HASH') {
 144     if (defined $_[0]->{group_by}) {
 145       $ret = $self->_sqlcase(' group by ')
 146                .$self->_recurse_fields($_[0]->{group_by});
 147     }
 148     if (defined $_[0]->{having}) {
 149       my $frag;
 150       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 151       push(@{$self->{having_bind}}, @extra);
 152       $ret .= $self->_sqlcase(' having ').$frag;
 153     }
 154     if (defined $_[0]->{order_by}) {
 155       $ret .= $self->_order_by($_[0]->{order_by});
 156     }
 157   } elsif (ref $_[0] eq 'SCALAR') {
 158     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 159   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 160     my @order = @{+shift};
 161     $ret = $self->_sqlcase(' order by ')
 162           .join(', ', map {
 163                         my $r = $self->_order_by($_, @_);
 164                         $r =~ s/^ ?ORDER BY //i;
 165                         $r;
 166                       } @order);
 167   } else {
 168     $ret = $self->SUPER::_order_by(@_);
 169   }
 170   return $ret;
 171 }
 172
 173 sub _order_directions {
 174   my ($self, $order) = @_;
 175   $order = $order->{order_by} if ref $order eq 'HASH';
 176   return $self->SUPER::_order_directions($order);
 177 }
 178
 179 sub _table {
 180   my ($self, $from) = @_;
 181   if (ref $from eq 'ARRAY') {
 182     return $self->_recurse_from(@$from);
 183   } elsif (ref $from eq 'HASH') {
 184     return $self->_make_as($from);
 185   } else {
 186     return $from; # would love to quote here but _table ends up getting called
 187                   # twice during an ->select without a limit clause due to
 188                   # the way S::A::Limit->select works. should maybe consider
 189                   # bypassing this and doing S::A::select($self, ...) in
 190                   # our select method above. meantime, quoting shims have
 191                   # been added to select/insert/update/delete here
 192   }
 193 }
 194
 195 sub _recurse_from {
 196   my ($self, $from, @join) = @_;
 197   my @sqlf;
 198   push(@sqlf, $self->_make_as($from));
 199   foreach my $j (@join) {
 200     my ($to, $on) = @$j;
 201
 202     # check whether a join type exists
 203     my $join_clause = '';
 204     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 205     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 206       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 207     } else {
 208       $join_clause = ' JOIN ';
 209     }
 210     push(@sqlf, $join_clause);
 211
 212     if (ref $to eq 'ARRAY') {
 213       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 214     } else {
 215       push(@sqlf, $self->_make_as($to));
 216     }
 217     push(@sqlf, ' ON ', $self->_join_condition($on));
 218   }
 219   return join('', @sqlf);
 220 }
 221
 222 sub _make_as {
 223   my ($self, $from) = @_;
 224   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 225                      reverse each %{$self->_skip_options($from)});
 226 }
 227
 228 sub _skip_options {
 229   my ($self, $hash) = @_;
 230   my $clean_hash = {};
 231   $clean_hash->{$_} = $hash->{$_}
 232     for grep {!/^-/} keys %$hash;
 233   return $clean_hash;
 234 }
 235
 236 sub _join_condition {
 237   my ($self, $cond) = @_;
 238   if (ref $cond eq 'HASH') {
 239     my %j;
 240     for (keys %$cond) {
 241       my $v = $cond->{$_};
 242       if (ref $v) {
 243         # XXX no throw_exception() in this package and croak() fails with strange results
 244         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 245             if ref($v) ne 'SCALAR';
 246         $j{$_} = $v;
 247       }
 248       else {
 249         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 250       }
 251     };
 252     return scalar($self->_recurse_where(\%j));
 253   } elsif (ref $cond eq 'ARRAY') {
 254     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 255   } else {
 256     die "Can't handle this yet!";
 257   }
 258 }
 259
 260 sub _quote {
 261   my ($self, $label) = @_;
 262   return '' unless defined $label;
 263   return "*" if $label eq '*';
 264   return $label unless $self->{quote_char};
 265   if(ref $self->{quote_char} eq "ARRAY"){
 266     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 267       if !defined $self->{name_sep};
 268     my $sep = $self->{name_sep};
 269     return join($self->{name_sep},
 270         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 271        split(/\Q$sep\E/,$label));
 272   }
 273   return $self->SUPER::_quote($label);
 274 }
 275
 276 sub limit_dialect {
 277     my $self = shift;
 278     $self->{limit_dialect} = shift if @_;
 279     return $self->{limit_dialect};
 280 }
 281
 282 sub quote_char {
 283     my $self = shift;
 284     $self->{quote_char} = shift if @_;
 285     return $self->{quote_char};
 286 }
 287
 288 sub name_sep {
 289     my $self = shift;
 290     $self->{name_sep} = shift if @_;
 291     return $self->{name_sep};
 292 }
 293
 294 } # End of BEGIN block
 295
 296 =head1 NAME
 297
 298 DBIx::Class::Storage::DBI - DBI storage handler
 299
 300 =head1 SYNOPSIS
 301
 302 =head1 DESCRIPTION
 303
 304 This class represents the connection to an RDBMS via L<DBI>.  See
 305 L<DBIx::Class::Storage> for general information.  This pod only
 306 documents DBI-specific methods and behaviors.
 307
 308 =head1 METHODS
 309
 310 =cut
 311
 312 sub new {
 313   my $new = shift->next::method(@_);
 314
 315   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 This can be set to an arrayref of literal sql statements, which will
 351 be executed immediately after making the connection to the database
 352 every time we [re-]connect.
 353
 354 =item disable_sth_caching
 355
 356 If set to a true value, this option will disable the caching of
 357 statement handles via L<DBI/prepare_cached>.
 358
 359 =item limit_dialect
 360
 361 Sets the limit dialect. This is useful for JDBC-bridge among others
 362 where the remote SQL-dialect cannot be determined by the name of the
 363 driver alone.
 364
 365 =item quote_char
 366
 367 Specifies what characters to use to quote table and column names. If
 368 you use this you will want to specify L<name_sep> as well.
 369
 370 quote_char expects either a single character, in which case is it is placed
 371 on either side of the table/column, or an arrayref of length 2 in which case the
 372 table/column name is placed between the elements.
 373
 374 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 375 use C<quote_char =E<gt> [qw/[ ]/]>.
 376
 377 =item name_sep
 378
 379 This only needs to be used in conjunction with L<quote_char>, and is used to
 380 specify the charecter that seperates elements (schemas, tables, columns) from
 381 each other. In most cases this is simply a C<.>.
 382
 383 =item unsafe
 384
 385 This Storage driver normally installs its own C<HandleError>, sets
 386 C<RaiseError> on, and sets C<PrintError> off on all database handles,
 387 including those supplied by a coderef.  It does this so that it can
 388 have consistent and useful error behavior.
 389
 390 If you set this option to a true value, Storage will not do its usual
 391 modifications to the database handle's C<RaiseError>, C<PrintError>, and
 392 C<HandleError> attributes, and instead relies on the settings in your
 393 connect_info DBI options (or the values you set in your connection
 394 coderef, in the case that you are connecting via coderef).
 395
 396 Note that your custom settings can cause Storage to malfunction,
 397 especially if you set a C<HandleError> handler that suppresses exceptions
 398 and/or disable C<RaiseError>.
 399
 400 =back
 401
 402 These options can be mixed in with your other L<DBI> connection attributes,
 403 or placed in a seperate hashref after all other normal L<DBI> connection
 404 arguments.
 405
 406 Every time C<connect_info> is invoked, any previous settings for
 407 these options will be cleared before setting the new ones, regardless of
 408 whether any options are specified in the new C<connect_info>.
 409
 410 Another Important Note:
 411
 412 DBIC can do some wonderful magic with handling exceptions,
 413 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 414 combined with C<txn_do> for transaction support.
 415
 416 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 417 in an assumed transaction between commits, and you're telling us you'd
 418 like to manage that manually.  A lot of DBIC's magic protections
 419 go away.  We can't protect you from exceptions due to database
 420 disconnects because we don't know anything about how to restart your
 421 transactions.  You're on your own for handling all sorts of exceptional
 422 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 423 be with raw DBI.
 424
 425 Examples:
 426
 427   # Simple SQLite connection
 428   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 429
 430   # Connect via subref
 431   ->connect_info([ sub { DBI->connect(...) } ]);
 432
 433   # A bit more complicated
 434   ->connect_info(
 435     [
 436       'dbi:Pg:dbname=foo',
 437       'postgres',
 438       'my_pg_password',
 439       { AutoCommit => 1 },
 440       { quote_char => q{"}, name_sep => q{.} },
 441     ]
 442   );
 443
 444   # Equivalent to the previous example
 445   ->connect_info(
 446     [
 447       'dbi:Pg:dbname=foo',
 448       'postgres',
 449       'my_pg_password',
 450       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 451     ]
 452   );
 453
 454   # Subref + DBIC-specific connection options
 455   ->connect_info(
 456     [
 457       sub { DBI->connect(...) },
 458       {
 459           quote_char => q{`},
 460           name_sep => q{@},
 461           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 462           disable_sth_caching => 1,
 463       },
 464     ]
 465   );
 466
 467 =cut
 468
 469 sub connect_info {
 470   my ($self, $info_arg) = @_;
 471
 472   return $self->_connect_info if !$info_arg;
 473
 474   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 475   #  the new set of options
 476   $self->_sql_maker(undef);
 477   $self->_sql_maker_opts({});
 478   $self->_connect_info([@$info_arg]); # copy for _connect_info
 479
 480   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 481
 482   my $last_info = $dbi_info->[-1];
 483   if(ref $last_info eq 'HASH') {
 484     for my $storage_opt (qw/on_connect_do disable_sth_caching unsafe/) {
 485       if(my $value = delete $last_info->{$storage_opt}) {
 486         $self->$storage_opt($value);
 487       }
 488     }
 489     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 490       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 491         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 492       }
 493     }
 494
 495     # Get rid of any trailing empty hashref
 496     pop(@$dbi_info) if !keys %$last_info;
 497   }
 498   $self->_dbi_connect_info($dbi_info);
 499
 500   $self->_connect_info;
 501 }
 502
 503 =head2 on_connect_do
 504
 505 This method is deprecated in favor of setting via L</connect_info>.
 506
 507 =head2 dbh_do
 508
 509 Arguments: $subref, @extra_coderef_args?
 510
 511 Execute the given subref using the new exception-based connection management.
 512
 513 The first two arguments will be the storage object that C<dbh_do> was called
 514 on and a database handle to use.  Any additional arguments will be passed
 515 verbatim to the called subref as arguments 2 and onwards.
 516
 517 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 518 exception handling and reconnection (or failover in future subclasses).
 519
 520 Your subref should have no side-effects outside of the database, as
 521 there is the potential for your subref to be partially double-executed
 522 if the database connection was stale/dysfunctional.
 523
 524 Example:
 525
 526   my @stuff = $schema->storage->dbh_do(
 527     sub {
 528       my ($storage, $dbh, @cols) = @_;
 529       my $cols = join(q{, }, @cols);
 530       $dbh->selectrow_array("SELECT $cols FROM foo");
 531     },
 532     @column_list
 533   );
 534
 535 =cut
 536
 537 sub dbh_do {
 538   my $self = shift;
 539   my $coderef = shift;
 540
 541   ref $coderef eq 'CODE' or $self->throw_exception
 542     ('$coderef must be a CODE reference');
 543
 544   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 545       || $self->{transaction_depth};
 546
 547   local $self->{_in_dbh_do} = 1;
 548
 549   my @result;
 550   my $want_array = wantarray;
 551
 552   eval {
 553     $self->_verify_pid if $self->_dbh;
 554     $self->_populate_dbh if !$self->_dbh;
 555     if($want_array) {
 556         @result = $coderef->($self, $self->_dbh, @_);
 557     }
 558     elsif(defined $want_array) {
 559         $result[0] = $coderef->($self, $self->_dbh, @_);
 560     }
 561     else {
 562         $coderef->($self, $self->_dbh, @_);
 563     }
 564   };
 565
 566   my $exception = $@;
 567   if(!$exception) { return $want_array ? @result : $result[0] }
 568
 569   $self->throw_exception($exception) if $self->connected;
 570
 571   # We were not connected - reconnect and retry, but let any
 572   #  exception fall right through this time
 573   $self->_populate_dbh;
 574   $coderef->($self, $self->_dbh, @_);
 575 }
 576
 577 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 578 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 579 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 580 sub txn_do {
 581   my $self = shift;
 582   my $coderef = shift;
 583
 584   ref $coderef eq 'CODE' or $self->throw_exception
 585     ('$coderef must be a CODE reference');
 586
 587   local $self->{_in_dbh_do} = 1;
 588
 589   my @result;
 590   my $want_array = wantarray;
 591
 592   my $tried = 0;
 593   while(1) {
 594     eval {
 595       $self->_verify_pid if $self->_dbh;
 596       $self->_populate_dbh if !$self->_dbh;
 597
 598       $self->txn_begin;
 599       if($want_array) {
 600           @result = $coderef->(@_);
 601       }
 602       elsif(defined $want_array) {
 603           $result[0] = $coderef->(@_);
 604       }
 605       else {
 606           $coderef->(@_);
 607       }
 608       $self->txn_commit;
 609     };
 610
 611     my $exception = $@;
 612     if(!$exception) { return $want_array ? @result : $result[0] }
 613
 614     if($tried++ > 0 || $self->connected) {
 615       eval { $self->txn_rollback };
 616       my $rollback_exception = $@;
 617       if($rollback_exception) {
 618         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 619         $self->throw_exception($exception)  # propagate nested rollback
 620           if $rollback_exception =~ /$exception_class/;
 621
 622         $self->throw_exception(
 623           "Transaction aborted: ${exception}. "
 624           . "Rollback failed: ${rollback_exception}"
 625         );
 626       }
 627       $self->throw_exception($exception)
 628     }
 629
 630     # We were not connected, and was first try - reconnect and retry
 631     # via the while loop
 632     $self->_populate_dbh;
 633   }
 634 }
 635
 636 =head2 disconnect
 637
 638 Our C<disconnect> method also performs a rollback first if the
 639 database is not in C<AutoCommit> mode.
 640
 641 =cut
 642
 643 sub disconnect {
 644   my ($self) = @_;
 645
 646   if( $self->connected ) {
 647     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 648     $self->_dbh->disconnect;
 649     $self->_dbh(undef);
 650     $self->{_dbh_gen}++;
 651   }
 652 }
 653
 654 sub connected {
 655   my ($self) = @_;
 656
 657   if(my $dbh = $self->_dbh) {
 658       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 659           $self->_dbh(undef);
 660           $self->{_dbh_gen}++;
 661           return;
 662       }
 663       else {
 664           $self->_verify_pid;
 665       }
 666       return ($dbh->FETCH('Active') && $dbh->ping);
 667   }
 668
 669   return 0;
 670 }
 671
 672 # handle pid changes correctly
 673 #  NOTE: assumes $self->_dbh is a valid $dbh
 674 sub _verify_pid {
 675   my ($self) = @_;
 676
 677   return if $self->_conn_pid == $$;
 678
 679   $self->_dbh->{InactiveDestroy} = 1;
 680   $self->_dbh(undef);
 681   $self->{_dbh_gen}++;
 682
 683   return;
 684 }
 685
 686 sub ensure_connected {
 687   my ($self) = @_;
 688
 689   unless ($self->connected) {
 690     $self->_populate_dbh;
 691   }
 692 }
 693
 694 =head2 dbh
 695
 696 Returns the dbh - a data base handle of class L<DBI>.
 697
 698 =cut
 699
 700 sub dbh {
 701   my ($self) = @_;
 702
 703   $self->ensure_connected;
 704   return $self->_dbh;
 705 }
 706
 707 sub _sql_maker_args {
 708     my ($self) = @_;
 709
 710     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 711 }
 712
 713 sub sql_maker {
 714   my ($self) = @_;
 715   unless ($self->_sql_maker) {
 716     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 717   }
 718   return $self->_sql_maker;
 719 }
 720
 721 sub _populate_dbh {
 722   my ($self) = @_;
 723   my @info = @{$self->_dbi_connect_info || []};
 724   $self->_dbh($self->_connect(@info));
 725
 726   # Always set the transaction depth on connect, since
 727   #  there is no transaction in progress by definition
 728   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 729
 730   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 731     my $driver = $self->_dbh->{Driver}->{Name};
 732     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 733       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 734       $self->_rebless() if $self->can('_rebless');
 735     }
 736   }
 737
 738   # if on-connect sql statements are given execute them
 739   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 740     $self->debugobj->query_start($sql_statement) if $self->debug();
 741     $self->_dbh->do($sql_statement);
 742     $self->debugobj->query_end($sql_statement) if $self->debug();
 743   }
 744
 745   $self->_conn_pid($$);
 746   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 747 }
 748
 749 sub _connect {
 750   my ($self, @info) = @_;
 751
 752   $self->throw_exception("You failed to provide any connection info")
 753     if !@info;
 754
 755   my ($old_connect_via, $dbh);
 756
 757   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 758     $old_connect_via = $DBI::connect_via;
 759     $DBI::connect_via = 'connect';
 760   }
 761
 762   eval {
 763     if(ref $info[0] eq 'CODE') {
 764        $dbh = &{$info[0]}
 765     }
 766     else {
 767        $dbh = DBI->connect(@info);
 768     }
 769
 770     if(!$self->unsafe) {
 771       my $weak_self = $self;
 772       weaken($weak_self);
 773       $dbh->{HandleError} = sub {
 774           $weak_self->throw_exception("DBI Exception: $_[0]")
 775       };
 776       $dbh->{RaiseError} = 1;
 777       $dbh->{PrintError} = 0;
 778     }
 779   };
 780
 781   $DBI::connect_via = $old_connect_via if $old_connect_via;
 782
 783   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 784     if !$dbh || $@;
 785
 786   $dbh;
 787 }
 788
 789
 790 sub txn_begin {
 791   my $self = shift;
 792   if($self->{transaction_depth}++ == 0) {
 793     $self->debugobj->txn_begin()
 794       if $self->debug;
 795     # this isn't ->_dbh-> because
 796     #  we should reconnect on begin_work
 797     #  for AutoCommit users
 798     $self->dbh->begin_work;
 799   }
 800 }
 801
 802 sub txn_commit {
 803   my $self = shift;
 804   if ($self->{transaction_depth} == 1) {
 805     my $dbh = $self->_dbh;
 806     $self->debugobj->txn_commit()
 807       if ($self->debug);
 808     $dbh->commit;
 809     $self->{transaction_depth} = 0
 810       if $dbh->{AutoCommit};
 811   }
 812   elsif($self->{transaction_depth} > 1) {
 813     $self->{transaction_depth}--
 814   }
 815 }
 816
 817 sub txn_rollback {
 818   my $self = shift;
 819   my $dbh = $self->_dbh;
 820   my $autocommit;
 821   eval {
 822     $autocommit = $dbh->{AutoCommit};
 823     if ($self->{transaction_depth} == 1) {
 824       $self->debugobj->txn_rollback()
 825         if ($self->debug);
 826       $dbh->rollback;
 827       $self->{transaction_depth} = 0
 828         if $autocommit;
 829     }
 830     elsif($self->{transaction_depth} > 1) {
 831       $self->{transaction_depth}--;
 832     }
 833     else {
 834       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 835     }
 836   };
 837   if ($@) {
 838     my $error = $@;
 839     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 840     $error =~ /$exception_class/ and $self->throw_exception($error);
 841     # ensure that a failed rollback resets the transaction depth
 842     $self->{transaction_depth} = $autocommit ? 0 : 1;
 843     $self->throw_exception($error);
 844   }
 845 }
 846
 847 # This used to be the top-half of _execute.  It was split out to make it
 848 #  easier to override in NoBindVars without duping the rest.  It takes up
 849 #  all of _execute's args, and emits $sql, @bind.
 850 sub _prep_for_execute {
 851   my ($self, $op, $extra_bind, $ident, $args) = @_;
 852
 853   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 854   unshift(@bind,
 855     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 856       if $extra_bind;
 857
 858   return ($sql, \@bind);
 859 }
 860
 861 sub _dbh_execute {
 862   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 863
 864   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 865     $ident = $ident->from();
 866   }
 867
 868   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 869
 870   if ($self->debug) {
 871       my @debug_bind =
 872         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 873       $self->debugobj->query_start($sql, @debug_bind);
 874   }
 875
 876   my $sth = $self->sth($sql,$op);
 877
 878   my $placeholder_index = 1;
 879
 880   foreach my $bound (@$bind) {
 881     my $attributes = {};
 882     my($column_name, @data) = @$bound;
 883
 884     if ($bind_attributes) {
 885       $attributes = $bind_attributes->{$column_name}
 886       if defined $bind_attributes->{$column_name};
 887     }
 888
 889     foreach my $data (@data) {
 890       $data = ref $data ? ''.$data : $data; # stringify args
 891
 892       $sth->bind_param($placeholder_index, $data, $attributes);
 893       $placeholder_index++;
 894     }
 895   }
 896
 897   # Can this fail without throwing an exception anyways???
 898   my $rv = $sth->execute();
 899   $self->throw_exception($sth->errstr) if !$rv;
 900
 901   if ($self->debug) {
 902      my @debug_bind =
 903        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 904      $self->debugobj->query_end($sql, @debug_bind);
 905   }
 906
 907   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 908 }
 909
 910 sub _execute {
 911     my $self = shift;
 912     $self->dbh_do($self->can('_dbh_execute'), @_)
 913 }
 914
 915 sub insert {
 916   my ($self, $source, $to_insert) = @_;
 917
 918   my $ident = $source->from;
 919   my $bind_attributes = $self->source_bind_attributes($source);
 920
 921   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 922
 923   return $to_insert;
 924 }
 925
 926 ## Still not quite perfect, and EXPERIMENTAL
 927 ## Currently it is assumed that all values passed will be "normal", i.e. not
 928 ## scalar refs, or at least, all the same type as the first set, the statement is
 929 ## only prepped once.
 930 sub insert_bulk {
 931   my ($self, $source, $cols, $data) = @_;
 932   my %colvalues;
 933   my $table = $source->from;
 934   @colvalues{@$cols} = (0..$#$cols);
 935   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 936
 937   if ($self->debug) {
 938       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 939       $self->debugobj->query_start($sql, @debug_bind);
 940   }
 941   my $sth = $self->sth($sql);
 942
 943 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 944
 945   ## This must be an arrayref, else nothing works!
 946
 947   my $tuple_status = [];
 948
 949   ##use Data::Dumper;
 950   ##print STDERR Dumper( $data, $sql, [@bind] );
 951
 952   my $time = time();
 953
 954   ## Get the bind_attributes, if any exist
 955   my $bind_attributes = $self->source_bind_attributes($source);
 956
 957   ## Bind the values and execute
 958   my $placeholder_index = 1;
 959
 960   foreach my $bound (@bind) {
 961
 962     my $attributes = {};
 963     my ($column_name, $data_index) = @$bound;
 964
 965     if( $bind_attributes ) {
 966       $attributes = $bind_attributes->{$column_name}
 967       if defined $bind_attributes->{$column_name};
 968     }
 969
 970     my @data = map { $_->[$data_index] } @$data;
 971
 972     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 973     $placeholder_index++;
 974   }
 975   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
 976   $self->throw_exception($sth->errstr) if !$rv;
 977
 978   if ($self->debug) {
 979       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 980       $self->debugobj->query_end($sql, @debug_bind);
 981   }
 982   return (wantarray ? ($rv, $sth, @bind) : $rv);
 983 }
 984
 985 sub update {
 986   my $self = shift @_;
 987   my $source = shift @_;
 988   my $bind_attributes = $self->source_bind_attributes($source);
 989
 990   return $self->_execute('update' => [], $source, $bind_attributes, @_);
 991 }
 992
 993
 994 sub delete {
 995   my $self = shift @_;
 996   my $source = shift @_;
 997
 998   my $bind_attrs = {}; ## If ever it's needed...
 999
1000   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1001 }
1002
1003 sub _select {
1004   my ($self, $ident, $select, $condition, $attrs) = @_;
1005   my $order = $attrs->{order_by};
1006   if (ref $condition eq 'SCALAR') {
1007     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1008   }
1009   if (exists $attrs->{group_by} || $attrs->{having}) {
1010     $order = {
1011       group_by => $attrs->{group_by},
1012       having => $attrs->{having},
1013       ($order ? (order_by => $order) : ())
1014     };
1015   }
1016   my $bind_attrs = {}; ## Future support
1017   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1018   if ($attrs->{software_limit} ||
1019       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1020         $attrs->{software_limit} = 1;
1021   } else {
1022     $self->throw_exception("rows attribute must be positive if present")
1023       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1024     push @args, $attrs->{rows}, $attrs->{offset};
1025   }
1026   return $self->_execute(@args);
1027 }
1028
1029 sub source_bind_attributes {
1030   my ($self, $source) = @_;
1031
1032   my $bind_attributes;
1033   foreach my $column ($source->columns) {
1034
1035     my $data_type = $source->column_info($column)->{data_type} || '';
1036     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1037      if $data_type;
1038   }
1039
1040   return $bind_attributes;
1041 }
1042
1043 =head2 select
1044
1045 =over 4
1046
1047 =item Arguments: $ident, $select, $condition, $attrs
1048
1049 =back
1050
1051 Handle a SQL select statement.
1052
1053 =cut
1054
1055 sub select {
1056   my $self = shift;
1057   my ($ident, $select, $condition, $attrs) = @_;
1058   return $self->cursor->new($self, \@_, $attrs);
1059 }
1060
1061 sub select_single {
1062   my $self = shift;
1063   my ($rv, $sth, @bind) = $self->_select(@_);
1064   my @row = $sth->fetchrow_array;
1065   # Need to call finish() to work round broken DBDs
1066   $sth->finish();
1067   return @row;
1068 }
1069
1070 =head2 sth
1071
1072 =over 4
1073
1074 =item Arguments: $sql
1075
1076 =back
1077
1078 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1079
1080 =cut
1081
1082 sub _dbh_sth {
1083   my ($self, $dbh, $sql) = @_;
1084
1085   # 3 is the if_active parameter which avoids active sth re-use
1086   my $sth = $self->disable_sth_caching
1087     ? $dbh->prepare($sql)
1088     : $dbh->prepare_cached($sql, {}, 3);
1089
1090   # XXX You would think RaiseError would make this impossible,
1091   #  but apparently that's not true :(
1092   $self->throw_exception($dbh->errstr) if !$sth;
1093
1094   $sth;
1095 }
1096
1097 sub sth {
1098   my ($self, $sql) = @_;
1099   $self->dbh_do($self->can('_dbh_sth'), $sql);
1100 }
1101
1102 sub _dbh_columns_info_for {
1103   my ($self, $dbh, $table) = @_;
1104
1105   if ($dbh->can('column_info')) {
1106     my %result;
1107     eval {
1108       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1109       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1110       $sth->execute();
1111       while ( my $info = $sth->fetchrow_hashref() ){
1112         my %column_info;
1113         $column_info{data_type}   = $info->{TYPE_NAME};
1114         $column_info{size}      = $info->{COLUMN_SIZE};
1115         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1116         $column_info{default_value} = $info->{COLUMN_DEF};
1117         my $col_name = $info->{COLUMN_NAME};
1118         $col_name =~ s/^\"(.*)\"$/$1/;
1119
1120         $result{$col_name} = \%column_info;
1121       }
1122     };
1123     return \%result if !$@ && scalar keys %result;
1124   }
1125
1126   my %result;
1127   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1128   $sth->execute;
1129   my @columns = @{$sth->{NAME_lc}};
1130   for my $i ( 0 .. $#columns ){
1131     my %column_info;
1132     $column_info{data_type} = $sth->{TYPE}->[$i];
1133     $column_info{size} = $sth->{PRECISION}->[$i];
1134     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1135
1136     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1137       $column_info{data_type} = $1;
1138       $column_info{size}    = $2;
1139     }
1140
1141     $result{$columns[$i]} = \%column_info;
1142   }
1143   $sth->finish;
1144
1145   foreach my $col (keys %result) {
1146     my $colinfo = $result{$col};
1147     my $type_num = $colinfo->{data_type};
1148     my $type_name;
1149     if(defined $type_num && $dbh->can('type_info')) {
1150       my $type_info = $dbh->type_info($type_num);
1151       $type_name = $type_info->{TYPE_NAME} if $type_info;
1152       $colinfo->{data_type} = $type_name if $type_name;
1153     }
1154   }
1155
1156   return \%result;
1157 }
1158
1159 sub columns_info_for {
1160   my ($self, $table) = @_;
1161   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1162 }
1163
1164 =head2 last_insert_id
1165
1166 Return the row id of the last insert.
1167
1168 =cut
1169
1170 sub _dbh_last_insert_id {
1171     my ($self, $dbh, $source, $col) = @_;
1172     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1173     $dbh->func('last_insert_rowid');
1174 }
1175
1176 sub last_insert_id {
1177   my $self = shift;
1178   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1179 }
1180
1181 =head2 sqlt_type
1182
1183 Returns the database driver name.
1184
1185 =cut
1186
1187 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1188
1189 =head2 bind_attribute_by_data_type
1190
1191 Given a datatype from column info, returns a database specific bind attribute for
1192 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1193 just handle it.
1194
1195 Generally only needed for special case column types, like bytea in postgres.
1196
1197 =cut
1198
1199 sub bind_attribute_by_data_type {
1200     return;
1201 }
1202
1203 =head2 create_ddl_dir (EXPERIMENTAL)
1204
1205 =over 4
1206
1207 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1208
1209 =back
1210
1211 Creates a SQL file based on the Schema, for each of the specified
1212 database types, in the given directory.
1213
1214 Note that this feature is currently EXPERIMENTAL and may not work correctly
1215 across all databases, or fully handle complex relationships.
1216
1217 =cut
1218
1219 sub create_ddl_dir
1220 {
1221   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1222
1223   if(!$dir || !-d $dir)
1224   {
1225     warn "No directory given, using ./\n";
1226     $dir = "./";
1227   }
1228   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1229   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1230   $version ||= $schema->VERSION || '1.x';
1231   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1232
1233   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1234       . $self->_check_sqlt_message . q{'})
1235           if !$self->_check_sqlt_version;
1236
1237   my $sqlt = SQL::Translator->new({
1238 #      debug => 1,
1239       add_drop_table => 1,
1240   });
1241   foreach my $db (@$databases)
1242   {
1243     $sqlt->reset();
1244     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1245 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1246     $sqlt = $self->configure_sqlt($sqlt, $db);
1247     $sqlt->data($schema);
1248     $sqlt->producer($db);
1249
1250     my $file;
1251     my $filename = $schema->ddl_filename($db, $dir, $version);
1252     if(-e $filename)
1253     {
1254       warn("$filename already exists, skipping $db");
1255       next;
1256     }
1257
1258     my $output = $sqlt->translate;
1259     if(!$output)
1260     {
1261       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1262       next;
1263     }
1264     if(!open($file, ">$filename"))
1265     {
1266         $self->throw_exception("Can't open $filename for writing ($!)");
1267         next;
1268     }
1269     print $file $output;
1270     close($file);
1271
1272     if($preversion)
1273     {
1274       require SQL::Translator::Diff;
1275
1276       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1277 #      print "Previous version $prefilename\n";
1278       if(!-e $prefilename)
1279       {
1280         warn("No previous schema file found ($prefilename)");
1281         next;
1282       }
1283       #### We need to reparse the SQLite file we just wrote, so that
1284       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1285       ##   FIXME: rip Diff to pieces!
1286 #      my $target_schema = $sqlt->schema;
1287 #      unless ( $target_schema->name ) {
1288 #        $target_schema->name( $filename );
1289 #      }
1290       my @input;
1291       push @input, {file => $prefilename, parser => $db};
1292       push @input, {file => $filename, parser => $db};
1293       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1294         my $file   = $_->{'file'};
1295         my $parser = $_->{'parser'};
1296
1297         my $t = SQL::Translator->new;
1298         $t->debug( 0 );
1299         $t->trace( 0 );
1300         $t->parser( $parser )            or die $t->error;
1301         my $out = $t->translate( $file ) or die $t->error;
1302         my $schema = $t->schema;
1303         unless ( $schema->name ) {
1304           $schema->name( $file );
1305         }
1306         ($schema, $parser);
1307       } @input;
1308
1309       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1310                                                     $target_schema, $db,
1311                                                     {}
1312                                                    );
1313       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1314       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1315       if(-e $difffile)
1316       {
1317         warn("$difffile already exists, skipping");
1318         next;
1319       }
1320       if(!open $file, ">$difffile")
1321       {
1322         $self->throw_exception("Can't write to $difffile ($!)");
1323         next;
1324       }
1325       print $file $diff;
1326       close($file);
1327     }
1328   }
1329 }
1330
1331 sub configure_sqlt() {
1332   my $self = shift;
1333   my $tr = shift;
1334   my $db = shift || $self->sqlt_type;
1335   if ($db eq 'PostgreSQL') {
1336     $tr->quote_table_names(0);
1337     $tr->quote_field_names(0);
1338   }
1339   return $tr;
1340 }
1341
1342 =head2 deployment_statements
1343
1344 =over 4
1345
1346 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1347
1348 =back
1349
1350 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1351 The database driver name is given by C<$type>, though the value from
1352 L</sqlt_type> is used if it is not specified.
1353
1354 C<$directory> is used to return statements from files in a previously created
1355 L</create_ddl_dir> directory and is optional. The filenames are constructed
1356 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1357
1358 If no C<$directory> is specified then the statements are constructed on the
1359 fly using L<SQL::Translator> and C<$version> is ignored.
1360
1361 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1362
1363 =cut
1364
1365 sub deployment_statements {
1366   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1367   # Need to be connected to get the correct sqlt_type
1368   $self->ensure_connected() unless $type;
1369   $type ||= $self->sqlt_type;
1370   $version ||= $schema->VERSION || '1.x';
1371   $dir ||= './';
1372   my $filename = $schema->ddl_filename($type, $dir, $version);
1373   if(-f $filename)
1374   {
1375       my $file;
1376       open($file, "<$filename")
1377         or $self->throw_exception("Can't open $filename ($!)");
1378       my @rows = <$file>;
1379       close($file);
1380       return join('', @rows);
1381   }
1382
1383   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1384       . $self->_check_sqlt_message . q{'})
1385           if !$self->_check_sqlt_version;
1386
1387   require SQL::Translator::Parser::DBIx::Class;
1388   eval qq{use SQL::Translator::Producer::${type}};
1389   $self->throw_exception($@) if $@;
1390
1391   # sources needs to be a parser arg, but for simplicty allow at top level
1392   # coming in
1393   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1394       if exists $sqltargs->{sources};
1395
1396   my $tr = SQL::Translator->new(%$sqltargs);
1397   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1398   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1399
1400   return;
1401
1402 }
1403
1404 sub deploy {
1405   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1406   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1407     for ( split(";\n", $statement)) {
1408       next if($_ =~ /^--/);
1409       next if(!$_);
1410 #      next if($_ =~ /^DROP/m);
1411       next if($_ =~ /^BEGIN TRANSACTION/m);
1412       next if($_ =~ /^COMMIT/m);
1413       next if $_ =~ /^\s+$/; # skip whitespace only
1414       $self->debugobj->query_start($_) if $self->debug;
1415       $self->dbh->do($_); # shouldn't be using ->dbh ?
1416       $self->debugobj->query_end($_) if $self->debug;
1417     }
1418   }
1419 }
1420
1421 =head2 datetime_parser
1422
1423 Returns the datetime parser class
1424
1425 =cut
1426
1427 sub datetime_parser {
1428   my $self = shift;
1429   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1430 }
1431
1432 =head2 datetime_parser_type
1433
1434 Defines (returns) the datetime parser class - currently hardwired to
1435 L<DateTime::Format::MySQL>
1436
1437 =cut
1438
1439 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1440
1441 =head2 build_datetime_parser
1442
1443 See L</datetime_parser>
1444
1445 =cut
1446
1447 sub build_datetime_parser {
1448   my $self = shift;
1449   my $type = $self->datetime_parser_type(@_);
1450   eval "use ${type}";
1451   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1452   return $type;
1453 }
1454
1455 {
1456     my $_check_sqlt_version; # private
1457     my $_check_sqlt_message; # private
1458     sub _check_sqlt_version {
1459         return $_check_sqlt_version if defined $_check_sqlt_version;
1460         eval 'use SQL::Translator 0.08';
1461         $_check_sqlt_message = $@ ? $@ : '';
1462         $_check_sqlt_version = $@ ? 0 : 1;
1463     }
1464
1465     sub _check_sqlt_message {
1466         _check_sqlt_version if !defined $_check_sqlt_message;
1467         $_check_sqlt_message;
1468     }
1469 }
1470
1471 sub DESTROY {
1472   my $self = shift;
1473   return if !$self->_dbh;
1474   $self->_verify_pid;
1475   $self->_dbh(undef);
1476 }
1477
1478 1;
1479
1480 =head1 SQL METHODS
1481
1482 The module defines a set of methods within the DBIC::SQL::Abstract
1483 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1484 SQL query functions.
1485
1486 The following methods are extended:-
1487
1488 =over 4
1489
1490 =item delete
1491
1492 =item insert
1493
1494 =item select
1495
1496 =item update
1497
1498 =item limit_dialect
1499
1500 See L</connect_info> for details.
1501 For setting, this method is deprecated in favor of L</connect_info>.
1502
1503 =item quote_char
1504
1505 See L</connect_info> for details.
1506 For setting, this method is deprecated in favor of L</connect_info>.
1507
1508 =item name_sep
1509
1510 See L</connect_info> for details.
1511 For setting, this method is deprecated in favor of L</connect_info>.
1512
1513 =back
1514
1515 =head1 AUTHORS
1516
1517 Matt S. Trout <mst@shadowcatsystems.co.uk>
1518
1519 Andy Grundman <andy@hybridized.org>
1520
1521 =head1 LICENSE
1522
1523 You may distribute this code under the same terms as Perl itself.
1524
1525 =cut