lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   $self->SUPER::select($table, $self->_recurse_fields($fields),
  21                          $where, $order, @rest);
  22 }
  23
  24 sub _emulate_limit {
  25   my $self = shift;
  26   if ($_[3] == -1) {
  27     return $_[1].$self->_order_by($_[2]);
  28   } else {
  29     return $self->SUPER::_emulate_limit(@_);
  30   }
  31 }
  32
  33 sub _recurse_fields {
  34   my ($self, $fields) = @_;
  35   my $ref = ref $fields;
  36   return $self->_quote($fields) unless $ref;
  37   return $$fields if $ref eq 'SCALAR';
  38
  39   if ($ref eq 'ARRAY') {
  40     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  41   } elsif ($ref eq 'HASH') {
  42     foreach my $func (keys %$fields) {
  43       return $self->_sqlcase($func)
  44         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  45     }
  46   }
  47 }
  48
  49 sub _order_by {
  50   my $self = shift;
  51   my $ret = '';
  52   if (ref $_[0] eq 'HASH') {
  53     if (defined $_[0]->{group_by}) {
  54       $ret = $self->_sqlcase(' group by ')
  55                .$self->_recurse_fields($_[0]->{group_by});
  56     }
  57     if (defined $_[0]->{order_by}) {
  58       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  59     }
  60   } else {
  61     $ret = $self->SUPER::_order_by(@_);
  62   }
  63   return $ret;
  64 }
  65
  66 sub _table {
  67   my ($self, $from) = @_;
  68   if (ref $from eq 'ARRAY') {
  69     return $self->_recurse_from(@$from);
  70   } elsif (ref $from eq 'HASH') {
  71     return $self->_make_as($from);
  72   } else {
  73     return $from;
  74   }
  75 }
  76
  77 sub _recurse_from {
  78   my ($self, $from, @join) = @_;
  79   my @sqlf;
  80   push(@sqlf, $self->_make_as($from));
  81   foreach my $j (@join) {
  82     my ($to, $on) = @$j;
  83
  84     # check whether a join type exists
  85     my $join_clause = '';
  86     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  87       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  88     } else {
  89       $join_clause = ' JOIN ';
  90     }
  91     push(@sqlf, $join_clause);
  92
  93     if (ref $to eq 'ARRAY') {
  94       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  95     } else {
  96       push(@sqlf, $self->_make_as($to));
  97     }
  98     push(@sqlf, ' ON ', $self->_join_condition($on));
  99   }
 100   return join('', @sqlf);
 101 }
 102
 103 sub _make_as {
 104   my ($self, $from) = @_;
 105   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 106                            reverse each %{$self->_skip_options($from)});
 107 }
 108
 109 sub _skip_options {
 110   my ($self, $hash) = @_;
 111   my $clean_hash = {};
 112   $clean_hash->{$_} = $hash->{$_}
 113     for grep {!/^-/} keys %$hash;
 114   return $clean_hash;
 115 }
 116
 117 sub _join_condition {
 118   my ($self, $cond) = @_;
 119   if (ref $cond eq 'HASH') {
 120     my %j;
 121     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 122     return $self->_recurse_where(\%j);
 123   } elsif (ref $cond eq 'ARRAY') {
 124     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 125   } else {
 126     die "Can't handle this yet!";
 127   }
 128 }
 129
 130 sub _quote {
 131   my ($self, $label) = @_;
 132   return '' unless defined $label;
 133   return $self->SUPER::_quote($label);
 134 }
 135
 136 # Accessor for setting limit dialect. This is useful
 137 # for JDBC-bridge among others where the remote SQL-dialect cannot
 138 # be determined by the name of the driver alone.
 139 #
 140 sub limit_dialect {
 141     my $self = shift;
 142     $self->{limit_dialect} = shift if @_;
 143     return $self->{limit_dialect};
 144 }
 145
 146 } # End of BEGIN block
 147
 148 use base qw/DBIx::Class/;
 149
 150 __PACKAGE__->load_components(qw/AccessorGroup/);
 151
 152 __PACKAGE__->mk_group_accessors('simple' =>
 153   qw/connect_info _dbh _sql_maker debug debugfh cursor on_connect_do transaction_depth/);
 154
 155 sub new {
 156   my $new = bless({}, ref $_[0] || $_[0]);
 157   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 158   $new->transaction_depth(0);
 159   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 160      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 161     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 162   } else {
 163     $new->debugfh(IO::File->new('>&STDERR'));
 164   }
 165   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 166   return $new;
 167 }
 168
 169 =head1 NAME
 170
 171 DBIx::Class::Storage::DBI - DBI storage handler
 172
 173 =head1 SYNOPSIS
 174
 175 =head1 DESCRIPTION
 176
 177 This class represents the connection to the database
 178
 179 =head1 METHODS
 180
 181 =cut
 182
 183 =head2 on_connect_do
 184
 185 Executes the sql statements given as a listref on every db connect.
 186
 187 =head2 debug
 188
 189 Causes SQL trace information to be emitted on C<debugfh> filehandle
 190 (or C<STDERR> if C<debugfh> has not specifically been set).
 191
 192 =head2 debugfh
 193
 194 Sets or retrieves the filehandle used for trace/debug output.  This
 195 should be an IO::Handle compatible object (only the C<print> method is
 196 used).  Initially set to be STDERR - although see information on the
 197 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 198
 199 =cut
 200
 201 sub disconnect {
 202   my ($self) = @_;
 203
 204   $self->_dbh->disconnect if $self->_dbh;
 205 }
 206
 207 sub connected {
 208   my ($self) = @_;
 209
 210   my $dbh;
 211   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 212 }
 213
 214 sub ensure_connected {
 215   my ($self) = @_;
 216
 217   unless ($self->connected) {
 218     $self->_populate_dbh;
 219   }
 220 }
 221
 222 sub dbh {
 223   my ($self) = @_;
 224
 225   $self->ensure_connected;
 226   return $self->_dbh;
 227 }
 228
 229 sub sql_maker {
 230   my ($self) = @_;
 231   unless ($self->_sql_maker) {
 232     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 233   }
 234   return $self->_sql_maker;
 235 }
 236
 237 sub _populate_dbh {
 238   my ($self) = @_;
 239   my @info = @{$self->connect_info || []};
 240   $self->_dbh($self->_connect(@info));
 241
 242   # if on-connect sql statements are given execute them
 243   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 244     $self->_dbh->do($sql_statement);
 245   }
 246 }
 247
 248 sub _connect {
 249   my ($self, @info) = @_;
 250   return DBI->connect(@info);
 251 }
 252
 253 =head2 txn_begin
 254
 255 Calls begin_work on the current dbh.
 256
 257 =cut
 258
 259 sub txn_begin {
 260   my $self = shift;
 261   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 262 }
 263
 264 =head2 txn_commit
 265
 266 Issues a commit against the current dbh.
 267
 268 =cut
 269
 270 sub txn_commit {
 271   my $self = shift;
 272   if ($self->{transaction_depth} == 0) {
 273     $self->dbh->commit unless $self->dbh->{AutoCommit};
 274   }
 275   else {
 276     $self->dbh->commit if --$self->{transaction_depth} == 0;
 277   }
 278 }
 279
 280 =head2 txn_rollback
 281
 282 Issues a rollback against the current dbh.
 283
 284 =cut
 285
 286 sub txn_rollback {
 287   my $self = shift;
 288   if ($self->{transaction_depth} == 0) {
 289     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 290   }
 291   else {
 292     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 293   }
 294 }
 295
 296 sub _execute {
 297   my ($self, $op, $extra_bind, $ident, @args) = @_;
 298   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 299   unshift(@bind, @$extra_bind) if $extra_bind;
 300   $self->debugfh->print("$sql: @bind\n") if $self->debug;
 301   my $sth = $self->sth($sql,$op);
 302   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 303   my $rv;
 304   if ($sth) {
 305     $rv = $sth->execute(@bind);
 306   } else {
 307     croak "'$sql' did not generate a statement.";
 308   }
 309   return (wantarray ? ($rv, $sth, @bind) : $rv);
 310 }
 311
 312 sub insert {
 313   my ($self, $ident, $to_insert) = @_;
 314   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 315     unless ($self->_execute('insert' => [], $ident, $to_insert));
 316   return $to_insert;
 317 }
 318
 319 sub update {
 320   return shift->_execute('update' => [], @_);
 321 }
 322
 323 sub delete {
 324   return shift->_execute('delete' => [], @_);
 325 }
 326
 327 sub _select {
 328   my ($self, $ident, $select, $condition, $attrs) = @_;
 329   my $order = $attrs->{order_by};
 330   if (ref $condition eq 'SCALAR') {
 331     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 332   }
 333   if (exists $attrs->{group_by}) {
 334     $order = { group_by => $attrs->{group_by},
 335                ($order ? (order_by => $order) : ()) };
 336   }
 337   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 338   if ($attrs->{software_limit} ||
 339       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 340         $attrs->{software_limit} = 1;
 341   } else {
 342     push @args, $attrs->{rows}, $attrs->{offset};
 343   }
 344   return $self->_execute(@args);
 345 }
 346
 347 sub select {
 348   my $self = shift;
 349   my ($ident, $select, $condition, $attrs) = @_;
 350   return $self->cursor->new($self, \@_, $attrs);
 351 }
 352
 353 # Need to call finish() to work round broken DBDs
 354
 355 sub select_single {
 356   my $self = shift;
 357   my ($rv, $sth, @bind) = $self->_select(@_);
 358   my @row = $sth->fetchrow_array;
 359   $sth->finish();
 360   return @row;
 361 }
 362
 363 sub sth {
 364   my ($self, $sql) = @_;
 365   # 3 is the if_active parameter which avoids active sth re-use
 366   return $self->dbh->prepare_cached($sql, {}, 3);
 367 }
 368
 369 =head2 columns_info_for
 370
 371 Returns database type info for a given table columns.
 372
 373 =cut
 374
 375 sub columns_info_for {
 376     my ($self, $table) = @_;
 377     my %result;
 378     if ( $self->dbh->can( 'column_info' ) ){
 379         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 380         $sth->execute();
 381         while ( my $info = $sth->fetchrow_hashref() ){
 382             my %column_info;
 383             $column_info{data_type} = $info->{TYPE_NAME};
 384             $column_info{size} = $info->{COLUMN_SIZE};
 385             $column_info{is_nullable} = $info->{NULLABLE};
 386             $result{$info->{COLUMN_NAME}} = \%column_info;
 387         }
 388     }else{
 389         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 390         $sth->execute;
 391         my @columns = @{$sth->{NAME}};
 392         for my $i ( 0 .. $#columns ){
 393             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 394         }
 395     }
 396     return \%result;
 397 }
 398
 399 1;
 400
 401 =head1 ENVIRONMENT VARIABLES
 402
 403 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 404
 405 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 406 is produced (as when the L<debug> method is set).
 407
 408 If the value is of the form C<1=/path/name> then the trace output is
 409 written to the file C</path/name>.
 410
 411 =head1 AUTHORS
 412
 413 Matt S. Trout <mst@shadowcatsystems.co.uk>
 414
 415 Andy Grundman <andy@hybridized.org>
 416
 417 =head1 LICENSE
 418
 419 You may distribute this code under the same terms as Perl itself.
 420
 421 =cut
 422