lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util();
  13 use List::Util();
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  33
  34
  35 =head1 NAME
  36
  37 DBIx::Class::Storage::DBI - DBI storage handler
  38
  39 =head1 SYNOPSIS
  40
  41   my $schema = MySchema->connect('dbi:SQLite:my.db');
  42
  43   $schema->storage->debug(1);
  44   $schema->dbh_do("DROP TABLE authors");
  45
  46   $schema->resultset('Book')->search({
  47      written_on => $schema->storage->datetime_parser(DateTime->now)
  48   });
  49
  50 =head1 DESCRIPTION
  51
  52 This class represents the connection to an RDBMS via L<DBI>.  See
  53 L<DBIx::Class::Storage> for general information.  This pod only
  54 documents DBI-specific methods and behaviors.
  55
  56 =head1 METHODS
  57
  58 =cut
  59
  60 sub new {
  61   my $new = shift->next::method(@_);
  62
  63   $new->transaction_depth(0);
  64   $new->_sql_maker_opts({});
  65   $new->{savepoints} = [];
  66   $new->{_in_dbh_do} = 0;
  67   $new->{_dbh_gen} = 0;
  68
  69   $new;
  70 }
  71
  72 =head2 connect_info
  73
  74 This method is normally called by L<DBIx::Class::Schema/connection>, which
  75 encapsulates its argument list in an arrayref before passing them here.
  76
  77 The argument list may contain:
  78
  79 =over
  80
  81 =item *
  82
  83 The same 4-element argument set one would normally pass to
  84 L<DBI/connect>, optionally followed by
  85 L<extra attributes|/DBIx::Class specific connection attributes>
  86 recognized by DBIx::Class:
  87
  88   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
  89
  90 =item *
  91
  92 A single code reference which returns a connected
  93 L<DBI database handle|DBI/connect> optionally followed by
  94 L<extra attributes|/DBIx::Class specific connection attributes> recognized
  95 by DBIx::Class:
  96
  97   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
  98
  99 =item *
 100
 101 A single hashref with all the attributes and the dsn/user/password
 102 mixed together:
 103
 104   $connect_info_args = [{
 105     dsn => $dsn,
 106     user => $user,
 107     password => $pass,
 108     %dbi_attributes,
 109     %extra_attributes,
 110   }];
 111
 112 This is particularly useful for L<Catalyst> based applications, allowing the
 113 following config (L<Config::General> style):
 114
 115   <Model::DB>
 116     schema_class   App::DB
 117     <connect_info>
 118       dsn          dbi:mysql:database=test
 119       user         testuser
 120       password     TestPass
 121       AutoCommit   1
 122     </connect_info>
 123   </Model::DB>
 124
 125 =back
 126
 127 Please note that the L<DBI> docs recommend that you always explicitly
 128 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 129 recommends that it be set to I<1>, and that you perform transactions
 130 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 131 to I<1> if you do not do explicitly set it to zero.  This is the default
 132 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 133
 134 =head3 DBIx::Class specific connection attributes
 135
 136 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 137 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 138 the following connection options. These options can be mixed in with your other
 139 L<DBI> connection attributes, or placed in a seperate hashref
 140 (C<\%extra_attributes>) as shown above.
 141
 142 Every time C<connect_info> is invoked, any previous settings for
 143 these options will be cleared before setting the new ones, regardless of
 144 whether any options are specified in the new C<connect_info>.
 145
 146
 147 =over
 148
 149 =item on_connect_do
 150
 151 Specifies things to do immediately after connecting or re-connecting to
 152 the database.  Its value may contain:
 153
 154 =over
 155
 156 =item a scalar
 157
 158 This contains one SQL statement to execute.
 159
 160 =item an array reference
 161
 162 This contains SQL statements to execute in order.  Each element contains
 163 a string or a code reference that returns a string.
 164
 165 =item a code reference
 166
 167 This contains some code to execute.  Unlike code references within an
 168 array reference, its return value is ignored.
 169
 170 =back
 171
 172 =item on_disconnect_do
 173
 174 Takes arguments in the same form as L</on_connect_do> and executes them
 175 immediately before disconnecting from the database.
 176
 177 Note, this only runs if you explicitly call L</disconnect> on the
 178 storage object.
 179
 180 =item disable_sth_caching
 181
 182 If set to a true value, this option will disable the caching of
 183 statement handles via L<DBI/prepare_cached>.
 184
 185 =item limit_dialect
 186
 187 Sets the limit dialect. This is useful for JDBC-bridge among others
 188 where the remote SQL-dialect cannot be determined by the name of the
 189 driver alone. See also L<SQL::Abstract::Limit>.
 190
 191 =item quote_char
 192
 193 Specifies what characters to use to quote table and column names. If
 194 you use this you will want to specify L</name_sep> as well.
 195
 196 C<quote_char> expects either a single character, in which case is it
 197 is placed on either side of the table/column name, or an arrayref of length
 198 2 in which case the table/column name is placed between the elements.
 199
 200 For example under MySQL you should use C<< quote_char => '`' >>, and for
 201 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 202
 203 =item name_sep
 204
 205 This only needs to be used in conjunction with C<quote_char>, and is used to
 206 specify the charecter that seperates elements (schemas, tables, columns) from
 207 each other. In most cases this is simply a C<.>.
 208
 209 The consequences of not supplying this value is that L<SQL::Abstract>
 210 will assume DBIx::Class' uses of aliases to be complete column
 211 names. The output will look like I<"me.name"> when it should actually
 212 be I<"me"."name">.
 213
 214 =item unsafe
 215
 216 This Storage driver normally installs its own C<HandleError>, sets
 217 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 218 all database handles, including those supplied by a coderef.  It does this
 219 so that it can have consistent and useful error behavior.
 220
 221 If you set this option to a true value, Storage will not do its usual
 222 modifications to the database handle's attributes, and instead relies on
 223 the settings in your connect_info DBI options (or the values you set in
 224 your connection coderef, in the case that you are connecting via coderef).
 225
 226 Note that your custom settings can cause Storage to malfunction,
 227 especially if you set a C<HandleError> handler that suppresses exceptions
 228 and/or disable C<RaiseError>.
 229
 230 =item auto_savepoint
 231
 232 If this option is true, L<DBIx::Class> will use savepoints when nesting
 233 transactions, making it possible to recover from failure in the inner
 234 transaction without having to abort all outer transactions.
 235
 236 =item cursor_class
 237
 238 Use this argument to supply a cursor class other than the default
 239 L<DBIx::Class::Storage::DBI::Cursor>.
 240
 241 =back
 242
 243 Some real-life examples of arguments to L</connect_info> and
 244 L<DBIx::Class::Schema/connect>
 245
 246   # Simple SQLite connection
 247   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 248
 249   # Connect via subref
 250   ->connect_info([ sub { DBI->connect(...) } ]);
 251
 252   # A bit more complicated
 253   ->connect_info(
 254     [
 255       'dbi:Pg:dbname=foo',
 256       'postgres',
 257       'my_pg_password',
 258       { AutoCommit => 1 },
 259       { quote_char => q{"}, name_sep => q{.} },
 260     ]
 261   );
 262
 263   # Equivalent to the previous example
 264   ->connect_info(
 265     [
 266       'dbi:Pg:dbname=foo',
 267       'postgres',
 268       'my_pg_password',
 269       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 270     ]
 271   );
 272
 273   # Same, but with hashref as argument
 274   # See parse_connect_info for explanation
 275   ->connect_info(
 276     [{
 277       dsn         => 'dbi:Pg:dbname=foo',
 278       user        => 'postgres',
 279       password    => 'my_pg_password',
 280       AutoCommit  => 1,
 281       quote_char  => q{"},
 282       name_sep    => q{.},
 283     }]
 284   );
 285
 286   # Subref + DBIx::Class-specific connection options
 287   ->connect_info(
 288     [
 289       sub { DBI->connect(...) },
 290       {
 291           quote_char => q{`},
 292           name_sep => q{@},
 293           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 294           disable_sth_caching => 1,
 295       },
 296     ]
 297   );
 298
 299
 300
 301 =cut
 302
 303 sub connect_info {
 304   my ($self, $info_arg) = @_;
 305
 306   return $self->_connect_info if !$info_arg;
 307
 308   my @args = @$info_arg;  # take a shallow copy for further mutilation
 309   $self->_connect_info([@args]); # copy for _connect_info
 310
 311
 312   # combine/pre-parse arguments depending on invocation style
 313
 314   my %attrs;
 315   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 316     %attrs = %{ $args[1] || {} };
 317     @args = $args[0];
 318   }
 319   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 320     %attrs = %{$args[0]};
 321     @args = ();
 322     for (qw/password user dsn/) {
 323       unshift @args, delete $attrs{$_};
 324     }
 325   }
 326   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 327     %attrs = (
 328       % { $args[3] || {} },
 329       % { $args[4] || {} },
 330     );
 331     @args = @args[0,1,2];
 332   }
 333
 334   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 335   #  the new set of options
 336   $self->_sql_maker(undef);
 337   $self->_sql_maker_opts({});
 338
 339   if(keys %attrs) {
 340     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 341       if(my $value = delete $attrs{$storage_opt}) {
 342         $self->$storage_opt($value);
 343       }
 344     }
 345     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 346       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 347         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 348       }
 349     }
 350   }
 351
 352   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 353
 354   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 355   $self->_connect_info;
 356 }
 357
 358 =head2 on_connect_do
 359
 360 This method is deprecated in favour of setting via L</connect_info>.
 361
 362
 363 =head2 dbh_do
 364
 365 Arguments: ($subref | $method_name), @extra_coderef_args?
 366
 367 Execute the given $subref or $method_name using the new exception-based
 368 connection management.
 369
 370 The first two arguments will be the storage object that C<dbh_do> was called
 371 on and a database handle to use.  Any additional arguments will be passed
 372 verbatim to the called subref as arguments 2 and onwards.
 373
 374 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 375 exception handling and reconnection (or failover in future subclasses).
 376
 377 Your subref should have no side-effects outside of the database, as
 378 there is the potential for your subref to be partially double-executed
 379 if the database connection was stale/dysfunctional.
 380
 381 Example:
 382
 383   my @stuff = $schema->storage->dbh_do(
 384     sub {
 385       my ($storage, $dbh, @cols) = @_;
 386       my $cols = join(q{, }, @cols);
 387       $dbh->selectrow_array("SELECT $cols FROM foo");
 388     },
 389     @column_list
 390   );
 391
 392 =cut
 393
 394 sub dbh_do {
 395   my $self = shift;
 396   my $code = shift;
 397
 398   my $dbh = $self->_dbh;
 399
 400   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 401       || $self->{transaction_depth};
 402
 403   local $self->{_in_dbh_do} = 1;
 404
 405   my @result;
 406   my $want_array = wantarray;
 407
 408   eval {
 409     $self->_verify_pid if $dbh;
 410     if(!$self->_dbh) {
 411         $self->_populate_dbh;
 412         $dbh = $self->_dbh;
 413     }
 414
 415     if($want_array) {
 416         @result = $self->$code($dbh, @_);
 417     }
 418     elsif(defined $want_array) {
 419         $result[0] = $self->$code($dbh, @_);
 420     }
 421     else {
 422         $self->$code($dbh, @_);
 423     }
 424   };
 425
 426   my $exception = $@;
 427   if(!$exception) { return $want_array ? @result : $result[0] }
 428
 429   $self->throw_exception($exception) if $self->connected;
 430
 431   # We were not connected - reconnect and retry, but let any
 432   #  exception fall right through this time
 433   $self->_populate_dbh;
 434   $self->$code($self->_dbh, @_);
 435 }
 436
 437 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 438 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 439 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 440 sub txn_do {
 441   my $self = shift;
 442   my $coderef = shift;
 443
 444   ref $coderef eq 'CODE' or $self->throw_exception
 445     ('$coderef must be a CODE reference');
 446
 447   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 448
 449   local $self->{_in_dbh_do} = 1;
 450
 451   my @result;
 452   my $want_array = wantarray;
 453
 454   my $tried = 0;
 455   while(1) {
 456     eval {
 457       $self->_verify_pid if $self->_dbh;
 458       $self->_populate_dbh if !$self->_dbh;
 459
 460       $self->txn_begin;
 461       if($want_array) {
 462           @result = $coderef->(@_);
 463       }
 464       elsif(defined $want_array) {
 465           $result[0] = $coderef->(@_);
 466       }
 467       else {
 468           $coderef->(@_);
 469       }
 470       $self->txn_commit;
 471     };
 472
 473     my $exception = $@;
 474     if(!$exception) { return $want_array ? @result : $result[0] }
 475
 476     if($tried++ > 0 || $self->connected) {
 477       eval { $self->txn_rollback };
 478       my $rollback_exception = $@;
 479       if($rollback_exception) {
 480         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 481         $self->throw_exception($exception)  # propagate nested rollback
 482           if $rollback_exception =~ /$exception_class/;
 483
 484         $self->throw_exception(
 485           "Transaction aborted: ${exception}. "
 486           . "Rollback failed: ${rollback_exception}"
 487         );
 488       }
 489       $self->throw_exception($exception)
 490     }
 491
 492     # We were not connected, and was first try - reconnect and retry
 493     # via the while loop
 494     $self->_populate_dbh;
 495   }
 496 }
 497
 498 =head2 disconnect
 499
 500 Our C<disconnect> method also performs a rollback first if the
 501 database is not in C<AutoCommit> mode.
 502
 503 =cut
 504
 505 sub disconnect {
 506   my ($self) = @_;
 507
 508   if( $self->connected ) {
 509     my $connection_do = $self->on_disconnect_do;
 510     $self->_do_connection_actions($connection_do) if ref($connection_do);
 511
 512     $self->_dbh->rollback unless $self->_dbh_autocommit;
 513     $self->_dbh->disconnect;
 514     $self->_dbh(undef);
 515     $self->{_dbh_gen}++;
 516   }
 517 }
 518
 519 =head2 with_deferred_fk_checks
 520
 521 =over 4
 522
 523 =item Arguments: C<$coderef>
 524
 525 =item Return Value: The return value of $coderef
 526
 527 =back
 528
 529 Storage specific method to run the code ref with FK checks deferred or
 530 in MySQL's case disabled entirely.
 531
 532 =cut
 533
 534 # Storage subclasses should override this
 535 sub with_deferred_fk_checks {
 536   my ($self, $sub) = @_;
 537
 538   $sub->();
 539 }
 540
 541 sub connected {
 542   my ($self) = @_;
 543
 544   if(my $dbh = $self->_dbh) {
 545       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 546           $self->_dbh(undef);
 547           $self->{_dbh_gen}++;
 548           return;
 549       }
 550       else {
 551           $self->_verify_pid;
 552           return 0 if !$self->_dbh;
 553       }
 554       return ($dbh->FETCH('Active') && $dbh->ping);
 555   }
 556
 557   return 0;
 558 }
 559
 560 # handle pid changes correctly
 561 #  NOTE: assumes $self->_dbh is a valid $dbh
 562 sub _verify_pid {
 563   my ($self) = @_;
 564
 565   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 566
 567   $self->_dbh->{InactiveDestroy} = 1;
 568   $self->_dbh(undef);
 569   $self->{_dbh_gen}++;
 570
 571   return;
 572 }
 573
 574 sub ensure_connected {
 575   my ($self) = @_;
 576
 577   unless ($self->connected) {
 578     $self->_populate_dbh;
 579   }
 580 }
 581
 582 =head2 dbh
 583
 584 Returns the dbh - a data base handle of class L<DBI>.
 585
 586 =cut
 587
 588 sub dbh {
 589   my ($self) = @_;
 590
 591   $self->ensure_connected;
 592   return $self->_dbh;
 593 }
 594
 595 sub _sql_maker_args {
 596     my ($self) = @_;
 597
 598     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 599 }
 600
 601 sub sql_maker {
 602   my ($self) = @_;
 603   unless ($self->_sql_maker) {
 604     my $sql_maker_class = $self->sql_maker_class;
 605     $self->ensure_class_loaded ($sql_maker_class);
 606     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 607   }
 608   return $self->_sql_maker;
 609 }
 610
 611 sub _rebless {}
 612
 613 sub _populate_dbh {
 614   my ($self) = @_;
 615   my @info = @{$self->_dbi_connect_info || []};
 616   $self->_dbh($self->_connect(@info));
 617
 618   $self->_conn_pid($$);
 619   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 620
 621   $self->_determine_driver;
 622
 623   # Always set the transaction depth on connect, since
 624   #  there is no transaction in progress by definition
 625   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 626
 627   my $connection_do = $self->on_connect_do;
 628   $self->_do_connection_actions($connection_do) if $connection_do;
 629 }
 630
 631 sub _determine_driver {
 632   my ($self) = @_;
 633
 634   if (ref $self eq 'DBIx::Class::Storage::DBI') {
 635     my $driver;
 636
 637     if ($self->_dbh) { # we are connected
 638       $driver = $self->_dbh->{Driver}{Name};
 639     } else {
 640       # try to use dsn to not require being connected, the driver may still
 641       # force a connection in _rebless to determine version
 642       ($driver) = $self->_dbi_connect_info->[0] =~ /dbi:([^:]+):/i;
 643     }
 644
 645     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 646       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 647       $self->_rebless();
 648     }
 649   }
 650 }
 651
 652 sub _do_connection_actions {
 653   my $self = shift;
 654   my $connection_do = shift;
 655
 656   if (!ref $connection_do) {
 657     $self->_do_query($connection_do);
 658   }
 659   elsif (ref $connection_do eq 'ARRAY') {
 660     $self->_do_query($_) foreach @$connection_do;
 661   }
 662   elsif (ref $connection_do eq 'CODE') {
 663     $connection_do->($self);
 664   }
 665   else {
 666     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref $connection_do) );
 667   }
 668
 669   return $self;
 670 }
 671
 672 sub _do_query {
 673   my ($self, $action) = @_;
 674
 675   if (ref $action eq 'CODE') {
 676     $action = $action->($self);
 677     $self->_do_query($_) foreach @$action;
 678   }
 679   else {
 680     # Most debuggers expect ($sql, @bind), so we need to exclude
 681     # the attribute hash which is the second argument to $dbh->do
 682     # furthermore the bind values are usually to be presented
 683     # as named arrayref pairs, so wrap those here too
 684     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 685     my $sql = shift @do_args;
 686     my $attrs = shift @do_args;
 687     my @bind = map { [ undef, $_ ] } @do_args;
 688
 689     $self->_query_start($sql, @bind);
 690     $self->_dbh->do($sql, $attrs, @do_args);
 691     $self->_query_end($sql, @bind);
 692   }
 693
 694   return $self;
 695 }
 696
 697 sub _connect {
 698   my ($self, @info) = @_;
 699
 700   $self->throw_exception("You failed to provide any connection info")
 701     if !@info;
 702
 703   my ($old_connect_via, $dbh);
 704
 705   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 706     $old_connect_via = $DBI::connect_via;
 707     $DBI::connect_via = 'connect';
 708   }
 709
 710   eval {
 711     if(ref $info[0] eq 'CODE') {
 712        $dbh = &{$info[0]}
 713     }
 714     else {
 715        $dbh = DBI->connect(@info);
 716     }
 717
 718     if($dbh && !$self->unsafe) {
 719       my $weak_self = $self;
 720       Scalar::Util::weaken($weak_self);
 721       $dbh->{HandleError} = sub {
 722           if ($weak_self) {
 723             $weak_self->throw_exception("DBI Exception: $_[0]");
 724           }
 725           else {
 726             croak ("DBI Exception: $_[0]");
 727           }
 728       };
 729       $dbh->{ShowErrorStatement} = 1;
 730       $dbh->{RaiseError} = 1;
 731       $dbh->{PrintError} = 0;
 732     }
 733   };
 734
 735   $DBI::connect_via = $old_connect_via if $old_connect_via;
 736
 737   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 738     if !$dbh || $@;
 739
 740   $self->_dbh_autocommit($dbh->{AutoCommit});
 741
 742   $dbh;
 743 }
 744
 745 sub svp_begin {
 746   my ($self, $name) = @_;
 747
 748   $name = $self->_svp_generate_name
 749     unless defined $name;
 750
 751   $self->throw_exception ("You can't use savepoints outside a transaction")
 752     if $self->{transaction_depth} == 0;
 753
 754   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 755     unless $self->can('_svp_begin');
 756
 757   push @{ $self->{savepoints} }, $name;
 758
 759   $self->debugobj->svp_begin($name) if $self->debug;
 760
 761   return $self->_svp_begin($name);
 762 }
 763
 764 sub svp_release {
 765   my ($self, $name) = @_;
 766
 767   $self->throw_exception ("You can't use savepoints outside a transaction")
 768     if $self->{transaction_depth} == 0;
 769
 770   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 771     unless $self->can('_svp_release');
 772
 773   if (defined $name) {
 774     $self->throw_exception ("Savepoint '$name' does not exist")
 775       unless grep { $_ eq $name } @{ $self->{savepoints} };
 776
 777     # Dig through the stack until we find the one we are releasing.  This keeps
 778     # the stack up to date.
 779     my $svp;
 780
 781     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 782   } else {
 783     $name = pop @{ $self->{savepoints} };
 784   }
 785
 786   $self->debugobj->svp_release($name) if $self->debug;
 787
 788   return $self->_svp_release($name);
 789 }
 790
 791 sub svp_rollback {
 792   my ($self, $name) = @_;
 793
 794   $self->throw_exception ("You can't use savepoints outside a transaction")
 795     if $self->{transaction_depth} == 0;
 796
 797   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 798     unless $self->can('_svp_rollback');
 799
 800   if (defined $name) {
 801       # If they passed us a name, verify that it exists in the stack
 802       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 803           $self->throw_exception("Savepoint '$name' does not exist!");
 804       }
 805
 806       # Dig through the stack until we find the one we are releasing.  This keeps
 807       # the stack up to date.
 808       while(my $s = pop(@{ $self->{savepoints} })) {
 809           last if($s eq $name);
 810       }
 811       # Add the savepoint back to the stack, as a rollback doesn't remove the
 812       # named savepoint, only everything after it.
 813       push(@{ $self->{savepoints} }, $name);
 814   } else {
 815       # We'll assume they want to rollback to the last savepoint
 816       $name = $self->{savepoints}->[-1];
 817   }
 818
 819   $self->debugobj->svp_rollback($name) if $self->debug;
 820
 821   return $self->_svp_rollback($name);
 822 }
 823
 824 sub _svp_generate_name {
 825     my ($self) = @_;
 826
 827     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 828 }
 829
 830 sub txn_begin {
 831   my $self = shift;
 832   $self->ensure_connected();
 833   if($self->{transaction_depth} == 0) {
 834     $self->debugobj->txn_begin()
 835       if $self->debug;
 836     # this isn't ->_dbh-> because
 837     #  we should reconnect on begin_work
 838     #  for AutoCommit users
 839     $self->dbh->begin_work;
 840   } elsif ($self->auto_savepoint) {
 841     $self->svp_begin;
 842   }
 843   $self->{transaction_depth}++;
 844 }
 845
 846 sub txn_commit {
 847   my $self = shift;
 848   if ($self->{transaction_depth} == 1) {
 849     my $dbh = $self->_dbh;
 850     $self->debugobj->txn_commit()
 851       if ($self->debug);
 852     $dbh->commit;
 853     $self->{transaction_depth} = 0
 854       if $self->_dbh_autocommit;
 855   }
 856   elsif($self->{transaction_depth} > 1) {
 857     $self->{transaction_depth}--;
 858     $self->svp_release
 859       if $self->auto_savepoint;
 860   }
 861 }
 862
 863 sub txn_rollback {
 864   my $self = shift;
 865   my $dbh = $self->_dbh;
 866   eval {
 867     if ($self->{transaction_depth} == 1) {
 868       $self->debugobj->txn_rollback()
 869         if ($self->debug);
 870       $self->{transaction_depth} = 0
 871         if $self->_dbh_autocommit;
 872       $dbh->rollback;
 873     }
 874     elsif($self->{transaction_depth} > 1) {
 875       $self->{transaction_depth}--;
 876       if ($self->auto_savepoint) {
 877         $self->svp_rollback;
 878         $self->svp_release;
 879       }
 880     }
 881     else {
 882       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 883     }
 884   };
 885   if ($@) {
 886     my $error = $@;
 887     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 888     $error =~ /$exception_class/ and $self->throw_exception($error);
 889     # ensure that a failed rollback resets the transaction depth
 890     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 891     $self->throw_exception($error);
 892   }
 893 }
 894
 895 # This used to be the top-half of _execute.  It was split out to make it
 896 #  easier to override in NoBindVars without duping the rest.  It takes up
 897 #  all of _execute's args, and emits $sql, @bind.
 898 sub _prep_for_execute {
 899   my ($self, $op, $extra_bind, $ident, $args) = @_;
 900
 901   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 902     $ident = $ident->from();
 903   }
 904
 905   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 906
 907   unshift(@bind,
 908     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 909       if $extra_bind;
 910   return ($sql, \@bind);
 911 }
 912
 913 =head2 as_query
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: \[ $sql, @bind ]
 920
 921 =back
 922
 923 Returns the SQL statement and bind vars that would result from the given
 924 ResultSet (does not actually run a query)
 925
 926 =cut
 927
 928 sub as_query {
 929   my ($self, $rs) = @_;
 930
 931   my $sql_maker = $self->sql_maker;
 932   local $sql_maker->{for};
 933
 934   my $attr = $rs->_resolved_attrs;
 935
 936   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $order, $rows, $offset) = $self->_select_args(...);
 937   my @args = $self->_select_args($attr->{from}, $attr->{select}, $attr->{where}, $attr);
 938
 939   # my ($sql, $bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $order, $rows, $offset ]);
 940   my ($sql, $bind) = $self->_prep_for_execute(
 941     @args[0 .. 2],
 942     [ @args[4 .. $#args] ],
 943   );
 944   return \[ "($sql)", @{ $bind || [] }];
 945 }
 946
 947 sub _fix_bind_params {
 948     my ($self, @bind) = @_;
 949
 950     ### Turn @bind from something like this:
 951     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 952     ### to this:
 953     ###   ( "'1'", "'1'", "'3'" )
 954     return
 955         map {
 956             if ( defined( $_ && $_->[1] ) ) {
 957                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 958             }
 959             else { q{'NULL'}; }
 960         } @bind;
 961 }
 962
 963 sub _query_start {
 964     my ( $self, $sql, @bind ) = @_;
 965
 966     if ( $self->debug ) {
 967         @bind = $self->_fix_bind_params(@bind);
 968
 969         $self->debugobj->query_start( $sql, @bind );
 970     }
 971 }
 972
 973 sub _query_end {
 974     my ( $self, $sql, @bind ) = @_;
 975
 976     if ( $self->debug ) {
 977         @bind = $self->_fix_bind_params(@bind);
 978         $self->debugobj->query_end( $sql, @bind );
 979     }
 980 }
 981
 982 sub _dbh_execute {
 983   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 984
 985   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 986
 987   $self->_query_start( $sql, @$bind );
 988
 989   my $sth = $self->sth($sql,$op);
 990
 991   my $placeholder_index = 1;
 992
 993   foreach my $bound (@$bind) {
 994     my $attributes = {};
 995     my($column_name, @data) = @$bound;
 996
 997     if ($bind_attributes) {
 998       $attributes = $bind_attributes->{$column_name}
 999       if defined $bind_attributes->{$column_name};
1000     }
1001
1002     foreach my $data (@data) {
1003       my $ref = ref $data;
1004       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1005
1006       $sth->bind_param($placeholder_index, $data, $attributes);
1007       $placeholder_index++;
1008     }
1009   }
1010
1011   # Can this fail without throwing an exception anyways???
1012   my $rv = $sth->execute();
1013   $self->throw_exception($sth->errstr) if !$rv;
1014
1015   $self->_query_end( $sql, @$bind );
1016
1017   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1018 }
1019
1020 sub _execute {
1021     my $self = shift;
1022     $self->dbh_do('_dbh_execute', @_)
1023 }
1024
1025 sub insert {
1026   my ($self, $source, $to_insert) = @_;
1027
1028   my $ident = $source->from;
1029   my $bind_attributes = $self->source_bind_attributes($source);
1030
1031   my $updated_cols = {};
1032
1033   $self->ensure_connected;
1034   foreach my $col ( $source->columns ) {
1035     if ( !defined $to_insert->{$col} ) {
1036       my $col_info = $source->column_info($col);
1037
1038       if ( $col_info->{auto_nextval} ) {
1039         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1040       }
1041     }
1042   }
1043
1044   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1045
1046   return $updated_cols;
1047 }
1048
1049 ## Still not quite perfect, and EXPERIMENTAL
1050 ## Currently it is assumed that all values passed will be "normal", i.e. not
1051 ## scalar refs, or at least, all the same type as the first set, the statement is
1052 ## only prepped once.
1053 sub insert_bulk {
1054   my ($self, $source, $cols, $data) = @_;
1055   my %colvalues;
1056   my $table = $source->from;
1057   @colvalues{@$cols} = (0..$#$cols);
1058   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1059
1060   $self->_query_start( $sql, @bind );
1061   my $sth = $self->sth($sql);
1062
1063 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1064
1065   ## This must be an arrayref, else nothing works!
1066   my $tuple_status = [];
1067
1068   ## Get the bind_attributes, if any exist
1069   my $bind_attributes = $self->source_bind_attributes($source);
1070
1071   ## Bind the values and execute
1072   my $placeholder_index = 1;
1073
1074   foreach my $bound (@bind) {
1075
1076     my $attributes = {};
1077     my ($column_name, $data_index) = @$bound;
1078
1079     if( $bind_attributes ) {
1080       $attributes = $bind_attributes->{$column_name}
1081       if defined $bind_attributes->{$column_name};
1082     }
1083
1084     my @data = map { $_->[$data_index] } @$data;
1085
1086     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1087     $placeholder_index++;
1088   }
1089   my $rv = eval { $sth->execute_array({ArrayTupleStatus => $tuple_status}) };
1090   if (my $err = $@) {
1091     my $i = 0;
1092     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1093
1094     $self->throw_exception($sth->errstr || "Unexpected populate error: $err")
1095       if ($i > $#$tuple_status);
1096
1097     require Data::Dumper;
1098     local $Data::Dumper::Terse = 1;
1099     local $Data::Dumper::Indent = 1;
1100     local $Data::Dumper::Useqq = 1;
1101     local $Data::Dumper::Quotekeys = 0;
1102
1103     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1104       $tuple_status->[$i][1],
1105       Data::Dumper::Dumper(
1106         { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) }
1107       ),
1108     );
1109   }
1110   $self->throw_exception($sth->errstr) if !$rv;
1111
1112   $self->_query_end( $sql, @bind );
1113   return (wantarray ? ($rv, $sth, @bind) : $rv);
1114 }
1115
1116 sub update {
1117   my $self = shift @_;
1118   my $source = shift @_;
1119   my $bind_attributes = $self->source_bind_attributes($source);
1120
1121   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1122 }
1123
1124
1125 sub delete {
1126   my $self = shift @_;
1127   my $source = shift @_;
1128
1129   my $bind_attrs = $self->source_bind_attributes($source);
1130
1131   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1132 }
1133
1134 # We were sent here because the $rs contains a complex search
1135 # which will require a subquery to select the correct rows
1136 # (i.e. joined or limited resultsets)
1137 #
1138 # Genarating a single PK column subquery is trivial and supported
1139 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1140 # Look at _multipk_update_delete()
1141 sub _subq_update_delete {
1142   my $self = shift;
1143   my ($rs, $op, $values) = @_;
1144
1145   my $rsrc = $rs->result_source;
1146
1147   # we already check this, but double check naively just in case. Should be removed soon
1148   my $sel = $rs->_resolved_attrs->{select};
1149   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1150   my @pcols = $rsrc->primary_columns;
1151   if (@$sel != @pcols) {
1152     $self->throw_exception (
1153       'Subquery update/delete can not be called on resultsets selecting a'
1154      .' number of columns different than the number of primary keys'
1155     );
1156   }
1157
1158   if (@pcols == 1) {
1159     return $self->$op (
1160       $rsrc,
1161       $op eq 'update' ? $values : (),
1162       { $pcols[0] => { -in => $rs->as_query } },
1163     );
1164   }
1165
1166   else {
1167     return $self->_multipk_update_delete (@_);
1168   }
1169 }
1170
1171 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1172 # resultset update/delete involving subqueries. So by default resort
1173 # to simple (and inefficient) delete_all style per-row opearations,
1174 # while allowing specific storages to override this with a faster
1175 # implementation.
1176 #
1177 sub _multipk_update_delete {
1178   return shift->_per_row_update_delete (@_);
1179 }
1180
1181 # This is the default loop used to delete/update rows for multi PK
1182 # resultsets, and used by mysql exclusively (because it can't do anything
1183 # else).
1184 #
1185 # We do not use $row->$op style queries, because resultset update/delete
1186 # is not expected to cascade (this is what delete_all/update_all is for).
1187 #
1188 # There should be no race conditions as the entire operation is rolled
1189 # in a transaction.
1190 #
1191 sub _per_row_update_delete {
1192   my $self = shift;
1193   my ($rs, $op, $values) = @_;
1194
1195   my $rsrc = $rs->result_source;
1196   my @pcols = $rsrc->primary_columns;
1197
1198   my $guard = $self->txn_scope_guard;
1199
1200   # emulate the return value of $sth->execute for non-selects
1201   my $row_cnt = '0E0';
1202
1203   my $subrs_cur = $rs->cursor;
1204   while (my @pks = $subrs_cur->next) {
1205
1206     my $cond;
1207     for my $i (0.. $#pcols) {
1208       $cond->{$pcols[$i]} = $pks[$i];
1209     }
1210
1211     $self->$op (
1212       $rsrc,
1213       $op eq 'update' ? $values : (),
1214       $cond,
1215     );
1216
1217     $row_cnt++;
1218   }
1219
1220   $guard->commit;
1221
1222   return $row_cnt;
1223 }
1224
1225 sub _select {
1226   my $self = shift;
1227   my $sql_maker = $self->sql_maker;
1228   local $sql_maker->{for};
1229   return $self->_execute($self->_select_args(@_));
1230 }
1231
1232 sub _select_args {
1233   my ($self, $ident, $select, $condition, $attrs) = @_;
1234
1235   my $for = delete $attrs->{for};
1236   my $sql_maker = $self->sql_maker;
1237   $sql_maker->{for} = $for;
1238
1239   my $order = { map
1240     { $attrs->{$_} ? ( $_ => $attrs->{$_} ) : ()  }
1241     (qw/order_by group_by having _virtual_order_by/ )
1242   };
1243
1244
1245   my $bind_attrs = {};
1246
1247   my $alias2source = $self->_resolve_ident_sources ($ident);
1248
1249   for my $alias (keys %$alias2source) {
1250     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1251     for my $col (keys %$bindtypes) {
1252
1253       my $fqcn = join ('.', $alias, $col);
1254       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1255
1256       # so that unqualified searches can be bound too
1257       $bind_attrs->{$col} = $bind_attrs->{$fqcn} if $alias eq 'me';
1258     }
1259   }
1260
1261   # This would be the point to deflate anything found in $condition
1262   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1263   # expect a row object. And all we have is a resultsource (it is trivial
1264   # to extract deflator coderefs via $alias2source above).
1265   #
1266   # I don't see a way forward other than changing the way deflators are
1267   # invoked, and that's just bad...
1268
1269   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1270   if ($attrs->{software_limit} ||
1271       $sql_maker->_default_limit_syntax eq "GenericSubQ") {
1272         $attrs->{software_limit} = 1;
1273   } else {
1274     $self->throw_exception("rows attribute must be positive if present")
1275       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1276
1277     # MySQL actually recommends this approach.  I cringe.
1278     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1279     push @args, $attrs->{rows}, $attrs->{offset};
1280   }
1281   return @args;
1282 }
1283
1284 sub _resolve_ident_sources {
1285   my ($self, $ident) = @_;
1286
1287   my $alias2source = {};
1288
1289   # the reason this is so contrived is that $ident may be a {from}
1290   # structure, specifying multiple tables to join
1291   if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1292     $alias2source->{$ident->alias} = $ident;
1293   }
1294   elsif (ref $ident eq 'ARRAY') {
1295
1296     for (@$ident) {
1297       my $tabinfo;
1298       if (ref $_ eq 'HASH') {
1299         $tabinfo = $_;
1300       }
1301       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
1302         $tabinfo = $_->[0];
1303       }
1304
1305       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-result_source}
1306         if ($tabinfo->{-result_source});
1307     }
1308   }
1309
1310   return $alias2source;
1311 }
1312
1313 sub count {
1314   my ($self, $source, $attrs) = @_;
1315
1316   my $tmp_attrs = { %$attrs };
1317
1318   # take off any pagers, record_filter is cdbi, and no point of ordering a count
1319   delete $tmp_attrs->{$_} for (qw/select as rows offset page order_by record_filter/);
1320
1321   # overwrite the selector
1322   $tmp_attrs->{select} = { count => '*' };
1323
1324   my $tmp_rs = $source->resultset_class->new($source, $tmp_attrs);
1325   my ($count) = $tmp_rs->cursor->next;
1326
1327   # if the offset/rows attributes are still present, we did not use
1328   # a subquery, so we need to make the calculations in software
1329   $count -= $attrs->{offset} if $attrs->{offset};
1330   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1331   $count = 0 if ($count < 0);
1332
1333   return $count;
1334 }
1335
1336 sub count_grouped {
1337   my ($self, $source, $attrs) = @_;
1338
1339   # copy for the subquery, we need to do some adjustments to it too
1340   my $sub_attrs = { %$attrs };
1341
1342   # these can not go in the subquery, and there is no point of ordering it
1343   delete $sub_attrs->{$_} for qw/prefetch collapse select as order_by/;
1344
1345   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1346   # simply deleting group_by suffices, as the code below will re-fill it
1347   # Note: we check $attrs, as $sub_attrs has collapse deleted
1348   if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1349     delete $sub_attrs->{group_by};
1350   }
1351
1352   $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($source->primary_columns) ];
1353   $sub_attrs->{select} = $self->_grouped_count_select ($source, $sub_attrs);
1354
1355   $attrs->{from} = [{
1356     count_subq => $source->resultset_class->new ($source, $sub_attrs )->as_query
1357   }];
1358
1359   # the subquery replaces this
1360   delete $attrs->{$_} for qw/where bind prefetch collapse group_by having having_bind rows offset page pager/;
1361
1362   return $self->count ($source, $attrs);
1363 }
1364
1365 #
1366 # Returns a SELECT to go with a supplied GROUP BY
1367 # (caled by count_grouped so a group_by is present)
1368 # Most databases expect them to match, but some
1369 # choke in various ways.
1370 #
1371 sub _grouped_count_select {
1372   my ($self, $source, $rs_args) = @_;
1373   return $rs_args->{group_by};
1374 }
1375
1376 sub source_bind_attributes {
1377   my ($self, $source) = @_;
1378
1379   my $bind_attributes;
1380   foreach my $column ($source->columns) {
1381
1382     my $data_type = $source->column_info($column)->{data_type} || '';
1383     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1384      if $data_type;
1385   }
1386
1387   return $bind_attributes;
1388 }
1389
1390 =head2 select
1391
1392 =over 4
1393
1394 =item Arguments: $ident, $select, $condition, $attrs
1395
1396 =back
1397
1398 Handle a SQL select statement.
1399
1400 =cut
1401
1402 sub select {
1403   my $self = shift;
1404   my ($ident, $select, $condition, $attrs) = @_;
1405   return $self->cursor_class->new($self, \@_, $attrs);
1406 }
1407
1408 sub select_single {
1409   my $self = shift;
1410   my ($rv, $sth, @bind) = $self->_select(@_);
1411   my @row = $sth->fetchrow_array;
1412   my @nextrow = $sth->fetchrow_array if @row;
1413   if(@row && @nextrow) {
1414     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1415   }
1416   # Need to call finish() to work round broken DBDs
1417   $sth->finish();
1418   return @row;
1419 }
1420
1421 =head2 sth
1422
1423 =over 4
1424
1425 =item Arguments: $sql
1426
1427 =back
1428
1429 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1430
1431 =cut
1432
1433 sub _dbh_sth {
1434   my ($self, $dbh, $sql) = @_;
1435
1436   # 3 is the if_active parameter which avoids active sth re-use
1437   my $sth = $self->disable_sth_caching
1438     ? $dbh->prepare($sql)
1439     : $dbh->prepare_cached($sql, {}, 3);
1440
1441   # XXX You would think RaiseError would make this impossible,
1442   #  but apparently that's not true :(
1443   $self->throw_exception($dbh->errstr) if !$sth;
1444
1445   $sth;
1446 }
1447
1448 sub sth {
1449   my ($self, $sql) = @_;
1450   $self->dbh_do('_dbh_sth', $sql);
1451 }
1452
1453 sub _dbh_columns_info_for {
1454   my ($self, $dbh, $table) = @_;
1455
1456   if ($dbh->can('column_info')) {
1457     my %result;
1458     eval {
1459       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1460       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1461       $sth->execute();
1462       while ( my $info = $sth->fetchrow_hashref() ){
1463         my %column_info;
1464         $column_info{data_type}   = $info->{TYPE_NAME};
1465         $column_info{size}      = $info->{COLUMN_SIZE};
1466         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1467         $column_info{default_value} = $info->{COLUMN_DEF};
1468         my $col_name = $info->{COLUMN_NAME};
1469         $col_name =~ s/^\"(.*)\"$/$1/;
1470
1471         $result{$col_name} = \%column_info;
1472       }
1473     };
1474     return \%result if !$@ && scalar keys %result;
1475   }
1476
1477   my %result;
1478   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1479   $sth->execute;
1480   my @columns = @{$sth->{NAME_lc}};
1481   for my $i ( 0 .. $#columns ){
1482     my %column_info;
1483     $column_info{data_type} = $sth->{TYPE}->[$i];
1484     $column_info{size} = $sth->{PRECISION}->[$i];
1485     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1486
1487     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1488       $column_info{data_type} = $1;
1489       $column_info{size}    = $2;
1490     }
1491
1492     $result{$columns[$i]} = \%column_info;
1493   }
1494   $sth->finish;
1495
1496   foreach my $col (keys %result) {
1497     my $colinfo = $result{$col};
1498     my $type_num = $colinfo->{data_type};
1499     my $type_name;
1500     if(defined $type_num && $dbh->can('type_info')) {
1501       my $type_info = $dbh->type_info($type_num);
1502       $type_name = $type_info->{TYPE_NAME} if $type_info;
1503       $colinfo->{data_type} = $type_name if $type_name;
1504     }
1505   }
1506
1507   return \%result;
1508 }
1509
1510 sub columns_info_for {
1511   my ($self, $table) = @_;
1512   $self->dbh_do('_dbh_columns_info_for', $table);
1513 }
1514
1515 =head2 last_insert_id
1516
1517 Return the row id of the last insert.
1518
1519 =cut
1520
1521 sub _dbh_last_insert_id {
1522     # All Storage's need to register their own _dbh_last_insert_id
1523     # the old SQLite-based method was highly inappropriate
1524
1525     my $self = shift;
1526     my $class = ref $self;
1527     $self->throw_exception (<<EOE);
1528
1529 No _dbh_last_insert_id() method found in $class.
1530 Since the method of obtaining the autoincrement id of the last insert
1531 operation varies greatly between different databases, this method must be
1532 individually implemented for every storage class.
1533 EOE
1534 }
1535
1536 sub last_insert_id {
1537   my $self = shift;
1538   $self->dbh_do('_dbh_last_insert_id', @_);
1539 }
1540
1541 =head2 sqlt_type
1542
1543 Returns the database driver name.
1544
1545 =cut
1546
1547 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1548
1549 =head2 bind_attribute_by_data_type
1550
1551 Given a datatype from column info, returns a database specific bind
1552 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1553 let the database planner just handle it.
1554
1555 Generally only needed for special case column types, like bytea in postgres.
1556
1557 =cut
1558
1559 sub bind_attribute_by_data_type {
1560     return;
1561 }
1562
1563 =head2 create_ddl_dir (EXPERIMENTAL)
1564
1565 =over 4
1566
1567 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1568
1569 =back
1570
1571 Creates a SQL file based on the Schema, for each of the specified
1572 database engines in C<\@databases> in the given directory.
1573 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
1574
1575 Given a previous version number, this will also create a file containing
1576 the ALTER TABLE statements to transform the previous schema into the
1577 current one. Note that these statements may contain C<DROP TABLE> or
1578 C<DROP COLUMN> statements that can potentially destroy data.
1579
1580 The file names are created using the C<ddl_filename> method below, please
1581 override this method in your schema if you would like a different file
1582 name format. For the ALTER file, the same format is used, replacing
1583 $version in the name with "$preversion-$version".
1584
1585 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
1586 The most common value for this would be C<< { add_drop_table => 1 } >>
1587 to have the SQL produced include a C<DROP TABLE> statement for each table
1588 created. For quoting purposes supply C<quote_table_names> and
1589 C<quote_field_names>.
1590
1591 If no arguments are passed, then the following default values are assumed:
1592
1593 =over 4
1594
1595 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
1596
1597 =item version    - $schema->schema_version
1598
1599 =item directory  - './'
1600
1601 =item preversion - <none>
1602
1603 =back
1604
1605 By default, C<\%sqlt_args> will have
1606
1607  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1608
1609 merged with the hash passed in. To disable any of those features, pass in a
1610 hashref like the following
1611
1612  { ignore_constraint_names => 0, # ... other options }
1613
1614
1615 Note that this feature is currently EXPERIMENTAL and may not work correctly
1616 across all databases, or fully handle complex relationships.
1617
1618 WARNING: Please check all SQL files created, before applying them.
1619
1620 =cut
1621
1622 sub create_ddl_dir {
1623   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1624
1625   if(!$dir || !-d $dir) {
1626     carp "No directory given, using ./\n";
1627     $dir = "./";
1628   }
1629   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1630   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1631
1632   my $schema_version = $schema->schema_version || '1.x';
1633   $version ||= $schema_version;
1634
1635   $sqltargs = {
1636     add_drop_table => 1,
1637     ignore_constraint_names => 1,
1638     ignore_index_names => 1,
1639     %{$sqltargs || {}}
1640   };
1641
1642   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1643       . $self->_check_sqlt_message . q{'})
1644           if !$self->_check_sqlt_version;
1645
1646   my $sqlt = SQL::Translator->new( $sqltargs );
1647
1648   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1649   my $sqlt_schema = $sqlt->translate({ data => $schema })
1650     or $self->throw_exception ($sqlt->error);
1651
1652   foreach my $db (@$databases) {
1653     $sqlt->reset();
1654     $sqlt->{schema} = $sqlt_schema;
1655     $sqlt->producer($db);
1656
1657     my $file;
1658     my $filename = $schema->ddl_filename($db, $version, $dir);
1659     if (-e $filename && ($version eq $schema_version )) {
1660       # if we are dumping the current version, overwrite the DDL
1661       carp "Overwriting existing DDL file - $filename";
1662       unlink($filename);
1663     }
1664
1665     my $output = $sqlt->translate;
1666     if(!$output) {
1667       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1668       next;
1669     }
1670     if(!open($file, ">$filename")) {
1671       $self->throw_exception("Can't open $filename for writing ($!)");
1672       next;
1673     }
1674     print $file $output;
1675     close($file);
1676
1677     next unless ($preversion);
1678
1679     require SQL::Translator::Diff;
1680
1681     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1682     if(!-e $prefilename) {
1683       carp("No previous schema file found ($prefilename)");
1684       next;
1685     }
1686
1687     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1688     if(-e $difffile) {
1689       carp("Overwriting existing diff file - $difffile");
1690       unlink($difffile);
1691     }
1692
1693     my $source_schema;
1694     {
1695       my $t = SQL::Translator->new($sqltargs);
1696       $t->debug( 0 );
1697       $t->trace( 0 );
1698
1699       $t->parser( $db )
1700         or $self->throw_exception ($t->error);
1701
1702       my $out = $t->translate( $prefilename )
1703         or $self->throw_exception ($t->error);
1704
1705       $source_schema = $t->schema;
1706
1707       $source_schema->name( $prefilename )
1708         unless ( $source_schema->name );
1709     }
1710
1711     # The "new" style of producers have sane normalization and can support
1712     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1713     # And we have to diff parsed SQL against parsed SQL.
1714     my $dest_schema = $sqlt_schema;
1715
1716     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1717       my $t = SQL::Translator->new($sqltargs);
1718       $t->debug( 0 );
1719       $t->trace( 0 );
1720
1721       $t->parser( $db )
1722         or $self->throw_exception ($t->error);
1723
1724       my $out = $t->translate( $filename )
1725         or $self->throw_exception ($t->error);
1726
1727       $dest_schema = $t->schema;
1728
1729       $dest_schema->name( $filename )
1730         unless $dest_schema->name;
1731     }
1732
1733     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1734                                                   $dest_schema,   $db,
1735                                                   $sqltargs
1736                                                  );
1737     if(!open $file, ">$difffile") {
1738       $self->throw_exception("Can't write to $difffile ($!)");
1739       next;
1740     }
1741     print $file $diff;
1742     close($file);
1743   }
1744 }
1745
1746 =head2 deployment_statements
1747
1748 =over 4
1749
1750 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1751
1752 =back
1753
1754 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1755
1756 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
1757 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
1758
1759 C<$directory> is used to return statements from files in a previously created
1760 L</create_ddl_dir> directory and is optional. The filenames are constructed
1761 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1762
1763 If no C<$directory> is specified then the statements are constructed on the
1764 fly using L<SQL::Translator> and C<$version> is ignored.
1765
1766 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1767
1768 =cut
1769
1770 sub deployment_statements {
1771   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1772   # Need to be connected to get the correct sqlt_type
1773   $self->ensure_connected() unless $type;
1774   $type ||= $self->sqlt_type;
1775   $version ||= $schema->schema_version || '1.x';
1776   $dir ||= './';
1777   my $filename = $schema->ddl_filename($type, $version, $dir);
1778   if(-f $filename)
1779   {
1780       my $file;
1781       open($file, "<$filename")
1782         or $self->throw_exception("Can't open $filename ($!)");
1783       my @rows = <$file>;
1784       close($file);
1785       return join('', @rows);
1786   }
1787
1788   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1789       . $self->_check_sqlt_message . q{'})
1790           if !$self->_check_sqlt_version;
1791
1792   require SQL::Translator::Parser::DBIx::Class;
1793   eval qq{use SQL::Translator::Producer::${type}};
1794   $self->throw_exception($@) if $@;
1795
1796   # sources needs to be a parser arg, but for simplicty allow at top level
1797   # coming in
1798   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1799       if exists $sqltargs->{sources};
1800
1801   my $tr = SQL::Translator->new(%$sqltargs);
1802   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1803   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1804 }
1805
1806 sub deploy {
1807   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1808   my $deploy = sub {
1809     my $line = shift;
1810     return if($line =~ /^--/);
1811     return if(!$line);
1812     # next if($line =~ /^DROP/m);
1813     return if($line =~ /^BEGIN TRANSACTION/m);
1814     return if($line =~ /^COMMIT/m);
1815     return if $line =~ /^\s+$/; # skip whitespace only
1816     $self->_query_start($line);
1817     eval {
1818       $self->dbh->do($line); # shouldn't be using ->dbh ?
1819     };
1820     if ($@) {
1821       carp qq{$@ (running "${line}")};
1822     }
1823     $self->_query_end($line);
1824   };
1825   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
1826   if (@statements > 1) {
1827     foreach my $statement (@statements) {
1828       $deploy->( $statement );
1829     }
1830   }
1831   elsif (@statements == 1) {
1832     foreach my $line ( split(";\n", $statements[0])) {
1833       $deploy->( $line );
1834     }
1835   }
1836 }
1837
1838 =head2 datetime_parser
1839
1840 Returns the datetime parser class
1841
1842 =cut
1843
1844 sub datetime_parser {
1845   my $self = shift;
1846   return $self->{datetime_parser} ||= do {
1847     $self->ensure_connected;
1848     $self->build_datetime_parser(@_);
1849   };
1850 }
1851
1852 =head2 datetime_parser_type
1853
1854 Defines (returns) the datetime parser class - currently hardwired to
1855 L<DateTime::Format::MySQL>
1856
1857 =cut
1858
1859 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1860
1861 =head2 build_datetime_parser
1862
1863 See L</datetime_parser>
1864
1865 =cut
1866
1867 sub build_datetime_parser {
1868   my $self = shift;
1869   my $type = $self->datetime_parser_type(@_);
1870   eval "use ${type}";
1871   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1872   return $type;
1873 }
1874
1875 {
1876     my $_check_sqlt_version; # private
1877     my $_check_sqlt_message; # private
1878     sub _check_sqlt_version {
1879         return $_check_sqlt_version if defined $_check_sqlt_version;
1880         eval 'use SQL::Translator "0.09003"';
1881         $_check_sqlt_message = $@ || '';
1882         $_check_sqlt_version = !$@;
1883     }
1884
1885     sub _check_sqlt_message {
1886         _check_sqlt_version if !defined $_check_sqlt_message;
1887         $_check_sqlt_message;
1888     }
1889 }
1890
1891 =head2 is_replicating
1892
1893 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1894 replicate from a master database.  Default is undef, which is the result
1895 returned by databases that don't support replication.
1896
1897 =cut
1898
1899 sub is_replicating {
1900     return;
1901
1902 }
1903
1904 =head2 lag_behind_master
1905
1906 Returns a number that represents a certain amount of lag behind a master db
1907 when a given storage is replicating.  The number is database dependent, but
1908 starts at zero and increases with the amount of lag. Default in undef
1909
1910 =cut
1911
1912 sub lag_behind_master {
1913     return;
1914 }
1915
1916 sub DESTROY {
1917   my $self = shift;
1918   return if !$self->_dbh;
1919   $self->_verify_pid;
1920   $self->_dbh(undef);
1921 }
1922
1923 1;
1924
1925 =head1 USAGE NOTES
1926
1927 =head2 DBIx::Class and AutoCommit
1928
1929 DBIx::Class can do some wonderful magic with handling exceptions,
1930 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1931 combined with C<txn_do> for transaction support.
1932
1933 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1934 in an assumed transaction between commits, and you're telling us you'd
1935 like to manage that manually.  A lot of the magic protections offered by
1936 this module will go away.  We can't protect you from exceptions due to database
1937 disconnects because we don't know anything about how to restart your
1938 transactions.  You're on your own for handling all sorts of exceptional
1939 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1940 be with raw DBI.
1941
1942
1943
1944 =head1 AUTHORS
1945
1946 Matt S. Trout <mst@shadowcatsystems.co.uk>
1947
1948 Andy Grundman <andy@hybridized.org>
1949
1950 =head1 LICENSE
1951
1952 You may distribute this code under the same terms as Perl itself.
1953
1954 =cut