lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Scalar::Util 'blessed';
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  18        transaction_depth/
  19 );
  20
  21 BEGIN {
  22
  23 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  24
  25 use base qw/SQL::Abstract::Limit/;
  26
  27 # This prevents the caching of $dbh in S::A::L, I believe
  28 sub new {
  29   my $self = shift->SUPER::new(@_);
  30
  31   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  32   #   it with what it resolves to:
  33   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  34     if ref $self->{limit_dialect};
  35
  36   $self;
  37 }
  38
  39 sub _RowNumberOver {
  40   my ($self, $sql, $order, $rows, $offset ) = @_;
  41
  42   $offset += 1;
  43   my $last = $rows + $offset;
  44   my ( $order_by ) = $self->_order_by( $order );
  45
  46   $sql = <<"";
  47 SELECT * FROM
  48 (
  49    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  50       $sql
  51       $order_by
  52    ) Q1
  53 ) Q2
  54 WHERE ROW_NUM BETWEEN $offset AND $last
  55
  56   return $sql;
  57 }
  58
  59
  60 # While we're at it, this should make LIMIT queries more efficient,
  61 #  without digging into things too deeply
  62 use Scalar::Util 'blessed';
  63 sub _find_syntax {
  64   my ($self, $syntax) = @_;
  65   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  66   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  67     return 'RowNumberOver';
  68   }
  69
  70   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  71 }
  72
  73 sub select {
  74   my ($self, $table, $fields, $where, $order, @rest) = @_;
  75   $table = $self->_quote($table) unless ref($table);
  76   local $self->{rownum_hack_count} = 1
  77     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  78   @rest = (-1) unless defined $rest[0];
  79   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  80     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  81   local $self->{having_bind} = [];
  82   my ($sql, @ret) = $self->SUPER::select(
  83     $table, $self->_recurse_fields($fields), $where, $order, @rest
  84   );
  85   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  86 }
  87
  88 sub insert {
  89   my $self = shift;
  90   my $table = shift;
  91   $table = $self->_quote($table) unless ref($table);
  92   $self->SUPER::insert($table, @_);
  93 }
  94
  95 sub update {
  96   my $self = shift;
  97   my $table = shift;
  98   $table = $self->_quote($table) unless ref($table);
  99   $self->SUPER::update($table, @_);
 100 }
 101
 102 sub delete {
 103   my $self = shift;
 104   my $table = shift;
 105   $table = $self->_quote($table) unless ref($table);
 106   $self->SUPER::delete($table, @_);
 107 }
 108
 109 sub _emulate_limit {
 110   my $self = shift;
 111   if ($_[3] == -1) {
 112     return $_[1].$self->_order_by($_[2]);
 113   } else {
 114     return $self->SUPER::_emulate_limit(@_);
 115   }
 116 }
 117
 118 sub _recurse_fields {
 119   my ($self, $fields) = @_;
 120   my $ref = ref $fields;
 121   return $self->_quote($fields) unless $ref;
 122   return $$fields if $ref eq 'SCALAR';
 123
 124   if ($ref eq 'ARRAY') {
 125     return join(', ', map {
 126       $self->_recurse_fields($_)
 127       .(exists $self->{rownum_hack_count}
 128          ? ' AS col'.$self->{rownum_hack_count}++
 129          : '')
 130      } @$fields);
 131   } elsif ($ref eq 'HASH') {
 132     foreach my $func (keys %$fields) {
 133       return $self->_sqlcase($func)
 134         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 135     }
 136   }
 137 }
 138
 139 sub _order_by {
 140   my $self = shift;
 141   my $ret = '';
 142   my @extra;
 143   if (ref $_[0] eq 'HASH') {
 144     if (defined $_[0]->{group_by}) {
 145       $ret = $self->_sqlcase(' group by ')
 146                .$self->_recurse_fields($_[0]->{group_by});
 147     }
 148     if (defined $_[0]->{having}) {
 149       my $frag;
 150       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 151       push(@{$self->{having_bind}}, @extra);
 152       $ret .= $self->_sqlcase(' having ').$frag;
 153     }
 154     if (defined $_[0]->{order_by}) {
 155       $ret .= $self->_order_by($_[0]->{order_by});
 156     }
 157   } elsif (ref $_[0] eq 'SCALAR') {
 158     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 159   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 160     my @order = @{+shift};
 161     $ret = $self->_sqlcase(' order by ')
 162           .join(', ', map {
 163                         my $r = $self->_order_by($_, @_);
 164                         $r =~ s/^ ?ORDER BY //i;
 165                         $r;
 166                       } @order);
 167   } else {
 168     $ret = $self->SUPER::_order_by(@_);
 169   }
 170   return $ret;
 171 }
 172
 173 sub _order_directions {
 174   my ($self, $order) = @_;
 175   $order = $order->{order_by} if ref $order eq 'HASH';
 176   return $self->SUPER::_order_directions($order);
 177 }
 178
 179 sub _table {
 180   my ($self, $from) = @_;
 181   if (ref $from eq 'ARRAY') {
 182     return $self->_recurse_from(@$from);
 183   } elsif (ref $from eq 'HASH') {
 184     return $self->_make_as($from);
 185   } else {
 186     return $from; # would love to quote here but _table ends up getting called
 187                   # twice during an ->select without a limit clause due to
 188                   # the way S::A::Limit->select works. should maybe consider
 189                   # bypassing this and doing S::A::select($self, ...) in
 190                   # our select method above. meantime, quoting shims have
 191                   # been added to select/insert/update/delete here
 192   }
 193 }
 194
 195 sub _recurse_from {
 196   my ($self, $from, @join) = @_;
 197   my @sqlf;
 198   push(@sqlf, $self->_make_as($from));
 199   foreach my $j (@join) {
 200     my ($to, $on) = @$j;
 201
 202     # check whether a join type exists
 203     my $join_clause = '';
 204     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 205     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 206       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 207     } else {
 208       $join_clause = ' JOIN ';
 209     }
 210     push(@sqlf, $join_clause);
 211
 212     if (ref $to eq 'ARRAY') {
 213       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 214     } else {
 215       push(@sqlf, $self->_make_as($to));
 216     }
 217     push(@sqlf, ' ON ', $self->_join_condition($on));
 218   }
 219   return join('', @sqlf);
 220 }
 221
 222 sub _make_as {
 223   my ($self, $from) = @_;
 224   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 225                      reverse each %{$self->_skip_options($from)});
 226 }
 227
 228 sub _skip_options {
 229   my ($self, $hash) = @_;
 230   my $clean_hash = {};
 231   $clean_hash->{$_} = $hash->{$_}
 232     for grep {!/^-/} keys %$hash;
 233   return $clean_hash;
 234 }
 235
 236 sub _join_condition {
 237   my ($self, $cond) = @_;
 238   if (ref $cond eq 'HASH') {
 239     my %j;
 240     for (keys %$cond) {
 241       my $v = $cond->{$_};
 242       if (ref $v) {
 243         # XXX no throw_exception() in this package and croak() fails with strange results
 244         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 245             if ref($v) ne 'SCALAR';
 246         $j{$_} = $v;
 247       }
 248       else {
 249         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 250       }
 251     };
 252     return scalar($self->_recurse_where(\%j));
 253   } elsif (ref $cond eq 'ARRAY') {
 254     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 255   } else {
 256     die "Can't handle this yet!";
 257   }
 258 }
 259
 260 sub _quote {
 261   my ($self, $label) = @_;
 262   return '' unless defined $label;
 263   return "*" if $label eq '*';
 264   return $label unless $self->{quote_char};
 265   if(ref $self->{quote_char} eq "ARRAY"){
 266     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 267       if !defined $self->{name_sep};
 268     my $sep = $self->{name_sep};
 269     return join($self->{name_sep},
 270         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 271        split(/\Q$sep\E/,$label));
 272   }
 273   return $self->SUPER::_quote($label);
 274 }
 275
 276 sub limit_dialect {
 277     my $self = shift;
 278     $self->{limit_dialect} = shift if @_;
 279     return $self->{limit_dialect};
 280 }
 281
 282 sub quote_char {
 283     my $self = shift;
 284     $self->{quote_char} = shift if @_;
 285     return $self->{quote_char};
 286 }
 287
 288 sub name_sep {
 289     my $self = shift;
 290     $self->{name_sep} = shift if @_;
 291     return $self->{name_sep};
 292 }
 293
 294 } # End of BEGIN block
 295
 296 =head1 NAME
 297
 298 DBIx::Class::Storage::DBI - DBI storage handler
 299
 300 =head1 SYNOPSIS
 301
 302 =head1 DESCRIPTION
 303
 304 This class represents the connection to an RDBMS via L<DBI>.  See
 305 L<DBIx::Class::Storage> for general information.  This pod only
 306 documents DBI-specific methods and behaviors.
 307
 308 =head1 METHODS
 309
 310 =cut
 311
 312 sub new {
 313   my $new = shift->next::method(@_);
 314
 315   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 This can be set to an arrayref of literal sql statements, which will
 351 be executed immediately after making the connection to the database
 352 every time we [re-]connect.
 353
 354 =item disable_sth_caching
 355
 356 If set to a true value, this option will disable the caching of
 357 statement handles via L<DBI/prepare_cached>.
 358
 359 =item limit_dialect
 360
 361 Sets the limit dialect. This is useful for JDBC-bridge among others
 362 where the remote SQL-dialect cannot be determined by the name of the
 363 driver alone.
 364
 365 =item quote_char
 366
 367 Specifies what characters to use to quote table and column names. If
 368 you use this you will want to specify L<name_sep> as well.
 369
 370 quote_char expects either a single character, in which case is it is placed
 371 on either side of the table/column, or an arrayref of length 2 in which case the
 372 table/column name is placed between the elements.
 373
 374 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 375 use C<quote_char =E<gt> [qw/[ ]/]>.
 376
 377 =item name_sep
 378
 379 This only needs to be used in conjunction with L<quote_char>, and is used to
 380 specify the charecter that seperates elements (schemas, tables, columns) from
 381 each other. In most cases this is simply a C<.>.
 382
 383 =back
 384
 385 These options can be mixed in with your other L<DBI> connection attributes,
 386 or placed in a seperate hashref after all other normal L<DBI> connection
 387 arguments.
 388
 389 Every time C<connect_info> is invoked, any previous settings for
 390 these options will be cleared before setting the new ones, regardless of
 391 whether any options are specified in the new C<connect_info>.
 392
 393 Important note:  DBIC expects the returned database handle provided by
 394 a subref argument to have RaiseError set on it.  If it doesn't, things
 395 might not work very well, YMMV.  If you don't use a subref, DBIC will
 396 force this setting for you anyways.  Setting HandleError to anything
 397 other than simple exception object wrapper might cause problems too.
 398
 399 Another Important Note:
 400
 401 DBIC can do some wonderful magic with handling exceptions,
 402 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 403 combined with C<txn_do> for transaction support.
 404
 405 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 406 in an assumed transaction between commits, and you're telling us you'd
 407 like to manage that manually.  A lot of DBIC's magic protections
 408 go away.  We can't protect you from exceptions due to database
 409 disconnects because we don't know anything about how to restart your
 410 transactions.  You're on your own for handling all sorts of exceptional
 411 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 412 be with raw DBI.
 413
 414 Examples:
 415
 416   # Simple SQLite connection
 417   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 418
 419   # Connect via subref
 420   ->connect_info([ sub { DBI->connect(...) } ]);
 421
 422   # A bit more complicated
 423   ->connect_info(
 424     [
 425       'dbi:Pg:dbname=foo',
 426       'postgres',
 427       'my_pg_password',
 428       { AutoCommit => 1 },
 429       { quote_char => q{"}, name_sep => q{.} },
 430     ]
 431   );
 432
 433   # Equivalent to the previous example
 434   ->connect_info(
 435     [
 436       'dbi:Pg:dbname=foo',
 437       'postgres',
 438       'my_pg_password',
 439       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 440     ]
 441   );
 442
 443   # Subref + DBIC-specific connection options
 444   ->connect_info(
 445     [
 446       sub { DBI->connect(...) },
 447       {
 448           quote_char => q{`},
 449           name_sep => q{@},
 450           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 451           disable_sth_caching => 1,
 452       },
 453     ]
 454   );
 455
 456 =cut
 457
 458 sub connect_info {
 459   my ($self, $info_arg) = @_;
 460
 461   return $self->_connect_info if !$info_arg;
 462
 463   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 464   #  the new set of options
 465   $self->_sql_maker(undef);
 466   $self->_sql_maker_opts({});
 467   $self->_connect_info([@$info_arg]); # copy for _connect_info
 468
 469   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 470
 471   my $last_info = $dbi_info->[-1];
 472   if(ref $last_info eq 'HASH') {
 473     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 474       if(my $value = delete $last_info->{$storage_opt}) {
 475         $self->$storage_opt($value);
 476       }
 477     }
 478     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 479       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 480         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 481       }
 482     }
 483
 484     # Get rid of any trailing empty hashref
 485     pop(@$dbi_info) if !keys %$last_info;
 486   }
 487   $self->_dbi_connect_info($dbi_info);
 488
 489   $self->_connect_info;
 490 }
 491
 492 =head2 on_connect_do
 493
 494 This method is deprecated in favor of setting via L</connect_info>.
 495
 496 =head2 dbh_do
 497
 498 Arguments: $subref, @extra_coderef_args?
 499
 500 Execute the given subref using the new exception-based connection management.
 501
 502 The first two arguments will be the storage object that C<dbh_do> was called
 503 on and a database handle to use.  Any additional arguments will be passed
 504 verbatim to the called subref as arguments 2 and onwards.
 505
 506 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 507 exception handling and reconnection (or failover in future subclasses).
 508
 509 Your subref should have no side-effects outside of the database, as
 510 there is the potential for your subref to be partially double-executed
 511 if the database connection was stale/dysfunctional.
 512
 513 Example:
 514
 515   my @stuff = $schema->storage->dbh_do(
 516     sub {
 517       my ($storage, $dbh, @cols) = @_;
 518       my $cols = join(q{, }, @cols);
 519       $dbh->selectrow_array("SELECT $cols FROM foo");
 520     },
 521     @column_list
 522   );
 523
 524 =cut
 525
 526 sub dbh_do {
 527   my $self = shift;
 528   my $coderef = shift;
 529
 530   ref $coderef eq 'CODE' or $self->throw_exception
 531     ('$coderef must be a CODE reference');
 532
 533   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 534       || $self->{transaction_depth};
 535
 536   local $self->{_in_dbh_do} = 1;
 537
 538   my @result;
 539   my $want_array = wantarray;
 540
 541   eval {
 542     $self->_verify_pid if $self->_dbh;
 543     $self->_populate_dbh if !$self->_dbh;
 544     if($want_array) {
 545         @result = $coderef->($self, $self->_dbh, @_);
 546     }
 547     elsif(defined $want_array) {
 548         $result[0] = $coderef->($self, $self->_dbh, @_);
 549     }
 550     else {
 551         $coderef->($self, $self->_dbh, @_);
 552     }
 553   };
 554
 555   my $exception = $@;
 556   if(!$exception) { return $want_array ? @result : $result[0] }
 557
 558   $self->throw_exception($exception) if $self->connected;
 559
 560   # We were not connected - reconnect and retry, but let any
 561   #  exception fall right through this time
 562   $self->_populate_dbh;
 563   $coderef->($self, $self->_dbh, @_);
 564 }
 565
 566 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 567 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 568 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 569 sub txn_do {
 570   my $self = shift;
 571   my $coderef = shift;
 572
 573   ref $coderef eq 'CODE' or $self->throw_exception
 574     ('$coderef must be a CODE reference');
 575
 576   local $self->{_in_dbh_do} = 1;
 577
 578   my @result;
 579   my $want_array = wantarray;
 580
 581   my $tried = 0;
 582   while(1) {
 583     eval {
 584       $self->_verify_pid if $self->_dbh;
 585       $self->_populate_dbh if !$self->_dbh;
 586
 587       $self->txn_begin;
 588       if($want_array) {
 589           @result = $coderef->(@_);
 590       }
 591       elsif(defined $want_array) {
 592           $result[0] = $coderef->(@_);
 593       }
 594       else {
 595           $coderef->(@_);
 596       }
 597       $self->txn_commit;
 598     };
 599
 600     my $exception = $@;
 601     if(!$exception) { return $want_array ? @result : $result[0] }
 602
 603     if($tried++ > 0 || $self->connected) {
 604       eval { $self->txn_rollback };
 605       my $rollback_exception = $@;
 606       if($rollback_exception) {
 607         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 608         $self->throw_exception($exception)  # propagate nested rollback
 609           if $rollback_exception =~ /$exception_class/;
 610
 611         $self->throw_exception(
 612           "Transaction aborted: ${exception}. "
 613           . "Rollback failed: ${rollback_exception}"
 614         );
 615       }
 616       $self->throw_exception($exception)
 617     }
 618
 619     # We were not connected, and was first try - reconnect and retry
 620     # via the while loop
 621     $self->_populate_dbh;
 622   }
 623 }
 624
 625 =head2 disconnect
 626
 627 Our C<disconnect> method also performs a rollback first if the
 628 database is not in C<AutoCommit> mode.
 629
 630 =cut
 631
 632 sub disconnect {
 633   my ($self) = @_;
 634
 635   if( $self->connected ) {
 636     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 637     $self->_dbh->disconnect;
 638     $self->_dbh(undef);
 639     $self->{_dbh_gen}++;
 640   }
 641 }
 642
 643 sub connected {
 644   my ($self) = @_;
 645
 646   if(my $dbh = $self->_dbh) {
 647       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 648           $self->_dbh(undef);
 649           $self->{_dbh_gen}++;
 650           return;
 651       }
 652       else {
 653           $self->_verify_pid;
 654       }
 655       return ($dbh->FETCH('Active') && $dbh->ping);
 656   }
 657
 658   return 0;
 659 }
 660
 661 # handle pid changes correctly
 662 #  NOTE: assumes $self->_dbh is a valid $dbh
 663 sub _verify_pid {
 664   my ($self) = @_;
 665
 666   return if $self->_conn_pid == $$;
 667
 668   $self->_dbh->{InactiveDestroy} = 1;
 669   $self->_dbh(undef);
 670   $self->{_dbh_gen}++;
 671
 672   return;
 673 }
 674
 675 sub ensure_connected {
 676   my ($self) = @_;
 677
 678   unless ($self->connected) {
 679     $self->_populate_dbh;
 680   }
 681 }
 682
 683 =head2 dbh
 684
 685 Returns the dbh - a data base handle of class L<DBI>.
 686
 687 =cut
 688
 689 sub dbh {
 690   my ($self) = @_;
 691
 692   $self->ensure_connected;
 693   return $self->_dbh;
 694 }
 695
 696 sub _sql_maker_args {
 697     my ($self) = @_;
 698
 699     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 700 }
 701
 702 sub sql_maker {
 703   my ($self) = @_;
 704   unless ($self->_sql_maker) {
 705     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 706   }
 707   return $self->_sql_maker;
 708 }
 709
 710 sub _populate_dbh {
 711   my ($self) = @_;
 712   my @info = @{$self->_dbi_connect_info || []};
 713   $self->_dbh($self->_connect(@info));
 714
 715   # Always set the transaction depth on connect, since
 716   #  there is no transaction in progress by definition
 717   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 718
 719   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 720     my $driver = $self->_dbh->{Driver}->{Name};
 721     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 722       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 723       $self->_rebless() if $self->can('_rebless');
 724     }
 725   }
 726
 727   # if on-connect sql statements are given execute them
 728   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 729     $self->debugobj->query_start($sql_statement) if $self->debug();
 730     $self->_dbh->do($sql_statement);
 731     $self->debugobj->query_end($sql_statement) if $self->debug();
 732   }
 733
 734   $self->_conn_pid($$);
 735   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 736 }
 737
 738 sub _connect {
 739   my ($self, @info) = @_;
 740
 741   $self->throw_exception("You failed to provide any connection info")
 742       if !@info;
 743
 744   my ($old_connect_via, $dbh);
 745
 746   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 747       $old_connect_via = $DBI::connect_via;
 748       $DBI::connect_via = 'connect';
 749   }
 750
 751   eval {
 752     if(ref $info[0] eq 'CODE') {
 753        $dbh = &{$info[0]}
 754     }
 755     else {
 756        $dbh = DBI->connect(@info);
 757        $dbh->{RaiseError} = 1;
 758        $dbh->{PrintError} = 0;
 759        $dbh->{PrintWarn} = 0;
 760     }
 761   };
 762
 763   $DBI::connect_via = $old_connect_via if $old_connect_via;
 764
 765   if (!$dbh || $@) {
 766     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 767   }
 768
 769   $dbh;
 770 }
 771
 772
 773 sub txn_begin {
 774   my $self = shift;
 775   if($self->{transaction_depth}++ == 0) {
 776     $self->debugobj->txn_begin()
 777       if $self->debug;
 778     # this isn't ->_dbh-> because
 779     #  we should reconnect on begin_work
 780     #  for AutoCommit users
 781     $self->dbh->begin_work;
 782   }
 783 }
 784
 785 sub txn_commit {
 786   my $self = shift;
 787   if ($self->{transaction_depth} == 1) {
 788     my $dbh = $self->_dbh;
 789     $self->debugobj->txn_commit()
 790       if ($self->debug);
 791     $dbh->commit;
 792     $self->{transaction_depth} = 0
 793       if $dbh->{AutoCommit};
 794   }
 795   elsif($self->{transaction_depth} > 1) {
 796     $self->{transaction_depth}--
 797   }
 798 }
 799
 800 sub txn_rollback {
 801   my $self = shift;
 802   my $dbh = $self->_dbh;
 803   my $autocommit;
 804   eval {
 805     $autocommit = $dbh->{AutoCommit};
 806     if ($self->{transaction_depth} == 1) {
 807       $self->debugobj->txn_rollback()
 808         if ($self->debug);
 809       $dbh->rollback;
 810       $self->{transaction_depth} = 0
 811         if $autocommit;
 812     }
 813     elsif($self->{transaction_depth} > 1) {
 814       $self->{transaction_depth}--;
 815     }
 816     else {
 817       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 818     }
 819   };
 820   if ($@) {
 821     my $error = $@;
 822     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 823     $error =~ /$exception_class/ and $self->throw_exception($error);
 824     # ensure that a failed rollback resets the transaction depth
 825     $self->{transaction_depth} = $autocommit ? 0 : 1;
 826     $self->throw_exception($error);
 827   }
 828 }
 829
 830 # This used to be the top-half of _execute.  It was split out to make it
 831 #  easier to override in NoBindVars without duping the rest.  It takes up
 832 #  all of _execute's args, and emits $sql, @bind.
 833 sub _prep_for_execute {
 834   my ($self, $op, $extra_bind, $ident, @args) = @_;
 835
 836   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 837   unshift(@bind,
 838     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 839       if $extra_bind;
 840   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 841
 842   return ($sql, @bind);
 843 }
 844
 845 sub _execute {
 846   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 847
 848   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 849     $ident = $ident->from();
 850   }
 851
 852   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 853   unshift(@bind,
 854     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 855       if $extra_bind;
 856   if ($self->debug) {
 857       my @debug_bind =
 858         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 859       $self->debugobj->query_start($sql, @debug_bind);
 860   }
 861   my $sth = eval { $self->sth($sql,$op) };
 862
 863   if (!$sth || $@) {
 864     $self->throw_exception(
 865       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 866     );
 867   }
 868
 869   my $rv;
 870   if ($sth) {
 871     my $time = time();
 872     $rv = eval {
 873       my $placeholder_index = 1;
 874
 875       foreach my $bound (@bind) {
 876
 877         my $attributes = {};
 878         my($column_name, @data) = @$bound;
 879
 880         if( $bind_attributes ) {
 881           $attributes = $bind_attributes->{$column_name}
 882           if defined $bind_attributes->{$column_name};
 883         }
 884
 885         foreach my $data (@data)
 886         {
 887           $data = ref $data ? ''.$data : $data; # stringify args
 888
 889           $sth->bind_param($placeholder_index, $data, $attributes);
 890           $placeholder_index++;
 891         }
 892       }
 893       $sth->execute();
 894     };
 895
 896     if ($@ || !$rv) {
 897       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 898     }
 899   } else {
 900     $self->throw_exception("'$sql' did not generate a statement.");
 901   }
 902   if ($self->debug) {
 903      my @debug_bind =
 904        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 905      $self->debugobj->query_end($sql, @debug_bind);
 906   }
 907   return (wantarray ? ($rv, $sth, @bind) : $rv);
 908 }
 909
 910 sub insert {
 911   my ($self, $source, $to_insert) = @_;
 912
 913   my $ident = $source->from;
 914   my $bind_attributes = $self->source_bind_attributes($source);
 915
 916   $self->throw_exception(
 917     "Couldn't insert ".join(', ',
 918       map "$_ => $to_insert->{$_}", keys %$to_insert
 919     )." into ${ident}"
 920   ) unless ($self->_execute('insert' => [], $source, $bind_attributes, $to_insert));
 921   return $to_insert;
 922 }
 923
 924 ## Still not quite perfect, and EXPERIMENTAL
 925 ## Currently it is assumed that all values passed will be "normal", i.e. not
 926 ## scalar refs, or at least, all the same type as the first set, the statement is
 927 ## only prepped once.
 928 sub insert_bulk {
 929   my ($self, $source, $cols, $data) = @_;
 930   my %colvalues;
 931   my $table = $source->from;
 932   @colvalues{@$cols} = (0..$#$cols);
 933   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 934
 935   if ($self->debug) {
 936       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 937       $self->debugobj->query_start($sql, @debug_bind);
 938   }
 939   my $sth = $self->sth($sql);
 940
 941 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 942
 943   my $rv;
 944
 945   ## This must be an arrayref, else nothing works!
 946
 947   my $tuple_status = [];
 948
 949   ##use Data::Dumper;
 950   ##print STDERR Dumper( $data, $sql, [@bind] );
 951
 952   if ($sth) {
 953
 954     my $time = time();
 955
 956     ## Get the bind_attributes, if any exist
 957     my $bind_attributes = $self->source_bind_attributes($source);
 958
 959     ## Bind the values and execute
 960     $rv = eval {
 961
 962      my $placeholder_index = 1;
 963
 964         foreach my $bound (@bind) {
 965
 966           my $attributes = {};
 967           my ($column_name, $data_index) = @$bound;
 968
 969           if( $bind_attributes ) {
 970             $attributes = $bind_attributes->{$column_name}
 971             if defined $bind_attributes->{$column_name};
 972           }
 973
 974           my @data = map { $_->[$data_index] } @$data;
 975
 976           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 977           $placeholder_index++;
 978       }
 979       $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 980
 981     };
 982
 983     if ($@ || !defined $rv) {
 984       my $errors = '';
 985       foreach my $tuple (@$tuple_status) {
 986           $errors .= "\n" . $tuple->[1] if(ref $tuple);
 987       }
 988       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
 989     }
 990   } else {
 991     $self->throw_exception("'$sql' did not generate a statement.");
 992   }
 993   if ($self->debug) {
 994       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 995       $self->debugobj->query_end($sql, @debug_bind);
 996   }
 997   return (wantarray ? ($rv, $sth, @bind) : $rv);
 998 }
 999
1000 sub update {
1001   my $self = shift @_;
1002   my $source = shift @_;
1003   my $bind_attributes = $self->source_bind_attributes($source);
1004
1005   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1006 }
1007
1008
1009 sub delete {
1010   my $self = shift @_;
1011   my $source = shift @_;
1012
1013   my $bind_attrs = {}; ## If ever it's needed...
1014
1015   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1016 }
1017
1018 sub _select {
1019   my ($self, $ident, $select, $condition, $attrs) = @_;
1020   my $order = $attrs->{order_by};
1021   if (ref $condition eq 'SCALAR') {
1022     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1023   }
1024   if (exists $attrs->{group_by} || $attrs->{having}) {
1025     $order = {
1026       group_by => $attrs->{group_by},
1027       having => $attrs->{having},
1028       ($order ? (order_by => $order) : ())
1029     };
1030   }
1031   my $bind_attrs = {}; ## Future support
1032   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1033   if ($attrs->{software_limit} ||
1034       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1035         $attrs->{software_limit} = 1;
1036   } else {
1037     $self->throw_exception("rows attribute must be positive if present")
1038       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1039     push @args, $attrs->{rows}, $attrs->{offset};
1040   }
1041   return $self->_execute(@args);
1042 }
1043
1044 sub source_bind_attributes {
1045   my ($self, $source) = @_;
1046
1047   my $bind_attributes;
1048   foreach my $column ($source->columns) {
1049
1050     my $data_type = $source->column_info($column)->{data_type} || '';
1051     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1052      if $data_type;
1053   }
1054
1055   return $bind_attributes;
1056 }
1057
1058 =head2 select
1059
1060 =over 4
1061
1062 =item Arguments: $ident, $select, $condition, $attrs
1063
1064 =back
1065
1066 Handle a SQL select statement.
1067
1068 =cut
1069
1070 sub select {
1071   my $self = shift;
1072   my ($ident, $select, $condition, $attrs) = @_;
1073   return $self->cursor->new($self, \@_, $attrs);
1074 }
1075
1076 sub select_single {
1077   my $self = shift;
1078   my ($rv, $sth, @bind) = $self->_select(@_);
1079   my @row = $sth->fetchrow_array;
1080   # Need to call finish() to work round broken DBDs
1081   $sth->finish();
1082   return @row;
1083 }
1084
1085 =head2 sth
1086
1087 =over 4
1088
1089 =item Arguments: $sql
1090
1091 =back
1092
1093 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1094
1095 =cut
1096
1097 sub _dbh_sth {
1098   my ($self, $dbh, $sql) = @_;
1099
1100   # 3 is the if_active parameter which avoids active sth re-use
1101   my $sth = $self->disable_sth_caching
1102     ? $dbh->prepare($sql)
1103     : $dbh->prepare_cached($sql, {}, 3);
1104
1105   $self->throw_exception(
1106     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1107   ) if !$sth;
1108
1109   $sth;
1110 }
1111
1112 sub sth {
1113   my ($self, $sql) = @_;
1114   $self->dbh_do($self->can('_dbh_sth'), $sql);
1115 }
1116
1117 sub _dbh_columns_info_for {
1118   my ($self, $dbh, $table) = @_;
1119
1120   if ($dbh->can('column_info')) {
1121     my %result;
1122     eval {
1123       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1124       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1125       $sth->execute();
1126       while ( my $info = $sth->fetchrow_hashref() ){
1127         my %column_info;
1128         $column_info{data_type}   = $info->{TYPE_NAME};
1129         $column_info{size}      = $info->{COLUMN_SIZE};
1130         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1131         $column_info{default_value} = $info->{COLUMN_DEF};
1132         my $col_name = $info->{COLUMN_NAME};
1133         $col_name =~ s/^\"(.*)\"$/$1/;
1134
1135         $result{$col_name} = \%column_info;
1136       }
1137     };
1138     return \%result if !$@ && scalar keys %result;
1139   }
1140
1141   my %result;
1142   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1143   $sth->execute;
1144   my @columns = @{$sth->{NAME_lc}};
1145   for my $i ( 0 .. $#columns ){
1146     my %column_info;
1147     $column_info{data_type} = $sth->{TYPE}->[$i];
1148     $column_info{size} = $sth->{PRECISION}->[$i];
1149     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1150
1151     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1152       $column_info{data_type} = $1;
1153       $column_info{size}    = $2;
1154     }
1155
1156     $result{$columns[$i]} = \%column_info;
1157   }
1158   $sth->finish;
1159
1160   foreach my $col (keys %result) {
1161     my $colinfo = $result{$col};
1162     my $type_num = $colinfo->{data_type};
1163     my $type_name;
1164     if(defined $type_num && $dbh->can('type_info')) {
1165       my $type_info = $dbh->type_info($type_num);
1166       $type_name = $type_info->{TYPE_NAME} if $type_info;
1167       $colinfo->{data_type} = $type_name if $type_name;
1168     }
1169   }
1170
1171   return \%result;
1172 }
1173
1174 sub columns_info_for {
1175   my ($self, $table) = @_;
1176   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1177 }
1178
1179 =head2 last_insert_id
1180
1181 Return the row id of the last insert.
1182
1183 =cut
1184
1185 sub _dbh_last_insert_id {
1186     my ($self, $dbh, $source, $col) = @_;
1187     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1188     $dbh->func('last_insert_rowid');
1189 }
1190
1191 sub last_insert_id {
1192   my $self = shift;
1193   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1194 }
1195
1196 =head2 sqlt_type
1197
1198 Returns the database driver name.
1199
1200 =cut
1201
1202 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1203
1204 =head2 bind_attribute_by_data_type
1205
1206 Given a datatype from column info, returns a database specific bind attribute for
1207 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1208 just handle it.
1209
1210 Generally only needed for special case column types, like bytea in postgres.
1211
1212 =cut
1213
1214 sub bind_attribute_by_data_type {
1215     return;
1216 }
1217
1218 =head2 create_ddl_dir (EXPERIMENTAL)
1219
1220 =over 4
1221
1222 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1223
1224 =back
1225
1226 Creates a SQL file based on the Schema, for each of the specified
1227 database types, in the given directory.
1228
1229 Note that this feature is currently EXPERIMENTAL and may not work correctly
1230 across all databases, or fully handle complex relationships.
1231
1232 =cut
1233
1234 sub create_ddl_dir
1235 {
1236   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1237
1238   if(!$dir || !-d $dir)
1239   {
1240     warn "No directory given, using ./\n";
1241     $dir = "./";
1242   }
1243   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1244   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1245   $version ||= $schema->VERSION || '1.x';
1246   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1247
1248   eval "use SQL::Translator";
1249   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1250
1251   my $sqlt = SQL::Translator->new({
1252 #      debug => 1,
1253       add_drop_table => 1,
1254   });
1255   foreach my $db (@$databases)
1256   {
1257     $sqlt->reset();
1258     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1259 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1260     $sqlt = $self->configure_sqlt($sqlt, $db);
1261     $sqlt->data($schema);
1262     $sqlt->producer($db);
1263
1264     my $file;
1265     my $filename = $schema->ddl_filename($db, $dir, $version);
1266     if(-e $filename)
1267     {
1268       warn("$filename already exists, skipping $db");
1269       next;
1270     }
1271
1272     my $output = $sqlt->translate;
1273     if(!$output)
1274     {
1275       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1276       next;
1277     }
1278     if(!open($file, ">$filename"))
1279     {
1280         $self->throw_exception("Can't open $filename for writing ($!)");
1281         next;
1282     }
1283     print $file $output;
1284     close($file);
1285
1286     if($preversion)
1287     {
1288       eval "use SQL::Translator::Diff";
1289       if($@)
1290       {
1291         warn("Can't diff versions without SQL::Translator::Diff: $@");
1292         next;
1293       }
1294
1295       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1296 #      print "Previous version $prefilename\n";
1297       if(!-e $prefilename)
1298       {
1299         warn("No previous schema file found ($prefilename)");
1300         next;
1301       }
1302       #### We need to reparse the SQLite file we just wrote, so that
1303       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1304       ##   FIXME: rip Diff to pieces!
1305 #      my $target_schema = $sqlt->schema;
1306 #      unless ( $target_schema->name ) {
1307 #        $target_schema->name( $filename );
1308 #      }
1309       my @input;
1310       push @input, {file => $prefilename, parser => $db};
1311       push @input, {file => $filename, parser => $db};
1312       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1313         my $file   = $_->{'file'};
1314         my $parser = $_->{'parser'};
1315
1316         my $t = SQL::Translator->new;
1317         $t->debug( 0 );
1318         $t->trace( 0 );
1319         $t->parser( $parser )            or die $t->error;
1320         my $out = $t->translate( $file ) or die $t->error;
1321         my $schema = $t->schema;
1322         unless ( $schema->name ) {
1323           $schema->name( $file );
1324         }
1325         ($schema, $parser);
1326       } @input;
1327
1328       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1329                                                     $target_schema, $db,
1330                                                     {}
1331                                                    );
1332       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1333       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1334       if(-e $difffile)
1335       {
1336         warn("$difffile already exists, skipping");
1337         next;
1338       }
1339       if(!open $file, ">$difffile")
1340       {
1341         $self->throw_exception("Can't write to $difffile ($!)");
1342         next;
1343       }
1344       print $file $diff;
1345       close($file);
1346     }
1347   }
1348 }
1349
1350 sub configure_sqlt() {
1351   my $self = shift;
1352   my $tr = shift;
1353   my $db = shift || $self->sqlt_type;
1354   if ($db eq 'PostgreSQL') {
1355     $tr->quote_table_names(0);
1356     $tr->quote_field_names(0);
1357   }
1358   return $tr;
1359 }
1360
1361 =head2 deployment_statements
1362
1363 =over 4
1364
1365 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1366
1367 =back
1368
1369 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1370 The database driver name is given by C<$type>, though the value from
1371 L</sqlt_type> is used if it is not specified.
1372
1373 C<$directory> is used to return statements from files in a previously created
1374 L</create_ddl_dir> directory and is optional. The filenames are constructed
1375 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1376
1377 If no C<$directory> is specified then the statements are constructed on the
1378 fly using L<SQL::Translator> and C<$version> is ignored.
1379
1380 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1381
1382 =cut
1383
1384 sub deployment_statements {
1385   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1386   # Need to be connected to get the correct sqlt_type
1387   $self->ensure_connected() unless $type;
1388   $type ||= $self->sqlt_type;
1389   $version ||= $schema->VERSION || '1.x';
1390   $dir ||= './';
1391   my $filename = $schema->ddl_filename($type, $dir, $version);
1392   if(-f $filename)
1393   {
1394       my $file;
1395       open($file, "<$filename")
1396         or $self->throw_exception("Can't open $filename ($!)");
1397       my @rows = <$file>;
1398       close($file);
1399       return join('', @rows);
1400   }
1401
1402   eval "use SQL::Translator";
1403   if(!$@)
1404   {
1405     eval "use SQL::Translator::Parser::DBIx::Class;";
1406     $self->throw_exception($@) if $@;
1407     eval "use SQL::Translator::Producer::${type};";
1408     $self->throw_exception($@) if $@;
1409
1410     # sources needs to be a parser arg, but for simplicty allow at top level
1411     # coming in
1412     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1413         if exists $sqltargs->{sources};
1414
1415     my $tr = SQL::Translator->new(%$sqltargs);
1416     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1417     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1418   }
1419
1420   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1421   return;
1422
1423 }
1424
1425 sub deploy {
1426   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1427   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1428     for ( split(";\n", $statement)) {
1429       next if($_ =~ /^--/);
1430       next if(!$_);
1431 #      next if($_ =~ /^DROP/m);
1432       next if($_ =~ /^BEGIN TRANSACTION/m);
1433       next if($_ =~ /^COMMIT/m);
1434       next if $_ =~ /^\s+$/; # skip whitespace only
1435       $self->debugobj->query_start($_) if $self->debug;
1436       $self->dbh->do($_) or warn $self->dbh->errstr, "\nSQL was:\n $_"; # XXX throw_exception?
1437       $self->debugobj->query_end($_) if $self->debug;
1438     }
1439   }
1440 }
1441
1442 =head2 datetime_parser
1443
1444 Returns the datetime parser class
1445
1446 =cut
1447
1448 sub datetime_parser {
1449   my $self = shift;
1450   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1451 }
1452
1453 =head2 datetime_parser_type
1454
1455 Defines (returns) the datetime parser class - currently hardwired to
1456 L<DateTime::Format::MySQL>
1457
1458 =cut
1459
1460 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1461
1462 =head2 build_datetime_parser
1463
1464 See L</datetime_parser>
1465
1466 =cut
1467
1468 sub build_datetime_parser {
1469   my $self = shift;
1470   my $type = $self->datetime_parser_type(@_);
1471   eval "use ${type}";
1472   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1473   return $type;
1474 }
1475
1476 sub DESTROY {
1477   my $self = shift;
1478   return if !$self->_dbh;
1479   $self->_verify_pid;
1480   $self->_dbh(undef);
1481 }
1482
1483 1;
1484
1485 =head1 SQL METHODS
1486
1487 The module defines a set of methods within the DBIC::SQL::Abstract
1488 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1489 SQL query functions.
1490
1491 The following methods are extended:-
1492
1493 =over 4
1494
1495 =item delete
1496
1497 =item insert
1498
1499 =item select
1500
1501 =item update
1502
1503 =item limit_dialect
1504
1505 See L</connect_info> for details.
1506 For setting, this method is deprecated in favor of L</connect_info>.
1507
1508 =item quote_char
1509
1510 See L</connect_info> for details.
1511 For setting, this method is deprecated in favor of L</connect_info>.
1512
1513 =item name_sep
1514
1515 See L</connect_info> for details.
1516 For setting, this method is deprecated in favor of L</connect_info>.
1517
1518 =back
1519
1520 =head1 AUTHORS
1521
1522 Matt S. Trout <mst@shadowcatsystems.co.uk>
1523
1524 Andy Grundman <andy@hybridized.org>
1525
1526 =head1 LICENSE
1527
1528 You may distribute this code under the same terms as Perl itself.
1529
1530 =cut