lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  23 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  24
  25 BEGIN {
  26
  27 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  28
  29 use base qw/SQL::Abstract::Limit/;
  30
  31 # This prevents the caching of $dbh in S::A::L, I believe
  32 sub new {
  33   my $self = shift->SUPER::new(@_);
  34
  35   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  36   #   it with what it resolves to:
  37   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  38     if ref $self->{limit_dialect};
  39
  40   $self;
  41 }
  42
  43 sub _RowNumberOver {
  44   my ($self, $sql, $order, $rows, $offset ) = @_;
  45
  46   $offset += 1;
  47   my $last = $rows + $offset;
  48   my ( $order_by ) = $self->_order_by( $order );
  49
  50   $sql = <<"";
  51 SELECT * FROM
  52 (
  53    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  54       $sql
  55       $order_by
  56    ) Q1
  57 ) Q2
  58 WHERE ROW_NUM BETWEEN $offset AND $last
  59
  60   return $sql;
  61 }
  62
  63
  64 # While we're at it, this should make LIMIT queries more efficient,
  65 #  without digging into things too deeply
  66 use Scalar::Util 'blessed';
  67 sub _find_syntax {
  68   my ($self, $syntax) = @_;
  69   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  70   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  71     return 'RowNumberOver';
  72   }
  73
  74   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  75 }
  76
  77 sub select {
  78   my ($self, $table, $fields, $where, $order, @rest) = @_;
  79   $table = $self->_quote($table) unless ref($table);
  80   local $self->{rownum_hack_count} = 1
  81     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  82   @rest = (-1) unless defined $rest[0];
  83   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  84     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  85   local $self->{having_bind} = [];
  86   my ($sql, @ret) = $self->SUPER::select(
  87     $table, $self->_recurse_fields($fields), $where, $order, @rest
  88   );
  89   $sql .=
  90     $self->{for} ?
  91     (
  92       $self->{for} eq 'update' ? ' FOR UPDATE' :
  93       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  94       ''
  95     ) :
  96     ''
  97   ;
  98   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  99 }
 100
 101 sub insert {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::insert($table, @_);
 106 }
 107
 108 sub update {
 109   my $self = shift;
 110   my $table = shift;
 111   $table = $self->_quote($table) unless ref($table);
 112   $self->SUPER::update($table, @_);
 113 }
 114
 115 sub delete {
 116   my $self = shift;
 117   my $table = shift;
 118   $table = $self->_quote($table) unless ref($table);
 119   $self->SUPER::delete($table, @_);
 120 }
 121
 122 sub _emulate_limit {
 123   my $self = shift;
 124   if ($_[3] == -1) {
 125     return $_[1].$self->_order_by($_[2]);
 126   } else {
 127     return $self->SUPER::_emulate_limit(@_);
 128   }
 129 }
 130
 131 sub _recurse_fields {
 132   my ($self, $fields, $params) = @_;
 133   my $ref = ref $fields;
 134   return $self->_quote($fields) unless $ref;
 135   return $$fields if $ref eq 'SCALAR';
 136
 137   if ($ref eq 'ARRAY') {
 138     return join(', ', map {
 139       $self->_recurse_fields($_)
 140         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 141           ? ' AS col'.$self->{rownum_hack_count}++
 142           : '')
 143       } @$fields);
 144   } elsif ($ref eq 'HASH') {
 145     foreach my $func (keys %$fields) {
 146       return $self->_sqlcase($func)
 147         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 148     }
 149   }
 150 }
 151
 152 sub _order_by {
 153   my $self = shift;
 154   my $ret = '';
 155   my @extra;
 156   if (ref $_[0] eq 'HASH') {
 157     if (defined $_[0]->{group_by}) {
 158       $ret = $self->_sqlcase(' group by ')
 159         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 160     }
 161     if (defined $_[0]->{having}) {
 162       my $frag;
 163       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 164       push(@{$self->{having_bind}}, @extra);
 165       $ret .= $self->_sqlcase(' having ').$frag;
 166     }
 167     if (defined $_[0]->{order_by}) {
 168       $ret .= $self->_order_by($_[0]->{order_by});
 169     }
 170   } elsif (ref $_[0] eq 'SCALAR') {
 171     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 172   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 173     my @order = @{+shift};
 174     $ret = $self->_sqlcase(' order by ')
 175           .join(', ', map {
 176                         my $r = $self->_order_by($_, @_);
 177                         $r =~ s/^ ?ORDER BY //i;
 178                         $r;
 179                       } @order);
 180   } else {
 181     $ret = $self->SUPER::_order_by(@_);
 182   }
 183   return $ret;
 184 }
 185
 186 sub _order_directions {
 187   my ($self, $order) = @_;
 188   $order = $order->{order_by} if ref $order eq 'HASH';
 189   return $self->SUPER::_order_directions($order);
 190 }
 191
 192 sub _table {
 193   my ($self, $from) = @_;
 194   if (ref $from eq 'ARRAY') {
 195     return $self->_recurse_from(@$from);
 196   } elsif (ref $from eq 'HASH') {
 197     return $self->_make_as($from);
 198   } else {
 199     return $from; # would love to quote here but _table ends up getting called
 200                   # twice during an ->select without a limit clause due to
 201                   # the way S::A::Limit->select works. should maybe consider
 202                   # bypassing this and doing S::A::select($self, ...) in
 203                   # our select method above. meantime, quoting shims have
 204                   # been added to select/insert/update/delete here
 205   }
 206 }
 207
 208 sub _recurse_from {
 209   my ($self, $from, @join) = @_;
 210   my @sqlf;
 211   push(@sqlf, $self->_make_as($from));
 212   foreach my $j (@join) {
 213     my ($to, $on) = @$j;
 214
 215     # check whether a join type exists
 216     my $join_clause = '';
 217     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 218     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 219       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 220     } else {
 221       $join_clause = ' JOIN ';
 222     }
 223     push(@sqlf, $join_clause);
 224
 225     if (ref $to eq 'ARRAY') {
 226       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 227     } else {
 228       push(@sqlf, $self->_make_as($to));
 229     }
 230     push(@sqlf, ' ON ', $self->_join_condition($on));
 231   }
 232   return join('', @sqlf);
 233 }
 234
 235 sub _make_as {
 236   my ($self, $from) = @_;
 237   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 238                      reverse each %{$self->_skip_options($from)});
 239 }
 240
 241 sub _skip_options {
 242   my ($self, $hash) = @_;
 243   my $clean_hash = {};
 244   $clean_hash->{$_} = $hash->{$_}
 245     for grep {!/^-/} keys %$hash;
 246   return $clean_hash;
 247 }
 248
 249 sub _join_condition {
 250   my ($self, $cond) = @_;
 251   if (ref $cond eq 'HASH') {
 252     my %j;
 253     for (keys %$cond) {
 254       my $v = $cond->{$_};
 255       if (ref $v) {
 256         # XXX no throw_exception() in this package and croak() fails with strange results
 257         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 258             if ref($v) ne 'SCALAR';
 259         $j{$_} = $v;
 260       }
 261       else {
 262         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 263       }
 264     };
 265     return scalar($self->_recurse_where(\%j));
 266   } elsif (ref $cond eq 'ARRAY') {
 267     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 268   } else {
 269     die "Can't handle this yet!";
 270   }
 271 }
 272
 273 sub _quote {
 274   my ($self, $label) = @_;
 275   return '' unless defined $label;
 276   return "*" if $label eq '*';
 277   return $label unless $self->{quote_char};
 278   if(ref $self->{quote_char} eq "ARRAY"){
 279     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 280       if !defined $self->{name_sep};
 281     my $sep = $self->{name_sep};
 282     return join($self->{name_sep},
 283         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 284        split(/\Q$sep\E/,$label));
 285   }
 286   return $self->SUPER::_quote($label);
 287 }
 288
 289 sub limit_dialect {
 290     my $self = shift;
 291     $self->{limit_dialect} = shift if @_;
 292     return $self->{limit_dialect};
 293 }
 294
 295 sub quote_char {
 296     my $self = shift;
 297     $self->{quote_char} = shift if @_;
 298     return $self->{quote_char};
 299 }
 300
 301 sub name_sep {
 302     my $self = shift;
 303     $self->{name_sep} = shift if @_;
 304     return $self->{name_sep};
 305 }
 306
 307 } # End of BEGIN block
 308
 309 =head1 NAME
 310
 311 DBIx::Class::Storage::DBI - DBI storage handler
 312
 313 =head1 SYNOPSIS
 314
 315 =head1 DESCRIPTION
 316
 317 This class represents the connection to an RDBMS via L<DBI>.  See
 318 L<DBIx::Class::Storage> for general information.  This pod only
 319 documents DBI-specific methods and behaviors.
 320
 321 =head1 METHODS
 322
 323 =cut
 324
 325 sub new {
 326   my $new = shift->next::method(@_);
 327
 328   $new->transaction_depth(0);
 329   $new->_sql_maker_opts({});
 330   $new->{_in_dbh_do} = 0;
 331   $new->{_dbh_gen} = 0;
 332
 333   $new;
 334 }
 335
 336 =head2 connect_info
 337
 338 The arguments of C<connect_info> are always a single array reference.
 339
 340 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 341 encapsulates its argument list in an arrayref before calling
 342 C<connect_info> here.
 343
 344 The arrayref can either contain the same set of arguments one would
 345 normally pass to L<DBI/connect>, or a lone code reference which returns
 346 a connected database handle.  Please note that the L<DBI> docs
 347 recommend that you always explicitly set C<AutoCommit> to either
 348 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 349 to C<1>, and that you perform transactions via our L</txn_do>
 350 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 351 set it to zero.  This is the default for most DBDs.  See below for more
 352 details.
 353
 354 In either case, if the final argument in your connect_info happens
 355 to be a hashref, C<connect_info> will look there for several
 356 connection-specific options:
 357
 358 =over 4
 359
 360 =item on_connect_do
 361
 362 Specifies things to do immediately after connecting or re-connecting to
 363 the database.  Its value may contain:
 364
 365 =over
 366
 367 =item an array reference
 368
 369 This contains SQL statements to execute in order.  Each element contains
 370 a string or a code reference that returns a string.
 371
 372 =item a code reference
 373
 374 This contains some code to execute.  Unlike code references within an
 375 array reference, its return value is ignored.
 376
 377 =back
 378
 379 =item on_disconnect_do
 380
 381 Takes arguments in the same form as L<on_connect_do> and executes them
 382 immediately before disconnecting from the database.
 383
 384 Note, this only runs if you explicitly call L<disconnect> on the
 385 storage object.
 386
 387 =item disable_sth_caching
 388
 389 If set to a true value, this option will disable the caching of
 390 statement handles via L<DBI/prepare_cached>.
 391
 392 =item limit_dialect
 393
 394 Sets the limit dialect. This is useful for JDBC-bridge among others
 395 where the remote SQL-dialect cannot be determined by the name of the
 396 driver alone.
 397
 398 =item quote_char
 399
 400 Specifies what characters to use to quote table and column names. If
 401 you use this you will want to specify L<name_sep> as well.
 402
 403 quote_char expects either a single character, in which case is it is placed
 404 on either side of the table/column, or an arrayref of length 2 in which case the
 405 table/column name is placed between the elements.
 406
 407 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 408 use C<quote_char =E<gt> [qw/[ ]/]>.
 409
 410 =item name_sep
 411
 412 This only needs to be used in conjunction with L<quote_char>, and is used to
 413 specify the charecter that seperates elements (schemas, tables, columns) from
 414 each other. In most cases this is simply a C<.>.
 415
 416 =item unsafe
 417
 418 This Storage driver normally installs its own C<HandleError>, sets
 419 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 420 all database handles, including those supplied by a coderef.  It does this
 421 so that it can have consistent and useful error behavior.
 422
 423 If you set this option to a true value, Storage will not do its usual
 424 modifications to the database handle's attributes, and instead relies on
 425 the settings in your connect_info DBI options (or the values you set in
 426 your connection coderef, in the case that you are connecting via coderef).
 427
 428 Note that your custom settings can cause Storage to malfunction,
 429 especially if you set a C<HandleError> handler that suppresses exceptions
 430 and/or disable C<RaiseError>.
 431
 432 =back
 433
 434 These options can be mixed in with your other L<DBI> connection attributes,
 435 or placed in a seperate hashref after all other normal L<DBI> connection
 436 arguments.
 437
 438 Every time C<connect_info> is invoked, any previous settings for
 439 these options will be cleared before setting the new ones, regardless of
 440 whether any options are specified in the new C<connect_info>.
 441
 442 Another Important Note:
 443
 444 DBIC can do some wonderful magic with handling exceptions,
 445 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 446 combined with C<txn_do> for transaction support.
 447
 448 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 449 in an assumed transaction between commits, and you're telling us you'd
 450 like to manage that manually.  A lot of DBIC's magic protections
 451 go away.  We can't protect you from exceptions due to database
 452 disconnects because we don't know anything about how to restart your
 453 transactions.  You're on your own for handling all sorts of exceptional
 454 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 455 be with raw DBI.
 456
 457 Examples:
 458
 459   # Simple SQLite connection
 460   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 461
 462   # Connect via subref
 463   ->connect_info([ sub { DBI->connect(...) } ]);
 464
 465   # A bit more complicated
 466   ->connect_info(
 467     [
 468       'dbi:Pg:dbname=foo',
 469       'postgres',
 470       'my_pg_password',
 471       { AutoCommit => 1 },
 472       { quote_char => q{"}, name_sep => q{.} },
 473     ]
 474   );
 475
 476   # Equivalent to the previous example
 477   ->connect_info(
 478     [
 479       'dbi:Pg:dbname=foo',
 480       'postgres',
 481       'my_pg_password',
 482       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Subref + DBIC-specific connection options
 487   ->connect_info(
 488     [
 489       sub { DBI->connect(...) },
 490       {
 491           quote_char => q{`},
 492           name_sep => q{@},
 493           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 494           disable_sth_caching => 1,
 495       },
 496     ]
 497   );
 498
 499 =cut
 500
 501 sub connect_info {
 502   my ($self, $info_arg) = @_;
 503
 504   return $self->_connect_info if !$info_arg;
 505
 506   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 507   #  the new set of options
 508   $self->_sql_maker(undef);
 509   $self->_sql_maker_opts({});
 510   $self->_connect_info([@$info_arg]); # copy for _connect_info
 511
 512   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 513
 514   my $last_info = $dbi_info->[-1];
 515   if(ref $last_info eq 'HASH') {
 516     $last_info = { %$last_info }; # so delete is non-destructive
 517     my @storage_option = qw(
 518       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 519     );
 520     for my $storage_opt (@storage_option) {
 521       if(my $value = delete $last_info->{$storage_opt}) {
 522         $self->$storage_opt($value);
 523       }
 524     }
 525     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 526       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 527         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 528       }
 529     }
 530     # re-insert modified hashref
 531     $dbi_info->[-1] = $last_info;
 532
 533     # Get rid of any trailing empty hashref
 534     pop(@$dbi_info) if !keys %$last_info;
 535   }
 536   $self->_dbi_connect_info($dbi_info);
 537
 538   $self->_connect_info;
 539 }
 540
 541 =head2 on_connect_do
 542
 543 This method is deprecated in favor of setting via L</connect_info>.
 544
 545 =head2 dbh_do
 546
 547 Arguments: ($subref | $method_name), @extra_coderef_args?
 548
 549 Execute the given $subref or $method_name using the new exception-based
 550 connection management.
 551
 552 The first two arguments will be the storage object that C<dbh_do> was called
 553 on and a database handle to use.  Any additional arguments will be passed
 554 verbatim to the called subref as arguments 2 and onwards.
 555
 556 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 557 exception handling and reconnection (or failover in future subclasses).
 558
 559 Your subref should have no side-effects outside of the database, as
 560 there is the potential for your subref to be partially double-executed
 561 if the database connection was stale/dysfunctional.
 562
 563 Example:
 564
 565   my @stuff = $schema->storage->dbh_do(
 566     sub {
 567       my ($storage, $dbh, @cols) = @_;
 568       my $cols = join(q{, }, @cols);
 569       $dbh->selectrow_array("SELECT $cols FROM foo");
 570     },
 571     @column_list
 572   );
 573
 574 =cut
 575
 576 sub dbh_do {
 577   my $self = shift;
 578   my $code = shift;
 579
 580   my $dbh = $self->_dbh;
 581
 582   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 583       || $self->{transaction_depth};
 584
 585   local $self->{_in_dbh_do} = 1;
 586
 587   my @result;
 588   my $want_array = wantarray;
 589
 590   eval {
 591     $self->_verify_pid if $dbh;
 592     if( !$dbh ) {
 593         $self->_populate_dbh;
 594         $dbh = $self->_dbh;
 595     }
 596
 597     if($want_array) {
 598         @result = $self->$code($dbh, @_);
 599     }
 600     elsif(defined $want_array) {
 601         $result[0] = $self->$code($dbh, @_);
 602     }
 603     else {
 604         $self->$code($dbh, @_);
 605     }
 606   };
 607
 608   my $exception = $@;
 609   if(!$exception) { return $want_array ? @result : $result[0] }
 610
 611   $self->throw_exception($exception) if $self->connected;
 612
 613   # We were not connected - reconnect and retry, but let any
 614   #  exception fall right through this time
 615   $self->_populate_dbh;
 616   $self->$code($self->_dbh, @_);
 617 }
 618
 619 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 620 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 621 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 622 sub txn_do {
 623   my $self = shift;
 624   my $coderef = shift;
 625
 626   ref $coderef eq 'CODE' or $self->throw_exception
 627     ('$coderef must be a CODE reference');
 628
 629   return $coderef->(@_) if $self->{transaction_depth};
 630
 631   local $self->{_in_dbh_do} = 1;
 632
 633   my @result;
 634   my $want_array = wantarray;
 635
 636   my $tried = 0;
 637   while(1) {
 638     eval {
 639       $self->_verify_pid if $self->_dbh;
 640       $self->_populate_dbh if !$self->_dbh;
 641
 642       $self->txn_begin;
 643       if($want_array) {
 644           @result = $coderef->(@_);
 645       }
 646       elsif(defined $want_array) {
 647           $result[0] = $coderef->(@_);
 648       }
 649       else {
 650           $coderef->(@_);
 651       }
 652       $self->txn_commit;
 653     };
 654
 655     my $exception = $@;
 656     if(!$exception) { return $want_array ? @result : $result[0] }
 657
 658     if($tried++ > 0 || $self->connected) {
 659       eval { $self->txn_rollback };
 660       my $rollback_exception = $@;
 661       if($rollback_exception) {
 662         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 663         $self->throw_exception($exception)  # propagate nested rollback
 664           if $rollback_exception =~ /$exception_class/;
 665
 666         $self->throw_exception(
 667           "Transaction aborted: ${exception}. "
 668           . "Rollback failed: ${rollback_exception}"
 669         );
 670       }
 671       $self->throw_exception($exception)
 672     }
 673
 674     # We were not connected, and was first try - reconnect and retry
 675     # via the while loop
 676     $self->_populate_dbh;
 677   }
 678 }
 679
 680 =head2 disconnect
 681
 682 Our C<disconnect> method also performs a rollback first if the
 683 database is not in C<AutoCommit> mode.
 684
 685 =cut
 686
 687 sub disconnect {
 688   my ($self) = @_;
 689
 690   if( $self->connected ) {
 691     my $connection_do = $self->on_disconnect_do;
 692     $self->_do_connection_actions($connection_do) if ref($connection_do);
 693
 694     $self->_dbh->rollback unless $self->_dbh_autocommit;
 695     $self->_dbh->disconnect;
 696     $self->_dbh(undef);
 697     $self->{_dbh_gen}++;
 698   }
 699 }
 700
 701 sub connected {
 702   my ($self) = @_;
 703
 704   if(my $dbh = $self->_dbh) {
 705       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 706           $self->_dbh(undef);
 707           $self->{_dbh_gen}++;
 708           return;
 709       }
 710       else {
 711           $self->_verify_pid;
 712           return 0 if !$self->_dbh;
 713       }
 714       return ($dbh->FETCH('Active') && $dbh->ping);
 715   }
 716
 717   return 0;
 718 }
 719
 720 # handle pid changes correctly
 721 #  NOTE: assumes $self->_dbh is a valid $dbh
 722 sub _verify_pid {
 723   my ($self) = @_;
 724
 725   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 726
 727   $self->_dbh->{InactiveDestroy} = 1;
 728   $self->_dbh(undef);
 729   $self->{_dbh_gen}++;
 730
 731   return;
 732 }
 733
 734 sub ensure_connected {
 735   my ($self) = @_;
 736
 737   unless ($self->connected) {
 738     $self->_populate_dbh;
 739   }
 740 }
 741
 742 =head2 dbh
 743
 744 Returns the dbh - a data base handle of class L<DBI>.
 745
 746 =cut
 747
 748 sub dbh {
 749   my ($self) = @_;
 750
 751   $self->ensure_connected;
 752   return $self->_dbh;
 753 }
 754
 755 sub _sql_maker_args {
 756     my ($self) = @_;
 757
 758     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 759 }
 760
 761 sub sql_maker {
 762   my ($self) = @_;
 763   unless ($self->_sql_maker) {
 764     my $sql_maker_class = $self->sql_maker_class;
 765     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 766   }
 767   return $self->_sql_maker;
 768 }
 769
 770 sub _rebless {}
 771
 772 sub _populate_dbh {
 773   my ($self) = @_;
 774   my @info = @{$self->_dbi_connect_info || []};
 775   $self->_dbh($self->_connect(@info));
 776
 777   # Always set the transaction depth on connect, since
 778   #  there is no transaction in progress by definition
 779   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 780
 781   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 782     my $driver = $self->_dbh->{Driver}->{Name};
 783     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 784       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 785       $self->_rebless();
 786     }
 787   }
 788
 789   my $connection_do = $self->on_connect_do;
 790   $self->_do_connection_actions($connection_do) if ref($connection_do);
 791
 792   $self->_conn_pid($$);
 793   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 794 }
 795
 796 sub _do_connection_actions {
 797   my $self = shift;
 798   my $connection_do = shift;
 799
 800   if (ref $connection_do eq 'ARRAY') {
 801     $self->_do_query($_) foreach @$connection_do;
 802   }
 803   elsif (ref $connection_do eq 'CODE') {
 804     $connection_do->();
 805   }
 806
 807   return $self;
 808 }
 809
 810 sub _do_query {
 811   my ($self, $action) = @_;
 812
 813   if (ref $action eq 'CODE') {
 814     $action = $action->($self);
 815     $self->_do_query($_) foreach @$action;
 816   }
 817   else {
 818     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 819     $self->_query_start(@to_run);
 820     $self->_dbh->do(@to_run);
 821     $self->_query_end(@to_run);
 822   }
 823
 824   return $self;
 825 }
 826
 827 sub _connect {
 828   my ($self, @info) = @_;
 829
 830   $self->throw_exception("You failed to provide any connection info")
 831     if !@info;
 832
 833   my ($old_connect_via, $dbh);
 834
 835   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 836     $old_connect_via = $DBI::connect_via;
 837     $DBI::connect_via = 'connect';
 838   }
 839
 840   eval {
 841     if(ref $info[0] eq 'CODE') {
 842        $dbh = &{$info[0]}
 843     }
 844     else {
 845        $dbh = DBI->connect(@info);
 846     }
 847
 848     if($dbh && !$self->unsafe) {
 849       my $weak_self = $self;
 850       weaken($weak_self);
 851       $dbh->{HandleError} = sub {
 852           $weak_self->throw_exception("DBI Exception: $_[0]")
 853       };
 854       $dbh->{ShowErrorStatement} = 1;
 855       $dbh->{RaiseError} = 1;
 856       $dbh->{PrintError} = 0;
 857     }
 858   };
 859
 860   $DBI::connect_via = $old_connect_via if $old_connect_via;
 861
 862   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 863     if !$dbh || $@;
 864
 865   $self->_dbh_autocommit($dbh->{AutoCommit});
 866
 867   $dbh;
 868 }
 869
 870
 871 sub txn_begin {
 872   my $self = shift;
 873   $self->ensure_connected();
 874   if($self->{transaction_depth} == 0) {
 875     $self->debugobj->txn_begin()
 876       if $self->debug;
 877     # this isn't ->_dbh-> because
 878     #  we should reconnect on begin_work
 879     #  for AutoCommit users
 880     $self->dbh->begin_work;
 881   }
 882   $self->{transaction_depth}++;
 883 }
 884
 885 sub txn_commit {
 886   my $self = shift;
 887   if ($self->{transaction_depth} == 1) {
 888     my $dbh = $self->_dbh;
 889     $self->debugobj->txn_commit()
 890       if ($self->debug);
 891     $dbh->commit;
 892     $self->{transaction_depth} = 0
 893       if $self->_dbh_autocommit;
 894   }
 895   elsif($self->{transaction_depth} > 1) {
 896     $self->{transaction_depth}--
 897   }
 898 }
 899
 900 sub txn_rollback {
 901   my $self = shift;
 902   my $dbh = $self->_dbh;
 903   eval {
 904     if ($self->{transaction_depth} == 1) {
 905       $self->debugobj->txn_rollback()
 906         if ($self->debug);
 907       $self->{transaction_depth} = 0
 908         if $self->_dbh_autocommit;
 909       $dbh->rollback;
 910     }
 911     elsif($self->{transaction_depth} > 1) {
 912       $self->{transaction_depth}--;
 913     }
 914     else {
 915       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 916     }
 917   };
 918   if ($@) {
 919     my $error = $@;
 920     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 921     $error =~ /$exception_class/ and $self->throw_exception($error);
 922     # ensure that a failed rollback resets the transaction depth
 923     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 924     $self->throw_exception($error);
 925   }
 926 }
 927
 928 # This used to be the top-half of _execute.  It was split out to make it
 929 #  easier to override in NoBindVars without duping the rest.  It takes up
 930 #  all of _execute's args, and emits $sql, @bind.
 931 sub _prep_for_execute {
 932   my ($self, $op, $extra_bind, $ident, $args) = @_;
 933
 934   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 935   unshift(@bind,
 936     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 937       if $extra_bind;
 938
 939   return ($sql, \@bind);
 940 }
 941
 942 sub _fix_bind_params {
 943     my ($self, @bind) = @_;
 944
 945     ### Turn @bind from something like this:
 946     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 947     ### to this:
 948     ###   ( "'1'", "'1'", "'3'" )
 949     return
 950         map {
 951             if ( defined( $_ && $_->[1] ) ) {
 952                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 953             }
 954             else { q{'NULL'}; }
 955         } @bind;
 956 }
 957
 958 sub _query_start {
 959     my ( $self, $sql, @bind ) = @_;
 960
 961     if ( $self->debug ) {
 962         @bind = $self->_fix_bind_params(@bind);
 963         $self->debugobj->query_start( $sql, @bind );
 964     }
 965 }
 966
 967 sub _query_end {
 968     my ( $self, $sql, @bind ) = @_;
 969
 970     if ( $self->debug ) {
 971         @bind = $self->_fix_bind_params(@bind);
 972         $self->debugobj->query_end( $sql, @bind );
 973     }
 974 }
 975
 976 sub _dbh_execute {
 977   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 978
 979   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 980     $ident = $ident->from();
 981   }
 982
 983   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 984
 985   $self->_query_start( $sql, @$bind );
 986
 987   my $sth = $self->sth($sql,$op);
 988
 989   my $placeholder_index = 1;
 990
 991   foreach my $bound (@$bind) {
 992     my $attributes = {};
 993     my($column_name, @data) = @$bound;
 994
 995     if ($bind_attributes) {
 996       $attributes = $bind_attributes->{$column_name}
 997       if defined $bind_attributes->{$column_name};
 998     }
 999
1000     foreach my $data (@data) {
1001       $data = ref $data ? ''.$data : $data; # stringify args
1002
1003       $sth->bind_param($placeholder_index, $data, $attributes);
1004       $placeholder_index++;
1005     }
1006   }
1007
1008   # Can this fail without throwing an exception anyways???
1009   my $rv = $sth->execute();
1010   $self->throw_exception($sth->errstr) if !$rv;
1011
1012   $self->_query_end( $sql, @$bind );
1013
1014   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1015 }
1016
1017 sub _execute {
1018     my $self = shift;
1019     $self->dbh_do('_dbh_execute', @_)
1020 }
1021
1022 sub insert {
1023   my ($self, $source, $to_insert) = @_;
1024
1025   my $ident = $source->from;
1026   my $bind_attributes = $self->source_bind_attributes($source);
1027
1028   foreach my $col ( $source->columns ) {
1029     if ( !defined $to_insert->{$col} ) {
1030       my $col_info = $source->column_info($col);
1031
1032       if ( $col_info->{auto_nextval} ) {
1033         $self->ensure_connected;
1034         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1035       }
1036     }
1037   }
1038
1039   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1040
1041   return $to_insert;
1042 }
1043
1044 ## Still not quite perfect, and EXPERIMENTAL
1045 ## Currently it is assumed that all values passed will be "normal", i.e. not
1046 ## scalar refs, or at least, all the same type as the first set, the statement is
1047 ## only prepped once.
1048 sub insert_bulk {
1049   my ($self, $source, $cols, $data) = @_;
1050   my %colvalues;
1051   my $table = $source->from;
1052   @colvalues{@$cols} = (0..$#$cols);
1053   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1054
1055   $self->_query_start( $sql, @bind );
1056   my $sth = $self->sth($sql);
1057
1058 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1059
1060   ## This must be an arrayref, else nothing works!
1061
1062   my $tuple_status = [];
1063
1064   ##use Data::Dumper;
1065   ##print STDERR Dumper( $data, $sql, [@bind] );
1066
1067   my $time = time();
1068
1069   ## Get the bind_attributes, if any exist
1070   my $bind_attributes = $self->source_bind_attributes($source);
1071
1072   ## Bind the values and execute
1073   my $placeholder_index = 1;
1074
1075   foreach my $bound (@bind) {
1076
1077     my $attributes = {};
1078     my ($column_name, $data_index) = @$bound;
1079
1080     if( $bind_attributes ) {
1081       $attributes = $bind_attributes->{$column_name}
1082       if defined $bind_attributes->{$column_name};
1083     }
1084
1085     my @data = map { $_->[$data_index] } @$data;
1086
1087     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1088     $placeholder_index++;
1089   }
1090   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1091   $self->throw_exception($sth->errstr) if !$rv;
1092
1093   $self->_query_end( $sql, @bind );
1094   return (wantarray ? ($rv, $sth, @bind) : $rv);
1095 }
1096
1097 sub update {
1098   my $self = shift @_;
1099   my $source = shift @_;
1100   my $bind_attributes = $self->source_bind_attributes($source);
1101
1102   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1103 }
1104
1105
1106 sub delete {
1107   my $self = shift @_;
1108   my $source = shift @_;
1109
1110   my $bind_attrs = {}; ## If ever it's needed...
1111
1112   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1113 }
1114
1115 sub _select {
1116   my ($self, $ident, $select, $condition, $attrs) = @_;
1117   my $order = $attrs->{order_by};
1118
1119   if (ref $condition eq 'SCALAR') {
1120     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1121   }
1122
1123   my $for = delete $attrs->{for};
1124   my $sql_maker = $self->sql_maker;
1125   local $sql_maker->{for} = $for;
1126
1127   if (exists $attrs->{group_by} || $attrs->{having}) {
1128     $order = {
1129       group_by => $attrs->{group_by},
1130       having => $attrs->{having},
1131       ($order ? (order_by => $order) : ())
1132     };
1133   }
1134   my $bind_attrs = {}; ## Future support
1135   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1136   if ($attrs->{software_limit} ||
1137       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1138         $attrs->{software_limit} = 1;
1139   } else {
1140     $self->throw_exception("rows attribute must be positive if present")
1141       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1142
1143     # MySQL actually recommends this approach.  I cringe.
1144     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1145     push @args, $attrs->{rows}, $attrs->{offset};
1146   }
1147
1148   return $self->_execute(@args);
1149 }
1150
1151 sub source_bind_attributes {
1152   my ($self, $source) = @_;
1153
1154   my $bind_attributes;
1155   foreach my $column ($source->columns) {
1156
1157     my $data_type = $source->column_info($column)->{data_type} || '';
1158     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1159      if $data_type;
1160   }
1161
1162   return $bind_attributes;
1163 }
1164
1165 =head2 select
1166
1167 =over 4
1168
1169 =item Arguments: $ident, $select, $condition, $attrs
1170
1171 =back
1172
1173 Handle a SQL select statement.
1174
1175 =cut
1176
1177 sub select {
1178   my $self = shift;
1179   my ($ident, $select, $condition, $attrs) = @_;
1180   return $self->cursor_class->new($self, \@_, $attrs);
1181 }
1182
1183 sub select_single {
1184   my $self = shift;
1185   my ($rv, $sth, @bind) = $self->_select(@_);
1186   my @row = $sth->fetchrow_array;
1187   # Need to call finish() to work round broken DBDs
1188   $sth->finish();
1189   return @row;
1190 }
1191
1192 =head2 sth
1193
1194 =over 4
1195
1196 =item Arguments: $sql
1197
1198 =back
1199
1200 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1201
1202 =cut
1203
1204 sub _dbh_sth {
1205   my ($self, $dbh, $sql) = @_;
1206
1207   # 3 is the if_active parameter which avoids active sth re-use
1208   my $sth = $self->disable_sth_caching
1209     ? $dbh->prepare($sql)
1210     : $dbh->prepare_cached($sql, {}, 3);
1211
1212   # XXX You would think RaiseError would make this impossible,
1213   #  but apparently that's not true :(
1214   $self->throw_exception($dbh->errstr) if !$sth;
1215
1216   $sth;
1217 }
1218
1219 sub sth {
1220   my ($self, $sql) = @_;
1221   $self->dbh_do('_dbh_sth', $sql);
1222 }
1223
1224 sub _dbh_columns_info_for {
1225   my ($self, $dbh, $table) = @_;
1226
1227   if ($dbh->can('column_info')) {
1228     my %result;
1229     eval {
1230       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1231       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1232       $sth->execute();
1233       while ( my $info = $sth->fetchrow_hashref() ){
1234         my %column_info;
1235         $column_info{data_type}   = $info->{TYPE_NAME};
1236         $column_info{size}      = $info->{COLUMN_SIZE};
1237         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1238         $column_info{default_value} = $info->{COLUMN_DEF};
1239         my $col_name = $info->{COLUMN_NAME};
1240         $col_name =~ s/^\"(.*)\"$/$1/;
1241
1242         $result{$col_name} = \%column_info;
1243       }
1244     };
1245     return \%result if !$@ && scalar keys %result;
1246   }
1247
1248   my %result;
1249   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1250   $sth->execute;
1251   my @columns = @{$sth->{NAME_lc}};
1252   for my $i ( 0 .. $#columns ){
1253     my %column_info;
1254     $column_info{data_type} = $sth->{TYPE}->[$i];
1255     $column_info{size} = $sth->{PRECISION}->[$i];
1256     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1257
1258     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1259       $column_info{data_type} = $1;
1260       $column_info{size}    = $2;
1261     }
1262
1263     $result{$columns[$i]} = \%column_info;
1264   }
1265   $sth->finish;
1266
1267   foreach my $col (keys %result) {
1268     my $colinfo = $result{$col};
1269     my $type_num = $colinfo->{data_type};
1270     my $type_name;
1271     if(defined $type_num && $dbh->can('type_info')) {
1272       my $type_info = $dbh->type_info($type_num);
1273       $type_name = $type_info->{TYPE_NAME} if $type_info;
1274       $colinfo->{data_type} = $type_name if $type_name;
1275     }
1276   }
1277
1278   return \%result;
1279 }
1280
1281 sub columns_info_for {
1282   my ($self, $table) = @_;
1283   $self->dbh_do('_dbh_columns_info_for', $table);
1284 }
1285
1286 =head2 last_insert_id
1287
1288 Return the row id of the last insert.
1289
1290 =cut
1291
1292 sub _dbh_last_insert_id {
1293     my ($self, $dbh, $source, $col) = @_;
1294     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1295     $dbh->func('last_insert_rowid');
1296 }
1297
1298 sub last_insert_id {
1299   my $self = shift;
1300   $self->dbh_do('_dbh_last_insert_id', @_);
1301 }
1302
1303 =head2 sqlt_type
1304
1305 Returns the database driver name.
1306
1307 =cut
1308
1309 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1310
1311 =head2 bind_attribute_by_data_type
1312
1313 Given a datatype from column info, returns a database specific bind attribute for
1314 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1315 just handle it.
1316
1317 Generally only needed for special case column types, like bytea in postgres.
1318
1319 =cut
1320
1321 sub bind_attribute_by_data_type {
1322     return;
1323 }
1324
1325 =head2 create_ddl_dir
1326
1327 =over 4
1328
1329 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1330
1331 =back
1332
1333 Creates a SQL file based on the Schema, for each of the specified
1334 database types, in the given directory.
1335
1336 =cut
1337
1338 sub create_ddl_dir
1339 {
1340   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1341
1342   if(!$dir || !-d $dir)
1343   {
1344     warn "No directory given, using ./\n";
1345     $dir = "./";
1346   }
1347   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1348   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1349   $version ||= $schema->VERSION || '1.x';
1350   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1351
1352   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1353       . $self->_check_sqlt_message . q{'})
1354           if !$self->_check_sqlt_version;
1355
1356   my $sqlt = SQL::Translator->new( $sqltargs );
1357
1358   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1359   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1360
1361   foreach my $db (@$databases)
1362   {
1363     $sqlt->reset();
1364     $sqlt = $self->configure_sqlt($sqlt, $db);
1365     $sqlt->{schema} = $sqlt_schema;
1366     $sqlt->producer($db);
1367
1368     my $file;
1369     my $filename = $schema->ddl_filename($db, $dir, $version);
1370     if(-e $filename)
1371     {
1372       warn("$filename already exists, skipping $db");
1373       next unless ($preversion);
1374     } else {
1375       my $output = $sqlt->translate;
1376       if(!$output)
1377       {
1378         warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1379         next;
1380       }
1381       if(!open($file, ">$filename"))
1382       {
1383           $self->throw_exception("Can't open $filename for writing ($!)");
1384           next;
1385       }
1386       print $file $output;
1387       close($file);
1388     }
1389     if($preversion)
1390     {
1391       require SQL::Translator::Diff;
1392
1393       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1394 #      print "Previous version $prefilename\n";
1395       if(!-e $prefilename)
1396       {
1397         warn("No previous schema file found ($prefilename)");
1398         next;
1399       }
1400
1401       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1402       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1403       if(-e $difffile)
1404       {
1405         warn("$difffile already exists, skipping");
1406         next;
1407       }
1408
1409       my $source_schema;
1410       {
1411         my $t = SQL::Translator->new($sqltargs);
1412         $t->debug( 0 );
1413         $t->trace( 0 );
1414         $t->parser( $db )                       or die $t->error;
1415         $t = $self->configure_sqlt($t, $db);
1416         my $out = $t->translate( $prefilename ) or die $t->error;
1417         $source_schema = $t->schema;
1418         unless ( $source_schema->name ) {
1419           $source_schema->name( $prefilename );
1420         }
1421       }
1422
1423       # The "new" style of producers have sane normalization and can support
1424       # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1425       # And we have to diff parsed SQL against parsed SQL.
1426       my $dest_schema = $sqlt_schema;
1427
1428       unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1429         my $t = SQL::Translator->new($sqltargs);
1430         $t->debug( 0 );
1431         $t->trace( 0 );
1432         $t->parser( $db )                    or die $t->error;
1433         $t = $self->configure_sqlt($t, $db);
1434         my $out = $t->translate( $filename ) or die $t->error;
1435         $dest_schema = $t->schema;
1436         $dest_schema->name( $filename )
1437           unless $dest_schema->name;
1438       }
1439
1440       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1441                                                     $dest_schema,   $db,
1442                                                     $sqltargs
1443                                                    );
1444       if(!open $file, ">$difffile")
1445       {
1446         $self->throw_exception("Can't write to $difffile ($!)");
1447         next;
1448       }
1449       print $file $diff;
1450       close($file);
1451     }
1452   }
1453 }
1454
1455 sub configure_sqlt() {
1456   my $self = shift;
1457   my $tr = shift;
1458   my $db = shift || $self->sqlt_type;
1459   if ($db eq 'PostgreSQL') {
1460     $tr->quote_table_names(0);
1461     $tr->quote_field_names(0);
1462   }
1463   return $tr;
1464 }
1465
1466 =head2 deployment_statements
1467
1468 =over 4
1469
1470 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1471
1472 =back
1473
1474 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1475 The database driver name is given by C<$type>, though the value from
1476 L</sqlt_type> is used if it is not specified.
1477
1478 C<$directory> is used to return statements from files in a previously created
1479 L</create_ddl_dir> directory and is optional. The filenames are constructed
1480 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1481
1482 If no C<$directory> is specified then the statements are constructed on the
1483 fly using L<SQL::Translator> and C<$version> is ignored.
1484
1485 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1486
1487 =cut
1488
1489 sub deployment_statements {
1490   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1491   # Need to be connected to get the correct sqlt_type
1492   $self->ensure_connected() unless $type;
1493   $type ||= $self->sqlt_type;
1494   $version ||= $schema->VERSION || '1.x';
1495   $dir ||= './';
1496   my $filename = $schema->ddl_filename($type, $dir, $version);
1497   if(-f $filename)
1498   {
1499       my $file;
1500       open($file, "<$filename")
1501         or $self->throw_exception("Can't open $filename ($!)");
1502       my @rows = <$file>;
1503       close($file);
1504       return join('', @rows);
1505   }
1506
1507   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1508       . $self->_check_sqlt_message . q{'})
1509           if !$self->_check_sqlt_version;
1510
1511   require SQL::Translator::Parser::DBIx::Class;
1512   eval qq{use SQL::Translator::Producer::${type}};
1513   $self->throw_exception($@) if $@;
1514
1515   # sources needs to be a parser arg, but for simplicty allow at top level
1516   # coming in
1517   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1518       if exists $sqltargs->{sources};
1519
1520   my $tr = SQL::Translator->new(%$sqltargs);
1521   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1522   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1523
1524   return;
1525
1526 }
1527
1528 sub deploy {
1529   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1530   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1531     foreach my $line ( split(";\n", $statement)) {
1532       next if($line =~ /^--/);
1533       next if(!$line);
1534 #      next if($line =~ /^DROP/m);
1535       next if($line =~ /^BEGIN TRANSACTION/m);
1536       next if($line =~ /^COMMIT/m);
1537       next if $line =~ /^\s+$/; # skip whitespace only
1538       $self->_query_start($line);
1539       eval {
1540         $self->dbh->do($line); # shouldn't be using ->dbh ?
1541       };
1542       if ($@) {
1543         warn qq{$@ (running "${line}")};
1544       }
1545       $self->_query_end($line);
1546     }
1547   }
1548 }
1549
1550 =head2 datetime_parser
1551
1552 Returns the datetime parser class
1553
1554 =cut
1555
1556 sub datetime_parser {
1557   my $self = shift;
1558   return $self->{datetime_parser} ||= do {
1559     $self->ensure_connected;
1560     $self->build_datetime_parser(@_);
1561   };
1562 }
1563
1564 =head2 datetime_parser_type
1565
1566 Defines (returns) the datetime parser class - currently hardwired to
1567 L<DateTime::Format::MySQL>
1568
1569 =cut
1570
1571 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1572
1573 =head2 build_datetime_parser
1574
1575 See L</datetime_parser>
1576
1577 =cut
1578
1579 sub build_datetime_parser {
1580   my $self = shift;
1581   my $type = $self->datetime_parser_type(@_);
1582   eval "use ${type}";
1583   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1584   return $type;
1585 }
1586
1587 {
1588     my $_check_sqlt_version; # private
1589     my $_check_sqlt_message; # private
1590     sub _check_sqlt_version {
1591         return $_check_sqlt_version if defined $_check_sqlt_version;
1592         eval 'use SQL::Translator "0.09"';
1593         $_check_sqlt_message = $@ || '';
1594         $_check_sqlt_version = !$@;
1595     }
1596
1597     sub _check_sqlt_message {
1598         _check_sqlt_version if !defined $_check_sqlt_message;
1599         $_check_sqlt_message;
1600     }
1601 }
1602
1603 sub DESTROY {
1604   my $self = shift;
1605   return if !$self->_dbh;
1606   $self->_verify_pid;
1607   $self->_dbh(undef);
1608 }
1609
1610 1;
1611
1612 =head1 SQL METHODS
1613
1614 The module defines a set of methods within the DBIC::SQL::Abstract
1615 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1616 SQL query functions.
1617
1618 The following methods are extended:-
1619
1620 =over 4
1621
1622 =item delete
1623
1624 =item insert
1625
1626 =item select
1627
1628 =item update
1629
1630 =item limit_dialect
1631
1632 See L</connect_info> for details.
1633 For setting, this method is deprecated in favor of L</connect_info>.
1634
1635 =item quote_char
1636
1637 See L</connect_info> for details.
1638 For setting, this method is deprecated in favor of L</connect_info>.
1639
1640 =item name_sep
1641
1642 See L</connect_info> for details.
1643 For setting, this method is deprecated in favor of L</connect_info>.
1644
1645 =back
1646
1647 =head1 AUTHORS
1648
1649 Matt S. Trout <mst@shadowcatsystems.co.uk>
1650
1651 Andy Grundman <andy@hybridized.org>
1652
1653 =head1 LICENSE
1654
1655 You may distribute this code under the same terms as Perl itself.
1656
1657 =cut