lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util();
  15 use List::Util();
  16 use Data::Dumper::Concise();
  17 use Sub::Name ();
  18
  19 use File::Path ();
  20
  21 __PACKAGE__->mk_group_accessors('simple' =>
  22   qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid
  23      _conn_tid transaction_depth _dbh_autocommit _driver_determined savepoints
  24      _server_info_hash/
  25 );
  26
  27 # the values for these accessors are picked out (and deleted) from
  28 # the attribute hashref passed to connect_info
  29 my @storage_options = qw/
  30   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  31   disable_sth_caching unsafe auto_savepoint
  32 /;
  33 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  34
  35
  36 # default cursor class, overridable in connect_info attributes
  37 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  38
  39 __PACKAGE__->mk_group_accessors('inherited' => qw/
  40   sql_maker_class
  41   _supports_insert_returning
  42 /);
  43 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  44
  45 # Each of these methods need _determine_driver called before itself
  46 # in order to function reliably. This is a purely DRY optimization
  47 my @rdbms_specific_methods = qw/
  48   deployment_statements
  49   sqlt_type
  50   build_datetime_parser
  51   datetime_parser_type
  52
  53   insert
  54   insert_bulk
  55   update
  56   delete
  57   select
  58   select_single
  59 /;
  60
  61 for my $meth (@rdbms_specific_methods) {
  62
  63   my $orig = __PACKAGE__->can ($meth)
  64     or next;
  65
  66   no strict qw/refs/;
  67   no warnings qw/redefine/;
  68   *{__PACKAGE__ ."::$meth"} = Sub::Name::subname $meth => sub {
  69     if (not $_[0]->_driver_determined) {
  70       $_[0]->_determine_driver;
  71       goto $_[0]->can($meth);
  72     }
  73     $orig->(@_);
  74   };
  75 }
  76
  77
  78 =head1 NAME
  79
  80 DBIx::Class::Storage::DBI - DBI storage handler
  81
  82 =head1 SYNOPSIS
  83
  84   my $schema = MySchema->connect('dbi:SQLite:my.db');
  85
  86   $schema->storage->debug(1);
  87
  88   my @stuff = $schema->storage->dbh_do(
  89     sub {
  90       my ($storage, $dbh, @args) = @_;
  91       $dbh->do("DROP TABLE authors");
  92     },
  93     @column_list
  94   );
  95
  96   $schema->resultset('Book')->search({
  97      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
  98   });
  99
 100 =head1 DESCRIPTION
 101
 102 This class represents the connection to an RDBMS via L<DBI>.  See
 103 L<DBIx::Class::Storage> for general information.  This pod only
 104 documents DBI-specific methods and behaviors.
 105
 106 =head1 METHODS
 107
 108 =cut
 109
 110 sub new {
 111   my $new = shift->next::method(@_);
 112
 113   $new->transaction_depth(0);
 114   $new->_sql_maker_opts({});
 115   $new->{savepoints} = [];
 116   $new->{_in_dbh_do} = 0;
 117   $new->{_dbh_gen} = 0;
 118
 119   # read below to see what this does
 120   $new->_arm_global_destructor;
 121
 122   $new;
 123 }
 124
 125 # This is hack to work around perl shooting stuff in random
 126 # order on exit(). If we do not walk the remaining storage
 127 # objects in an END block, there is a *small but real* chance
 128 # of a fork()ed child to kill the parent's shared DBI handle,
 129 # *before perl reaches the DESTROY in this package*
 130 # Yes, it is ugly and effective.
 131 {
 132   my %seek_and_destroy;
 133
 134   sub _arm_global_destructor {
 135     my $self = shift;
 136     my $key = Scalar::Util::refaddr ($self);
 137     $seek_and_destroy{$key} = $self;
 138     Scalar::Util::weaken ($seek_and_destroy{$key});
 139   }
 140
 141   END {
 142     local $?; # just in case the DBI destructor changes it somehow
 143
 144     # destroy just the object if not native to this process/thread
 145     $_->_preserve_foreign_dbh for (grep
 146       { defined $_ }
 147       values %seek_and_destroy
 148     );
 149   }
 150 }
 151
 152 sub DESTROY {
 153   my $self = shift;
 154
 155   # destroy just the object if not native to this process/thread
 156   $self->_preserve_foreign_dbh;
 157
 158   # some databases need this to stop spewing warnings
 159   if (my $dbh = $self->_dbh) {
 160     local $@;
 161     eval {
 162       %{ $dbh->{CachedKids} } = ();
 163       $dbh->disconnect;
 164     };
 165   }
 166
 167   $self->_dbh(undef);
 168 }
 169
 170 sub _preserve_foreign_dbh {
 171   my $self = shift;
 172
 173   return unless $self->_dbh;
 174
 175   $self->_verify_tid;
 176
 177   return unless $self->_dbh;
 178
 179   $self->_verify_pid;
 180
 181 }
 182
 183 # handle pid changes correctly - do not destroy parent's connection
 184 sub _verify_pid {
 185   my $self = shift;
 186
 187   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 188
 189   $self->_dbh->{InactiveDestroy} = 1;
 190   $self->_dbh(undef);
 191   $self->{_dbh_gen}++;
 192
 193   return;
 194 }
 195
 196 # very similar to above, but seems to FAIL if I set InactiveDestroy
 197 sub _verify_tid {
 198   my $self = shift;
 199
 200   if ( ! defined $self->_conn_tid ) {
 201     return; # no threads
 202   }
 203   elsif ( $self->_conn_tid == threads->tid ) {
 204     return; # same thread
 205   }
 206
 207   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 208   $self->_dbh(undef);
 209   $self->{_dbh_gen}++;
 210
 211   return;
 212 }
 213
 214
 215 =head2 connect_info
 216
 217 This method is normally called by L<DBIx::Class::Schema/connection>, which
 218 encapsulates its argument list in an arrayref before passing them here.
 219
 220 The argument list may contain:
 221
 222 =over
 223
 224 =item *
 225
 226 The same 4-element argument set one would normally pass to
 227 L<DBI/connect>, optionally followed by
 228 L<extra attributes|/DBIx::Class specific connection attributes>
 229 recognized by DBIx::Class:
 230
 231   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 232
 233 =item *
 234
 235 A single code reference which returns a connected
 236 L<DBI database handle|DBI/connect> optionally followed by
 237 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 238 by DBIx::Class:
 239
 240   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 241
 242 =item *
 243
 244 A single hashref with all the attributes and the dsn/user/password
 245 mixed together:
 246
 247   $connect_info_args = [{
 248     dsn => $dsn,
 249     user => $user,
 250     password => $pass,
 251     %dbi_attributes,
 252     %extra_attributes,
 253   }];
 254
 255   $connect_info_args = [{
 256     dbh_maker => sub { DBI->connect (...) },
 257     %dbi_attributes,
 258     %extra_attributes,
 259   }];
 260
 261 This is particularly useful for L<Catalyst> based applications, allowing the
 262 following config (L<Config::General> style):
 263
 264   <Model::DB>
 265     schema_class   App::DB
 266     <connect_info>
 267       dsn          dbi:mysql:database=test
 268       user         testuser
 269       password     TestPass
 270       AutoCommit   1
 271     </connect_info>
 272   </Model::DB>
 273
 274 The C<dsn>/C<user>/C<password> combination can be substituted by the
 275 C<dbh_maker> key whose value is a coderef that returns a connected
 276 L<DBI database handle|DBI/connect>
 277
 278 =back
 279
 280 Please note that the L<DBI> docs recommend that you always explicitly
 281 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 282 recommends that it be set to I<1>, and that you perform transactions
 283 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 284 to I<1> if you do not do explicitly set it to zero.  This is the default
 285 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 286
 287 =head3 DBIx::Class specific connection attributes
 288
 289 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 290 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 291 the following connection options. These options can be mixed in with your other
 292 L<DBI> connection attributes, or placed in a separate hashref
 293 (C<\%extra_attributes>) as shown above.
 294
 295 Every time C<connect_info> is invoked, any previous settings for
 296 these options will be cleared before setting the new ones, regardless of
 297 whether any options are specified in the new C<connect_info>.
 298
 299
 300 =over
 301
 302 =item on_connect_do
 303
 304 Specifies things to do immediately after connecting or re-connecting to
 305 the database.  Its value may contain:
 306
 307 =over
 308
 309 =item a scalar
 310
 311 This contains one SQL statement to execute.
 312
 313 =item an array reference
 314
 315 This contains SQL statements to execute in order.  Each element contains
 316 a string or a code reference that returns a string.
 317
 318 =item a code reference
 319
 320 This contains some code to execute.  Unlike code references within an
 321 array reference, its return value is ignored.
 322
 323 =back
 324
 325 =item on_disconnect_do
 326
 327 Takes arguments in the same form as L</on_connect_do> and executes them
 328 immediately before disconnecting from the database.
 329
 330 Note, this only runs if you explicitly call L</disconnect> on the
 331 storage object.
 332
 333 =item on_connect_call
 334
 335 A more generalized form of L</on_connect_do> that calls the specified
 336 C<connect_call_METHOD> methods in your storage driver.
 337
 338   on_connect_do => 'select 1'
 339
 340 is equivalent to:
 341
 342   on_connect_call => [ [ do_sql => 'select 1' ] ]
 343
 344 Its values may contain:
 345
 346 =over
 347
 348 =item a scalar
 349
 350 Will call the C<connect_call_METHOD> method.
 351
 352 =item a code reference
 353
 354 Will execute C<< $code->($storage) >>
 355
 356 =item an array reference
 357
 358 Each value can be a method name or code reference.
 359
 360 =item an array of arrays
 361
 362 For each array, the first item is taken to be the C<connect_call_> method name
 363 or code reference, and the rest are parameters to it.
 364
 365 =back
 366
 367 Some predefined storage methods you may use:
 368
 369 =over
 370
 371 =item do_sql
 372
 373 Executes a SQL string or a code reference that returns a SQL string. This is
 374 what L</on_connect_do> and L</on_disconnect_do> use.
 375
 376 It can take:
 377
 378 =over
 379
 380 =item a scalar
 381
 382 Will execute the scalar as SQL.
 383
 384 =item an arrayref
 385
 386 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 387 attributes hashref and bind values.
 388
 389 =item a code reference
 390
 391 Will execute C<< $code->($storage) >> and execute the return array refs as
 392 above.
 393
 394 =back
 395
 396 =item datetime_setup
 397
 398 Execute any statements necessary to initialize the database session to return
 399 and accept datetime/timestamp values used with
 400 L<DBIx::Class::InflateColumn::DateTime>.
 401
 402 Only necessary for some databases, see your specific storage driver for
 403 implementation details.
 404
 405 =back
 406
 407 =item on_disconnect_call
 408
 409 Takes arguments in the same form as L</on_connect_call> and executes them
 410 immediately before disconnecting from the database.
 411
 412 Calls the C<disconnect_call_METHOD> methods as opposed to the
 413 C<connect_call_METHOD> methods called by L</on_connect_call>.
 414
 415 Note, this only runs if you explicitly call L</disconnect> on the
 416 storage object.
 417
 418 =item disable_sth_caching
 419
 420 If set to a true value, this option will disable the caching of
 421 statement handles via L<DBI/prepare_cached>.
 422
 423 =item limit_dialect
 424
 425 Sets the limit dialect. This is useful for JDBC-bridge among others
 426 where the remote SQL-dialect cannot be determined by the name of the
 427 driver alone. See also L<SQL::Abstract::Limit>.
 428
 429 =item quote_char
 430
 431 Specifies what characters to use to quote table and column names. If
 432 you use this you will want to specify L</name_sep> as well.
 433
 434 C<quote_char> expects either a single character, in which case is it
 435 is placed on either side of the table/column name, or an arrayref of length
 436 2 in which case the table/column name is placed between the elements.
 437
 438 For example under MySQL you should use C<< quote_char => '`' >>, and for
 439 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 440
 441 =item name_sep
 442
 443 This only needs to be used in conjunction with C<quote_char>, and is used to
 444 specify the character that separates elements (schemas, tables, columns) from
 445 each other. In most cases this is simply a C<.>.
 446
 447 The consequences of not supplying this value is that L<SQL::Abstract>
 448 will assume DBIx::Class' uses of aliases to be complete column
 449 names. The output will look like I<"me.name"> when it should actually
 450 be I<"me"."name">.
 451
 452 =item unsafe
 453
 454 This Storage driver normally installs its own C<HandleError>, sets
 455 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 456 all database handles, including those supplied by a coderef.  It does this
 457 so that it can have consistent and useful error behavior.
 458
 459 If you set this option to a true value, Storage will not do its usual
 460 modifications to the database handle's attributes, and instead relies on
 461 the settings in your connect_info DBI options (or the values you set in
 462 your connection coderef, in the case that you are connecting via coderef).
 463
 464 Note that your custom settings can cause Storage to malfunction,
 465 especially if you set a C<HandleError> handler that suppresses exceptions
 466 and/or disable C<RaiseError>.
 467
 468 =item auto_savepoint
 469
 470 If this option is true, L<DBIx::Class> will use savepoints when nesting
 471 transactions, making it possible to recover from failure in the inner
 472 transaction without having to abort all outer transactions.
 473
 474 =item cursor_class
 475
 476 Use this argument to supply a cursor class other than the default
 477 L<DBIx::Class::Storage::DBI::Cursor>.
 478
 479 =back
 480
 481 Some real-life examples of arguments to L</connect_info> and
 482 L<DBIx::Class::Schema/connect>
 483
 484   # Simple SQLite connection
 485   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 486
 487   # Connect via subref
 488   ->connect_info([ sub { DBI->connect(...) } ]);
 489
 490   # Connect via subref in hashref
 491   ->connect_info([{
 492     dbh_maker => sub { DBI->connect(...) },
 493     on_connect_do => 'alter session ...',
 494   }]);
 495
 496   # A bit more complicated
 497   ->connect_info(
 498     [
 499       'dbi:Pg:dbname=foo',
 500       'postgres',
 501       'my_pg_password',
 502       { AutoCommit => 1 },
 503       { quote_char => q{"}, name_sep => q{.} },
 504     ]
 505   );
 506
 507   # Equivalent to the previous example
 508   ->connect_info(
 509     [
 510       'dbi:Pg:dbname=foo',
 511       'postgres',
 512       'my_pg_password',
 513       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 514     ]
 515   );
 516
 517   # Same, but with hashref as argument
 518   # See parse_connect_info for explanation
 519   ->connect_info(
 520     [{
 521       dsn         => 'dbi:Pg:dbname=foo',
 522       user        => 'postgres',
 523       password    => 'my_pg_password',
 524       AutoCommit  => 1,
 525       quote_char  => q{"},
 526       name_sep    => q{.},
 527     }]
 528   );
 529
 530   # Subref + DBIx::Class-specific connection options
 531   ->connect_info(
 532     [
 533       sub { DBI->connect(...) },
 534       {
 535           quote_char => q{`},
 536           name_sep => q{@},
 537           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 538           disable_sth_caching => 1,
 539       },
 540     ]
 541   );
 542
 543
 544
 545 =cut
 546
 547 sub connect_info {
 548   my ($self, $info) = @_;
 549
 550   return $self->_connect_info if !$info;
 551
 552   $self->_connect_info($info); # copy for _connect_info
 553
 554   $info = $self->_normalize_connect_info($info)
 555     if ref $info eq 'ARRAY';
 556
 557   for my $storage_opt (keys %{ $info->{storage_options} }) {
 558     my $value = $info->{storage_options}{$storage_opt};
 559
 560     $self->$storage_opt($value);
 561   }
 562
 563   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 564   #  the new set of options
 565   $self->_sql_maker(undef);
 566   $self->_sql_maker_opts({});
 567
 568   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 569     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 570
 571     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 572   }
 573
 574   my %attrs = (
 575     %{ $self->_default_dbi_connect_attributes || {} },
 576     %{ $info->{attributes} || {} },
 577   );
 578
 579   my @args = @{ $info->{arguments} };
 580
 581   $self->_dbi_connect_info([@args,
 582     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 583
 584   return $self->_connect_info;
 585 }
 586
 587 sub _normalize_connect_info {
 588   my ($self, $info_arg) = @_;
 589   my %info;
 590
 591   my @args = @$info_arg;  # take a shallow copy for further mutilation
 592
 593   # combine/pre-parse arguments depending on invocation style
 594
 595   my %attrs;
 596   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 597     %attrs = %{ $args[1] || {} };
 598     @args = $args[0];
 599   }
 600   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 601     %attrs = %{$args[0]};
 602     @args = ();
 603     if (my $code = delete $attrs{dbh_maker}) {
 604       @args = $code;
 605
 606       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 607       if (@ignored) {
 608         carp sprintf (
 609             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 610           . "to the result of 'dbh_maker'",
 611
 612           join (', ', map { "'$_'" } (@ignored) ),
 613         );
 614       }
 615     }
 616     else {
 617       @args = delete @attrs{qw/dsn user password/};
 618     }
 619   }
 620   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 621     %attrs = (
 622       % { $args[3] || {} },
 623       % { $args[4] || {} },
 624     );
 625     @args = @args[0,1,2];
 626   }
 627
 628   $info{arguments} = \@args;
 629
 630   my @storage_opts = grep exists $attrs{$_},
 631     @storage_options, 'cursor_class';
 632
 633   @{ $info{storage_options} }{@storage_opts} =
 634     delete @attrs{@storage_opts} if @storage_opts;
 635
 636   my @sql_maker_opts = grep exists $attrs{$_},
 637     qw/limit_dialect quote_char name_sep/;
 638
 639   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 640     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 641
 642   $info{attributes} = \%attrs if %attrs;
 643
 644   return \%info;
 645 }
 646
 647 sub _default_dbi_connect_attributes {
 648   return {
 649     AutoCommit => 1,
 650     RaiseError => 1,
 651     PrintError => 0,
 652   };
 653 }
 654
 655 =head2 on_connect_do
 656
 657 This method is deprecated in favour of setting via L</connect_info>.
 658
 659 =cut
 660
 661 =head2 on_disconnect_do
 662
 663 This method is deprecated in favour of setting via L</connect_info>.
 664
 665 =cut
 666
 667 sub _parse_connect_do {
 668   my ($self, $type) = @_;
 669
 670   my $val = $self->$type;
 671   return () if not defined $val;
 672
 673   my @res;
 674
 675   if (not ref($val)) {
 676     push @res, [ 'do_sql', $val ];
 677   } elsif (ref($val) eq 'CODE') {
 678     push @res, $val;
 679   } elsif (ref($val) eq 'ARRAY') {
 680     push @res, map { [ 'do_sql', $_ ] } @$val;
 681   } else {
 682     $self->throw_exception("Invalid type for $type: ".ref($val));
 683   }
 684
 685   return \@res;
 686 }
 687
 688 =head2 dbh_do
 689
 690 Arguments: ($subref | $method_name), @extra_coderef_args?
 691
 692 Execute the given $subref or $method_name using the new exception-based
 693 connection management.
 694
 695 The first two arguments will be the storage object that C<dbh_do> was called
 696 on and a database handle to use.  Any additional arguments will be passed
 697 verbatim to the called subref as arguments 2 and onwards.
 698
 699 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 700 exception handling and reconnection (or failover in future subclasses).
 701
 702 Your subref should have no side-effects outside of the database, as
 703 there is the potential for your subref to be partially double-executed
 704 if the database connection was stale/dysfunctional.
 705
 706 Example:
 707
 708   my @stuff = $schema->storage->dbh_do(
 709     sub {
 710       my ($storage, $dbh, @cols) = @_;
 711       my $cols = join(q{, }, @cols);
 712       $dbh->selectrow_array("SELECT $cols FROM foo");
 713     },
 714     @column_list
 715   );
 716
 717 =cut
 718
 719 sub dbh_do {
 720   my $self = shift;
 721   my $code = shift;
 722
 723   my $dbh = $self->_get_dbh;
 724
 725   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 726       || $self->{transaction_depth};
 727
 728   local $self->{_in_dbh_do} = 1;
 729
 730   my @result;
 731   my $want_array = wantarray;
 732
 733   eval {
 734
 735     if($want_array) {
 736         @result = $self->$code($dbh, @_);
 737     }
 738     elsif(defined $want_array) {
 739         $result[0] = $self->$code($dbh, @_);
 740     }
 741     else {
 742         $self->$code($dbh, @_);
 743     }
 744   };
 745
 746   # ->connected might unset $@ - copy
 747   my $exception = $@;
 748   if(!$exception) { return $want_array ? @result : $result[0] }
 749
 750   $self->throw_exception($exception) if $self->connected;
 751
 752   # We were not connected - reconnect and retry, but let any
 753   #  exception fall right through this time
 754   carp "Retrying $code after catching disconnected exception: $exception"
 755     if $ENV{DBIC_DBIRETRY_DEBUG};
 756   $self->_populate_dbh;
 757   $self->$code($self->_dbh, @_);
 758 }
 759
 760 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 761 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 762 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 763 sub txn_do {
 764   my $self = shift;
 765   my $coderef = shift;
 766
 767   ref $coderef eq 'CODE' or $self->throw_exception
 768     ('$coderef must be a CODE reference');
 769
 770   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 771
 772   local $self->{_in_dbh_do} = 1;
 773
 774   my @result;
 775   my $want_array = wantarray;
 776
 777   my $tried = 0;
 778   while(1) {
 779     eval {
 780       $self->_get_dbh;
 781
 782       $self->txn_begin;
 783       if($want_array) {
 784           @result = $coderef->(@_);
 785       }
 786       elsif(defined $want_array) {
 787           $result[0] = $coderef->(@_);
 788       }
 789       else {
 790           $coderef->(@_);
 791       }
 792       $self->txn_commit;
 793     };
 794
 795     # ->connected might unset $@ - copy
 796     my $exception = $@;
 797     if(!$exception) { return $want_array ? @result : $result[0] }
 798
 799     if($tried++ || $self->connected) {
 800       eval { $self->txn_rollback };
 801       my $rollback_exception = $@;
 802       if($rollback_exception) {
 803         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 804         $self->throw_exception($exception)  # propagate nested rollback
 805           if $rollback_exception =~ /$exception_class/;
 806
 807         $self->throw_exception(
 808           "Transaction aborted: ${exception}. "
 809           . "Rollback failed: ${rollback_exception}"
 810         );
 811       }
 812       $self->throw_exception($exception)
 813     }
 814
 815     # We were not connected, and was first try - reconnect and retry
 816     # via the while loop
 817     carp "Retrying $coderef after catching disconnected exception: $exception"
 818       if $ENV{DBIC_DBIRETRY_DEBUG};
 819     $self->_populate_dbh;
 820   }
 821 }
 822
 823 =head2 disconnect
 824
 825 Our C<disconnect> method also performs a rollback first if the
 826 database is not in C<AutoCommit> mode.
 827
 828 =cut
 829
 830 sub disconnect {
 831   my ($self) = @_;
 832
 833   if( $self->_dbh ) {
 834     my @actions;
 835
 836     push @actions, ( $self->on_disconnect_call || () );
 837     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 838
 839     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 840
 841     $self->_dbh_rollback unless $self->_dbh_autocommit;
 842
 843     %{ $self->_dbh->{CachedKids} } = ();
 844     $self->_dbh->disconnect;
 845     $self->_dbh(undef);
 846     $self->{_dbh_gen}++;
 847   }
 848 }
 849
 850 =head2 with_deferred_fk_checks
 851
 852 =over 4
 853
 854 =item Arguments: C<$coderef>
 855
 856 =item Return Value: The return value of $coderef
 857
 858 =back
 859
 860 Storage specific method to run the code ref with FK checks deferred or
 861 in MySQL's case disabled entirely.
 862
 863 =cut
 864
 865 # Storage subclasses should override this
 866 sub with_deferred_fk_checks {
 867   my ($self, $sub) = @_;
 868   $sub->();
 869 }
 870
 871 =head2 connected
 872
 873 =over
 874
 875 =item Arguments: none
 876
 877 =item Return Value: 1|0
 878
 879 =back
 880
 881 Verifies that the current database handle is active and ready to execute
 882 an SQL statement (e.g. the connection did not get stale, server is still
 883 answering, etc.) This method is used internally by L</dbh>.
 884
 885 =cut
 886
 887 sub connected {
 888   my $self = shift;
 889   return 0 unless $self->_seems_connected;
 890
 891   #be on the safe side
 892   local $self->_dbh->{RaiseError} = 1;
 893
 894   return $self->_ping;
 895 }
 896
 897 sub _seems_connected {
 898   my $self = shift;
 899
 900   $self->_preserve_foreign_dbh;
 901
 902   my $dbh = $self->_dbh
 903     or return 0;
 904
 905   return $dbh->FETCH('Active');
 906 }
 907
 908 sub _ping {
 909   my $self = shift;
 910
 911   my $dbh = $self->_dbh or return 0;
 912
 913   return $dbh->ping;
 914 }
 915
 916 sub ensure_connected {
 917   my ($self) = @_;
 918
 919   unless ($self->connected) {
 920     $self->_populate_dbh;
 921   }
 922 }
 923
 924 =head2 dbh
 925
 926 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 927 is guaranteed to be healthy by implicitly calling L</connected>, and if
 928 necessary performing a reconnection before returning. Keep in mind that this
 929 is very B<expensive> on some database engines. Consider using L</dbh_do>
 930 instead.
 931
 932 =cut
 933
 934 sub dbh {
 935   my ($self) = @_;
 936
 937   if (not $self->_dbh) {
 938     $self->_populate_dbh;
 939   } else {
 940     $self->ensure_connected;
 941   }
 942   return $self->_dbh;
 943 }
 944
 945 # this is the internal "get dbh or connect (don't check)" method
 946 sub _get_dbh {
 947   my $self = shift;
 948   $self->_preserve_foreign_dbh;
 949   $self->_populate_dbh unless $self->_dbh;
 950   return $self->_dbh;
 951 }
 952
 953 sub _sql_maker_args {
 954     my ($self) = @_;
 955
 956     return (
 957       bindtype=>'columns',
 958       array_datatypes => 1,
 959       limit_dialect => $self->_get_dbh,
 960       %{$self->_sql_maker_opts}
 961     );
 962 }
 963
 964 sub sql_maker {
 965   my ($self) = @_;
 966   unless ($self->_sql_maker) {
 967     my $sql_maker_class = $self->sql_maker_class;
 968     $self->ensure_class_loaded ($sql_maker_class);
 969     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 970   }
 971   return $self->_sql_maker;
 972 }
 973
 974 # nothing to do by default
 975 sub _rebless {}
 976 sub _init {}
 977
 978 sub _populate_dbh {
 979   my ($self) = @_;
 980
 981   my @info = @{$self->_dbi_connect_info || []};
 982   $self->_dbh(undef); # in case ->connected failed we might get sent here
 983   $self->_server_info_hash (undef);
 984   $self->_dbh($self->_connect(@info));
 985
 986   $self->_conn_pid($$);
 987   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 988
 989   $self->_determine_driver;
 990
 991   # Always set the transaction depth on connect, since
 992   #  there is no transaction in progress by definition
 993   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 994
 995   $self->_run_connection_actions unless $self->{_in_determine_driver};
 996 }
 997
 998 sub _run_connection_actions {
 999   my $self = shift;
1000   my @actions;
1001
1002   push @actions, ( $self->on_connect_call || () );
1003   push @actions, $self->_parse_connect_do ('on_connect_do');
1004
1005   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1006 }
1007
1008 sub _server_info {
1009   my $self = shift;
1010
1011   unless ($self->_server_info_hash) {
1012
1013     my %info;
1014
1015     my $server_version = $self->_get_server_version;
1016
1017     if (defined $server_version) {
1018       $info{dbms_version} = $server_version;
1019
1020       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1021       my @verparts = split (/\./, $numeric_version);
1022       if (
1023         @verparts
1024           &&
1025         $verparts[0] <= 999
1026       ) {
1027         # consider only up to 3 version parts, iff not more than 3 digits
1028         my @use_parts;
1029         while (@verparts && @use_parts < 3) {
1030           my $p = shift @verparts;
1031           last if $p > 999;
1032           push @use_parts, $p;
1033         }
1034         push @use_parts, 0 while @use_parts < 3;
1035
1036         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1037       }
1038     }
1039
1040     $self->_server_info_hash(\%info);
1041   }
1042
1043   return $self->_server_info_hash
1044 }
1045
1046 sub _get_server_version {
1047   eval { shift->_get_dbh->get_info(18) };
1048 }
1049
1050 sub _determine_driver {
1051   my ($self) = @_;
1052
1053   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1054     my $started_connected = 0;
1055     local $self->{_in_determine_driver} = 1;
1056
1057     if (ref($self) eq __PACKAGE__) {
1058       my $driver;
1059       if ($self->_dbh) { # we are connected
1060         $driver = $self->_dbh->{Driver}{Name};
1061         $started_connected = 1;
1062       } else {
1063         # if connect_info is a CODEREF, we have no choice but to connect
1064         if (ref $self->_dbi_connect_info->[0] &&
1065             Scalar::Util::reftype($self->_dbi_connect_info->[0]) eq 'CODE') {
1066           $self->_populate_dbh;
1067           $driver = $self->_dbh->{Driver}{Name};
1068         }
1069         else {
1070           # try to use dsn to not require being connected, the driver may still
1071           # force a connection in _rebless to determine version
1072           # (dsn may not be supplied at all if all we do is make a mock-schema)
1073           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1074           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1075           $driver ||= $ENV{DBI_DRIVER};
1076         }
1077       }
1078
1079       if ($driver) {
1080         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1081         if ($self->load_optional_class($storage_class)) {
1082           mro::set_mro($storage_class, 'c3');
1083           bless $self, $storage_class;
1084           $self->_rebless();
1085         }
1086       }
1087     }
1088
1089     $self->_driver_determined(1);
1090
1091     $self->_init; # run driver-specific initializations
1092
1093     $self->_run_connection_actions
1094         if !$started_connected && defined $self->_dbh;
1095   }
1096 }
1097
1098 sub _do_connection_actions {
1099   my $self          = shift;
1100   my $method_prefix = shift;
1101   my $call          = shift;
1102
1103   if (not ref($call)) {
1104     my $method = $method_prefix . $call;
1105     $self->$method(@_);
1106   } elsif (ref($call) eq 'CODE') {
1107     $self->$call(@_);
1108   } elsif (ref($call) eq 'ARRAY') {
1109     if (ref($call->[0]) ne 'ARRAY') {
1110       $self->_do_connection_actions($method_prefix, $_) for @$call;
1111     } else {
1112       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1113     }
1114   } else {
1115     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1116   }
1117
1118   return $self;
1119 }
1120
1121 sub connect_call_do_sql {
1122   my $self = shift;
1123   $self->_do_query(@_);
1124 }
1125
1126 sub disconnect_call_do_sql {
1127   my $self = shift;
1128   $self->_do_query(@_);
1129 }
1130
1131 # override in db-specific backend when necessary
1132 sub connect_call_datetime_setup { 1 }
1133
1134 sub _do_query {
1135   my ($self, $action) = @_;
1136
1137   if (ref $action eq 'CODE') {
1138     $action = $action->($self);
1139     $self->_do_query($_) foreach @$action;
1140   }
1141   else {
1142     # Most debuggers expect ($sql, @bind), so we need to exclude
1143     # the attribute hash which is the second argument to $dbh->do
1144     # furthermore the bind values are usually to be presented
1145     # as named arrayref pairs, so wrap those here too
1146     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1147     my $sql = shift @do_args;
1148     my $attrs = shift @do_args;
1149     my @bind = map { [ undef, $_ ] } @do_args;
1150
1151     $self->_query_start($sql, @bind);
1152     $self->_get_dbh->do($sql, $attrs, @do_args);
1153     $self->_query_end($sql, @bind);
1154   }
1155
1156   return $self;
1157 }
1158
1159 sub _connect {
1160   my ($self, @info) = @_;
1161
1162   $self->throw_exception("You failed to provide any connection info")
1163     if !@info;
1164
1165   my ($old_connect_via, $dbh);
1166
1167   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1168     $old_connect_via = $DBI::connect_via;
1169     $DBI::connect_via = 'connect';
1170   }
1171
1172   eval {
1173     if(ref $info[0] eq 'CODE') {
1174        $dbh = $info[0]->();
1175     }
1176     else {
1177        $dbh = DBI->connect(@info);
1178     }
1179
1180     if($dbh && !$self->unsafe) {
1181       my $weak_self = $self;
1182       Scalar::Util::weaken($weak_self);
1183       $dbh->{HandleError} = sub {
1184           if ($weak_self) {
1185             $weak_self->throw_exception("DBI Exception: $_[0]");
1186           }
1187           else {
1188             # the handler may be invoked by something totally out of
1189             # the scope of DBIC
1190             croak ("DBI Exception: $_[0]");
1191           }
1192       };
1193       $dbh->{ShowErrorStatement} = 1;
1194       $dbh->{RaiseError} = 1;
1195       $dbh->{PrintError} = 0;
1196     }
1197   };
1198
1199   $DBI::connect_via = $old_connect_via if $old_connect_via;
1200
1201   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1202     if !$dbh || $@;
1203
1204   $self->_dbh_autocommit($dbh->{AutoCommit});
1205
1206   $dbh;
1207 }
1208
1209 sub svp_begin {
1210   my ($self, $name) = @_;
1211
1212   $name = $self->_svp_generate_name
1213     unless defined $name;
1214
1215   $self->throw_exception ("You can't use savepoints outside a transaction")
1216     if $self->{transaction_depth} == 0;
1217
1218   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1219     unless $self->can('_svp_begin');
1220
1221   push @{ $self->{savepoints} }, $name;
1222
1223   $self->debugobj->svp_begin($name) if $self->debug;
1224
1225   return $self->_svp_begin($name);
1226 }
1227
1228 sub svp_release {
1229   my ($self, $name) = @_;
1230
1231   $self->throw_exception ("You can't use savepoints outside a transaction")
1232     if $self->{transaction_depth} == 0;
1233
1234   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1235     unless $self->can('_svp_release');
1236
1237   if (defined $name) {
1238     $self->throw_exception ("Savepoint '$name' does not exist")
1239       unless grep { $_ eq $name } @{ $self->{savepoints} };
1240
1241     # Dig through the stack until we find the one we are releasing.  This keeps
1242     # the stack up to date.
1243     my $svp;
1244
1245     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1246   } else {
1247     $name = pop @{ $self->{savepoints} };
1248   }
1249
1250   $self->debugobj->svp_release($name) if $self->debug;
1251
1252   return $self->_svp_release($name);
1253 }
1254
1255 sub svp_rollback {
1256   my ($self, $name) = @_;
1257
1258   $self->throw_exception ("You can't use savepoints outside a transaction")
1259     if $self->{transaction_depth} == 0;
1260
1261   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1262     unless $self->can('_svp_rollback');
1263
1264   if (defined $name) {
1265       # If they passed us a name, verify that it exists in the stack
1266       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1267           $self->throw_exception("Savepoint '$name' does not exist!");
1268       }
1269
1270       # Dig through the stack until we find the one we are releasing.  This keeps
1271       # the stack up to date.
1272       while(my $s = pop(@{ $self->{savepoints} })) {
1273           last if($s eq $name);
1274       }
1275       # Add the savepoint back to the stack, as a rollback doesn't remove the
1276       # named savepoint, only everything after it.
1277       push(@{ $self->{savepoints} }, $name);
1278   } else {
1279       # We'll assume they want to rollback to the last savepoint
1280       $name = $self->{savepoints}->[-1];
1281   }
1282
1283   $self->debugobj->svp_rollback($name) if $self->debug;
1284
1285   return $self->_svp_rollback($name);
1286 }
1287
1288 sub _svp_generate_name {
1289     my ($self) = @_;
1290
1291     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1292 }
1293
1294 sub txn_begin {
1295   my $self = shift;
1296
1297   # this means we have not yet connected and do not know the AC status
1298   # (e.g. coderef $dbh)
1299   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1300
1301   if($self->{transaction_depth} == 0) {
1302     $self->debugobj->txn_begin()
1303       if $self->debug;
1304     $self->_dbh_begin_work;
1305   }
1306   elsif ($self->auto_savepoint) {
1307     $self->svp_begin;
1308   }
1309   $self->{transaction_depth}++;
1310 }
1311
1312 sub _dbh_begin_work {
1313   my $self = shift;
1314
1315   # if the user is utilizing txn_do - good for him, otherwise we need to
1316   # ensure that the $dbh is healthy on BEGIN.
1317   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1318   # will be replaced by a failure of begin_work itself (which will be
1319   # then retried on reconnect)
1320   if ($self->{_in_dbh_do}) {
1321     $self->_dbh->begin_work;
1322   } else {
1323     $self->dbh_do(sub { $_[1]->begin_work });
1324   }
1325 }
1326
1327 sub txn_commit {
1328   my $self = shift;
1329   if ($self->{transaction_depth} == 1) {
1330     $self->debugobj->txn_commit()
1331       if ($self->debug);
1332     $self->_dbh_commit;
1333     $self->{transaction_depth} = 0
1334       if $self->_dbh_autocommit;
1335   }
1336   elsif($self->{transaction_depth} > 1) {
1337     $self->{transaction_depth}--;
1338     $self->svp_release
1339       if $self->auto_savepoint;
1340   }
1341 }
1342
1343 sub _dbh_commit {
1344   my $self = shift;
1345   my $dbh  = $self->_dbh
1346     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1347   $dbh->commit;
1348 }
1349
1350 sub txn_rollback {
1351   my $self = shift;
1352   my $dbh = $self->_dbh;
1353   eval {
1354     if ($self->{transaction_depth} == 1) {
1355       $self->debugobj->txn_rollback()
1356         if ($self->debug);
1357       $self->{transaction_depth} = 0
1358         if $self->_dbh_autocommit;
1359       $self->_dbh_rollback;
1360     }
1361     elsif($self->{transaction_depth} > 1) {
1362       $self->{transaction_depth}--;
1363       if ($self->auto_savepoint) {
1364         $self->svp_rollback;
1365         $self->svp_release;
1366       }
1367     }
1368     else {
1369       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1370     }
1371   };
1372   if ($@) {
1373     my $error = $@;
1374     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1375     $error =~ /$exception_class/ and $self->throw_exception($error);
1376     # ensure that a failed rollback resets the transaction depth
1377     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1378     $self->throw_exception($error);
1379   }
1380 }
1381
1382 sub _dbh_rollback {
1383   my $self = shift;
1384   my $dbh  = $self->_dbh
1385     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1386   $dbh->rollback;
1387 }
1388
1389 # This used to be the top-half of _execute.  It was split out to make it
1390 #  easier to override in NoBindVars without duping the rest.  It takes up
1391 #  all of _execute's args, and emits $sql, @bind.
1392 sub _prep_for_execute {
1393   my ($self, $op, $extra_bind, $ident, $args) = @_;
1394
1395   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1396     $ident = $ident->from();
1397   }
1398
1399   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1400
1401   unshift(@bind,
1402     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1403       if $extra_bind;
1404   return ($sql, \@bind);
1405 }
1406
1407
1408 sub _fix_bind_params {
1409     my ($self, @bind) = @_;
1410
1411     ### Turn @bind from something like this:
1412     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1413     ### to this:
1414     ###   ( "'1'", "'1'", "'3'" )
1415     return
1416         map {
1417             if ( defined( $_ && $_->[1] ) ) {
1418                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1419             }
1420             else { q{'NULL'}; }
1421         } @bind;
1422 }
1423
1424 sub _query_start {
1425     my ( $self, $sql, @bind ) = @_;
1426
1427     if ( $self->debug ) {
1428         @bind = $self->_fix_bind_params(@bind);
1429
1430         $self->debugobj->query_start( $sql, @bind );
1431     }
1432 }
1433
1434 sub _query_end {
1435     my ( $self, $sql, @bind ) = @_;
1436
1437     if ( $self->debug ) {
1438         @bind = $self->_fix_bind_params(@bind);
1439         $self->debugobj->query_end( $sql, @bind );
1440     }
1441 }
1442
1443 sub _dbh_execute {
1444   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1445
1446   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1447
1448   $self->_query_start( $sql, @$bind );
1449
1450   my $sth = $self->sth($sql,$op);
1451
1452   my $placeholder_index = 1;
1453
1454   foreach my $bound (@$bind) {
1455     my $attributes = {};
1456     my($column_name, @data) = @$bound;
1457
1458     if ($bind_attributes) {
1459       $attributes = $bind_attributes->{$column_name}
1460       if defined $bind_attributes->{$column_name};
1461     }
1462
1463     foreach my $data (@data) {
1464       my $ref = ref $data;
1465       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1466
1467       $sth->bind_param($placeholder_index, $data, $attributes);
1468       $placeholder_index++;
1469     }
1470   }
1471
1472   # Can this fail without throwing an exception anyways???
1473   my $rv = $sth->execute();
1474   $self->throw_exception($sth->errstr) if !$rv;
1475
1476   $self->_query_end( $sql, @$bind );
1477
1478   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1479 }
1480
1481 sub _execute {
1482     my $self = shift;
1483     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1484 }
1485
1486 sub _prefetch_insert_auto_nextvals {
1487   my ($self, $source, $to_insert) = @_;
1488
1489   my $upd = {};
1490
1491   foreach my $col ( $source->columns ) {
1492     if ( !defined $to_insert->{$col} ) {
1493       my $col_info = $source->column_info($col);
1494
1495       if ( $col_info->{auto_nextval} ) {
1496         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1497           'nextval',
1498           $col_info->{sequence} ||=
1499             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1500         );
1501       }
1502     }
1503   }
1504
1505   return $upd;
1506 }
1507
1508 sub insert {
1509   my $self = shift;
1510   my ($source, $to_insert, $opts) = @_;
1511
1512   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1513
1514   my $bind_attributes = $self->source_bind_attributes($source);
1515
1516   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1517
1518   if ($opts->{returning}) {
1519     my @ret_cols = @{$opts->{returning}};
1520
1521     my @ret_vals = eval {
1522       local $SIG{__WARN__} = sub {};
1523       my @r = $sth->fetchrow_array;
1524       $sth->finish;
1525       @r;
1526     };
1527
1528     my %ret;
1529     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1530
1531     $updated_cols = {
1532       %$updated_cols,
1533       %ret,
1534     };
1535   }
1536
1537   return $updated_cols;
1538 }
1539
1540 ## Currently it is assumed that all values passed will be "normal", i.e. not
1541 ## scalar refs, or at least, all the same type as the first set, the statement is
1542 ## only prepped once.
1543 sub insert_bulk {
1544   my ($self, $source, $cols, $data) = @_;
1545
1546   my %colvalues;
1547   @colvalues{@$cols} = (0..$#$cols);
1548
1549   for my $i (0..$#$cols) {
1550     my $first_val = $data->[0][$i];
1551     next unless ref $first_val eq 'SCALAR';
1552
1553     $colvalues{ $cols->[$i] } = $first_val;
1554   }
1555
1556   # check for bad data and stringify stringifiable objects
1557   my $bad_slice = sub {
1558     my ($msg, $col_idx, $slice_idx) = @_;
1559     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1560       $msg,
1561       $cols->[$col_idx],
1562       do {
1563         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1564         Data::Dumper::Concise::Dumper({
1565           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1566         }),
1567       }
1568     );
1569   };
1570
1571   for my $datum_idx (0..$#$data) {
1572     my $datum = $data->[$datum_idx];
1573
1574     for my $col_idx (0..$#$cols) {
1575       my $val            = $datum->[$col_idx];
1576       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1577       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1578
1579       if ($is_literal_sql) {
1580         if (not ref $val) {
1581           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1582         }
1583         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1584           $bad_slice->("$reftype reference found where literal SQL expected",
1585             $col_idx, $datum_idx);
1586         }
1587         elsif ($$val ne $$sqla_bind){
1588           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1589             $col_idx, $datum_idx);
1590         }
1591       }
1592       elsif (my $reftype = ref $val) {
1593         require overload;
1594         if (overload::Method($val, '""')) {
1595           $datum->[$col_idx] = "".$val;
1596         }
1597         else {
1598           $bad_slice->("$reftype reference found where bind expected",
1599             $col_idx, $datum_idx);
1600         }
1601       }
1602     }
1603   }
1604
1605   my ($sql, $bind) = $self->_prep_for_execute (
1606     'insert', undef, $source, [\%colvalues]
1607   );
1608   my @bind = @$bind;
1609
1610   my $empty_bind = 1 if (not @bind) &&
1611     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1612
1613   if ((not @bind) && (not $empty_bind)) {
1614     $self->throw_exception(
1615       'Cannot insert_bulk without support for placeholders'
1616     );
1617   }
1618
1619   # neither _execute_array, nor _execute_inserts_with_no_binds are
1620   # atomic (even if _execute _array is a single call). Thus a safety
1621   # scope guard
1622   my $guard = $self->txn_scope_guard;
1623
1624   $self->_query_start( $sql, ['__BULK__'] );
1625   my $sth = $self->sth($sql);
1626   my $rv = do {
1627     if ($empty_bind) {
1628       # bind_param_array doesn't work if there are no binds
1629       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1630     }
1631     else {
1632 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1633       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1634     }
1635   };
1636
1637   $self->_query_end( $sql, ['__BULK__'] );
1638
1639   $guard->commit;
1640
1641   return (wantarray ? ($rv, $sth, @bind) : $rv);
1642 }
1643
1644 sub _execute_array {
1645   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1646
1647   ## This must be an arrayref, else nothing works!
1648   my $tuple_status = [];
1649
1650   ## Get the bind_attributes, if any exist
1651   my $bind_attributes = $self->source_bind_attributes($source);
1652
1653   ## Bind the values and execute
1654   my $placeholder_index = 1;
1655
1656   foreach my $bound (@$bind) {
1657
1658     my $attributes = {};
1659     my ($column_name, $data_index) = @$bound;
1660
1661     if( $bind_attributes ) {
1662       $attributes = $bind_attributes->{$column_name}
1663       if defined $bind_attributes->{$column_name};
1664     }
1665
1666     my @data = map { $_->[$data_index] } @$data;
1667
1668     $sth->bind_param_array(
1669       $placeholder_index,
1670       [@data],
1671       (%$attributes ?  $attributes : ()),
1672     );
1673     $placeholder_index++;
1674   }
1675
1676   my $rv = eval {
1677     $self->_dbh_execute_array($sth, $tuple_status, @extra);
1678   };
1679   my $err = $@ || $sth->errstr;
1680
1681 # Statement must finish even if there was an exception.
1682   eval { $sth->finish };
1683   $err = $@ unless $err;
1684
1685   if ($err) {
1686     my $i = 0;
1687     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1688
1689     $self->throw_exception("Unexpected populate error: $err")
1690       if ($i > $#$tuple_status);
1691
1692     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1693       ($tuple_status->[$i][1] || $err),
1694       Data::Dumper::Concise::Dumper({
1695         map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols)
1696       }),
1697     );
1698   }
1699   return $rv;
1700 }
1701
1702 sub _dbh_execute_array {
1703     my ($self, $sth, $tuple_status, @extra) = @_;
1704
1705     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1706 }
1707
1708 sub _dbh_execute_inserts_with_no_binds {
1709   my ($self, $sth, $count) = @_;
1710
1711   eval {
1712     my $dbh = $self->_get_dbh;
1713     local $dbh->{RaiseError} = 1;
1714     local $dbh->{PrintError} = 0;
1715
1716     $sth->execute foreach 1..$count;
1717   };
1718   my $exception = $@;
1719
1720 # Make sure statement is finished even if there was an exception.
1721   eval { $sth->finish };
1722   $exception = $@ unless $exception;
1723
1724   $self->throw_exception($exception) if $exception;
1725
1726   return $count;
1727 }
1728
1729 sub update {
1730   my ($self, $source, @args) = @_;
1731
1732   my $bind_attrs = $self->source_bind_attributes($source);
1733
1734   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1735 }
1736
1737
1738 sub delete {
1739   my ($self, $source, @args) = @_;
1740
1741   my $bind_attrs = $self->source_bind_attributes($source);
1742
1743   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1744 }
1745
1746 # We were sent here because the $rs contains a complex search
1747 # which will require a subquery to select the correct rows
1748 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1749 #
1750 # Generating a single PK column subquery is trivial and supported
1751 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1752 # Look at _multipk_update_delete()
1753 sub _subq_update_delete {
1754   my $self = shift;
1755   my ($rs, $op, $values) = @_;
1756
1757   my $rsrc = $rs->result_source;
1758
1759   # quick check if we got a sane rs on our hands
1760   my @pcols = $rsrc->_pri_cols;
1761
1762   my $sel = $rs->_resolved_attrs->{select};
1763   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1764
1765   if (
1766       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1767         ne
1768       join ("\x00", sort @$sel )
1769   ) {
1770     $self->throw_exception (
1771       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1772     );
1773   }
1774
1775   if (@pcols == 1) {
1776     return $self->$op (
1777       $rsrc,
1778       $op eq 'update' ? $values : (),
1779       { $pcols[0] => { -in => $rs->as_query } },
1780     );
1781   }
1782
1783   else {
1784     return $self->_multipk_update_delete (@_);
1785   }
1786 }
1787
1788 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1789 # resultset update/delete involving subqueries. So by default resort
1790 # to simple (and inefficient) delete_all style per-row opearations,
1791 # while allowing specific storages to override this with a faster
1792 # implementation.
1793 #
1794 sub _multipk_update_delete {
1795   return shift->_per_row_update_delete (@_);
1796 }
1797
1798 # This is the default loop used to delete/update rows for multi PK
1799 # resultsets, and used by mysql exclusively (because it can't do anything
1800 # else).
1801 #
1802 # We do not use $row->$op style queries, because resultset update/delete
1803 # is not expected to cascade (this is what delete_all/update_all is for).
1804 #
1805 # There should be no race conditions as the entire operation is rolled
1806 # in a transaction.
1807 #
1808 sub _per_row_update_delete {
1809   my $self = shift;
1810   my ($rs, $op, $values) = @_;
1811
1812   my $rsrc = $rs->result_source;
1813   my @pcols = $rsrc->_pri_cols;
1814
1815   my $guard = $self->txn_scope_guard;
1816
1817   # emulate the return value of $sth->execute for non-selects
1818   my $row_cnt = '0E0';
1819
1820   my $subrs_cur = $rs->cursor;
1821   my @all_pk = $subrs_cur->all;
1822   for my $pks ( @all_pk) {
1823
1824     my $cond;
1825     for my $i (0.. $#pcols) {
1826       $cond->{$pcols[$i]} = $pks->[$i];
1827     }
1828
1829     $self->$op (
1830       $rsrc,
1831       $op eq 'update' ? $values : (),
1832       $cond,
1833     );
1834
1835     $row_cnt++;
1836   }
1837
1838   $guard->commit;
1839
1840   return $row_cnt;
1841 }
1842
1843 sub _select {
1844   my $self = shift;
1845   $self->_execute($self->_select_args(@_));
1846 }
1847
1848 sub _select_args_to_query {
1849   my $self = shift;
1850
1851   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1852   #  = $self->_select_args($ident, $select, $cond, $attrs);
1853   my ($op, $bind, $ident, $bind_attrs, @args) =
1854     $self->_select_args(@_);
1855
1856   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1857   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1858   $prepared_bind ||= [];
1859
1860   return wantarray
1861     ? ($sql, $prepared_bind, $bind_attrs)
1862     : \[ "($sql)", @$prepared_bind ]
1863   ;
1864 }
1865
1866 sub _select_args {
1867   my ($self, $ident, $select, $where, $attrs) = @_;
1868
1869   my $sql_maker = $self->sql_maker;
1870   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1871
1872   $attrs = {
1873     %$attrs,
1874     select => $select,
1875     from => $ident,
1876     where => $where,
1877     $rs_alias && $alias2source->{$rs_alias}
1878       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1879       : ()
1880     ,
1881   };
1882
1883   # calculate bind_attrs before possible $ident mangling
1884   my $bind_attrs = {};
1885   for my $alias (keys %$alias2source) {
1886     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1887     for my $col (keys %$bindtypes) {
1888
1889       my $fqcn = join ('.', $alias, $col);
1890       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1891
1892       # Unqialified column names are nice, but at the same time can be
1893       # rather ambiguous. What we do here is basically go along with
1894       # the loop, adding an unqualified column slot to $bind_attrs,
1895       # alongside the fully qualified name. As soon as we encounter
1896       # another column by that name (which would imply another table)
1897       # we unset the unqualified slot and never add any info to it
1898       # to avoid erroneous type binding. If this happens the users
1899       # only choice will be to fully qualify his column name
1900
1901       if (exists $bind_attrs->{$col}) {
1902         $bind_attrs->{$col} = {};
1903       }
1904       else {
1905         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1906       }
1907     }
1908   }
1909
1910   # adjust limits
1911   if (
1912     $attrs->{software_limit}
1913       ||
1914     $sql_maker->_default_limit_syntax eq "GenericSubQ"
1915   ) {
1916     $attrs->{software_limit} = 1;
1917   }
1918   else {
1919     $self->throw_exception("rows attribute must be positive if present")
1920       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1921
1922     # MySQL actually recommends this approach.  I cringe.
1923     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1924   }
1925
1926   my @limit;
1927
1928   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1929   # storage, unless software limit was requested
1930   if (
1931     #limited has_many
1932     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1933        ||
1934     # limited prefetch with RNO subqueries (otherwise a risk of column name clashes)
1935     (
1936       $attrs->{rows}
1937         &&
1938       $sql_maker->limit_dialect eq 'RowNumberOver'
1939         &&
1940       $attrs->{_prefetch_select}
1941         &&
1942       @{$attrs->{_prefetch_select}}
1943     )
1944       ||
1945     # grouped prefetch (to satisfy group_by == select)
1946     ( $attrs->{group_by}
1947         &&
1948       @{$attrs->{group_by}}
1949         &&
1950       $attrs->{_prefetch_select}
1951         &&
1952       @{$attrs->{_prefetch_select}}
1953     )
1954   ) {
1955     ($ident, $select, $where, $attrs)
1956       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1957   }
1958
1959   elsif (
1960     # the RNO limit dialect mangles the SQL such that the join gets lost
1961     # wrap a subquery here
1962     ($attrs->{rows} || $attrs->{offset})
1963       &&
1964     $sql_maker->limit_dialect eq 'RowNumberOver'
1965       &&
1966     (ref $ident eq 'ARRAY' && @$ident > 1)  # indicates a join
1967       &&
1968     scalar $self->_parse_order_by ($attrs->{order_by})
1969   ) {
1970
1971     push @limit, delete @{$attrs}{qw/rows offset/};
1972
1973     my $subq = $self->_select_args_to_query (
1974       $ident,
1975       $select,
1976       $where,
1977       $attrs,
1978     );
1979
1980     $ident = {
1981       -alias => $attrs->{alias},
1982       -source_handle => $ident->[0]{-source_handle},
1983       $attrs->{alias} => $subq,
1984     };
1985
1986     # all part of the subquery now
1987     delete @{$attrs}{qw/order_by group_by having/};
1988     $where = undef;
1989   }
1990
1991   elsif (! $attrs->{software_limit} ) {
1992     push @limit, $attrs->{rows}, $attrs->{offset};
1993   }
1994
1995   # try to simplify the joinmap further (prune unreferenced type-single joins)
1996   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1997
1998 ###
1999   # This would be the point to deflate anything found in $where
2000   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2001   # expect a row object. And all we have is a resultsource (it is trivial
2002   # to extract deflator coderefs via $alias2source above).
2003   #
2004   # I don't see a way forward other than changing the way deflators are
2005   # invoked, and that's just bad...
2006 ###
2007
2008   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
2009 }
2010
2011 # Returns a counting SELECT for a simple count
2012 # query. Abstracted so that a storage could override
2013 # this to { count => 'firstcol' } or whatever makes
2014 # sense as a performance optimization
2015 sub _count_select {
2016   #my ($self, $source, $rs_attrs) = @_;
2017   return { count => '*' };
2018 }
2019
2020
2021 sub source_bind_attributes {
2022   my ($self, $source) = @_;
2023
2024   my $bind_attributes;
2025   foreach my $column ($source->columns) {
2026
2027     my $data_type = $source->column_info($column)->{data_type} || '';
2028     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
2029      if $data_type;
2030   }
2031
2032   return $bind_attributes;
2033 }
2034
2035 =head2 select
2036
2037 =over 4
2038
2039 =item Arguments: $ident, $select, $condition, $attrs
2040
2041 =back
2042
2043 Handle a SQL select statement.
2044
2045 =cut
2046
2047 sub select {
2048   my $self = shift;
2049   my ($ident, $select, $condition, $attrs) = @_;
2050   return $self->cursor_class->new($self, \@_, $attrs);
2051 }
2052
2053 sub select_single {
2054   my $self = shift;
2055   my ($rv, $sth, @bind) = $self->_select(@_);
2056   my @row = $sth->fetchrow_array;
2057   my @nextrow = $sth->fetchrow_array if @row;
2058   if(@row && @nextrow) {
2059     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2060   }
2061   # Need to call finish() to work round broken DBDs
2062   $sth->finish();
2063   return @row;
2064 }
2065
2066 =head2 sth
2067
2068 =over 4
2069
2070 =item Arguments: $sql
2071
2072 =back
2073
2074 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2075
2076 =cut
2077
2078 sub _dbh_sth {
2079   my ($self, $dbh, $sql) = @_;
2080
2081   # 3 is the if_active parameter which avoids active sth re-use
2082   my $sth = $self->disable_sth_caching
2083     ? $dbh->prepare($sql)
2084     : $dbh->prepare_cached($sql, {}, 3);
2085
2086   # XXX You would think RaiseError would make this impossible,
2087   #  but apparently that's not true :(
2088   $self->throw_exception($dbh->errstr) if !$sth;
2089
2090   $sth;
2091 }
2092
2093 sub sth {
2094   my ($self, $sql) = @_;
2095   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2096 }
2097
2098 sub _dbh_columns_info_for {
2099   my ($self, $dbh, $table) = @_;
2100
2101   if ($dbh->can('column_info')) {
2102     my %result;
2103     eval {
2104       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2105       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2106       $sth->execute();
2107       while ( my $info = $sth->fetchrow_hashref() ){
2108         my %column_info;
2109         $column_info{data_type}   = $info->{TYPE_NAME};
2110         $column_info{size}      = $info->{COLUMN_SIZE};
2111         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2112         $column_info{default_value} = $info->{COLUMN_DEF};
2113         my $col_name = $info->{COLUMN_NAME};
2114         $col_name =~ s/^\"(.*)\"$/$1/;
2115
2116         $result{$col_name} = \%column_info;
2117       }
2118     };
2119     return \%result if !$@ && scalar keys %result;
2120   }
2121
2122   my %result;
2123   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2124   $sth->execute;
2125   my @columns = @{$sth->{NAME_lc}};
2126   for my $i ( 0 .. $#columns ){
2127     my %column_info;
2128     $column_info{data_type} = $sth->{TYPE}->[$i];
2129     $column_info{size} = $sth->{PRECISION}->[$i];
2130     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2131
2132     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2133       $column_info{data_type} = $1;
2134       $column_info{size}    = $2;
2135     }
2136
2137     $result{$columns[$i]} = \%column_info;
2138   }
2139   $sth->finish;
2140
2141   foreach my $col (keys %result) {
2142     my $colinfo = $result{$col};
2143     my $type_num = $colinfo->{data_type};
2144     my $type_name;
2145     if(defined $type_num && $dbh->can('type_info')) {
2146       my $type_info = $dbh->type_info($type_num);
2147       $type_name = $type_info->{TYPE_NAME} if $type_info;
2148       $colinfo->{data_type} = $type_name if $type_name;
2149     }
2150   }
2151
2152   return \%result;
2153 }
2154
2155 sub columns_info_for {
2156   my ($self, $table) = @_;
2157   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2158 }
2159
2160 =head2 last_insert_id
2161
2162 Return the row id of the last insert.
2163
2164 =cut
2165
2166 sub _dbh_last_insert_id {
2167     my ($self, $dbh, $source, $col) = @_;
2168
2169     my $id = eval { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2170
2171     return $id if defined $id;
2172
2173     my $class = ref $self;
2174     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2175 }
2176
2177 sub last_insert_id {
2178   my $self = shift;
2179   $self->_dbh_last_insert_id ($self->_dbh, @_);
2180 }
2181
2182 =head2 _native_data_type
2183
2184 =over 4
2185
2186 =item Arguments: $type_name
2187
2188 =back
2189
2190 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2191 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2192 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2193
2194 The default implementation returns C<undef>, implement in your Storage driver if
2195 you need this functionality.
2196
2197 Should map types from other databases to the native RDBMS type, for example
2198 C<VARCHAR2> to C<VARCHAR>.
2199
2200 Types with modifiers should map to the underlying data type. For example,
2201 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2202
2203 Composite types should map to the container type, for example
2204 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2205
2206 =cut
2207
2208 sub _native_data_type {
2209   #my ($self, $data_type) = @_;
2210   return undef
2211 }
2212
2213 # Check if placeholders are supported at all
2214 sub _placeholders_supported {
2215   my $self = shift;
2216   my $dbh  = $self->_get_dbh;
2217
2218   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2219   # but it is inaccurate more often than not
2220   eval {
2221     local $dbh->{PrintError} = 0;
2222     local $dbh->{RaiseError} = 1;
2223     $dbh->do('select ?', {}, 1);
2224   };
2225   return $@ ? 0 : 1;
2226 }
2227
2228 # Check if placeholders bound to non-string types throw exceptions
2229 #
2230 sub _typeless_placeholders_supported {
2231   my $self = shift;
2232   my $dbh  = $self->_get_dbh;
2233
2234   eval {
2235     local $dbh->{PrintError} = 0;
2236     local $dbh->{RaiseError} = 1;
2237     # this specifically tests a bind that is NOT a string
2238     $dbh->do('select 1 where 1 = ?', {}, 1);
2239   };
2240   return $@ ? 0 : 1;
2241 }
2242
2243 =head2 sqlt_type
2244
2245 Returns the database driver name.
2246
2247 =cut
2248
2249 sub sqlt_type {
2250   shift->_get_dbh->{Driver}->{Name};
2251 }
2252
2253 =head2 bind_attribute_by_data_type
2254
2255 Given a datatype from column info, returns a database specific bind
2256 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2257 let the database planner just handle it.
2258
2259 Generally only needed for special case column types, like bytea in postgres.
2260
2261 =cut
2262
2263 sub bind_attribute_by_data_type {
2264     return;
2265 }
2266
2267 =head2 is_datatype_numeric
2268
2269 Given a datatype from column_info, returns a boolean value indicating if
2270 the current RDBMS considers it a numeric value. This controls how
2271 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2272 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2273 be performed instead of the usual C<eq>.
2274
2275 =cut
2276
2277 sub is_datatype_numeric {
2278   my ($self, $dt) = @_;
2279
2280   return 0 unless $dt;
2281
2282   return $dt =~ /^ (?:
2283     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2284   ) $/ix;
2285 }
2286
2287
2288 =head2 create_ddl_dir
2289
2290 =over 4
2291
2292 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2293
2294 =back
2295
2296 Creates a SQL file based on the Schema, for each of the specified
2297 database engines in C<\@databases> in the given directory.
2298 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2299
2300 Given a previous version number, this will also create a file containing
2301 the ALTER TABLE statements to transform the previous schema into the
2302 current one. Note that these statements may contain C<DROP TABLE> or
2303 C<DROP COLUMN> statements that can potentially destroy data.
2304
2305 The file names are created using the C<ddl_filename> method below, please
2306 override this method in your schema if you would like a different file
2307 name format. For the ALTER file, the same format is used, replacing
2308 $version in the name with "$preversion-$version".
2309
2310 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2311 The most common value for this would be C<< { add_drop_table => 1 } >>
2312 to have the SQL produced include a C<DROP TABLE> statement for each table
2313 created. For quoting purposes supply C<quote_table_names> and
2314 C<quote_field_names>.
2315
2316 If no arguments are passed, then the following default values are assumed:
2317
2318 =over 4
2319
2320 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2321
2322 =item version    - $schema->schema_version
2323
2324 =item directory  - './'
2325
2326 =item preversion - <none>
2327
2328 =back
2329
2330 By default, C<\%sqlt_args> will have
2331
2332  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2333
2334 merged with the hash passed in. To disable any of those features, pass in a
2335 hashref like the following
2336
2337  { ignore_constraint_names => 0, # ... other options }
2338
2339
2340 WARNING: You are strongly advised to check all SQL files created, before applying
2341 them.
2342
2343 =cut
2344
2345 sub create_ddl_dir {
2346   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2347
2348   unless ($dir) {
2349     carp "No directory given, using ./\n";
2350     $dir = './';
2351   } else {
2352       -d $dir or File::Path::mkpath($dir)
2353           or $self->throw_exception("create_ddl_dir: $! creating dir '$dir'");
2354   }
2355
2356   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2357
2358   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2359   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2360
2361   my $schema_version = $schema->schema_version || '1.x';
2362   $version ||= $schema_version;
2363
2364   $sqltargs = {
2365     add_drop_table => 1,
2366     ignore_constraint_names => 1,
2367     ignore_index_names => 1,
2368     %{$sqltargs || {}}
2369   };
2370
2371   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2372     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2373   }
2374
2375   my $sqlt = SQL::Translator->new( $sqltargs );
2376
2377   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2378   my $sqlt_schema = $sqlt->translate({ data => $schema })
2379     or $self->throw_exception ($sqlt->error);
2380
2381   foreach my $db (@$databases) {
2382     $sqlt->reset();
2383     $sqlt->{schema} = $sqlt_schema;
2384     $sqlt->producer($db);
2385
2386     my $file;
2387     my $filename = $schema->ddl_filename($db, $version, $dir);
2388     if (-e $filename && ($version eq $schema_version )) {
2389       # if we are dumping the current version, overwrite the DDL
2390       carp "Overwriting existing DDL file - $filename";
2391       unlink($filename);
2392     }
2393
2394     my $output = $sqlt->translate;
2395     if(!$output) {
2396       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2397       next;
2398     }
2399     if(!open($file, ">$filename")) {
2400       $self->throw_exception("Can't open $filename for writing ($!)");
2401       next;
2402     }
2403     print $file $output;
2404     close($file);
2405
2406     next unless ($preversion);
2407
2408     require SQL::Translator::Diff;
2409
2410     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2411     if(!-e $prefilename) {
2412       carp("No previous schema file found ($prefilename)");
2413       next;
2414     }
2415
2416     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2417     if(-e $difffile) {
2418       carp("Overwriting existing diff file - $difffile");
2419       unlink($difffile);
2420     }
2421
2422     my $source_schema;
2423     {
2424       my $t = SQL::Translator->new($sqltargs);
2425       $t->debug( 0 );
2426       $t->trace( 0 );
2427
2428       $t->parser( $db )
2429         or $self->throw_exception ($t->error);
2430
2431       my $out = $t->translate( $prefilename )
2432         or $self->throw_exception ($t->error);
2433
2434       $source_schema = $t->schema;
2435
2436       $source_schema->name( $prefilename )
2437         unless ( $source_schema->name );
2438     }
2439
2440     # The "new" style of producers have sane normalization and can support
2441     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2442     # And we have to diff parsed SQL against parsed SQL.
2443     my $dest_schema = $sqlt_schema;
2444
2445     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2446       my $t = SQL::Translator->new($sqltargs);
2447       $t->debug( 0 );
2448       $t->trace( 0 );
2449
2450       $t->parser( $db )
2451         or $self->throw_exception ($t->error);
2452
2453       my $out = $t->translate( $filename )
2454         or $self->throw_exception ($t->error);
2455
2456       $dest_schema = $t->schema;
2457
2458       $dest_schema->name( $filename )
2459         unless $dest_schema->name;
2460     }
2461
2462     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2463                                                   $dest_schema,   $db,
2464                                                   $sqltargs
2465                                                  );
2466     if(!open $file, ">$difffile") {
2467       $self->throw_exception("Can't write to $difffile ($!)");
2468       next;
2469     }
2470     print $file $diff;
2471     close($file);
2472   }
2473 }
2474
2475 =head2 deployment_statements
2476
2477 =over 4
2478
2479 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2480
2481 =back
2482
2483 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2484
2485 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2486 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2487
2488 C<$directory> is used to return statements from files in a previously created
2489 L</create_ddl_dir> directory and is optional. The filenames are constructed
2490 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2491
2492 If no C<$directory> is specified then the statements are constructed on the
2493 fly using L<SQL::Translator> and C<$version> is ignored.
2494
2495 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2496
2497 =cut
2498
2499 sub deployment_statements {
2500   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2501   $type ||= $self->sqlt_type;
2502   $version ||= $schema->schema_version || '1.x';
2503   $dir ||= './';
2504   my $filename = $schema->ddl_filename($type, $version, $dir);
2505   if(-f $filename)
2506   {
2507       my $file;
2508       open($file, "<$filename")
2509         or $self->throw_exception("Can't open $filename ($!)");
2510       my @rows = <$file>;
2511       close($file);
2512       return join('', @rows);
2513   }
2514
2515   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2516     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2517   }
2518
2519   # sources needs to be a parser arg, but for simplicty allow at top level
2520   # coming in
2521   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2522       if exists $sqltargs->{sources};
2523
2524   my $tr = SQL::Translator->new(
2525     producer => "SQL::Translator::Producer::${type}",
2526     %$sqltargs,
2527     parser => 'SQL::Translator::Parser::DBIx::Class',
2528     data => $schema,
2529   );
2530
2531   my @ret;
2532   my $wa = wantarray;
2533   if ($wa) {
2534     @ret = $tr->translate;
2535   }
2536   else {
2537     $ret[0] = $tr->translate;
2538   }
2539
2540   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2541     unless (@ret && defined $ret[0]);
2542
2543   return $wa ? @ret : $ret[0];
2544 }
2545
2546 sub deploy {
2547   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2548   my $deploy = sub {
2549     my $line = shift;
2550     return if($line =~ /^--/);
2551     return if(!$line);
2552     # next if($line =~ /^DROP/m);
2553     return if($line =~ /^BEGIN TRANSACTION/m);
2554     return if($line =~ /^COMMIT/m);
2555     return if $line =~ /^\s+$/; # skip whitespace only
2556     $self->_query_start($line);
2557     eval {
2558       # do a dbh_do cycle here, as we need some error checking in
2559       # place (even though we will ignore errors)
2560       $self->dbh_do (sub { $_[1]->do($line) });
2561     };
2562     if ($@) {
2563       carp qq{$@ (running "${line}")};
2564     }
2565     $self->_query_end($line);
2566   };
2567   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2568   if (@statements > 1) {
2569     foreach my $statement (@statements) {
2570       $deploy->( $statement );
2571     }
2572   }
2573   elsif (@statements == 1) {
2574     foreach my $line ( split(";\n", $statements[0])) {
2575       $deploy->( $line );
2576     }
2577   }
2578 }
2579
2580 =head2 datetime_parser
2581
2582 Returns the datetime parser class
2583
2584 =cut
2585
2586 sub datetime_parser {
2587   my $self = shift;
2588   return $self->{datetime_parser} ||= do {
2589     $self->build_datetime_parser(@_);
2590   };
2591 }
2592
2593 =head2 datetime_parser_type
2594
2595 Defines (returns) the datetime parser class - currently hardwired to
2596 L<DateTime::Format::MySQL>
2597
2598 =cut
2599
2600 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2601
2602 =head2 build_datetime_parser
2603
2604 See L</datetime_parser>
2605
2606 =cut
2607
2608 sub build_datetime_parser {
2609   my $self = shift;
2610   my $type = $self->datetime_parser_type(@_);
2611   $self->ensure_class_loaded ($type);
2612   return $type;
2613 }
2614
2615
2616 =head2 is_replicating
2617
2618 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2619 replicate from a master database.  Default is undef, which is the result
2620 returned by databases that don't support replication.
2621
2622 =cut
2623
2624 sub is_replicating {
2625     return;
2626
2627 }
2628
2629 =head2 lag_behind_master
2630
2631 Returns a number that represents a certain amount of lag behind a master db
2632 when a given storage is replicating.  The number is database dependent, but
2633 starts at zero and increases with the amount of lag. Default in undef
2634
2635 =cut
2636
2637 sub lag_behind_master {
2638     return;
2639 }
2640
2641 =head2 relname_to_table_alias
2642
2643 =over 4
2644
2645 =item Arguments: $relname, $join_count
2646
2647 =back
2648
2649 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2650 queries.
2651
2652 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2653 way these aliases are named.
2654
2655 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2656 otherwise C<"$relname">.
2657
2658 =cut
2659
2660 sub relname_to_table_alias {
2661   my ($self, $relname, $join_count) = @_;
2662
2663   my $alias = ($join_count && $join_count > 1 ?
2664     join('_', $relname, $join_count) : $relname);
2665
2666   return $alias;
2667 }
2668
2669 1;
2670
2671 =head1 USAGE NOTES
2672
2673 =head2 DBIx::Class and AutoCommit
2674
2675 DBIx::Class can do some wonderful magic with handling exceptions,
2676 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2677 (the default) combined with C<txn_do> for transaction support.
2678
2679 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2680 in an assumed transaction between commits, and you're telling us you'd
2681 like to manage that manually.  A lot of the magic protections offered by
2682 this module will go away.  We can't protect you from exceptions due to database
2683 disconnects because we don't know anything about how to restart your
2684 transactions.  You're on your own for handling all sorts of exceptional
2685 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2686 be with raw DBI.
2687
2688
2689 =head1 AUTHORS
2690
2691 Matt S. Trout <mst@shadowcatsystems.co.uk>
2692
2693 Andy Grundman <andy@hybridized.org>
2694
2695 =head1 LICENSE
2696
2697 You may distribute this code under the same terms as Perl itself.
2698
2699 =cut