lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8
   9 BEGIN {
  10
  11 package DBIC::SQL::Abstract; # Temporary. Merge upstream.
  12
  13 use base qw/SQL::Abstract::Limit/;
  14
  15 sub select {
  16   my ($self, $table, $fields, $where, $order, @rest) = @_;
  17   @rest = (-1) unless defined $rest[0];
  18   $self->SUPER::select($table, $self->_recurse_fields($fields),
  19                          $where, $order, @rest);
  20 }
  21
  22 sub _emulate_limit {
  23   my $self = shift;
  24   if ($_[3] == -1) {
  25     return $_[1].$self->_order_by($_[2]);
  26   } else {
  27     return $self->SUPER::_emulate_limit(@_);
  28   }
  29 }
  30
  31 sub _recurse_fields {
  32   my ($self, $fields) = @_;
  33   my $ref = ref $fields;
  34   return $self->_quote($fields) unless $ref;
  35   return $$fields if $ref eq 'SCALAR';
  36
  37   if ($ref eq 'ARRAY') {
  38     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  39   } elsif ($ref eq 'HASH') {
  40     foreach my $func (keys %$fields) {
  41       return $self->_sqlcase($func)
  42         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  43     }
  44   }
  45 }
  46
  47 sub _order_by {
  48   my $self = shift;
  49   my $ret = '';
  50   if (ref $_[0] eq 'HASH') {
  51     if (defined $_[0]->{group_by}) {
  52       $ret = $self->_sqlcase(' group by ')
  53                .$self->_recurse_fields($_[0]->{group_by});
  54     }
  55     if (defined $_[0]->{order_by}) {
  56       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  57     }
  58   } else {
  59     $ret = $self->SUPER::_order_by(@_);
  60   }
  61   return $ret;
  62 }
  63
  64 sub _table {
  65   my ($self, $from) = @_;
  66   if (ref $from eq 'ARRAY') {
  67     return $self->_recurse_from(@$from);
  68   } elsif (ref $from eq 'HASH') {
  69     return $self->_make_as($from);
  70   } else {
  71     return $from;
  72   }
  73 }
  74
  75 sub _recurse_from {
  76   my ($self, $from, @join) = @_;
  77   my @sqlf;
  78   push(@sqlf, $self->_make_as($from));
  79   foreach my $j (@join) {
  80     my ($to, $on) = @$j;
  81
  82     # check whether a join type exists
  83     my $join_clause = '';
  84     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  85       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  86     } else {
  87       $join_clause = ' JOIN ';
  88     }
  89     push(@sqlf, $join_clause);
  90
  91     if (ref $to eq 'ARRAY') {
  92       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  93     } else {
  94       push(@sqlf, $self->_make_as($to));
  95     }
  96     push(@sqlf, ' ON ', $self->_join_condition($on));
  97   }
  98   return join('', @sqlf);
  99 }
 100
 101 sub _make_as {
 102   my ($self, $from) = @_;
 103   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 104                            reverse each %{$self->_skip_options($from)});
 105 }
 106
 107 sub _skip_options {
 108   my ($self, $hash) = @_;
 109   my $clean_hash = {};
 110   $clean_hash->{$_} = $hash->{$_}
 111     for grep {!/^-/} keys %$hash;
 112   return $clean_hash;
 113 }
 114
 115 sub _join_condition {
 116   my ($self, $cond) = @_;
 117   die "no chance" unless ref $cond eq 'HASH';
 118   my %j;
 119   for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 120   return $self->_recurse_where(\%j);
 121 }
 122
 123 sub _quote {
 124   my ($self, $label) = @_;
 125   return '' unless defined $label;
 126   return $self->SUPER::_quote($label);
 127 }
 128
 129 } # End of BEGIN block
 130
 131 use base qw/DBIx::Class/;
 132
 133 __PACKAGE__->load_components(qw/Exception AccessorGroup/);
 134
 135 __PACKAGE__->mk_group_accessors('simple' =>
 136   qw/connect_info _dbh _sql_maker debug cursor/);
 137
 138 our $TRANSACTION = 0;
 139
 140 sub new {
 141   my $new = bless({}, ref $_[0] || $_[0]);
 142   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 143   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 144   return $new;
 145 }
 146
 147 =head1 NAME
 148
 149 DBIx::Class::Storage::DBI - DBI storage handler
 150
 151 =head1 SYNOPSIS
 152
 153 =head1 DESCRIPTION
 154
 155 This class represents the connection to the database
 156
 157 =head1 METHODS
 158
 159 =cut
 160
 161 sub dbh {
 162   my ($self) = @_;
 163   my $dbh;
 164   unless (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping) {
 165     $self->_populate_dbh;
 166   }
 167   return $self->_dbh;
 168 }
 169
 170 sub sql_maker {
 171   my ($self) = @_;
 172   unless ($self->_sql_maker) {
 173     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 174   }
 175   return $self->_sql_maker;
 176 }
 177
 178 sub _populate_dbh {
 179   my ($self) = @_;
 180   my @info = @{$self->connect_info || []};
 181   $self->_dbh($self->_connect(@info));
 182 }
 183
 184 sub _connect {
 185   my ($self, @info) = @_;
 186   return DBI->connect(@info);
 187 }
 188
 189 =head2 txn_begin
 190
 191 Calls begin_work on the current dbh.
 192
 193 =cut
 194
 195 sub txn_begin {
 196   $_[0]->dbh->begin_work if $TRANSACTION++ == 0 and $_[0]->dbh->{AutoCommit};
 197 }
 198
 199 =head2 txn_commit
 200
 201 Issues a commit against the current dbh.
 202
 203 =cut
 204
 205 sub txn_commit {
 206   if ($TRANSACTION == 0) {
 207     $_[0]->dbh->commit;
 208   }
 209   else {
 210     $_[0]->dbh->commit if --$TRANSACTION == 0;
 211   }
 212 }
 213
 214 =head2 txn_rollback
 215
 216 Issues a rollback against the current dbh.
 217
 218 =cut
 219
 220 sub txn_rollback {
 221   if ($TRANSACTION == 0) {
 222     $_[0]->dbh->rollback;
 223   }
 224   else {
 225     --$TRANSACTION == 0 ? $_[0]->dbh->rollback : die $@;
 226   }
 227 }
 228
 229 sub _execute {
 230   my ($self, $op, $extra_bind, $ident, @args) = @_;
 231   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 232   unshift(@bind, @$extra_bind) if $extra_bind;
 233   warn "$sql: @bind" if $self->debug;
 234   my $sth = $self->sth($sql,$op);
 235   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 236   my $rv = $sth->execute(@bind);
 237   return (wantarray ? ($rv, $sth, @bind) : $rv);
 238 }
 239
 240 sub insert {
 241   my ($self, $ident, $to_insert) = @_;
 242   $self->throw( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 243     unless ($self->_execute('insert' => [], $ident, $to_insert));
 244   return $to_insert;
 245 }
 246
 247 sub update {
 248   return shift->_execute('update' => [], @_);
 249 }
 250
 251 sub delete {
 252   return shift->_execute('delete' => [], @_);
 253 }
 254
 255 sub _select {
 256   my ($self, $ident, $select, $condition, $attrs) = @_;
 257   my $order = $attrs->{order_by};
 258   if (ref $condition eq 'SCALAR') {
 259     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 260   }
 261   if (exists $attrs->{group_by}) {
 262     $order = { group_by => $attrs->{group_by},
 263                ($order ? (order_by => $order) : ()) };
 264   }
 265   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 266   if ($attrs->{software_limit} ||
 267       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 268         $attrs->{software_limit} = 1;
 269   } else {
 270     push @args, $attrs->{rows}, $attrs->{offset};
 271   }
 272   return $self->_execute(@args);
 273 }
 274
 275 sub select {
 276   my $self = shift;
 277   my ($ident, $select, $condition, $attrs) = @_;
 278   my ($rv, $sth, @bind) = $self->_select(@_);
 279   return $self->cursor->new($sth, \@bind, $attrs);
 280 }
 281
 282 sub select_single {
 283   my $self = shift;
 284   my ($rv, $sth, @bind) = $self->_select(@_);
 285   return $sth->fetchrow_array;
 286 }
 287
 288 sub sth {
 289   my ($self, $sql, $op) = @_;
 290   my $meth = (defined $op && $op ne 'select' ? 'prepare_cached' : 'prepare');
 291   return $self->dbh->$meth($sql);
 292 }
 293
 294 1;
 295
 296 =head1 AUTHORS
 297
 298 Matt S. Trout <mst@shadowcatsystems.co.uk>
 299
 300 Andy Grundman <andy@hybridized.org>
 301
 302 =head1 LICENSE
 303
 304 You may distribute this code under the same terms as Perl itself.
 305
 306 =cut
 307